t/db_dependent/Items.t

   1 #!/usr/bin/perl
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  17 #
  18
  19 use Modern::Perl;
  20 use Data::Dumper;
  21
  22 use MARC::Record;
  23 use C4::Items;
  24 use C4::Biblio;
  25 use Koha::Items;
  26 use Koha::Database;
  27 use Koha::DateUtils qw( dt_from_string );
  28 use Koha::Library;
  29 use Koha::DateUtils;
  30 use Koha::MarcSubfieldStructures;
  31 use Koha::Caches;
  32 use Koha::AuthorisedValues;
  33
  34 use t::lib::Mocks;
  35 use t::lib::TestBuilder;
  36
  37 use Test::More tests => 15;
  38
  39 use Test::Warn;
  40
  41 my $schema = Koha::Database->new->schema;
  42 my $location = 'My Location';
  43
  44 subtest 'General Add, Get and Del tests' => sub {
  45
  46     plan tests => 16;
  47
  48     $schema->storage->txn_begin;
  49
  50     my $builder = t::lib::TestBuilder->new;
  51     my $library = $builder->build({
  52         source => 'Branch',
  53     });
  54     my $itemtype = $builder->build({
  55         source => 'Itemtype',
  56     });
  57
  58     # Create a biblio instance for testing
  59     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
  60     my $biblio = $builder->build_sample_biblio();
  61
  62     # Add an item.
  63     my ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, itype => $itemtype->{itemtype} } , $biblio->biblionumber);
  64     cmp_ok($item_bibnum, '==', $biblio->biblionumber, "New item is linked to correct biblionumber.");
  65     cmp_ok($item_bibitemnum, '==', $biblio->biblioitem->biblioitemnumber, "New item is linked to correct biblioitemnumber.");
  66
  67     # Get item.
  68     my $getitem = Koha::Items->find($itemnumber);
  69     cmp_ok($getitem->itemnumber, '==', $itemnumber, "Retrieved item has correct itemnumber.");
  70     cmp_ok($getitem->biblioitemnumber, '==', $item_bibitemnum, "Retrieved item has correct biblioitemnumber.");
  71     is( $getitem->location, $location, "The location should not have been modified" );
  72     is( $getitem->permanent_location, $location, "The permanent_location should have been set to the location value" );
  73
  74
  75     # Do not modify anything, and do not explode!
  76     my $dbh = C4::Context->dbh;
  77     local $dbh->{RaiseError} = 1;
  78     ModItem({}, $biblio->biblionumber, $itemnumber);
  79
  80     # Modify item; setting barcode.
  81     ModItem({ barcode => '987654321' }, $biblio->biblionumber, $itemnumber);
  82     my $moditem = Koha::Items->find($itemnumber);
  83     cmp_ok($moditem->barcode, '==', '987654321', 'Modified item barcode successfully to: '.$moditem->barcode . '.');
  84
  85     # Delete item.
  86     DelItem({ biblionumber => $biblio->biblionumber, itemnumber => $itemnumber });
  87     my $getdeleted = Koha::Items->find($itemnumber);
  88     is($getdeleted, undef, "Item deleted as expected.");
  89
  90     ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, permanent_location => 'my permanent location', itype => $itemtype->{itemtype} } , $biblio->biblionumber);
  91     $getitem = Koha::Items->find($itemnumber);
  92     is( $getitem->location, $location, "The location should not have been modified" );
  93     is( $getitem->permanent_location, 'my permanent location', "The permanent_location should not have modified" );
  94
  95     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber);
  96     $getitem = Koha::Items->find($itemnumber);
  97     is( $getitem->location, $location, "The location should have been set to correct location" );
  98     is( $getitem->permanent_location, $location, "The permanent_location should have been set to location" );
  99
 100     ModItem({ location => 'CART' }, $biblio->biblionumber, $itemnumber);
 101     $getitem = Koha::Items->find($itemnumber);
 102     is( $getitem->location, 'CART', "The location should have been set to CART" );
 103     is( $getitem->permanent_location, $location, "The permanent_location should not have been set to CART" );
 104
 105     t::lib::Mocks::mock_preference('item-level_itypes', '1');
 106     $getitem = Koha::Items->find($itemnumber);
 107     is( $getitem->effective_itemtype, $itemtype->{itemtype}, "Itemtype set correctly when using item-level_itypes" );
 108     t::lib::Mocks::mock_preference('item-level_itypes', '0');
 109     $getitem = Koha::Items->find($itemnumber);
 110     is( $getitem->effective_itemtype, $biblio->biblioitem->itemtype, "Itemtype set correctly when not using item-level_itypes" );
 111
 112     $schema->storage->txn_rollback;
 113 };
 114
 115 subtest 'ModItem tests' => sub {
 116     plan tests => 6;
 117
 118     $schema->storage->txn_begin;
 119
 120     my $builder = t::lib::TestBuilder->new;
 121     my $item = $builder->build({
 122         source => 'Item',
 123         value  => {
 124             itemlost     => 0,
 125             damaged      => 0,
 126             withdrawn    => 0,
 127             itemlost_on  => undef,
 128             damaged_on   => undef,
 129             withdrawn_on => undef,
 130         }
 131     });
 132
 133     my @fields = qw( itemlost withdrawn damaged );
 134     for my $field (@fields) {
 135         $item->{$field} = 1;
 136         ModItem( $item, $item->{biblionumber}, $item->{itemnumber} );
 137         my $post_mod_item = Koha::Items->find({ itemnumber => $item->{itemnumber} })->unblessed;
 138         is( output_pref({ str => $post_mod_item->{$field."_on"}, dateonly => 1 }), output_pref({ dt => dt_from_string(), dateonly => 1 }), "When updating $field, $field"."_on is updated" );
 139
 140         $item->{$field} = 0;
 141         ModItem( $item, $item->{biblionumber}, $item->{itemnumber} );
 142         $post_mod_item = Koha::Items->find({ itemnumber => $item->{itemnumber} })->unblessed;
 143         is( $post_mod_item->{$field."_on"}, undef, "When clearing $field, $field"."_on is cleared" );
 144     }
 145
 146     $schema->storage->txn_rollback;
 147
 148 };
 149
 150 subtest 'GetHiddenItemnumbers tests' => sub {
 151
 152     plan tests => 11;
 153
 154     # This sub is controlled by the OpacHiddenItems system preference.
 155
 156     $schema->storage->txn_begin;
 157
 158     my $builder = t::lib::TestBuilder->new;
 159     my $library1 = $builder->build({
 160         source => 'Branch',
 161     });
 162
 163     my $library2 = $builder->build({
 164         source => 'Branch',
 165     });
 166     my $itemtype = $builder->build({
 167         source => 'Itemtype',
 168     });
 169
 170     # Create a new biblio
 171     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 172     my $biblio = $builder->build_sample_biblio();
 173
 174     # Add two items
 175     my ( $item1_bibnum, $item1_bibitemnum, $item1_itemnumber ) = AddItem(
 176         {
 177             homebranch    => $library1->{branchcode},
 178             holdingbranch => $library1->{branchcode},
 179             withdrawn     => 1,
 180             itype         => $itemtype->{itemtype},
 181         },
 182         $biblio->biblionumber
 183     );
 184     my ( $item2_bibnum, $item2_bibitemnum, $item2_itemnumber ) = AddItem(
 185         {
 186             homebranch    => $library2->{branchcode},
 187             holdingbranch => $library2->{branchcode},
 188             withdrawn     => 0,
 189             itype         => $itemtype->{itemtype},
 190         },
 191         $biblio->biblionumber
 192     );
 193
 194     my $opachiddenitems;
 195     my @itemnumbers = ($item1_itemnumber,$item2_itemnumber);
 196     my @hidden;
 197     my @items;
 198     push @items, Koha::Items->find( $item1_itemnumber )->unblessed;
 199     push @items, Koha::Items->find( $item2_itemnumber )->unblessed;
 200
 201     # Empty OpacHiddenItems
 202     t::lib::Mocks::mock_preference('OpacHiddenItems','');
 203     ok( !defined( GetHiddenItemnumbers( { items => \@items } ) ),
 204         "Hidden items list undef if OpacHiddenItems empty");
 205
 206     # Blank spaces
 207     t::lib::Mocks::mock_preference('OpacHiddenItems','  ');
 208     ok( scalar GetHiddenItemnumbers( { items => \@items } ) == 0,
 209         "Hidden items list empty if OpacHiddenItems only contains blanks");
 210
 211     # One variable / value
 212     $opachiddenitems = "
 213         withdrawn: [1]";
 214     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 215     @hidden = GetHiddenItemnumbers( { items => \@items } );
 216     ok( scalar @hidden == 1, "Only one hidden item");
 217     is( $hidden[0], $item1_itemnumber, "withdrawn=1 is hidden");
 218
 219     # One variable, two values
 220     $opachiddenitems = "
 221         withdrawn: [1,0]";
 222     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 223     @hidden = GetHiddenItemnumbers( { items => \@items } );
 224     ok( scalar @hidden == 2, "Two items hidden");
 225     is_deeply( \@hidden, \@itemnumbers, "withdrawn=1 and withdrawn=0 hidden");
 226
 227     # Two variables, a value each
 228     $opachiddenitems = "
 229         withdrawn: [1]
 230         homebranch: [$library2->{branchcode}]
 231     ";
 232     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 233     @hidden = GetHiddenItemnumbers( { items => \@items } );
 234     ok( scalar @hidden == 2, "Two items hidden");
 235     is_deeply( \@hidden, \@itemnumbers, "withdrawn=1 and homebranch library2 hidden");
 236
 237     # Override hidden with patron category
 238     t::lib::Mocks::mock_preference( 'OpacHiddenItemsExceptions', 'S' );
 239     @hidden = GetHiddenItemnumbers( { items => \@items, borcat => 'PT' } );
 240     ok( scalar @hidden == 2, "Two items still hidden");
 241     @hidden = GetHiddenItemnumbers( { items => \@items, borcat => 'S' } );
 242     ok( scalar @hidden == 0, "Two items not hidden");
 243
 244     # Valid OpacHiddenItems, empty list
 245     @items = ();
 246     @hidden = GetHiddenItemnumbers( { items => \@items } );
 247     ok( scalar @hidden == 0, "Empty items list, no item hidden");
 248
 249     $schema->storage->txn_rollback;
 250 };
 251
 252 subtest 'GetItemsInfo tests' => sub {
 253
 254     plan tests => 7;
 255
 256     $schema->storage->txn_begin;
 257
 258     my $builder = t::lib::TestBuilder->new;
 259     my $library1 = $builder->build({
 260         source => 'Branch',
 261     });
 262     my $library2 = $builder->build({
 263         source => 'Branch',
 264     });
 265     my $itemtype = $builder->build({
 266         source => 'Itemtype',
 267     });
 268
 269     Koha::AuthorisedValues->delete;
 270     my $av1 = Koha::AuthorisedValue->new(
 271         {
 272             category         => 'RESTRICTED',
 273             authorised_value => '1',
 274             lib              => 'Restricted Access',
 275             lib_opac         => 'Restricted Access OPAC',
 276         }
 277     )->store();
 278
 279     # Add a biblio
 280     my $biblio = $builder->build_sample_biblio();
 281     # Add an item
 282     my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
 283         {
 284             homebranch    => $library1->{branchcode},
 285             holdingbranch => $library2->{branchcode},
 286             itype         => $itemtype->{itemtype},
 287             restricted    => 1,
 288         },
 289         $biblio->biblionumber
 290     );
 291
 292     my $library = Koha::Libraries->find( $library1->{branchcode} );
 293     $library->opac_info("homebranch OPAC info");
 294     $library->store;
 295
 296     $library = Koha::Libraries->find( $library2->{branchcode} );
 297     $library->opac_info("holdingbranch OPAC info");
 298     $library->store;
 299
 300     my @results = GetItemsInfo( $biblio->biblionumber );
 301     ok( @results, 'GetItemsInfo returns results');
 302
 303     is( $results[0]->{ home_branch_opac_info }, "homebranch OPAC info",
 304         'GetItemsInfo returns the correct home branch OPAC info notice' );
 305     is( $results[0]->{ holding_branch_opac_info }, "holdingbranch OPAC info",
 306         'GetItemsInfo returns the correct holding branch OPAC info notice' );
 307     is( exists( $results[0]->{ onsite_checkout } ), 1,
 308         'GetItemsInfo returns a onsite_checkout key' );
 309     is( $results[0]->{ restricted }, 1,
 310         'GetItemsInfo returns a restricted value code' );
 311     is( $results[0]->{ restrictedvalue }, "Restricted Access",
 312         'GetItemsInfo returns a restricted value description (staff)' );
 313     is( $results[0]->{ restrictedvalueopac }, "Restricted Access OPAC",
 314         'GetItemsInfo returns a restricted value description (OPAC)' );
 315
 316     $schema->storage->txn_rollback;
 317 };
 318
 319 subtest q{Test Koha::Database->schema()->resultset('Item')->itemtype()} => sub {
 320
 321     plan tests => 4;
 322
 323     $schema->storage->txn_begin;
 324
 325     my $biblio = $schema->resultset('Biblio')->create({
 326         title       => "Test title",
 327         datecreated => dt_from_string,
 328         biblioitems => [ { itemtype => 'BIB_LEVEL' } ],
 329     });
 330     my $biblioitem = $biblio->biblioitems->first;
 331     my $item = $schema->resultset('Item')->create({
 332         biblioitemnumber => $biblioitem->biblioitemnumber,
 333         biblionumber     => $biblio->biblionumber,
 334         itype            => "ITEM_LEVEL",
 335     });
 336
 337     t::lib::Mocks::mock_preference( 'item-level_itypes', 0 );
 338     is( $item->effective_itemtype(), 'BIB_LEVEL', '$item->itemtype() returns biblioitem.itemtype when item-level_itypes is disabled' );
 339
 340     t::lib::Mocks::mock_preference( 'item-level_itypes', 1 );
 341     is( $item->effective_itemtype(), 'ITEM_LEVEL', '$item->itemtype() returns items.itype when item-level_itypes is enabled' );
 342
 343     # If itemtype is not defined and item-level_level item types are set
 344     # fallback to biblio-level itemtype (Bug 14651) and warn
 345     $item->itype( undef );
 346     $item->update();
 347     my $effective_itemtype;
 348     warning_is { $effective_itemtype = $item->effective_itemtype() }
 349                 "item-level_itypes set but no itemtype set for item (".$item->itemnumber.")",
 350                 '->effective_itemtype() raises a warning when falling back to bib-level';
 351
 352     ok( defined $effective_itemtype &&
 353                 $effective_itemtype eq 'BIB_LEVEL',
 354         '$item->effective_itemtype() falls back to biblioitems.itemtype when item-level_itypes is enabled but undef' );
 355
 356     $schema->storage->txn_rollback;
 357 };
 358
 359 subtest 'SearchItems test' => sub {
 360     plan tests => 14;
 361
 362     $schema->storage->txn_begin;
 363     my $dbh = C4::Context->dbh;
 364     my $builder = t::lib::TestBuilder->new;
 365
 366     my $library1 = $builder->build({
 367         source => 'Branch',
 368     });
 369     my $library2 = $builder->build({
 370         source => 'Branch',
 371     });
 372     my $itemtype = $builder->build({
 373         source => 'Itemtype',
 374     });
 375
 376     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 377     my $cpl_items_before = SearchItemsByField( 'homebranch', $library1->{branchcode});
 378
 379     my $biblio = $builder->build_sample_biblio({ title => 'Silence in the library' });
 380     $builder->build_sample_biblio({ title => 'Silence in the shadow' });
 381
 382     my (undef, $initial_items_count) = SearchItems(undef, {rows => 1});
 383
 384     # Add two items
 385     my (undef, undef, $item1_itemnumber) = AddItem({
 386         homebranch => $library1->{branchcode},
 387         holdingbranch => $library1->{branchcode},
 388         itype => $itemtype->{itemtype},
 389     }, $biblio->biblionumber);
 390     my (undef, undef, $item2_itemnumber) = AddItem({
 391         homebranch => $library2->{branchcode},
 392         holdingbranch => $library2->{branchcode},
 393         itype => $itemtype->{itemtype},
 394     }, $biblio->biblionumber);
 395
 396     my ($items, $total_results);
 397
 398     ($items, $total_results) = SearchItems();
 399     is($total_results, $initial_items_count + 2, "Created 2 new items");
 400     is(scalar @$items, $total_results, "SearchItems() returns all items");
 401
 402     ($items, $total_results) = SearchItems(undef, {rows => 1});
 403     is($total_results, $initial_items_count + 2);
 404     is(scalar @$items, 1, "SearchItems(undef, {rows => 1}) returns only 1 item");
 405
 406     # Search all items where homebranch = 'CPL'
 407     my $filter = {
 408         field => 'homebranch',
 409         query => $library1->{branchcode},
 410         operator => '=',
 411     };
 412     ($items, $total_results) = SearchItems($filter);
 413     ok($total_results > 0, "There is at least one CPL item");
 414     my $all_items_are_CPL = 1;
 415     foreach my $item (@$items) {
 416         if ($item->{homebranch} ne $library1->{branchcode}) {
 417             $all_items_are_CPL = 0;
 418             last;
 419         }
 420     }
 421     ok($all_items_are_CPL, "All items returned by SearchItems are from CPL");
 422
 423     # Search all items where homebranch != 'CPL'
 424     $filter = {
 425         field => 'homebranch',
 426         query => $library1->{branchcode},
 427         operator => '!=',
 428     };
 429     ($items, $total_results) = SearchItems($filter);
 430     ok($total_results > 0, "There is at least one non-CPL item");
 431     my $all_items_are_not_CPL = 1;
 432     foreach my $item (@$items) {
 433         if ($item->{homebranch} eq $library1->{branchcode}) {
 434             $all_items_are_not_CPL = 0;
 435             last;
 436         }
 437     }
 438     ok($all_items_are_not_CPL, "All items returned by SearchItems are not from CPL");
 439
 440     # Search all items where biblio title (245$a) is like 'Silence in the %'
 441     $filter = {
 442         field => 'marc:245$a',
 443         query => 'Silence in the %',
 444         operator => 'like',
 445     };
 446     ($items, $total_results) = SearchItems($filter);
 447     ok($total_results >= 2, "There is at least 2 items with a biblio title like 'Silence in the %'");
 448
 449     # Search all items where biblio title is 'Silence in the library'
 450     # and homebranch is 'CPL'
 451     $filter = {
 452         conjunction => 'AND',
 453         filters => [
 454             {
 455                 field => 'marc:245$a',
 456                 query => 'Silence in the %',
 457                 operator => 'like',
 458             },
 459             {
 460                 field => 'homebranch',
 461                 query => $library1->{branchcode},
 462                 operator => '=',
 463             },
 464         ],
 465     };
 466     ($items, $total_results) = SearchItems($filter);
 467     my $found = 0;
 468     foreach my $item (@$items) {
 469         if ($item->{itemnumber} == $item1_itemnumber) {
 470             $found = 1;
 471             last;
 472         }
 473     }
 474     ok($found, "item1 found");
 475
 476     my $frameworkcode = q||;
 477     my ($itemfield) = GetMarcFromKohaField('items.itemnumber', $frameworkcode);
 478
 479     # Create item subfield 'z' without link
 480     $dbh->do('DELETE FROM marc_subfield_structure WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 481     $dbh->do('INSERT INTO marc_subfield_structure (tagfield, tagsubfield, frameworkcode) VALUES (?, "z", ?)', undef, $itemfield, $frameworkcode);
 482
 483     # Clear cache
 484     my $cache = Koha::Caches->get_instance();
 485     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 486     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 487     $cache->clear_from_cache("default_value_for_mod_marc-");
 488     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 489
 490     my $item3_record = new MARC::Record;
 491     $item3_record->append_fields(
 492         new MARC::Field(
 493             $itemfield, '', '',
 494             'z' => 'foobar',
 495             'y' => $itemtype->{itemtype}
 496         )
 497     );
 498     my (undef, undef, $item3_itemnumber) = AddItemFromMarc($item3_record,
 499         $biblio->biblionumber);
 500
 501     # Search item where item subfield z is "foobar"
 502     $filter = {
 503         field => 'marc:' . $itemfield . '$z',
 504         query => 'foobar',
 505         operator => 'like',
 506     };
 507     ($items, $total_results) = SearchItems($filter);
 508     ok(scalar @$items == 1, 'found 1 item with $z = "foobar"');
 509
 510     # Link $z to items.itemnotes (and make sure there is no other subfields
 511     # linked to it)
 512     $dbh->do('DELETE FROM marc_subfield_structure WHERE kohafield="items.itemnotes" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 513     $dbh->do('UPDATE marc_subfield_structure SET kohafield="items.itemnotes" WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 514
 515     # Clear cache
 516     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 517     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 518     $cache->clear_from_cache("default_value_for_mod_marc-");
 519     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 520
 521     ModItemFromMarc($item3_record, $biblio->biblionumber, $item3_itemnumber);
 522
 523     # Make sure the link is used
 524     my $item3 = Koha::Items->find($item3_itemnumber);
 525     ok($item3->itemnotes eq 'foobar', 'itemnotes eq "foobar"');
 526
 527     # Do the same search again.
 528     # This time it will search in items.itemnotes
 529     ($items, $total_results) = SearchItems($filter);
 530     ok(scalar @$items == 1, 'found 1 item with itemnotes = "foobar"');
 531
 532     my $cpl_items_after = SearchItemsByField( 'homebranch', $library1->{branchcode});
 533     is( ( scalar( @$cpl_items_after ) - scalar ( @$cpl_items_before ) ), 1, 'SearchItemsByField should return something' );
 534
 535     $schema->storage->txn_rollback;
 536 };
 537
 538 subtest 'Koha::Item(s) tests' => sub {
 539
 540     plan tests => 5;
 541
 542     $schema->storage->txn_begin();
 543
 544     my $builder = t::lib::TestBuilder->new;
 545     my $library1 = $builder->build({
 546         source => 'Branch',
 547     });
 548     my $library2 = $builder->build({
 549         source => 'Branch',
 550     });
 551     my $itemtype = $builder->build({
 552         source => 'Itemtype',
 553     });
 554
 555     # Create a biblio and item for testing
 556     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 557     my $biblio = $builder->build_sample_biblio();
 558     my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
 559         {
 560             homebranch    => $library1->{branchcode},
 561             holdingbranch => $library2->{branchcode},
 562             itype         => $itemtype->{itemtype},
 563         },
 564         $biblio->biblionumber
 565     );
 566
 567     # Get item.
 568     my $item = Koha::Items->find( $itemnumber );
 569     is( ref($item), 'Koha::Item', "Got Koha::Item" );
 570
 571     my $homebranch = $item->home_branch();
 572     is( ref($homebranch), 'Koha::Library', "Got Koha::Library from home_branch method" );
 573     is( $homebranch->branchcode(), $library1->{branchcode}, "Home branch code matches homebranch" );
 574
 575     my $holdingbranch = $item->holding_branch();
 576     is( ref($holdingbranch), 'Koha::Library', "Got Koha::Library from holding_branch method" );
 577     is( $holdingbranch->branchcode(), $library2->{branchcode}, "Home branch code matches holdingbranch" );
 578
 579     $schema->storage->txn_rollback;
 580 };
 581
 582 subtest 'C4::Biblio::EmbedItemsInMarcBiblio' => sub {
 583     plan tests => 8;
 584
 585     $schema->storage->txn_begin();
 586
 587     my $builder = t::lib::TestBuilder->new;
 588     my $library1 = $builder->build({
 589         source => 'Branch',
 590     });
 591     my $library2 = $builder->build({
 592         source => 'Branch',
 593     });
 594     my $itemtype = $builder->build({
 595         source => 'Itemtype',
 596     });
 597
 598     my $biblio = $builder->build_sample_biblio();
 599     my $item_infos = [
 600         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 601         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 602         { homebranch => $library1->{branchcode}, holdingbranch => $library1->{branchcode} },
 603         { homebranch => $library2->{branchcode}, holdingbranch => $library2->{branchcode} },
 604         { homebranch => $library2->{branchcode}, holdingbranch => $library2->{branchcode} },
 605         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 606         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 607         { homebranch => $library1->{branchcode}, holdingbranch => $library2->{branchcode} },
 608     ];
 609     my $number_of_items = scalar @$item_infos;
 610     my $number_of_items_with_homebranch_is_CPL =
 611       grep { $_->{homebranch} eq $library1->{branchcode} } @$item_infos;
 612
 613     my @itemnumbers;
 614     for my $item_info (@$item_infos) {
 615         my ( undef, undef, $itemnumber ) = AddItem(
 616             {
 617                 homebranch    => $item_info->{homebranch},
 618                 holdingbranch => $item_info->{holdingbanch},
 619                 itype         => $itemtype->{itemtype},
 620             },
 621             $biblio->biblionumber
 622         );
 623         push @itemnumbers, $itemnumber;
 624     }
 625
 626     # Emptied the OpacHiddenItems pref
 627     t::lib::Mocks::mock_preference( 'OpacHiddenItems', '' );
 628
 629     my ($itemfield) =
 630       C4::Biblio::GetMarcFromKohaField( 'items.itemnumber', '' );
 631     my $record = C4::Biblio::GetMarcBiblio({ biblionumber => $biblio->biblionumber });
 632     warning_is { C4::Biblio::EmbedItemsInMarcBiblio() }
 633     { carped => 'EmbedItemsInMarcBiblio: No MARC record passed' },
 634       'Should carp is no record passed.';
 635
 636     C4::Biblio::EmbedItemsInMarcBiblio({
 637         marc_record  => $record,
 638         biblionumber => $biblio->biblionumber });
 639     my @items = $record->field($itemfield);
 640     is( scalar @items, $number_of_items, 'Should return all items' );
 641
 642     my $marc_with_items = C4::Biblio::GetMarcBiblio({
 643         biblionumber => $biblio->biblionumber,
 644         embed_items  => 1 });
 645     is_deeply( $record, $marc_with_items, 'A direct call to GetMarcBiblio with items matches');
 646
 647     C4::Biblio::EmbedItemsInMarcBiblio({
 648         marc_record  => $record,
 649         biblionumber => $biblio->biblionumber,
 650         item_numbers => [ $itemnumbers[1], $itemnumbers[3] ] });
 651     @items = $record->field($itemfield);
 652     is( scalar @items, 2, 'Should return all items present in the list' );
 653
 654     C4::Biblio::EmbedItemsInMarcBiblio({
 655         marc_record  => $record,
 656         biblionumber => $biblio->biblionumber,
 657         opac         => 1 });
 658     @items = $record->field($itemfield);
 659     is( scalar @items, $number_of_items, 'Should return all items for opac' );
 660
 661     my $opachiddenitems = "
 662         homebranch: ['$library1->{branchcode}']";
 663     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 664
 665     C4::Biblio::EmbedItemsInMarcBiblio({
 666         marc_record  => $record,
 667         biblionumber => $biblio->biblionumber });
 668     @items = $record->field($itemfield);
 669     is( scalar @items,
 670         $number_of_items,
 671         'Even with OpacHiddenItems set, all items should have been embedded' );
 672
 673     C4::Biblio::EmbedItemsInMarcBiblio({
 674         marc_record  => $record,
 675         biblionumber => $biblio->biblionumber,
 676         opac         => 1 });
 677     @items = $record->field($itemfield);
 678     is(
 679         scalar @items,
 680         $number_of_items - $number_of_items_with_homebranch_is_CPL,
 681 'For OPAC, the pref OpacHiddenItems should have been take into account. Only items with homebranch ne CPL should have been embedded'
 682     );
 683
 684     $opachiddenitems = "
 685         homebranch: ['$library1->{branchcode}', '$library2->{branchcode}']";
 686     t::lib::Mocks::mock_preference( 'OpacHiddenItems', $opachiddenitems );
 687     C4::Biblio::EmbedItemsInMarcBiblio({
 688         marc_record  => $record,
 689         biblionumber => $biblio->biblionumber,
 690         opac         => 1 });
 691     @items = $record->field($itemfield);
 692     is(
 693         scalar @items,
 694         0,
 695 'For OPAC, If all items are hidden, no item should have been embedded'
 696     );
 697
 698     $schema->storage->txn_rollback;
 699 };
 700
 701
 702 subtest 'C4::Items::_build_default_values_for_mod_marc' => sub {
 703     plan tests => 4;
 704
 705     $schema->storage->txn_begin();
 706
 707     my $builder = t::lib::TestBuilder->new;
 708     my $framework = $builder->build({ source => 'BiblioFramework' });
 709
 710     # Link biblio.biblionumber and biblioitems.biblioitemnumber to avoid _koha_marc_update_bib_ids to fail with 'no biblio[item]number tag for framework"
 711     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '999', tagsubfield => [ 'c', 'd' ] })->delete;
 712     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '999', tagsubfield => 'c', kohafield => 'biblio.biblionumber' })->store;
 713     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '999', tagsubfield => 'd', kohafield => 'biblioitems.biblioitemnumber' })->store;
 714
 715     # Same for item fields: itemnumber, barcode, itype
 716     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '952', tagsubfield => [ '9', 'p', 'y' ] })->delete;
 717     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => '9', kohafield => 'items.itemnumber' })->store;
 718     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => 'p', kohafield => 'items.barcode' })->store;
 719     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '952', tagsubfield => 'y', kohafield => 'items.itype' })->store;
 720     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 721
 722     my $itemtype = $builder->build({ source => 'Itemtype' })->{itemtype};
 723
 724     # Create a record with a barcode
 725     my $biblio = $builder->build_sample_biblio({ frameworkcode => $framework->{frameworkcode} });
 726     my $item_record = new MARC::Record;
 727     my $a_barcode = 'a barcode';
 728     my $barcode_field = MARC::Field->new(
 729         '952', ' ', ' ',
 730         p => $a_barcode,
 731         y => $itemtype
 732     );
 733     my $itemtype_field = MARC::Field->new(
 734         '952', ' ', ' ',
 735         y => $itemtype
 736     );
 737     $item_record->append_fields( $barcode_field );
 738     my (undef, undef, $item_itemnumber) = AddItemFromMarc($item_record, $biblio->biblionumber);
 739
 740     # Make sure everything has been set up
 741     my $item = Koha::Items->find($item_itemnumber);
 742     is( $item->barcode, $a_barcode, 'Everything has been set up correctly, the barcode is defined as expected' );
 743
 744     # Delete the barcode field and save the record
 745     $item_record->delete_fields( $barcode_field );
 746     $item_record->append_fields( $itemtype_field ); # itemtype is mandatory
 747     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 748     $item = Koha::Items->find($item_itemnumber);
 749     is( $item->barcode, undef, 'The default value should have been set to the barcode, the field is mapped to a kohafield' );
 750
 751     # Re-add the barcode field and save the record
 752     $item_record->append_fields( $barcode_field );
 753     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 754     $item = Koha::Items->find($item_itemnumber);
 755     is( $item->barcode, $a_barcode, 'Everything has been set up correctly, the barcode is defined as expected' );
 756
 757     # Remove the mapping for barcode
 758     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '952', tagsubfield => 'p' })->delete;
 759
 760     # And make sure the caches are cleared
 761     my $cache = Koha::Caches->get_instance();
 762     $cache->clear_from_cache("default_value_for_mod_marc-");
 763     $cache->clear_from_cache("MarcSubfieldStructure-");
 764
 765     # Update the MARC field with another value
 766     $item_record->delete_fields( $barcode_field );
 767     my $another_barcode = 'another_barcode';
 768     my $another_barcode_field = MARC::Field->new(
 769         '952', ' ', ' ',
 770         p => $another_barcode,
 771     );
 772     $item_record->append_fields( $another_barcode_field );
 773     # The DB value should not have been updated
 774     ModItemFromMarc($item_record, $biblio->biblionumber, $item_itemnumber);
 775     $item = Koha::Items->find($item_itemnumber);
 776     is ( $item->barcode, $a_barcode, 'items.barcode is not mapped anymore, so the DB column has not been updated' );
 777
 778     $cache->clear_from_cache("default_value_for_mod_marc-");
 779     $cache->clear_from_cache( "MarcSubfieldStructure-" );
 780     $schema->storage->txn_rollback;
 781 };
 782
 783 subtest '_mod_item_dates' => sub {
 784     plan tests => 11;
 785
 786     is( C4::Items::_mod_item_dates(), undef, 'Call without parameters' );
 787     is( C4::Items::_mod_item_dates(1), undef, 'Call without hashref' );
 788
 789     my $orgitem;
 790     my $item = {
 791         itemcallnumber  => 'V II 149 1963',
 792         barcode         => '109304',
 793     };
 794     $orgitem = { %$item };
 795     C4::Items::_mod_item_dates($item);
 796     is_deeply( $item, $orgitem, 'No dates passed to _mod_item_dates' );
 797
 798     # add two correct dates
 799     t::lib::Mocks::mock_preference('dateformat', 'us');
 800     $item->{dateaccessioned} = '01/31/2016';
 801     $item->{onloan} =  $item->{dateaccessioned};
 802     $orgitem = { %$item };
 803     C4::Items::_mod_item_dates($item);
 804     is( $item->{dateaccessioned}, '2016-01-31', 'dateaccessioned is fine' );
 805     is( $item->{onloan}, '2016-01-31', 'onloan is fine too' );
 806
 807
 808     # add some invalid dates
 809     $item->{notexistingcolumndate} = '13/1/2015'; # wrong format
 810     $item->{anotherdate} = 'tralala'; # even worse
 811     $item->{myzerodate} = '0000-00-00'; # wrong too
 812     C4::Items::_mod_item_dates($item);
 813     is( $item->{notexistingcolumndate}, undef, 'Invalid date became NULL' );
 814     is( $item->{anotherdate}, undef, 'Second invalid date became NULL too' );
 815     is( $item->{myzerodate}, undef, '0000-00-00 became NULL too' );
 816
 817     # check if itemlost_on was not touched
 818     $item->{itemlost_on} = '12345678';
 819     $item->{withdrawn_on} = '12/31/2015 23:59:00';
 820     $item->{damaged_on} = '01/20/2017 09:00:00';
 821     $orgitem = { %$item };
 822     C4::Items::_mod_item_dates($item);
 823     is_deeply( $item, $orgitem, 'Colums with _on are not touched' );
 824
 825     t::lib::Mocks::mock_preference('dateformat', 'metric');
 826     $item->{dateaccessioned} = '01/31/2016'; #wrong
 827     $item->{yetanotherdatetime} = '20/01/2016 13:58:00'; #okay
 828     C4::Items::_mod_item_dates($item);
 829     is( $item->{dateaccessioned}, undef, 'dateaccessioned wrong format' );
 830     is( $item->{yetanotherdatetime}, '2016-01-20 13:58:00',
 831         'yetanotherdatetime is ok' );
 832 };
 833
 834 subtest 'get_hostitemnumbers_of' => sub {
 835     plan tests => 3;
 836
 837     $schema->storage->txn_begin;
 838     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 839     my $builder = t::lib::TestBuilder->new;
 840
 841     # Host item field without 0 or 9
 842     my $bib1 = MARC::Record->new();
 843     $bib1->append_fields(
 844         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 845         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 846         MARC::Field->new('773', ' ', ' ', b => 'b without 0 or 9'),
 847     );
 848     my ($biblionumber1, $bibitemnum1) = AddBiblio($bib1, '');
 849     my @itemnumbers1 = C4::Items::get_hostitemnumbers_of( $biblionumber1 );
 850     is( scalar @itemnumbers1, 0, '773 without 0 or 9');
 851
 852     # Correct host item field, analytical records on
 853     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 1);
 854     my $hostitem = $builder->build_sample_item();
 855     my $bib2 = MARC::Record->new();
 856     $bib2->append_fields(
 857         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 858         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 859         MARC::Field->new('773', ' ', ' ', 0 => $hostitem->biblionumber , 9 => $hostitem->itemnumber, b => 'b' ),
 860     );
 861     my ($biblionumber2, $bibitemnum2) = AddBiblio($bib2, '');
 862     my @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 863     is( scalar @itemnumbers2, 1, '773 with 0 and 9, EasyAnalyticalRecords on');
 864
 865     # Correct host item field, analytical records off
 866     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 0);
 867     @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 868     is( scalar @itemnumbers2, 0, '773 with 0 and 9, EasyAnalyticalRecords off');
 869
 870     $schema->storage->txn_rollback;
 871 };
 872
 873 subtest 'Test logging for ModItem' => sub {
 874
 875     plan tests => 3;
 876
 877     t::lib::Mocks::mock_preference('CataloguingLog', 1);
 878
 879     $schema->storage->txn_begin;
 880
 881     my $builder = t::lib::TestBuilder->new;
 882     my $library = $builder->build({
 883         source => 'Branch',
 884     });
 885     my $itemtype = $builder->build({
 886         source => 'Itemtype',
 887     });
 888
 889     # Create a biblio instance for testing
 890     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 891     my $biblio = $builder->build_sample_biblio();
 892
 893     # Add an item.
 894     my ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, location => $location, itype => $itemtype->{itemtype} } , $biblio->biblionumber);
 895
 896     # False means no logging
 897     $schema->resultset('ActionLog')->search()->delete();
 898     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber, { log_action => 0 });
 899     is( $schema->resultset('ActionLog')->count(), 0, 'False value does not trigger logging' );
 900
 901     # True means logging
 902     $schema->resultset('ActionLog')->search()->delete();
 903     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber, { log_action => 1 });
 904     is( $schema->resultset('ActionLog')->count(), 1, 'True value does trigger logging' );
 905
 906     # Undefined defaults to true
 907     $schema->resultset('ActionLog')->search()->delete();
 908     ModItem({ location => $location }, $biblio->biblionumber, $itemnumber);
 909     is( $schema->resultset('ActionLog')->count(), 1, 'Undefined value defaults to true, triggers logging' );
 910
 911     $schema->storage->txn_rollback;
 912 };
 913
 914 subtest 'Check stockrotationitem relationship' => sub {
 915     plan tests => 1;
 916
 917     $schema->storage->txn_begin();
 918
 919     my $builder = t::lib::TestBuilder->new;
 920     my $item = $builder->build({ source => 'Item' });
 921
 922     $builder->build({
 923         source => 'Stockrotationitem',
 924         value  => { itemnumber_id => $item->{itemnumber} }
 925     });
 926
 927     my $sritem = Koha::Items->find($item->{itemnumber})->stockrotationitem;
 928     isa_ok( $sritem, 'Koha::StockRotationItem', "Relationship works and correctly creates Koha::Object." );
 929
 930     $schema->storage->txn_rollback;
 931 };
 932
 933 subtest 'Check add_to_rota method' => sub {
 934     plan tests => 2;
 935
 936     $schema->storage->txn_begin();
 937
 938     my $builder = t::lib::TestBuilder->new;
 939     my $item = $builder->build({ source => 'Item' });
 940     my $rota = $builder->build({ source => 'Stockrotationrota' });
 941     my $srrota = Koha::StockRotationRotas->find($rota->{rota_id});
 942
 943     $builder->build({
 944         source => 'Stockrotationstage',
 945         value  => { rota_id => $rota->{rota_id} },
 946     });
 947
 948     my $sritem = Koha::Items->find($item->{itemnumber});
 949     $sritem->add_to_rota($rota->{rota_id});
 950
 951     is(
 952         Koha::StockRotationItems->find($item->{itemnumber})->stage_id,
 953         $srrota->stockrotationstages->next->stage_id,
 954         "Adding to a rota a new sritem item being assigned to its first stage."
 955     );
 956
 957     my $newrota = $builder->build({ source => 'Stockrotationrota' });
 958
 959     my $srnewrota = Koha::StockRotationRotas->find($newrota->{rota_id});
 960
 961     $builder->build({
 962         source => 'Stockrotationstage',
 963         value  => { rota_id => $newrota->{rota_id} },
 964     });
 965
 966     $sritem->add_to_rota($newrota->{rota_id});
 967
 968     is(
 969         Koha::StockRotationItems->find($item->{itemnumber})->stage_id,
 970         $srnewrota->stockrotationstages->next->stage_id,
 971         "Moving an item results in that sritem being assigned to the new first stage."
 972     );
 973
 974     $schema->storage->txn_rollback;
 975 };
 976
 977 subtest 'Split subfields in Item2Marc (Bug 21774)' => sub {
 978     plan tests => 3;
 979     $schema->storage->txn_begin;
 980
 981     my $builder = t::lib::TestBuilder->new;
 982     my $biblio = $builder->build({ source => 'Biblio', value => { frameworkcode => q{} } });
 983     my $item = $builder->build({ source => 'Item', value => { biblionumber => $biblio->{biblionumber}, ccode => 'A|B' } });
 984
 985     Koha::MarcSubfieldStructures->search({ tagfield => '952', tagsubfield => '8' })->delete; # theoretical precaution
 986     Koha::MarcSubfieldStructures->search({ kohafield => 'items.ccode' })->delete;
 987     my $mapping = Koha::MarcSubfieldStructure->new({ frameworkcode => q{}, tagfield => '952', tagsubfield => '8', kohafield => 'items.ccode' })->store;
 988
 989     # Start testing
 990     my $marc = C4::Items::Item2Marc( $item, $biblio->{biblionumber} );
 991     my @subs = $marc->subfield( $mapping->tagfield, $mapping->tagsubfield );
 992     is( @subs, 2, 'Expect two subfields' );
 993     is( $subs[0], 'A', 'First subfield matches' );
 994     is( $subs[1], 'B', 'Second subfield matches' );
 995
 996     $schema->storage->txn_rollback;
 997 };