t/db_dependent/Auth_with_ldap.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 4;
  21 use Test::MockModule;
  22 use Test::MockObject;
  23 use t::lib::Mocks;
  24 use t::lib::TestBuilder;
  25 use Test::Warn;
  26
  27 use C4::Context;
  28
  29 use Koha::Patrons;
  30
  31 my $dbh = '';
  32
  33 # Start transaction
  34 my $database = Koha::Database->new();
  35 my $schema = $database->schema();
  36 $schema->storage->txn_begin();
  37
  38 my $builder = t::lib::TestBuilder->new();
  39
  40 # Variables controlling LDAP server config
  41 my $update         = 0;
  42 my $replicate      = 0;
  43 my $auth_by_bind   = 1;
  44 my $anonymous_bind = 1;
  45
  46 # Variables controlling LDAP behaviour
  47 my $desired_authentication_result = 'success';
  48 my $desired_connection_result     = 'error';
  49 my $desired_admin_bind_result     = 'error';
  50 my $desired_search_result         = 'error';
  51 my $desired_count_result          = 1;
  52 my $desired_bind_result           = 'error';
  53 my $remaining_entry = 1;
  54 my $ret;
  55
  56 # Mock the context module
  57 my $context = Test::MockModule->new('C4::Context');
  58 $context->mock( 'config', \&mockedC4Config );
  59
  60 # Mock the Net::LDAP module
  61 my $net_ldap = Test::MockModule->new('Net::LDAP');
  62
  63 $net_ldap->mock(
  64     'new',
  65     sub {
  66         if ( $desired_connection_result eq 'error' ) {
  67
  68             # We were asked to fail the LDAP conexion
  69             return;
  70         }
  71         else {
  72             # Return a mocked Net::LDAP object (Test::MockObject)
  73             return mock_net_ldap();
  74         }
  75     }
  76 );
  77
  78 my $categorycode = $builder->build( { source => 'Category' } )->{categorycode};
  79 my $branchcode   = $builder->build( { source => 'Branch' } )->{branchcode};
  80 my $attr_type    = $builder->build(
  81     {
  82         source => 'BorrowerAttributeType',
  83         value  => {
  84             category_code => $categorycode
  85         }
  86     }
  87 );
  88 my $attr_type2    = $builder->build(
  89     {
  90         source => 'BorrowerAttributeType',
  91         value  => {
  92             category_code => $categorycode
  93         }
  94     }
  95 );
  96
  97 my $borrower = $builder->build(
  98     {
  99         source => 'Borrower',
 100         value  => {
 101             userid       => 'hola',
 102             branchcode   => $branchcode,
 103             categorycode => $categorycode
 104         }
 105     }
 106 );
 107
 108 $builder->build(
 109     {
 110         source => 'BorrowerAttribute',
 111         value  => {
 112             borrowernumber => $borrower->{borrowernumber},
 113             code           => $attr_type->{code},
 114             attribute      => 'FOO'
 115         }
 116     }
 117 );
 118
 119 # C4::Auth_with_ldap needs several stuff set first ^^^
 120 use_ok('C4::Auth_with_ldap');
 121 can_ok(
 122     'C4::Auth_with_ldap', qw/
 123       checkpw_ldap
 124       search_method /
 125 );
 126
 127 subtest 'checkpw_ldap tests' => sub {
 128
 129     plan tests => 4;
 130
 131     my $dbh = C4::Context->dbh;
 132     ## Connection fail tests
 133     $desired_connection_result = 'error';
 134     warning_is {
 135         $ret =
 136           C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola', password => 'hey' );
 137     }
 138     'LDAP connexion failed',
 139       'checkpw_ldap prints correct warning if LDAP conexion fails';
 140     is( $ret, 0, 'checkpw_ldap returns 0 if LDAP conexion fails' );
 141
 142     ## Connection success tests
 143     $desired_connection_result = 'success';
 144
 145     subtest 'auth_by_bind = 1 tests' => sub {
 146
 147         plan tests => 9;
 148
 149         $auth_by_bind = 1;
 150
 151         $desired_authentication_result = 'success';
 152         $anonymous_bind                = 1;
 153         $desired_admin_bind_result   = 'error';
 154         $desired_search_result         = 'error';
 155         reload_ldap_module();
 156
 157         warning_like {
 158             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 159                 password => 'hey' );
 160         }
 161         qr/Anonymous LDAP bind failed: LDAP error #1: error_name/,
 162           'checkpw_ldap prints correct warning if LDAP anonymous bind fails';
 163         is( $ret, 0, 'checkpw_ldap returns 0 if LDAP anonymous bind fails' );
 164
 165         $desired_authentication_result = 'success';
 166         $anonymous_bind                = 1;
 167         $desired_admin_bind_result   = 'success';
 168         $desired_search_result         = 'success';
 169         $desired_count_result          = 1;
 170         $desired_bind_result = 'success';
 171         $update                        = 1;
 172         reload_ldap_module();
 173
 174         t::lib::Mocks::mock_preference( 'ExtendedPatronAttributes', 1 );
 175         my $auth = Test::MockModule->new('C4::Auth_with_ldap');
 176         $auth->mock(
 177             'update_local',
 178             sub {
 179                 return $borrower->{cardnumber};
 180             }
 181         );
 182         $auth->mock(
 183             'ldap_entry_2_hash',
 184             sub {
 185                 return (
 186                     $attr_type2->{code}, 'BAR'
 187                 );
 188             }
 189         );
 190
 191         C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola', password => 'hey' );
 192         ok(
 193             @{
 194                 C4::Members::Attributes::GetBorrowerAttributes(
 195                     $borrower->{borrowernumber}
 196                 )
 197             },
 198             'Extended attributes are not deleted'
 199         );
 200
 201         is( C4::Members::Attributes::GetBorrowerAttributeValue($borrower->{borrowernumber}, $attr_type2->{code}), 'BAR', 'Mapped attribute is BAR' );
 202         $auth->unmock('update_local');
 203         $auth->unmock('ldap_entry_2_hash');
 204
 205         $update               = 0;
 206         $desired_count_result = 0;    # user auth problem
 207         Koha::Patrons->find( $borrower->{borrowernumber} )->delete;
 208         reload_ldap_module();
 209         is(
 210             C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola', password => 'hey' ),
 211             0,
 212             'checkpw_ldap returns 0 if user lookup returns 0'
 213         );
 214
 215         $desired_bind_result = 'error';
 216         reload_ldap_module();
 217
 218         warning_like {
 219             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 220                 password => 'hey' );
 221         }
 222         qr/LDAP bind failed as kohauser hola: LDAP error #1: error_name/,
 223           'checkpw_ldap prints correct warning if LDAP bind fails';
 224         is( $ret, -1,
 225             'checkpw_ldap returns -1 LDAP bind fails for user (Bug 8148)' );
 226
 227         # regression tests for bug 12831
 228         $desired_authentication_result = 'error';
 229         $anonymous_bind                = 0;
 230         $desired_admin_bind_result   = 'error';
 231         $desired_search_result         = 'success';
 232         $desired_count_result          = 0;           # user auth problem
 233         $desired_bind_result = 'error';
 234         reload_ldap_module();
 235
 236         warning_like {
 237             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 238                 password => 'hey' );
 239         }
 240         qr/LDAP bind failed as kohauser hola: LDAP error #1: error_name/,
 241           'checkpw_ldap prints correct warning if LDAP bind fails';
 242         is( $ret, 0,
 243             'checkpw_ldap returns 0 LDAP bind fails for user (Bug 12831)' );
 244
 245     };
 246
 247     subtest 'auth_by_bind = 0 tests' => sub {
 248
 249         plan tests => 8;
 250
 251         $auth_by_bind = 0;
 252
 253         # Anonymous bind
 254         $anonymous_bind            = 1;
 255         $desired_admin_bind_result = 'error';
 256         $desired_bind_result = 'error';
 257         reload_ldap_module();
 258
 259         warning_like {
 260             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 261                 password => 'hey' );
 262         }
 263 qr/LDAP bind failed as ldapuser cn=Manager,dc=metavore,dc=com: LDAP error #1: error_name/,
 264           'checkpw_ldap prints correct warning if LDAP bind fails';
 265         is( $ret, 0, 'checkpw_ldap returns 0 if bind fails' );
 266
 267         $anonymous_bind            = 1;
 268         $desired_admin_bind_result = 'success';
 269         $desired_bind_result = 'error';
 270         $desired_search_result = 'success';
 271         $desired_count_result = 1;
 272         reload_ldap_module();
 273
 274         warning_like {
 275             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 276                 password => 'hey' );
 277         }
 278 qr/LDAP Auth rejected : invalid password for user 'hola'./,
 279           'checkpw_ldap prints correct warning if LDAP bind fails';
 280         is( $ret, -1, 'checkpw_ldap returns -1 if bind fails (Bug 8148)' );
 281
 282         # Non-anonymous bind
 283         $anonymous_bind            = 0;
 284         $desired_admin_bind_result = 'error';
 285         $desired_bind_result = 'error';
 286         reload_ldap_module();
 287
 288         warning_like {
 289             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 290                 password => 'hey' );
 291         }
 292 qr/LDAP bind failed as ldapuser cn=Manager,dc=metavore,dc=com: LDAP error #1: error_name/,
 293           'checkpw_ldap prints correct warning if LDAP bind fails';
 294         is( $ret, 0, 'checkpw_ldap returns 0 if bind fails' );
 295
 296         $anonymous_bind            = 0;
 297         $desired_admin_bind_result = 'success';
 298         $desired_bind_result = 'error';
 299         reload_ldap_module();
 300
 301         warning_like {
 302             $ret = C4::Auth_with_ldap::checkpw_ldap( $dbh, 'hola',
 303                 password => 'hey' );
 304         }
 305 qr/LDAP Auth rejected : invalid password for user 'hola'./,
 306           'checkpw_ldap prints correct warning if LDAP bind fails';
 307         is( $ret, -1, 'checkpw_ldap returns -1 if bind fails (Bug 8148)' );
 308
 309     };
 310 };
 311
 312 subtest 'search_method tests' => sub {
 313
 314     plan tests => 3;
 315
 316     my $ldap = mock_net_ldap();
 317
 318     # Null params tests
 319     is( C4::Auth_with_ldap::search_method( $ldap, undef ),
 320         undef, 'search_method returns undef on undefined userid' );
 321     is( C4::Auth_with_ldap::search_method( undef, 'undef' ),
 322         undef, 'search_method returns undef on undefined ldap object' );
 323
 324     # search ->code and !->code
 325     $desired_search_result = 'error';
 326     reload_ldap_module();
 327     my $eval_retval =
 328       eval { $ret = C4::Auth_with_ldap::search_method( $ldap, 'undef' ); };
 329     like(
 330         $@,
 331         qr/LDAP search failed to return object : 1/,
 332 'search_method prints correct warning when db->search returns error code'
 333     );
 334 };
 335
 336 # Function that mocks the call to C4::Context->config(param)
 337 sub mockedC4Config {
 338     my $class = shift;
 339     my $param = shift;
 340
 341     if ( $param eq 'useshibboleth' ) {
 342         return 0;
 343     }
 344     if ( $param eq 'ldapserver' ) {
 345         my %ldap_mapping = (
 346             firstname    => { is => 'givenname' },
 347             surname      => { is => 'sn' },
 348             address      => { is => 'postaladdress' },
 349             city         => { is => 'l' },
 350             zipcode      => { is => 'postalcode' },
 351             branchcode   => { is => 'branch' },
 352             userid       => { is => 'uid' },
 353             password     => { is => 'userpassword' },
 354             email        => { is => 'mail' },
 355             categorycode => { is => 'employeetype' },
 356             phone        => { is => 'telephonenumber' },
 357         );
 358
 359         my %ldap_config = (
 360             anonymous_bind => $anonymous_bind,
 361             auth_by_bind   => $auth_by_bind,
 362             base           => 'dc=metavore,dc=com',
 363             hostname       => 'localhost',
 364             mapping        => \%ldap_mapping,
 365             pass           => 'metavore',
 366             principal_name => '%s@my_domain.com',
 367             replicate      => $replicate,
 368             update         => $update,
 369             user           => 'cn=Manager,dc=metavore,dc=com',
 370         );
 371         return \%ldap_config;
 372     }
 373     if ( $param =~ /(intranetdir|opachtdocs|intrahtdocs)/x ) {
 374         return q{};
 375     }
 376     if ( ref $class eq 'HASH' ) {
 377         return $class->{$param};
 378     }
 379     return;
 380 }
 381
 382 # Function that mocks the call to Net::LDAP
 383 sub mock_net_ldap {
 384
 385     my $mocked_ldap = Test::MockObject->new();
 386
 387     $mocked_ldap->mock( 'bind', sub {
 388         if (is_admin_bind(@_)) {
 389             return mock_net_ldap_message(
 390                 ($desired_admin_bind_result eq 'error' ) ? 1 : 0, # code
 391                 ($desired_admin_bind_result eq 'error' ) ? 1 : 0, # error
 392                 ($desired_admin_bind_result eq 'error' ) ? 'error_name' : 0, # error_name
 393                 ($desired_admin_bind_result eq 'error' ) ? 'error_text' : 0  # error_text
 394             );
 395         }
 396         else {
 397             if ( $desired_bind_result eq 'error' ) {
 398                 return mock_net_ldap_message(1,1,'error_name','error_text');
 399             }
 400             return mock_net_ldap_message(0,0,'','');
 401         }
 402     });
 403
 404     $mocked_ldap->mock(
 405         'search',
 406         sub {
 407
 408             $remaining_entry = 1
 409
 410             return mock_net_ldap_search(
 411                 {
 412                     count => ($desired_count_result)
 413                     ? $desired_count_result
 414                     : 1,    # default to 1
 415                     code => ( $desired_search_result eq 'error' )
 416                     ? 1
 417                     : 0,    # 0 == success
 418                     error => ( $desired_search_result eq 'error' ) ? 1
 419                     : 0,
 420                     error_text => ( $desired_search_result eq 'error' )
 421                     ? 'error_text'
 422                     : undef,
 423                     error_name => ( $desired_search_result eq 'error' )
 424                     ? 'error_name'
 425                     : undef,
 426                     shift_entry => mock_net_ldap_entry( 'sampledn', 1 )
 427                 }
 428             );
 429
 430         }
 431     );
 432
 433     return $mocked_ldap;
 434 }
 435
 436 sub mock_net_ldap_search {
 437     my ($parameters) = @_;
 438
 439     my $count       = $parameters->{count};
 440     my $code        = $parameters->{code};
 441     my $error       = $parameters->{error};
 442     my $error_text  = $parameters->{error_text};
 443     my $error_name  = $parameters->{error_name};
 444     my $shift_entry = $parameters->{shift_entry};
 445
 446     my $mocked_search = Test::MockObject->new();
 447     $mocked_search->mock( 'count',       sub { return $count; } );
 448     $mocked_search->mock( 'code',        sub { return $code; } );
 449     $mocked_search->mock( 'error',       sub { return $error; } );
 450     $mocked_search->mock( 'error_name',  sub { return $error_name; } );
 451     $mocked_search->mock( 'error_text',  sub { return $error_text; } );
 452     $mocked_search->mock( 'shift_entry', sub {
 453         if ($remaining_entry) {
 454             $remaining_entry--;
 455             return $shift_entry;
 456         }
 457         return '';
 458     });
 459
 460     return $mocked_search;
 461 }
 462
 463 sub mock_net_ldap_message {
 464     my ( $code, $error, $error_name, $error_text ) = @_;
 465
 466     my $mocked_message = Test::MockObject->new();
 467     $mocked_message->mock( 'code',       sub { $code } );
 468     $mocked_message->mock( 'error',      sub { $error } );
 469     $mocked_message->mock( 'error_name', sub { $error_name } );
 470     $mocked_message->mock( 'error_text', sub { $error_text } );
 471
 472     return $mocked_message;
 473 }
 474
 475 sub mock_net_ldap_entry {
 476     my ( $dn, $exists ) = @_;
 477
 478     my $mocked_entry = Test::MockObject->new();
 479     $mocked_entry->mock( 'dn',     sub { return $dn; } );
 480     $mocked_entry->mock( 'exists', sub { return $exists } );
 481
 482     return $mocked_entry;
 483 }
 484
 485 # TODO: Once we remove the global variables in C4::Auth_with_ldap
 486 # we shouldn't need this...
 487 # ... Horrible hack
 488 sub reload_ldap_module {
 489     delete $INC{'C4/Auth_with_ldap.pm'};
 490     require C4::Auth_with_ldap;
 491     C4::Auth_with_ldap->import;
 492     return;
 493 }
 494
 495 sub is_admin_bind {
 496     my @args = @_;
 497
 498     if ($#args <= 1 || $args[1] eq 'cn=Manager,dc=metavore,dc=com') {
 499         return 1;
 500     }
 501
 502     return 0;
 503 }
 504
 505 $schema->storage->txn_rollback;
 506
 507 1;