catalogue/detail.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18
  19 use Modern::Perl;
  20
  21 use CGI qw ( -utf8 );
  22 use HTML::Entities;
  23 use C4::Auth;
  24 use C4::Context;
  25 use C4::Koha;
  26 use C4::Serials;    #uses getsubscriptionfrom biblionumber
  27 use C4::Output;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Circulation;
  31 use C4::Reserves;
  32 use C4::Serials;
  33 use C4::XISBN qw(get_xisbns);
  34 use C4::External::Amazon;
  35 use C4::Search;        # enabled_staff_search_views
  36 use C4::Tags qw(get_tags);
  37 use C4::XSLT;
  38 use C4::Images;
  39 use Koha::DateUtils;
  40 use C4::HTML5Media;
  41 use C4::CourseReserves qw(GetItemCourseReservesInfo);
  42 use C4::Acquisition qw(GetOrdersByBiblionumber);
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblios;
  45 use Koha::Items;
  46 use Koha::ItemTypes;
  47 use Koha::Patrons;
  48 use Koha::Virtualshelves;
  49 use Koha::Plugins;
  50
  51 my $query = CGI->new();
  52
  53 my $analyze = $query->param('analyze');
  54
  55 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  56     {
  57     template_name   =>  'catalogue/detail.tt',
  58         query           => $query,
  59         type            => "intranet",
  60         authnotrequired => 0,
  61         flagsrequired   => { catalogue => 1 },
  62     }
  63 );
  64
  65 # Determine if we should be offering any enhancement plugin buttons
  66 if ( C4::Context->preference('UseKohaPlugins') &&
  67      C4::Context->config('enable_plugins') ) {
  68     # Only pass plugins that can offer a toolbar button
  69     my @plugins = Koha::Plugins->new()->GetPlugins({
  70         method => 'intranet_catalog_biblio_enhancements_toolbar_button'
  71     });
  72     $template->param(
  73         plugins => \@plugins
  74     );
  75 }
  76
  77 my $biblionumber = $query->param('biblionumber');
  78 $biblionumber = HTML::Entities::encode($biblionumber);
  79 my $record       = GetMarcBiblio({ biblionumber => $biblionumber });
  80
  81 if ( not defined $record ) {
  82     # biblionumber invalid -> report and exit
  83     $template->param( unknownbiblionumber => 1,
  84                       biblionumber => $biblionumber );
  85     output_html_with_http_headers $query, $cookie, $template->output;
  86     exit;
  87 }
  88
  89 if($query->cookie("holdfor")){
  90     my $holdfor_patron = Koha::Patrons->find( $query->cookie("holdfor") );
  91     $template->param(
  92         # FIXME Should pass the patron object
  93         holdfor => $query->cookie("holdfor"),
  94         holdfor_surname => $holdfor_patron->surname,
  95         holdfor_firstname => $holdfor_patron->firstname,
  96         holdfor_cardnumber => $holdfor_patron->cardnumber,
  97     );
  98 }
  99
 100 my $fw           = GetFrameworkCode($biblionumber);
 101 my $showallitems = $query->param('showallitems');
 102 my $marcflavour  = C4::Context->preference("marcflavour");
 103
 104 # XSLT processing of some stuff
 105 my $xslfile = C4::Context->preference('XSLTDetailsDisplay') || "default";
 106 my $lang   = $xslfile ? C4::Languages::getlanguage()  : undef;
 107 my $sysxml = $xslfile ? C4::XSLT::get_xslt_sysprefs() : undef;
 108
 109 if ( $xslfile ) {
 110     $template->param(
 111         XSLTDetailsDisplay => '1',
 112         XSLTBloc => XSLTParse4Display(
 113                         $biblionumber, $record, "XSLTDetailsDisplay",
 114                         1, undef, $sysxml, $xslfile, $lang
 115                     )
 116     );
 117 }
 118
 119 $template->param( 'SpineLabelShowPrintOnBibDetails' => C4::Context->preference("SpineLabelShowPrintOnBibDetails") );
 120 $template->param( ocoins => GetCOinSBiblio($record) );
 121
 122 # some useful variables for enhanced content;
 123 # in each case, we're grabbing the first value we find in
 124 # the record and normalizing it
 125 my $upc = GetNormalizedUPC($record,$marcflavour);
 126 my $ean = GetNormalizedEAN($record,$marcflavour);
 127 my $oclc = GetNormalizedOCLCNumber($record,$marcflavour);
 128 my $isbn = GetNormalizedISBN(undef,$record,$marcflavour);
 129
 130 $template->param(
 131     normalized_upc => $upc,
 132     normalized_ean => $ean,
 133     normalized_oclc => $oclc,
 134     normalized_isbn => $isbn,
 135 );
 136
 137 my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
 138 my $marcisbnsarray   = GetMarcISBN( $record, $marcflavour );
 139 my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
 140 my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
 141 my $marcseriesarray  = GetMarcSeries($record,$marcflavour);
 142 my $marcurlsarray    = GetMarcUrls    ($record,$marcflavour);
 143 my $marchostsarray  = GetMarcHosts($record,$marcflavour);
 144 my $subtitle         = GetRecordValue('subtitle', $record, $fw);
 145
 146 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search->unblessed } };
 147
 148 my $dbh = C4::Context->dbh;
 149
 150 my @all_items = GetItemsInfo( $biblionumber );
 151 my @items;
 152 my $patron = Koha::Patrons->find( $borrowernumber );
 153 for my $itm (@all_items) {
 154     push @items, $itm unless ( $itm->{itemlost} && $patron->category->hidelostitems && !$showallitems);
 155 }
 156
 157 # flag indicating existence of at least one item linked via a host record
 158 my $hostrecords;
 159 # adding items linked via host biblios
 160 my @hostitems = GetHostItemsInfo($record);
 161 if (@hostitems){
 162     $hostrecords =1;
 163     push (@items,@hostitems);
 164 }
 165
 166 my $dat = &GetBiblioData($biblionumber);
 167
 168 #coping with subscriptions
 169 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 170 my @subscriptions       = SearchSubscriptions({ biblionumber => $biblionumber, orderby => 'title' });
 171 my @subs;
 172
 173 foreach my $subscription (@subscriptions) {
 174     my %cell;
 175     my $serials_to_display;
 176     $cell{subscriptionid}    = $subscription->{subscriptionid};
 177     $cell{subscriptionnotes} = $subscription->{internalnotes};
 178     $cell{missinglist}       = $subscription->{missinglist};
 179     $cell{librariannote}     = $subscription->{librariannote};
 180     $cell{branchcode}        = $subscription->{branchcode};
 181     $cell{hasalert}          = $subscription->{hasalert};
 182     $cell{callnumber}        = $subscription->{callnumber};
 183     $cell{location}          = $subscription->{location};
 184     $cell{closed}            = $subscription->{closed};
 185     #get the three latest serials.
 186     $serials_to_display = $subscription->{staffdisplaycount};
 187     $serials_to_display = C4::Context->preference('StaffSerialIssueDisplayCount') unless $serials_to_display;
 188     $cell{staffdisplaycount} = $serials_to_display;
 189     $cell{latestserials} =
 190       GetLatestSerials( $subscription->{subscriptionid}, $serials_to_display );
 191     push @subs, \%cell;
 192 }
 193
 194
 195 # Get acquisition details
 196 if ( C4::Context->preference('AcquisitionDetails') ) {
 197     my $orders = Koha::Acquisition::Orders->search(
 198         { biblionumber => $biblionumber },
 199         {
 200             join => 'basketno',
 201             order_by => 'basketno.booksellerid'
 202         }
 203     );    # GetHistory sorted by aqbooksellerid, but does it make sense?
 204
 205     $template->param(
 206         orders => $orders,
 207     );
 208 }
 209
 210 if ( defined $dat->{'itemtype'} ) {
 211     $dat->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $dat->{itemtype} }{imageurl} );
 212 }
 213
 214 $dat->{'count'} = scalar @all_items + @hostitems;
 215 $dat->{'showncount'} = scalar @items + @hostitems;
 216 $dat->{'hiddencount'} = scalar @all_items + @hostitems - scalar @items;
 217
 218 my $shelflocations =
 219   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.location' } ) };
 220 my $collections =
 221   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.ccode' } ) };
 222 my $copynumbers =
 223   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.copynumber' } ) };
 224 my (@itemloop, @otheritemloop, %itemfields);
 225 my $norequests = 1;
 226
 227 my $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.itemlost', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 228 if ( $mss->count ) {
 229     $template->param( itemlostloop => GetAuthorisedValues( $mss->next->authorised_value ) );
 230 }
 231 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.damaged', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 232 if ( $mss->count ) {
 233     $template->param( itemdamagedloop => GetAuthorisedValues( $mss->next->authorised_value ) );
 234 }
 235 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.withdrawn', authorised_value => { not => undef } });
 236 if ( $mss->count ) {
 237     $template->param( itemwithdrawnloop => GetAuthorisedValues( $mss->next->authorised_value) );
 238 }
 239
 240 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.materials', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 241 my %materials_map;
 242 if ($mss->count) {
 243     my $materials_authvals = GetAuthorisedValues($mss->next->authorised_value);
 244     if ($materials_authvals) {
 245         foreach my $value (@$materials_authvals) {
 246             $materials_map{$value->{authorised_value}} = $value->{lib};
 247         }
 248     }
 249 }
 250
 251 my $analytics_flag;
 252 my $materials_flag; # set this if the items have anything in the materials field
 253 my $currentbranch = C4::Context->userenv ? C4::Context->userenv->{branch} : undef;
 254 if ($currentbranch and C4::Context->preference('SeparateHoldings')) {
 255     $template->param(SeparateHoldings => 1);
 256 }
 257 my $separatebranch = C4::Context->preference('SeparateHoldingsBranch') || 'homebranch';
 258 foreach my $item (@items) {
 259     my $itembranchcode = $item->{$separatebranch};
 260
 261     # can place holds defaults to yes
 262     $norequests = 0 unless ( ( $item->{'notforloan'} > 0 ) || ( $item->{'itemnotforloan'} > 0 ) );
 263
 264     $item->{imageurl} = defined $item->{itype} ? getitemtypeimagelocation('intranet', $itemtypes->{ $item->{itype} }{imageurl})
 265                                                : '';
 266
 267     $item->{datedue} = format_sqldatetime($item->{datedue});
 268
 269     #get shelf location and collection code description if they are authorised value.
 270     # same thing for copy number
 271     my $shelfcode = $item->{'location'};
 272     $item->{'location'} = $shelflocations->{$shelfcode} if ( defined( $shelfcode ) && defined($shelflocations) && exists( $shelflocations->{$shelfcode} ) );
 273     my $ccode = $item->{'ccode'};
 274     $item->{'ccode'} = $collections->{$ccode} if ( defined( $ccode ) && defined($collections) && exists( $collections->{$ccode} ) );
 275     my $copynumber = $item->{'copynumber'};
 276     $item->{'copynumber'} = $copynumbers->{$copynumber} if ( defined($copynumber) && defined($copynumbers) && exists( $copynumbers->{$copynumber} ) );
 277     foreach (qw(ccode enumchron copynumber stocknumber itemnotes itemnotes_nonpublic uri)) {
 278         $itemfields{$_} = 1 if ( $item->{$_} );
 279     }
 280
 281     # checking for holds
 282     my $item_object = Koha::Items->find( $item->{itemnumber} );
 283     my $holds = $item_object->current_holds;
 284     if ( my $first_hold = $holds->next ) {
 285         my $patron = Koha::Patrons->find( $first_hold->borrowernumber );
 286         $item->{backgroundcolor} = 'reserved';
 287         $item->{reservedate}     = $first_hold->reservedate;
 288         $item->{ReservedFor}     = $patron,
 289         $item->{ExpectedAtLibrary}      = $first_hold->branchcode;
 290         # Check waiting status
 291         $item->{waitingdate} = $first_hold->waitingdate;
 292     }
 293
 294     if ( my $checkout = $item_object->checkout ) {
 295         $item->{CheckedOutFor} = $checkout->patron;
 296     }
 297
 298     # Check the transit status
 299     my ( $transfertwhen, $transfertfrom, $transfertto ) = GetTransfers($item->{itemnumber});
 300     if ( defined( $transfertwhen ) && ( $transfertwhen ne '' ) ) {
 301         $item->{transfertwhen} = $transfertwhen;
 302         $item->{transfertfrom} = $transfertfrom;
 303         $item->{transfertto}   = $transfertto;
 304         $item->{nocancel} = 1;
 305     }
 306
 307     foreach my $f (qw( itemnotes )) {
 308         if ($item->{$f}) {
 309             $item->{$f} =~ s|\n|<br />|g;
 310             $itemfields{$f} = 1;
 311         }
 312     }
 313
 314     #item has a host number if its biblio number does not match the current bib
 315
 316     if ($item->{biblionumber} ne $biblionumber){
 317         $item->{hostbiblionumber} = $item->{biblionumber};
 318         $item->{hosttitle} = GetBiblioData($item->{biblionumber})->{title};
 319     }
 320
 321
 322     if ( $analyze ) {
 323         # count if item is used in analytical bibliorecords
 324         # The 'countanalytics' flag is only used in the templates if analyze is set
 325         my $countanalytics = C4::Context->preference('EasyAnalyticalRecords') ? GetAnalyticsCount($item->{itemnumber}) : 0;
 326         if ($countanalytics > 0){
 327             $analytics_flag=1;
 328             $item->{countanalytics} = $countanalytics;
 329         }
 330     }
 331
 332     if (defined($item->{'materials'}) && $item->{'materials'} =~ /\S/){
 333         $materials_flag = 1;
 334         if (defined $materials_map{ $item->{materials} }) {
 335             $item->{materials} = $materials_map{ $item->{materials} };
 336         }
 337     }
 338
 339     if ( C4::Context->preference('UseCourseReserves') ) {
 340         $item->{'course_reserves'} = GetItemCourseReservesInfo( itemnumber => $item->{'itemnumber'} );
 341     }
 342
 343     if ( C4::Context->preference('IndependentBranches') ) {
 344         my $userenv = C4::Context->userenv();
 345         if ( not C4::Context->IsSuperLibrarian()
 346             and $userenv->{branch} ne $item->{homebranch} ) {
 347             $item->{cannot_be_edited} = 1;
 348         }
 349     }
 350
 351     if ($currentbranch and $currentbranch ne "NO_LIBRARY_SET"
 352     and C4::Context->preference('SeparateHoldings')) {
 353         if ($itembranchcode and $itembranchcode eq $currentbranch) {
 354             push @itemloop, $item;
 355         } else {
 356             push @otheritemloop, $item;
 357         }
 358     } else {
 359         push @itemloop, $item;
 360     }
 361 }
 362
 363 # Display only one tab if one items list is empty
 364 if (scalar(@itemloop) == 0 || scalar(@otheritemloop) == 0) {
 365     $template->param(SeparateHoldings => 0);
 366     if (scalar(@itemloop) == 0) {
 367         @itemloop = @otheritemloop;
 368     }
 369 }
 370
 371 $template->param( norequests => $norequests );
 372 $template->param(
 373     MARCNOTES   => $marcnotesarray,
 374     MARCSUBJCTS => $marcsubjctsarray,
 375     MARCAUTHORS => $marcauthorsarray,
 376     MARCSERIES  => $marcseriesarray,
 377     MARCURLS => $marcurlsarray,
 378     MARCISBNS => $marcisbnsarray,
 379     MARCHOSTS => $marchostsarray,
 380     subtitle    => $subtitle,
 381     itemdata_ccode      => $itemfields{ccode},
 382     itemdata_enumchron  => $itemfields{enumchron},
 383     itemdata_uri        => $itemfields{uri},
 384     itemdata_copynumber => $itemfields{copynumber},
 385     itemdata_stocknumber => $itemfields{stocknumber},
 386     volinfo                => $itemfields{enumchron},
 387         itemdata_itemnotes  => $itemfields{itemnotes},
 388         itemdata_nonpublicnotes => $itemfields{itemnotes_nonpublic},
 389     z3950_search_params    => C4::Search::z3950_search_args($dat),
 390         hostrecords         => $hostrecords,
 391     analytics_flag    => $analytics_flag,
 392     C4::Search::enabled_staff_search_views,
 393         materials       => $materials_flag,
 394 );
 395
 396 if (C4::Context->preference("AlternateHoldingsField") && scalar @items == 0) {
 397     my $fieldspec = C4::Context->preference("AlternateHoldingsField");
 398     my $subfields = substr $fieldspec, 3;
 399     my $holdingsep = C4::Context->preference("AlternateHoldingsSeparator") || ' ';
 400     my @alternateholdingsinfo = ();
 401     my @holdingsfields = $record->field(substr $fieldspec, 0, 3);
 402
 403     for my $field (@holdingsfields) {
 404         my %holding = ( holding => '' );
 405         my $havesubfield = 0;
 406         for my $subfield ($field->subfields()) {
 407             if ((index $subfields, $$subfield[0]) >= 0) {
 408                 $holding{'holding'} .= $holdingsep if (length $holding{'holding'} > 0);
 409                 $holding{'holding'} .= $$subfield[1];
 410                 $havesubfield++;
 411             }
 412         }
 413         if ($havesubfield) {
 414             push(@alternateholdingsinfo, \%holding);
 415         }
 416     }
 417
 418     $template->param(
 419         ALTERNATEHOLDINGS   => \@alternateholdingsinfo,
 420         );
 421 }
 422
 423 my @results = ( $dat, );
 424 foreach ( keys %{$dat} ) {
 425     $template->param( "$_" => defined $dat->{$_} ? $dat->{$_} : '' );
 426 }
 427
 428 # does not work: my %views_enabled = map { $_ => 1 } $template->query(loop => 'EnableViews');
 429 # method query not found?!?!
 430 $template->param( AmazonTld => get_amazon_tld() ) if ( C4::Context->preference("AmazonCoverImages"));
 431 $template->param(
 432     itemloop        => \@itemloop,
 433     otheritemloop   => \@otheritemloop,
 434     biblionumber        => $biblionumber,
 435     ($analyze? 'analyze':'detailview') =>1,
 436     subscriptions       => \@subs,
 437     subscriptionsnumber => $subscriptionsnumber,
 438     subscriptiontitle   => $dat->{title},
 439     searchid            => scalar $query->param('searchid'),
 440 );
 441
 442 # $debug and $template->param(debug_display => 1);
 443
 444 # Lists
 445
 446 if (C4::Context->preference("virtualshelves") ) {
 447     my $shelves = Koha::Virtualshelves->search(
 448         {
 449             biblionumber => $biblionumber,
 450             category => 2,
 451         },
 452         {
 453             join => 'virtualshelfcontents',
 454         }
 455     );
 456     $template->param( 'shelves' => $shelves );
 457 }
 458
 459 # XISBN Stuff
 460 if (C4::Context->preference("FRBRizeEditions")==1) {
 461     eval {
 462         $template->param(
 463             XISBNS => scalar get_xisbns($isbn)
 464         );
 465     };
 466     if ($@) { warn "XISBN Failed $@"; }
 467 }
 468
 469 if ( C4::Context->preference("LocalCoverImages") == 1 ) {
 470     my @images = ListImagesForBiblio($biblionumber);
 471     $template->{VARS}->{localimages} = \@images;
 472 }
 473
 474 # HTML5 Media
 475 if ( (C4::Context->preference("HTML5MediaEnabled") eq 'both') or (C4::Context->preference("HTML5MediaEnabled") eq 'staff') ) {
 476     $template->param( C4::HTML5Media->gethtml5media($record));
 477 }
 478
 479 # Displaying tags
 480
 481 my $tag_quantity;
 482 if (C4::Context->preference('TagsEnabled') and $tag_quantity = C4::Context->preference('TagsShowOnDetail')) {
 483     $template->param(
 484         TagsEnabled => 1,
 485         TagsShowOnDetail => $tag_quantity
 486     );
 487     $template->param(TagLoop => get_tags({biblionumber=>$biblionumber, approved=>1,
 488                                 'sort'=>'-weight', limit=>$tag_quantity}));
 489 }
 490
 491 #we only need to pass the number of holds to the template
 492 my $biblio = Koha::Biblios->find( $biblionumber );
 493 my $holds = $biblio->holds;
 494 $template->param( holdcount => $holds->count );
 495
 496 my $StaffDetailItemSelection = C4::Context->preference('StaffDetailItemSelection');
 497 if ($StaffDetailItemSelection) {
 498     # Only enable item selection if user can execute at least one action
 499     if (
 500         $flags->{superlibrarian}
 501         || (
 502             ref $flags->{tools} eq 'HASH' && (
 503                 $flags->{tools}->{items_batchmod}       # Modify selected items
 504                 || $flags->{tools}->{items_batchdel}    # Delete selected items
 505             )
 506         )
 507         || ( ref $flags->{tools} eq '' && $flags->{tools} )
 508       )
 509     {
 510         $template->param(
 511             StaffDetailItemSelection => $StaffDetailItemSelection );
 512     }
 513 }
 514
 515 my @allorders_using_biblio = GetOrdersByBiblionumber ($biblionumber);
 516 my @deletedorders_using_biblio;
 517 my @orders_using_biblio;
 518 my @baskets_orders;
 519 my @baskets_deletedorders;
 520
 521 foreach my $myorder (@allorders_using_biblio) {
 522     my $basket = $myorder->{'basketno'};
 523     if ((defined $myorder->{'datecancellationprinted'}) and  ($myorder->{'datecancellationprinted'} ne '0000-00-00') ){
 524         push @deletedorders_using_biblio, $myorder;
 525         unless (grep(/^$basket$/, @baskets_deletedorders)){
 526             push @baskets_deletedorders,$myorder->{'basketno'};
 527         }
 528     }
 529     else {
 530         push @orders_using_biblio, $myorder;
 531         unless (grep(/^$basket$/, @baskets_orders)){
 532             push @baskets_orders,$myorder->{'basketno'};
 533             }
 534     }
 535 }
 536
 537 my $count_orders_using_biblio = scalar @orders_using_biblio ;
 538 $template->param (countorders => $count_orders_using_biblio);
 539
 540 my $count_deletedorders_using_biblio = scalar @deletedorders_using_biblio ;
 541 $template->param (countdeletedorders => $count_deletedorders_using_biblio);
 542
 543 $template->param (basketsorders => \@baskets_orders);
 544 $template->param (basketsdeletedorders => \@baskets_deletedorders);
 545
 546 output_html_with_http_headers $query, $cookie, $template->output;