members/deletemem.pl

   1 #!/usr/bin/perl
   2
   3 #script to delete items
   4 #written 2/5/00
   5 #by chris@katipo.co.nz
   6
   7 # Copyright 2000-2002 Katipo Communications
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 use Modern::Perl;
  25
  26 use CGI qw ( -utf8 );
  27 use C4::Context;
  28 use C4::Output;
  29 use C4::Auth;
  30 use C4::Members;
  31 use Koha::Patrons;
  32 use Koha::Token;
  33 use Koha::Patron::Categories;
  34
  35 my $input = new CGI;
  36
  37 my ($template, $loggedinuser, $cookie)
  38                 = get_template_and_user({template_name => "members/deletemem.tt",
  39                                         query => $input,
  40                                         type => "intranet",
  41                                         authnotrequired => 0,
  42                                         flagsrequired => {borrowers => 'edit_borrowers'},
  43                                         debug => 1,
  44                                         });
  45
  46 #print $input->header;
  47 my $member       = $input->param('member');
  48
  49 #Do not delete yourself...
  50 if ( $loggedinuser == $member ) {
  51     print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member&error=CANT_DELETE_YOURSELF");
  52     exit 0; # Exit without error
  53 }
  54
  55 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  56 my $patron         = Koha::Patrons->find( $member );
  57 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  58
  59 my $debits = $patron->account->outstanding_debits->total_outstanding;
  60 my $credits = abs $patron->account->outstanding_credits->total_outstanding;
  61 my $countissues = $patron->checkouts->count;
  62 my $userenv = C4::Context->userenv;
  63
  64 if ($patron->category->category_type eq "S") {
  65     unless(C4::Auth::haspermission($userenv->{'id'},{'staffaccess'=>1})) {
  66         print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member&error=CANT_DELETE_STAFF");
  67         exit 0; # Exit without error
  68     }
  69 } else {
  70     unless(C4::Auth::haspermission($userenv->{'id'},{'borrowers'=>'edit_borrowers'})) {
  71         print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member&error=CANT_DELETE");
  72         exit 0; # Exit without error
  73     }
  74 }
  75
  76 if (C4::Context->preference("IndependentBranches")) {
  77     my $userenv = C4::Context->userenv;
  78     if ( !C4::Context->IsSuperLibrarian() && $patron->branchcode){
  79         unless ($userenv->{branch} eq $patron->branchcode){
  80             print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member&error=CANT_DELETE_OTHERLIBRARY");
  81             exit 0; # Exit without error
  82         }
  83     }
  84 }
  85
  86 my $op = $input->param('op') || 'delete_confirm';
  87 my $dbh = C4::Context->dbh;
  88 my $is_guarantor = $patron->guarantee_relationships->count;
  89 my $countholds = $dbh->selectrow_array("SELECT COUNT(*) FROM reserves WHERE borrowernumber=?", undef, $member);
  90
  91 $template->param(
  92     patron        => $patron,
  93     ItemsOnIssues => $countissues,
  94     debits        => $debits,
  95     credits       => $credits,
  96     is_guarantor  => $is_guarantor,
  97     ItemsOnHold   => $countholds,
  98 );
  99
 100 if ( $op eq 'delete_confirm' or $countissues > 0 or $debits or $is_guarantor ) {
 101     $template->param(
 102         op         => 'delete_confirm',
 103         csrf_token => Koha::Token->new->generate_csrf({ session_id => scalar $input->cookie('CGISESSID') }),
 104     );
 105 } elsif ( $op eq 'delete_confirmed' ) {
 106     output_and_exit( $input, $cookie, $template, 'wrong_csrf_token' )
 107         unless Koha::Token->new->check_csrf( {
 108             session_id => $input->cookie('CGISESSID'),
 109             token  => scalar $input->param('csrf_token'),
 110         });
 111     my $patron = Koha::Patrons->find( $member );
 112     $patron->move_to_deleted;
 113     $patron->delete;
 114     # TODO Tell the user everything went ok
 115     print $input->redirect("/cgi-bin/koha/members/members-home.pl");
 116     exit 0; # Exit without error
 117 }
 118
 119 output_html_with_http_headers $input, $cookie, $template->output;