misc/cronjobs/update_patrons_category.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 BEGIN {
  21     # find Koha's Perl modules
  22     # test carefully before changing this
  23     use FindBin;
  24     eval { require "$FindBin::Bin/../kohalib.pl" };
  25 }
  26
  27 use C4::Context;
  28 use Getopt::Long;
  29 use Pod::Usage;
  30 use Koha::Logger;
  31 use Koha::Patrons;
  32 use Koha::Patron::Categories;
  33 use Koha::DateUtils;
  34 use Koha::Script -cron;
  35
  36 =head1 NAME
  37
  38 update_patrons_category.pl - Given a set of parameters update selected patrons from one catgeory to another. Options are cumulative.
  39
  40 =head1 SYNOPSIS
  41
  42 update_patrons_category.pl -f=categorycode -t=categorycode
  43                           [-b=branchcode] [--too_old] [--too_young] [-fo=X] [-fu=X]
  44                           [-rb=date] [-ra=date] [-v]
  45                           [--field column=value ...]
  46
  47 update_patrons_category.pl --help | --man
  48
  49 Options:
  50    --help                   brief help message
  51    --man                    full documentation
  52    -too_old                 update if over  maximum age for current category
  53    -too_young               update if under minimuum age  current category
  54    -fo=X --fineover=X       update if fines over  X amount
  55    -fu=X --fineunder=X      update if fines under X amount
  56    -rb=date --regbefore     update if registration date is before given date
  57    -ra=date --regafter      update if registration date is after a given date
  58    -d --dbfield name=value  where <name> is a column in the borrowers table, patrons will be updated if the field is equal to given <value>
  59    -v -verbose              verbose mode
  60    -c --confirm             commit changes to db, no action will be taken unless this switch is included
  61    -b --branch <branchname> only deal with patrons from this library/branch
  62    -f --from <categorycode> change patron category from this category
  63    -t --to   <categorycode> change patron category to this category
  64
  65 =head1 OPTIONS
  66
  67 =over 8
  68
  69 =item B<--help>
  70
  71 Print a brief help message and exits.
  72
  73 =item B<--man>
  74
  75 Prints the manual page and exits.
  76
  77 =item B<--verbose | -v>
  78
  79 Verbose. Without this flag set, only fatal errors are reported.
  80
  81 =item B<--confirm | -c>
  82
  83 Commit changes. Unless this flag set is, the script will report changes but not actually execute them on the database.
  84
  85 =item B<--branch | -b>
  86
  87 changes patrons for one specific branch. Use the value in the
  88 branches.branchcode table.
  89
  90 =item B<--from | -f>
  91
  92 *required* defines the category to update. Expects the code from categories.categorycode.
  93
  94 =item B<--to | -t>
  95
  96 *required* defines the category patrons will be converted to. Expects the code from categories.categorycode.
  97
  98 =item B<--too_old>
  99
 100 Update patron only if they are above the maximum age range specified for the 'from' category.
 101
 102 =item B<--too_young>
 103
 104 Update patron only if they are below the minimum age range specified for the 'from' category.
 105
 106 =item B<--fineover=X | -fo=X>
 107
 108 Supply a number and only account with fines over this number will be updated.
 109
 110 =item B<--fineunder=X | -fu=X>
 111
 112 Supply a number and only account with fines under this number will be updated.
 113
 114 =item B<--regbefore=date | -rb=date>
 115
 116 Enter a date in ISO format YYYY-MM-DD and only patrons registered before this date wil be updated.
 117
 118 =item B<--regafter=date | -ra=date>
 119
 120 Enter a date in ISO format YYYY-MM-DD and only patrons registered after this date wil be updated.
 121
 122 =item B<--field column=value | -d column=value>
 123
 124 Use this flag to specify a column in the borrowers table and update only patrons whose value in that column matches the value supplied (repeatable)
 125
 126 e.g.
 127 --field dateexpiry=2016-01-01
 128 will update all patrons who expired on that date, useful for schools etc.
 129
 130 =back
 131
 132 =head1 DESCRIPTION
 133
 134 This script is designed to update patrons from one category to another.
 135
 136 =head1 USAGE EXAMPLES
 137
 138 C<update_patron_categories.pl> - Suggests that you read this help. :)
 139
 140 C<update_patron_categories.pl> -b=<branchcode> -f=<categorycode> -t=<categorycode> --confirm  - Processes a single branch, and updates the patron categories from fromcat to tocat.
 141
 142 C<update_patron_categories.pl> -b=<branchcode> -f=<categorycode> -t=<categorycode>  --too_old --confirm  - Processes a single branch, and updates the patron categories from fromcat to tocat for patrons over the age range of fromcat.
 143
 144 C<update_patron_categories.pl> -f=<categorycode> -t=<categorycode> -v  - Processes all branches, shows all messages, and reports the patrons who would be affected. Takes no action on the database.
 145
 146 =cut
 147
 148 # These variables are set by command line options.
 149 # They are initially set to default values.
 150
 151 my $help    = 0;
 152 my $man     = 0;
 153 my $verbose = 0;
 154 my $doit    = 0;
 155 my $ageunder;
 156 my $ageover;
 157 my $remove_guarantors = 0;
 158 my $fine_min;
 159 my $fine_max;
 160 my $fromcat;
 161 my $tocat;
 162 my $reg_bef;
 163 my $reg_aft;
 164 my $branch_lim;
 165 my %fields;
 166
 167 GetOptions(
 168     'help|?'          => \$help,
 169     'man'             => \$man,
 170     'v|verbose'       => \$verbose,
 171     'c|confirm'       => \$doit,
 172     'f|from=s'        => \$fromcat,
 173     't|to=s'          => \$tocat,
 174     'too_old'         => \$ageover,
 175     'too_young'       => \$ageunder,
 176     'fo|finesover=s'  => \$fine_min,
 177     'fu|finesunder=s' => \$fine_max,
 178     'rb|regbefore=s'  => \$reg_bef,
 179     'ra|regafter=s'   => \$reg_aft,
 180     'b|branch=s'      => \$branch_lim,
 181     'd|field=s'       => \%fields
 182 );
 183
 184 pod2usage(1) if $help;
 185
 186 pod2usage( -verbose => 2 ) if $man;
 187
 188 if ( not $fromcat && $tocat ) {    #make sure we've specified the info we need.
 189     print "Must supply category from and to (-f & -t) please specify -help for usage tips.\n";
 190     pod2usage(1);
 191     exit;
 192 }
 193
 194 ( $verbose && !$doit ) and print "No actions will be taken (test mode)\n";
 195
 196 $verbose and print "Will update patrons from $fromcat to $tocat with conditions below (if any)\n";
 197
 198 my %params;
 199
 200 if ( $reg_bef || $reg_aft ) {
 201     my $date_bef;
 202     my $date_aft;
 203     if ( defined $reg_bef ) {
 204         eval { $date_bef = dt_from_string( $reg_bef, 'iso' ); };
 205     }
 206     die "$reg_bef is not a valid date before, aborting! Use a date in format YYYY-MM-DD.$@"
 207         if $@;
 208     if ( defined $reg_aft ) {
 209         eval { $date_aft = dt_from_string( $reg_aft, 'iso' ); };
 210     }
 211     die "$reg_bef is not a valid date after, aborting! Use a date in format YYYY-MM-DD.$@"
 212         if $@;
 213     $params{dateenrolled}{'<='} = $reg_bef if defined $date_bef;
 214     $params{dateenrolled}{'>='} = $reg_aft if defined $date_aft;
 215 }
 216
 217 my $cat_from = Koha::Patron::Categories->find($fromcat);
 218 my $cat_to   = Koha::Patron::Categories->find($tocat);
 219 die "Categories not found" unless $cat_from && $cat_to;
 220
 221 $params{"me.categorycode"} = $fromcat;
 222 $params{"me.branchcode"} = $branch_lim if $branch_lim;
 223
 224 if ($verbose) {
 225     print "Conditions:\n";
 226     print "    Registered before $reg_bef\n"      if $reg_bef;
 227     print "    Registered after  $reg_aft\n"      if $reg_aft;
 228     print "    Total fines more than $fine_min\n" if $fine_min;
 229     print "    Total fines less than $fine_max\n" if $fine_max;
 230     print "    Age below minimum for " . $cat_from->description . "\n" if $ageunder;
 231     print "    Age above maximum for " . $cat_from->description . "\n" if $ageover;
 232     if ( defined $branch_lim ) {
 233         print "    Branchcode of patron is $branch_lim\n";
 234     }
 235 }
 236
 237 while ( my ( $key, $value ) = each %fields ) {
 238     $verbose and print "    Borrower column $key is equal to $value\n";
 239     $params{ "me." . $key } = $value;
 240 }
 241 my $target_patrons = Koha::Patrons->search(\%params)->search_patrons_to_update_category(
 242     {
 243         from          => $fromcat,
 244         search_params => \%params,
 245         too_young     => $ageunder,
 246         too_old       => $ageover,
 247         fine_min      => $fine_min,
 248         fine_max      => $fine_max,
 249     }
 250 );
 251
 252 my $patrons_found    = $target_patrons->count;
 253 my $actually_updated = 0;
 254 my $testdisplay      = $doit ? "" : "WOULD HAVE ";
 255 if ($verbose) {
 256     while ( my $target_patron = $target_patrons->next() ) {
 257         $target_patron->discard_changes();
 258         $verbose
 259           and print $testdisplay
 260           . "Updated "
 261           . $target_patron->firstname() . " "
 262           . $target_patron->surname()
 263           . " from $fromcat to $tocat\n";
 264     }
 265     $target_patrons->reset;
 266 }
 267 if ($doit) {
 268     $actually_updated = $target_patrons->update_category_to( { category => $tocat } );
 269 }
 270
 271 $verbose and print "$patrons_found found, $actually_updated updated\n";