Koha/Template/Plugin/Branches.pm

   1 package Koha::Template::Plugin::Branches;
   2
   3 # Copyright ByWater Solutions 2012
   4 # Copyright BibLibre 2014
   5
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Template::Plugin;
  24 use base qw( Template::Plugin );
  25
  26 use C4::Koha;
  27 use C4::Context;
  28 use Koha::Libraries;
  29
  30 sub GetName {
  31     my ( $self, $branchcode ) = @_;
  32
  33     my $query = "SELECT branchname FROM branches WHERE branchcode = ?";
  34     my $sth   = C4::Context->dbh->prepare($query);
  35     $sth->execute($branchcode);
  36     my $b = $sth->fetchrow_hashref();
  37     return $b ? $b->{'branchname'} : q{};
  38 }
  39
  40 sub GetLoggedInBranchcode {
  41     my ($self) = @_;
  42
  43     return C4::Context->userenv ?
  44         C4::Context->userenv->{'branch'} :
  45         '';
  46 }
  47
  48 sub GetURL {
  49     my ( $self, $branchcode ) = @_;
  50
  51     my $query = "SELECT branchurl FROM branches WHERE branchcode = ?";
  52     my $sth   = C4::Context->dbh->prepare($query);
  53     $sth->execute($branchcode);
  54     my $b = $sth->fetchrow_hashref();
  55     return $b->{branchurl};
  56 }
  57
  58 sub all {
  59     my ( $self, $params ) = @_;
  60     my $selected = $params->{selected};
  61     my $unfiltered = $params->{unfiltered} || 0;
  62     my $search_params = $params->{search_params} || {};
  63
  64     if ( !$unfiltered ) {
  65         $search_params->{only_from_group} = $params->{only_from_group} || 0;
  66     }
  67
  68     my $libraries = $unfiltered
  69       ? Koha::Libraries->search( $search_params, { order_by => ['branchname'] } )->unblessed
  70       : Koha::Libraries->search_filtered( $search_params, { order_by => ['branchname'] } )->unblessed;
  71
  72     for my $l ( @$libraries ) {
  73         if (       defined $selected and $l->{branchcode} eq $selected
  74             or not defined $selected and C4::Context->userenv and $l->{branchcode} eq ( C4::Context->userenv->{branch} // q{} )
  75         ) {
  76             $l->{selected} = 1;
  77         }
  78     }
  79
  80     return $libraries;
  81 }
  82
  83 sub InIndependentBranchesMode {
  84     my ( $self ) = @_;
  85     return ( not C4::Context->preference("IndependentBranches") or C4::Context::IsSuperLibrarian );
  86 }
  87
  88 sub pickup_locations {
  89     my ( $self, $params ) = @_;
  90     my $search_params = $params->{search_params} || {};
  91     my $selected      = $params->{selected};
  92     my @libraries;
  93
  94     if(defined $search_params->{item} || defined $search_params->{biblio}) {
  95         my $item = $search_params->{'item'};
  96         my $biblio = $search_params->{'biblio'};
  97         my $patron = $search_params->{'patron'};
  98
  99         unless (! defined $patron || ref($patron) eq 'Koha::Patron') {
 100             $patron = Koha::Patrons->find($patron);
 101         }
 102
 103         if($item) {
 104             $item = Koha::Items->find($item) unless ref($item) eq 'Koha::Item';
 105             @libraries = map { $_->unblessed } $item->pickup_locations( {patron => $patron} ) if defined $item;
 106         } elsif($biblio) {
 107             $biblio = Koha::Biblios->find($biblio) unless ref($biblio) eq 'Koha::Biblio';
 108             @libraries = map { $_->unblessed } $biblio->pickup_locations( {patron => $patron} ) if defined $biblio;
 109         }
 110
 111     }
 112
 113     @libraries = Koha::Libraries->pickup_locations() unless @libraries;
 114
 115     for my $l (@libraries) {
 116         if ( defined $selected and $l->{branchcode} eq $selected
 117             or not defined $selected
 118             and C4::Context->userenv
 119             and $l->{branchcode} eq C4::Context->userenv->{branch} )
 120         {
 121             $l->{selected} = 1;
 122         }
 123     }
 124
 125     return \@libraries;
 126 }
 127
 128 1;