t/db_dependent/Koha/Patron/Messages.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 12;
  23
  24 use C4::Context;
  25 use Koha::ActionLogs;
  26 use Koha::Patron::Message;
  27 use Koha::Patron::Messages;
  28 use Koha::Patrons;
  29 use Koha::Database;
  30
  31 use t::lib::Mocks;
  32 use t::lib::TestBuilder;
  33
  34 my $schema = Koha::Database->new->schema;
  35 $schema->storage->txn_begin;
  36
  37 my $builder        = t::lib::TestBuilder->new;
  38 my $library        = $builder->build( { source => 'Branch' } );
  39 my $patron         = $builder->build( { source => 'Borrower', value => { branchcode => $library->{branchcode} } } );
  40 my $patron_2       = $builder->build( { source => 'Borrower' } );
  41 my $patron_3       = $builder->build( { source => 'Borrower' } );
  42 my $nb_of_logaction = get_nb_of_logactions();
  43 my $nb_of_messages = Koha::Patron::Messages->search->count;
  44
  45 t::lib::Mocks::mock_preference('BorrowersLog', 0);
  46 my $new_message_1  = Koha::Patron::Message->new(
  47     {   borrowernumber => $patron->{borrowernumber},
  48         branchcode     => $library->{branchcode},
  49         message_type   => 'L',
  50         message        => 'my message 1',
  51     }
  52 )->store;
  53 is( get_nb_of_logactions(), $nb_of_logaction, 'With BorrowersLog off, no new log should have been added' );
  54
  55 my $context = new Test::MockModule('C4::Context');
  56 $context->mock( 'userenv', sub {
  57     return {
  58         number => $patron_2->{borrowernumber},
  59     };
  60 });
  61
  62 t::lib::Mocks::mock_preference('BorrowersLog', 1);
  63 my $new_message_2  = Koha::Patron::Message->new(
  64     {   borrowernumber => $patron->{borrowernumber},
  65         branchcode     => $library->{branchcode},
  66         message_type   => 'B',
  67         message        => 'my message 2',
  68     }
  69 )->store;
  70
  71 my $new_message_3  = Koha::Patron::Message->new(
  72     {   borrowernumber => $patron->{borrowernumber},
  73         branchcode     => $library->{branchcode},
  74         message_type   => 'B',
  75         message        => 'my message 2',
  76         manager_id     => $patron_3->{borrowernumber},
  77     }
  78 )->store;
  79 is( get_nb_of_logactions(), $nb_of_logaction + 2, 'With BorrowersLog on, 2 new log should have been added when adding a new message' );
  80
  81 like( $new_message_1->message_id, qr|^\d+$|, 'Adding a new message should have set the message_id');
  82 is( Koha::Patron::Messages->search->count, $nb_of_messages + 3, 'The 3 messages should have been added' );
  83
  84 my $retrieved_message_1 = Koha::Patron::Messages->find( $new_message_1->message_id );
  85 is( $retrieved_message_1->message, $new_message_1->message, 'Find a message by id should return the correct message' );
  86 is( $retrieved_message_1->manager_id, undef, 'Manager id should not be filled in when it is not defined in userenv' );
  87 my $retrieved_message_2 = Koha::Patron::Messages->find( $new_message_2->message_id );
  88 is( $retrieved_message_2->manager_id, $patron_2->{borrowernumber}, 'Manager id should be filled in when it is defined in userenv' );
  89 my $retrieved_message_3 = Koha::Patron::Messages->find( $new_message_3->message_id );
  90 is( $retrieved_message_3->manager_id, $patron_3->{borrowernumber}, 'Manager id should be overwrite-able even if defined in userenv' );
  91
  92 t::lib::Mocks::mock_preference('BorrowersLog', 0);
  93 $retrieved_message_1->delete;
  94 is( Koha::Patron::Messages->search->count, $nb_of_messages + 2, 'Delete should have deleted the message 1' );
  95 is( get_nb_of_logactions(), $nb_of_logaction + 2, 'With BorrowersLog off, no new log should have been added when deleting a new message' );
  96
  97 t::lib::Mocks::mock_preference('BorrowersLog', 1);
  98 $new_message_2->delete;
  99 is( Koha::Patron::Messages->search->count, $nb_of_messages + 1, 'Delete should have deleted the message 2' );
 100 is( get_nb_of_logactions(), $nb_of_logaction + 3, 'With BorrowersLog on, 1 new log should have been added when deleting a new message' );
 101
 102 $schema->storage->txn_rollback;
 103
 104 sub get_nb_of_logactions {
 105     return Koha::ActionLogs->search({ module => 'MEMBERS' })->count;
 106 }
 107