Koha/SharedContent.pm

   1 package Koha::SharedContent;
   2
   3 # Copyright 2016 BibLibre Morgane Alonso
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21 use JSON;
  22 use HTTP::Request;
  23 use LWP::UserAgent;
  24
  25 use Koha::Serials;
  26 use Koha::Reports;
  27 use C4::Context;
  28
  29 =head1 NAME
  30
  31 Koha::SharedContent - Set of methods for querying Mana KB server
  32
  33 =head1 DESCRIPTION
  34
  35 Package for accessing shared content via Mana KB. Methods here are intended
  36 to build and process queries for requesting from Mana KB server.
  37
  38 =cut
  39
  40 =head2 process_request
  41
  42 Koha::SharedContent::process_request($request);
  43
  44 Send a request to Mana KB server. URL is defined in koha-conf.xml in mana_config
  45 tag. $request parameter must be a HTTP::Request object. See build_request method.
  46
  47 =cut
  48
  49 sub process_request {
  50     my $mana_request = shift;
  51     my $result;
  52     $mana_request->content_type('application/json');
  53     my $userAgent = LWP::UserAgent->new;
  54     if ( $mana_request->method eq "POST" ){
  55         my $content;
  56         if ($mana_request->content) {$content = from_json( $mana_request->content )};
  57         $content->{securitytoken} = C4::Context->preference("ManaToken");
  58         $mana_request->content( to_json($content) );
  59     }
  60
  61     my $response = $userAgent->request($mana_request);
  62
  63     eval { $result = from_json( $response->decoded_content, { utf8 => 1} ); };
  64     $result->{code} = $response->code;
  65     if ( $@ ){
  66         $result->{msg} = $@;
  67     }
  68     if ($response->is_error){
  69         $result->{msg} = "An error occurred, mana server returned: " . $response->message;
  70     }
  71     return $result ;
  72 }
  73
  74 =head2 increment_entity_value
  75
  76 Koha::SharedContent::increment_entity_value($entity_type, $mana_entity_id, $field);
  77
  78 Increment by 1 the field $field of a Mana entity. I.e, this is used to count the number
  79 of Koha instances using a specific entity.
  80
  81 =cut
  82
  83 sub increment_entity_value {
  84     return process_request(build_request('increment', @_));
  85 }
  86
  87 =head2 send_entity
  88
  89 my $result = Koha::SharedContent::send_entity($language, $borrowernumber, $mana_entity_id, $entity_type);
  90
  91 Share a Koha entity (i.e subscription or report) to Mana KB.
  92
  93 =cut
  94
  95 sub send_entity {
  96     my ($lang, $loggedinuser, $resourceid, $resourcetype, $content) = @_;
  97
  98     unless ( $content ) {
  99         $content = prepare_entity_data($lang, $loggedinuser, $resourceid, $resourcetype);
 100     }
 101
 102     my $result = process_request(build_request('post', $resourcetype, $content));
 103
 104     if ( $result and ($result->{code} eq "200" or $result->{code} eq "201") ) {
 105         my $packages = "Koha::".ucfirst($resourcetype)."s";
 106         my $resource = $packages->find($resourceid);
 107         eval { $resource->set( { mana_id => $result->{id} } )->store };
 108     }
 109     return $result;
 110 }
 111
 112 =head2 prepare_entity_data
 113
 114 $data = prepare_entity_data($language, $borrowernumber, $mana_entity_id, $entity_type);
 115
 116 Prepare Koha entity data to be sent to Mana KB.
 117
 118 =cut
 119
 120 sub prepare_entity_data {
 121     my ($lang, $loggedinuser, $ressourceid, $ressourcetype) = @_;
 122     $lang ||= C4::Context->preference('language');
 123
 124     my $mana_email;
 125     if ( $loggedinuser ne 0 ) {
 126         my $borrower = Koha::Patrons->find($loggedinuser);
 127         $mana_email = $borrower->first_valid_email_address
 128             || Koha::Libraries->find( C4::Context->userenv->{'branch'} )->branchemail
 129     }
 130     $mana_email = C4::Context->preference('KohaAdminEmailAddress')
 131       if ( ( not defined($mana_email) ) or ( $mana_email eq '' ) );
 132
 133     my %versions = C4::Context::get_versions();
 134
 135     my $mana_info = {
 136         language    => $lang,
 137         kohaversion => $versions{'kohaVersion'},
 138         exportemail => $mana_email
 139     };
 140
 141     my $ressource_mana_info;
 142     my $packages = "Koha::".ucfirst($ressourcetype)."s";
 143     my $package = "Koha::".ucfirst($ressourcetype);
 144     $ressource_mana_info = $package->get_sharable_info($ressourceid);
 145     $ressource_mana_info = { %$ressource_mana_info, %$mana_info };
 146
 147     return $ressource_mana_info;
 148 }
 149
 150 =head2 get_entity_by_id
 151
 152 my $entity = Koha::SharedContent::get_entity_by_id($entity_type, $mana_entity_id, [{usecomments => 1}]);
 153
 154 Retrieve a Mana entity to be imported into Koha. Add {usecomments => 1} to tell Mana to
 155 embed all user reviews.
 156
 157 =cut
 158
 159 sub get_entity_by_id {
 160     return process_request(build_request('getwithid', @_));
 161 }
 162
 163 =head2 search_entities
 164
 165 my $result = Koha::SharedContent::search_entities( $entity_type, $search_params );
 166 my $entities = $result->{data};
 167
 168 Search entities on ManaKB.
 169
 170 =cut
 171
 172 sub search_entities {
 173     return process_request(build_request('get', @_));
 174 }
 175
 176 =head2 build_request
 177
 178 $request = build_request($mana_method, [$param1, $param2, ...]);
 179
 180 Create a HTTP::Request object to be passed to process_request.
 181
 182 =cut
 183
 184 sub build_request {
 185     my $type = shift;
 186     my $resource = shift;
 187     my $mana_url = get_sharing_url();
 188
 189     if ( $type eq 'get' ) {
 190         my $params = shift;
 191         $params = join '&',
 192             map { defined $params->{$_} && $params->{$_} ne '' ? $_ . "=" . $params->{$_} : () }
 193             keys %$params;
 194         my $url = "$mana_url/$resource.json?$params";
 195         return HTTP::Request->new( GET => $url );
 196     }
 197
 198     if ( $type eq 'getwithid' ) {
 199         my $id = shift;
 200         my $params = shift;
 201         $params = join '&',
 202             map { defined $params->{$_} && $params->{$_} ne '' ? $_ . "=" . $params->{$_} : () }
 203             keys %$params;
 204
 205         my $url = "$mana_url/$resource/$id.json?$params";
 206         return HTTP::Request->new( GET => $url );
 207     }
 208
 209     if ( $type eq 'post' ) {
 210         my $content  = shift;
 211
 212         my $url = "$mana_url/$resource.json";
 213         my $request = HTTP::Request->new( POST => $url );
 214
 215         my $json = to_json( $content, { utf8 => 1 } );
 216         $request->content($json);
 217
 218         return $request;
 219     }
 220
 221     if ( $type eq 'increment' ) {
 222         my $id       = shift;
 223         my $field    = shift;
 224         my $step     = shift;
 225         my $param;
 226
 227         $param->{step} = $step || 1;
 228         $param->{id} = $id;
 229         $param->{resource} = $resource;
 230         $param = join '&',
 231            map { defined $param->{$_} ? $_ . "=" . $param->{$_} : () }
 232                keys %$param;
 233         my $url = "$mana_url/$resource/$id.json/increment/$field?$param";
 234         my $request = HTTP::Request->new( POST => $url );
 235
 236     }
 237 }
 238
 239 =head2 get_sharing_url
 240
 241 my $mana_url = get_sharing_url();
 242
 243 Get the Mana KB server URL set in koha config file.
 244
 245 =cut
 246
 247 sub get_sharing_url {
 248     return C4::Context->config('mana_config');
 249 }
 250
 251 1;