C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio;
  28 use C4::Circulation;
  29 use C4::Context;
  30 use C4::Items;
  31 use C4::Letters;
  32 use C4::Log;
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::Biblios;
  37 use Koha::Calendar;
  38 use Koha::CirculationRules;
  39 use Koha::Database;
  40 use Koha::DateUtils;
  41 use Koha::Hold;
  42 use Koha::Holds;
  43 use Koha::ItemTypes;
  44 use Koha::Items;
  45 use Koha::Libraries;
  46 use Koha::Old::Hold;
  47 use Koha::Patrons;
  48 use Koha::Plugins;
  49
  50 use Carp;
  51 use Data::Dumper;
  52 use List::MoreUtils qw( firstidx any );
  53
  54 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  55
  56 =head1 NAME
  57
  58 C4::Reserves - Koha functions for dealing with reservation.
  59
  60 =head1 SYNOPSIS
  61
  62   use C4::Reserves;
  63
  64 =head1 DESCRIPTION
  65
  66 This modules provides somes functions to deal with reservations.
  67
  68   Reserves are stored in reserves table.
  69   The following columns contains important values :
  70   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  71              =0      : then the reserve is being dealed
  72   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  73             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  74             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  75             F(inished) : the reserve has been completed, and is done
  76   - itemnumber : empty : the reserve is still unaffected to an item
  77                  filled: the reserve is attached to an item
  78   The complete workflow is :
  79   ==== 1st use case ====
  80   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  81   a library having it run "transfertodo", and clic on the list
  82          if there is no transfer to do, the reserve waiting
  83          patron can pick it up                                    P =0, F=W,    I=filled
  84          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  85            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  86   The patron borrow the book                                      P =0, F=F,    I=filled
  87
  88   ==== 2nd use case ====
  89   patron requests a document, a given item,
  90     If pickup is holding branch                                   P =0, F=W,   I=filled
  91     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  92         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  93   The patron borrow the book                                      P =0, F=F,    I=filled
  94
  95 =head1 FUNCTIONS
  96
  97 =cut
  98
  99 BEGIN {
 100     require Exporter;
 101     @ISA = qw(Exporter);
 102     @EXPORT = qw(
 103         &AddReserve
 104
 105         &GetReserveStatus
 106
 107         &GetOtherReserves
 108
 109         &ModReserveFill
 110         &ModReserveAffect
 111         &ModReserve
 112         &ModReserveStatus
 113         &ModReserveCancelAll
 114         &ModReserveMinusPriority
 115         &MoveReserve
 116
 117         &CheckReserves
 118         &CanBookBeReserved
 119         &CanItemBeReserved
 120         &CanReserveBeCanceledFromOpac
 121         &CancelExpiredReserves
 122
 123         &AutoUnsuspendReserves
 124
 125         &IsAvailableForItemLevelRequest
 126         ItemsAnyAvailableAndNotRestricted
 127
 128         &AlterPriority
 129         &ToggleLowestPriority
 130
 131         &ReserveSlip
 132         &ToggleSuspend
 133         &SuspendAll
 134
 135         &GetReservesControlBranch
 136
 137         IsItemOnHoldAndFound
 138
 139         GetMaxPatronHoldsForRecord
 140     );
 141     @EXPORT_OK = qw( MergeHolds );
 142 }
 143
 144 =head2 AddReserve
 145
 146     AddReserve(
 147         {
 148             branchcode       => $branchcode,
 149             borrowernumber   => $borrowernumber,
 150             biblionumber     => $biblionumber,
 151             priority         => $priority,
 152             reservation_date => $reservation_date,
 153             expiration_date  => $expiration_date,
 154             notes            => $notes,
 155             title            => $title,
 156             itemnumber       => $itemnumber,
 157             found            => $found,
 158             itemtype         => $itemtype,
 159         }
 160     );
 161
 162 Adds reserve and generates HOLDPLACED message.
 163
 164 The following tables are available witin the HOLDPLACED message:
 165
 166     branches
 167     borrowers
 168     biblio
 169     biblioitems
 170     items
 171     reserves
 172
 173 =cut
 174
 175 sub AddReserve {
 176     my ($params)       = @_;
 177     my $branch         = $params->{branchcode};
 178     my $borrowernumber = $params->{borrowernumber};
 179     my $biblionumber   = $params->{biblionumber};
 180     my $priority       = $params->{priority};
 181     my $resdate        = $params->{reservation_date};
 182     my $expdate        = $params->{expiration_date};
 183     my $notes          = $params->{notes};
 184     my $title          = $params->{title};
 185     my $checkitem      = $params->{itemnumber};
 186     my $found          = $params->{found};
 187     my $itemtype       = $params->{itemtype};
 188
 189     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 190         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 191
 192     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 193
 194     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 195     # of the document, we force the value $priority and $found .
 196     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 197         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 198
 199         if (
 200             # If item is already checked out, it cannot be set waiting
 201             !$item->onloan
 202
 203             # The item can't be waiting if it needs a transfer
 204             && $item->holdingbranch eq $branch
 205
 206             # Similarly, if in transit it can't be waiting
 207             && !$item->get_transfer
 208
 209             # If we can't hold damaged items, and it is damaged, it can't be waiting
 210             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 211
 212             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 213             && !$item->current_holds->count )
 214         {
 215             $priority = 0;
 216             $found = 'W';
 217         }
 218     }
 219
 220     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 221
 222         # Make room in reserves for this before those of a later reserve date
 223         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 224     }
 225
 226     my $waitingdate;
 227
 228     # If the reserv had the waiting status, we had the value of the resdate
 229     if ( $found && $found eq 'W' ) {
 230         $waitingdate = $resdate;
 231     }
 232
 233     # Don't add itemtype limit if specific item is selected
 234     $itemtype = undef if $checkitem;
 235
 236     # updates take place here
 237     my $hold = Koha::Hold->new(
 238         {
 239             borrowernumber => $borrowernumber,
 240             biblionumber   => $biblionumber,
 241             reservedate    => $resdate,
 242             branchcode     => $branch,
 243             priority       => $priority,
 244             reservenotes   => $notes,
 245             itemnumber     => $checkitem,
 246             found          => $found,
 247             waitingdate    => $waitingdate,
 248             expirationdate => $expdate,
 249             itemtype       => $itemtype,
 250             item_level_hold => $checkitem ? 1 : 0,
 251         }
 252     )->store();
 253     $hold->set_waiting() if $found && $found eq 'W';
 254
 255     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 256         if C4::Context->preference('HoldsLog');
 257
 258     my $reserve_id = $hold->id();
 259
 260     # add a reserve fee if needed
 261     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 262         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 263         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 264     }
 265
 266     _FixPriority({ biblionumber => $biblionumber});
 267
 268     # Send e-mail to librarian if syspref is active
 269     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 270         my $patron = Koha::Patrons->find( $borrowernumber );
 271         my $library = $patron->library;
 272         if ( my $letter =  C4::Letters::GetPreparedLetter (
 273             module => 'reserves',
 274             letter_code => 'HOLDPLACED',
 275             branchcode => $branch,
 276             lang => $patron->lang,
 277             tables => {
 278                 'branches'    => $library->unblessed,
 279                 'borrowers'   => $patron->unblessed,
 280                 'biblio'      => $biblionumber,
 281                 'biblioitems' => $biblionumber,
 282                 'items'       => $checkitem,
 283                 'reserves'    => $hold->unblessed,
 284             },
 285         ) ) {
 286
 287             my $branch_email_address = $library->inbound_email_address;
 288
 289             C4::Letters::EnqueueLetter(
 290                 {
 291                     letter                 => $letter,
 292                     borrowernumber         => $borrowernumber,
 293                     message_transport_type => 'email',
 294                     to_address             => $branch_email_address,
 295                 }
 296             );
 297         }
 298     }
 299
 300     Koha::Plugins->call('after_hold_create', $hold);
 301
 302     return $reserve_id;
 303 }
 304
 305 =head2 CanBookBeReserved
 306
 307   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode, $params)
 308   if ($canReserve eq 'OK') { #We can reserve this Item! }
 309
 310   $params are passed directly through to CanItemBeReserved
 311
 312 See CanItemBeReserved() for possible return values.
 313
 314 =cut
 315
 316 sub CanBookBeReserved{
 317     my ($borrowernumber, $biblionumber, $pickup_branchcode, $params) = @_;
 318
 319     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 320     #get items linked via host records
 321     my @hostitems = get_hostitemnumbers_of($biblionumber);
 322     if (@hostitems){
 323         push (@itemnumbers, @hostitems);
 324     }
 325
 326     my $canReserve = { status => '' };
 327     foreach my $itemnumber (@itemnumbers) {
 328         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode, $params );
 329         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 330     }
 331     return $canReserve;
 332 }
 333
 334 =head2 CanItemBeReserved
 335
 336   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode, $params)
 337   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 338
 339   current params are 'ignore_found_holds' - if true holds that have been trapped are not counted
 340   toward the patron limit, used by checkHighHolds to avoid counting the hold we will fill with the
 341   current checkout against the high holds threshold
 342
 343 @RETURNS { status => OK },              if the Item can be reserved.
 344          { status => ageRestricted },   if the Item is age restricted for this borrower.
 345          { status => damaged },         if the Item is damaged.
 346          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 347          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 348          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 349          { status => notReservable },   if holds on this item are not allowed
 350          { status => libraryNotFound },   if given branchcode is not an existing library
 351          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 352          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 353          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 354
 355 =cut
 356
 357 sub CanItemBeReserved {
 358     my ( $borrowernumber, $itemnumber, $pickup_branchcode, $params ) = @_;
 359
 360     my $dbh = C4::Context->dbh;
 361     my $ruleitemtype;    # itemtype of the matching issuing rule
 362     my $allowedreserves  = 0; # Total number of holds allowed across all records
 363     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 364     my $holds_per_day;        # Default to unlimited
 365
 366     # we retrieve borrowers and items informations #
 367     # item->{itype} will come for biblioitems if necessery
 368     my $item       = Koha::Items->find($itemnumber);
 369     my $biblio     = $item->biblio;
 370     my $patron = Koha::Patrons->find( $borrowernumber );
 371     my $borrower = $patron->unblessed;
 372
 373     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 374     return { status =>'damaged' }
 375       if ( $item->damaged
 376         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 377
 378     # Check for the age restriction
 379     my ( $ageRestriction, $daysToAgeRestriction ) =
 380       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 381     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 382
 383     # Check that the patron doesn't have an item level hold on this item already
 384     return { status =>'itemAlreadyOnHold' }
 385       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 386
 387     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 388
 389     my $querycount = q{
 390         SELECT count(*) AS count
 391           FROM reserves
 392      LEFT JOIN items USING (itemnumber)
 393      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 394      LEFT JOIN borrowers USING (borrowernumber)
 395          WHERE borrowernumber = ?
 396     };
 397
 398     my $branchcode  = "";
 399     my $branchfield = "reserves.branchcode";
 400
 401     if ( $controlbranch eq "ItemHomeLibrary" ) {
 402         $branchfield = "items.homebranch";
 403         $branchcode  = $item->homebranch;
 404     }
 405     elsif ( $controlbranch eq "PatronLibrary" ) {
 406         $branchfield = "borrowers.branchcode";
 407         $branchcode  = $borrower->{branchcode};
 408     }
 409
 410     # we retrieve rights
 411     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->effective_itemtype, $branchcode ) ) {
 412         $ruleitemtype     = $rights->{itemtype};
 413         $allowedreserves  = $rights->{reservesallowed} // $allowedreserves;
 414         $holds_per_record = $rights->{holds_per_record} // $holds_per_record;
 415         $holds_per_day    = $rights->{holds_per_day};
 416     }
 417     else {
 418         $ruleitemtype = undef;
 419     }
 420
 421     my $search_params = {
 422         borrowernumber => $borrowernumber,
 423         biblionumber   => $item->biblionumber,
 424     };
 425     $search_params->{found} = undef if $params->{ignore_found_holds};
 426
 427     my $holds = Koha::Holds->search($search_params);
 428     if (   defined $holds_per_record && $holds_per_record ne ''
 429         && $holds->count() >= $holds_per_record ) {
 430         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 431     }
 432
 433     my $today_holds = Koha::Holds->search({
 434         borrowernumber => $borrowernumber,
 435         reservedate    => dt_from_string->date
 436     });
 437
 438     if (   defined $holds_per_day && $holds_per_day ne ''
 439         && $today_holds->count() >= $holds_per_day )
 440     {
 441         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 442     }
 443
 444     # we retrieve count
 445
 446     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 447
 448     # If using item-level itypes, fall back to the record
 449     # level itemtype if the hold has no associated item
 450     $querycount .=
 451       C4::Context->preference('item-level_itypes')
 452       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 453       : " AND biblioitems.itemtype = ?"
 454       if defined $ruleitemtype;
 455
 456     my $sthcount = $dbh->prepare($querycount);
 457
 458     if ( defined $ruleitemtype ) {
 459         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 460     }
 461     else {
 462         $sthcount->execute( $borrowernumber, $branchcode );
 463     }
 464
 465     my $reservecount = "0";
 466     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 467         $reservecount = $rowcount->{count};
 468     }
 469
 470     # we check if it's ok or not
 471     if (   defined  $allowedreserves && $allowedreserves ne ''
 472         && $reservecount >= $allowedreserves ) {
 473         return { status => 'tooManyReserves', limit => $allowedreserves };
 474     }
 475
 476     # Now we need to check hold limits by patron category
 477     my $rule = Koha::CirculationRules->get_effective_rule(
 478         {
 479             categorycode => $borrower->{categorycode},
 480             branchcode   => $branchcode,
 481             rule_name    => 'max_holds',
 482         }
 483     );
 484     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 485         my $total_holds_count = Koha::Holds->search(
 486             {
 487                 borrowernumber => $borrower->{borrowernumber}
 488             }
 489         )->count();
 490
 491         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 492     }
 493
 494     my $reserves_control_branch =
 495       GetReservesControlBranch( $item->unblessed(), $borrower );
 496     my $branchitemrule =
 497       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 498
 499     if ( $branchitemrule->{holdallowed} == 0 ) {
 500         return { status => 'notReservable' };
 501     }
 502
 503     if (   $branchitemrule->{holdallowed} == 1
 504         && $borrower->{branchcode} ne $item->homebranch )
 505     {
 506         return { status => 'cannotReserveFromOtherBranches' };
 507     }
 508
 509     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 510     if ( $branchitemrule->{holdallowed} == 3) {
 511         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 512             return { status => 'branchNotInHoldGroup' };
 513         }
 514     }
 515
 516     # If reservecount is ok, we check item branch if IndependentBranches is ON
 517     # and canreservefromotherbranches is OFF
 518     if ( C4::Context->preference('IndependentBranches')
 519         and !C4::Context->preference('canreservefromotherbranches') )
 520     {
 521         if ( $item->homebranch ne $borrower->{branchcode} ) {
 522             return { status => 'cannotReserveFromOtherBranches' };
 523         }
 524     }
 525
 526     if ($pickup_branchcode) {
 527         my $destination = Koha::Libraries->find({
 528             branchcode => $pickup_branchcode,
 529         });
 530
 531         unless ($destination) {
 532             return { status => 'libraryNotFound' };
 533         }
 534         unless ($destination->pickup_location) {
 535             return { status => 'libraryNotPickupLocation' };
 536         }
 537         unless ($item->can_be_transferred({ to => $destination })) {
 538             return { status => 'cannotBeTransferred' };
 539         }
 540         unless ($branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 541             return { status => 'pickupNotInHoldGroup' };
 542         }
 543         unless ($branchitemrule->{hold_fulfillment_policy} ne 'patrongroup' || Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 544             return { status => 'pickupNotInHoldGroup' };
 545         }
 546     }
 547
 548     return { status => 'OK' };
 549 }
 550
 551 =head2 CanReserveBeCanceledFromOpac
 552
 553     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 554
 555     returns 1 if reserve can be cancelled by user from OPAC.
 556     First check if reserve belongs to user, next checks if reserve is not in
 557     transfer or waiting status
 558
 559 =cut
 560
 561 sub CanReserveBeCanceledFromOpac {
 562     my ($reserve_id, $borrowernumber) = @_;
 563
 564     return unless $reserve_id and $borrowernumber;
 565     my $reserve = Koha::Holds->find($reserve_id);
 566
 567     return 0 unless $reserve->borrowernumber == $borrowernumber;
 568     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 569
 570     return 1;
 571
 572 }
 573
 574 =head2 GetOtherReserves
 575
 576   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 577
 578 Check queued list of this document and check if this document must be transferred
 579
 580 =cut
 581
 582 sub GetOtherReserves {
 583     my ($itemnumber) = @_;
 584     my $messages;
 585     my $nextreservinfo;
 586     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 587     if ($checkreserves) {
 588         my $item = Koha::Items->find($itemnumber);
 589         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 590             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 591             #minus priorities of others reservs
 592             ModReserveMinusPriority(
 593                 $itemnumber,
 594                 $checkreserves->{'reserve_id'},
 595             );
 596
 597             #launch the subroutine dotransfer
 598             C4::Items::ModItemTransfer(
 599                 $itemnumber,
 600                 $item->holdingbranch,
 601                 $checkreserves->{'branchcode'},
 602                 'Reserve'
 603               ),
 604               ;
 605         }
 606
 607      #step 2b : case of a reservation on the same branch, set the waiting status
 608         else {
 609             $messages->{'waiting'} = 1;
 610             ModReserveMinusPriority(
 611                 $itemnumber,
 612                 $checkreserves->{'reserve_id'},
 613             );
 614             ModReserveStatus($itemnumber,'W');
 615         }
 616
 617         $nextreservinfo = $checkreserves;
 618     }
 619
 620     return ( $messages, $nextreservinfo );
 621 }
 622
 623 =head2 ChargeReserveFee
 624
 625     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 626
 627     Charge the fee for a reserve (if $fee > 0)
 628
 629 =cut
 630
 631 sub ChargeReserveFee {
 632     my ( $borrowernumber, $fee, $title ) = @_;
 633     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 634     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 635         {
 636             amount       => $fee,
 637             description  => $title,
 638             note         => undef,
 639             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 640             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 641             interface    => C4::Context->interface,
 642             invoice_type => undef,
 643             type         => 'RESERVE',
 644             item_id      => undef
 645         }
 646     );
 647 }
 648
 649 =head2 GetReserveFee
 650
 651     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 652
 653     Calculate the fee for a reserve (if applicable).
 654
 655 =cut
 656
 657 sub GetReserveFee {
 658     my ( $borrowernumber, $biblionumber ) = @_;
 659     my $borquery = qq{
 660 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 661     };
 662     my $issue_qry = qq{
 663 SELECT COUNT(*) FROM items
 664 LEFT JOIN issues USING (itemnumber)
 665 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 666     };
 667     my $holds_qry = qq{
 668 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 669     };
 670
 671     my $dbh = C4::Context->dbh;
 672     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 673     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 674     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 675         # This is a reconstruction of the old code:
 676         # Compare number of items with items issued, and optionally check holds
 677         # If not all items are issued and there are no holds: charge no fee
 678         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 679         my ( $notissued, $reserved );
 680         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 681             ( $biblionumber ) );
 682         if( $notissued ) {
 683             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 684                 ( $biblionumber, $borrowernumber ) );
 685             $fee = 0 if $reserved == 0;
 686         }
 687     }
 688     return $fee;
 689 }
 690
 691 =head2 GetReserveStatus
 692
 693   $reservestatus = GetReserveStatus($itemnumber);
 694
 695 Takes an itemnumber and returns the status of the reserve placed on it.
 696 If several reserves exist, the reserve with the lower priority is given.
 697
 698 =cut
 699
 700 ## FIXME: I don't think this does what it thinks it does.
 701 ## It only ever checks the first reserve result, even though
 702 ## multiple reserves for that bib can have the itemnumber set
 703 ## the sub is only used once in the codebase.
 704 sub GetReserveStatus {
 705     my ($itemnumber) = @_;
 706
 707     my $dbh = C4::Context->dbh;
 708
 709     my ($sth, $found, $priority);
 710     if ( $itemnumber ) {
 711         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 712         $sth->execute($itemnumber);
 713         ($found, $priority) = $sth->fetchrow_array;
 714     }
 715
 716     if(defined $found) {
 717         return 'Waiting'  if $found eq 'W' and $priority == 0;
 718         return 'Finished' if $found eq 'F';
 719     }
 720
 721     return 'Reserved' if defined $priority && $priority > 0;
 722
 723     return ''; # empty string here will remove need for checking undef, or less log lines
 724 }
 725
 726 =head2 CheckReserves
 727
 728   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 729   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 730   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 731
 732 Find a book in the reserves.
 733
 734 C<$itemnumber> is the book's item number.
 735 C<$lookahead> is the number of days to look in advance for future reserves.
 736
 737 As I understand it, C<&CheckReserves> looks for the given item in the
 738 reserves. If it is found, that's a match, and C<$status> is set to
 739 C<Waiting>.
 740
 741 Otherwise, it finds the most important item in the reserves with the
 742 same biblio number as this book (I'm not clear on this) and returns it
 743 with C<$status> set to C<Reserved>.
 744
 745 C<&CheckReserves> returns a two-element list:
 746
 747 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 748
 749 C<$reserve> is the reserve item that matched. It is a
 750 reference-to-hash whose keys are mostly the fields of the reserves
 751 table in the Koha database.
 752
 753 =cut
 754
 755 sub CheckReserves {
 756     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 757     my $dbh = C4::Context->dbh;
 758     my $sth;
 759     my $select;
 760     if (C4::Context->preference('item-level_itypes')){
 761         $select = "
 762            SELECT items.biblionumber,
 763            items.biblioitemnumber,
 764            itemtypes.notforloan,
 765            items.notforloan AS itemnotforloan,
 766            items.itemnumber,
 767            items.damaged,
 768            items.homebranch,
 769            items.holdingbranch
 770            FROM   items
 771            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 772            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 773         ";
 774     }
 775     else {
 776         $select = "
 777            SELECT items.biblionumber,
 778            items.biblioitemnumber,
 779            itemtypes.notforloan,
 780            items.notforloan AS itemnotforloan,
 781            items.itemnumber,
 782            items.damaged,
 783            items.homebranch,
 784            items.holdingbranch
 785            FROM   items
 786            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 787            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 788         ";
 789     }
 790
 791     if ($item) {
 792         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 793         $sth->execute($item);
 794     }
 795     else {
 796         $sth = $dbh->prepare("$select WHERE barcode = ?");
 797         $sth->execute($barcode);
 798     }
 799     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 800     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 801     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 802
 803     return unless $itemnumber; # bail if we got nothing.
 804     # if item is not for loan it cannot be reserved either.....
 805     # except where items.notforloan < 0 :  This indicates the item is holdable.
 806
 807     my @SkipHoldTrapOnNotForLoanValue = split( '|', C4::Context->preference('SkipHoldTrapOnNotForLoanValue') );
 808     return if @SkipHoldTrapOnNotForLoanValue && grep( $notforloan_per_item, @SkipHoldTrapOnNotForLoanValue );
 809
 810     my $dont_trap = C4::Context->preference('TrapHoldsOnOrder') ? ($notforloan_per_item > 0) : ($notforloan_per_item && 1 );
 811     return if $dont_trap or $notforloan_per_itemtype;
 812
 813     # Find this item in the reserves
 814     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 815
 816     # $priority and $highest are used to find the most important item
 817     # in the list returned by &_Findgroupreserve. (The lower $priority,
 818     # the more important the item.)
 819     # $highest is the most important item we've seen so far.
 820     my $highest;
 821
 822     if (scalar @reserves) {
 823         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 824         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 825         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 826
 827         my $priority = 10000000;
 828         foreach my $res (@reserves) {
 829             if ( $res->{'itemnumber'} && $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 830                 if ($res->{'found'} eq 'W') {
 831                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 832                 } else {
 833                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 834                 }
 835             } else {
 836                 my $patron;
 837                 my $item;
 838                 my $local_hold_match;
 839
 840                 if ($LocalHoldsPriority) {
 841                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 842                     $item = Koha::Items->find($itemnumber);
 843
 844                     my $local_holds_priority_item_branchcode =
 845                       $item->$LocalHoldsPriorityItemControl;
 846                     my $local_holds_priority_patron_branchcode =
 847                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 848                       ? $res->{branchcode}
 849                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 850                       ? $patron->branchcode
 851                       : undef;
 852                     $local_hold_match =
 853                       $local_holds_priority_item_branchcode eq
 854                       $local_holds_priority_patron_branchcode;
 855                 }
 856
 857                 # See if this item is more important than what we've got so far
 858                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 859                     $item ||= Koha::Items->find($itemnumber);
 860                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 861                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 862                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 863                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 864                     next if ($branchitemrule->{'holdallowed'} == 0);
 865                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 866                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 867                     next if (($branchitemrule->{'holdallowed'} == 3) && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 868                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 869                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 870                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 871                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 872                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 873                     $priority = $res->{'priority'};
 874                     $highest  = $res;
 875                     last if $local_hold_match;
 876                 }
 877             }
 878         }
 879     }
 880
 881     # If we get this far, then no exact match was found.
 882     # We return the most important (i.e. next) reservation.
 883     if ($highest) {
 884         $highest->{'itemnumber'} = $item;
 885         return ( "Reserved", $highest, \@reserves );
 886     }
 887
 888     return ( '' );
 889 }
 890
 891 =head2 CancelExpiredReserves
 892
 893   CancelExpiredReserves();
 894
 895 Cancels all reserves with an expiration date from before today.
 896
 897 =cut
 898
 899 sub CancelExpiredReserves {
 900     my $today = dt_from_string();
 901     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 902     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 903
 904     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 905     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 906     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 907
 908     # FIXME To move to Koha::Holds->search_expired (?)
 909     my $holds = Koha::Holds->search( $params );
 910
 911     while ( my $hold = $holds->next ) {
 912         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 913
 914         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 915
 916         my $cancel_params = {};
 917         if ( $hold->found eq 'W' ) {
 918             $cancel_params->{charge_cancel_fee} = 1;
 919         }
 920         $hold->cancel( $cancel_params );
 921     }
 922 }
 923
 924 =head2 AutoUnsuspendReserves
 925
 926   AutoUnsuspendReserves();
 927
 928 Unsuspends all suspended reserves with a suspend_until date from before today.
 929
 930 =cut
 931
 932 sub AutoUnsuspendReserves {
 933     my $today = dt_from_string();
 934
 935     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 936
 937     map { $_->resume() } @holds;
 938 }
 939
 940 =head2 ModReserve
 941
 942   ModReserve({ rank => $rank,
 943                reserve_id => $reserve_id,
 944                branchcode => $branchcode
 945                [, itemnumber => $itemnumber ]
 946                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 947               });
 948
 949 Change a hold request's priority or cancel it.
 950
 951 C<$rank> specifies the effect of the change.  If C<$rank>
 952 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 953 request alone when changing its priority in the holds queue
 954 for a bib.
 955
 956 If C<$rank> is 'del', the hold request is cancelled.
 957
 958 If C<$rank> is an integer greater than zero, the priority of
 959 the request is set to that value.  Since priority != 0 means
 960 that the item is not waiting on the hold shelf, setting the
 961 priority to a non-zero value also sets the request's found
 962 status and waiting date to NULL.
 963
 964 The optional C<$itemnumber> parameter is used only when
 965 C<$rank> is a non-zero integer; if supplied, the itemnumber
 966 of the hold request is set accordingly; if omitted, the itemnumber
 967 is cleared.
 968
 969 B<FIXME:> Note that the forgoing can have the effect of causing
 970 item-level hold requests to turn into title-level requests.  This
 971 will be fixed once reserves has separate columns for requested
 972 itemnumber and supplying itemnumber.
 973
 974 =cut
 975
 976 sub ModReserve {
 977     my ( $params ) = @_;
 978
 979     my $rank = $params->{'rank'};
 980     my $reserve_id = $params->{'reserve_id'};
 981     my $branchcode = $params->{'branchcode'};
 982     my $itemnumber = $params->{'itemnumber'};
 983     my $suspend_until = $params->{'suspend_until'};
 984     my $borrowernumber = $params->{'borrowernumber'};
 985     my $biblionumber = $params->{'biblionumber'};
 986
 987     return if $rank eq "W";
 988     return if $rank eq "n";
 989
 990     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 991
 992     my $hold;
 993     unless ( $reserve_id ) {
 994         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 995         return unless $holds->count; # FIXME Should raise an exception
 996         $hold = $holds->next;
 997         $reserve_id = $hold->reserve_id;
 998     }
 999
1000     $hold ||= Koha::Holds->find($reserve_id);
1001
1002     if ( $rank eq "del" ) {
1003         $hold->cancel;
1004     }
1005     elsif ($rank =~ /^\d+/ and $rank > 0) {
1006         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1007             if C4::Context->preference('HoldsLog');
1008
1009         my $properties = {
1010             priority    => $rank,
1011             branchcode  => $branchcode,
1012             itemnumber  => $itemnumber,
1013             found       => undef,
1014             waitingdate => undef
1015         };
1016         if (exists $params->{reservedate}) {
1017             $properties->{reservedate} = $params->{reservedate} || undef;
1018         }
1019         if (exists $params->{expirationdate}) {
1020             $properties->{expirationdate} = $params->{expirationdate} || undef;
1021         }
1022
1023         $hold->set($properties)->store();
1024
1025         if ( defined( $suspend_until ) ) {
1026             if ( $suspend_until ) {
1027                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1028                 $hold->suspend_hold( $suspend_until );
1029             } else {
1030                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1031                 # If the hold is not suspended, this does nothing.
1032                 $hold->set( { suspend_until => undef } )->store();
1033             }
1034         }
1035
1036         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1037     }
1038 }
1039
1040 =head2 ModReserveFill
1041
1042   &ModReserveFill($reserve);
1043
1044 Fill a reserve. If I understand this correctly, this means that the
1045 reserved book has been found and given to the patron who reserved it.
1046
1047 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1048 whose keys are fields from the reserves table in the Koha database.
1049
1050 =cut
1051
1052 sub ModReserveFill {
1053     my ($res) = @_;
1054     my $reserve_id = $res->{'reserve_id'};
1055
1056     my $hold = Koha::Holds->find($reserve_id);
1057     # get the priority on this record....
1058     my $priority = $hold->priority;
1059
1060     # update the hold statuses, no need to store it though, we will be deleting it anyway
1061     $hold->set(
1062         {
1063             found    => 'F',
1064             priority => 0,
1065         }
1066     );
1067
1068     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1069         if C4::Context->preference('HoldsLog');
1070
1071     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1072     Koha::Old::Hold->new( $hold->unblessed() )->store();
1073
1074     $hold->delete();
1075
1076     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1077         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1078         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1079     }
1080
1081     # now fix the priority on the others (if the priority wasn't
1082     # already sorted!)....
1083     unless ( $priority == 0 ) {
1084         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1085     }
1086 }
1087
1088 =head2 ModReserveStatus
1089
1090   &ModReserveStatus($itemnumber, $newstatus);
1091
1092 Update the reserve status for the active (priority=0) reserve.
1093
1094 $itemnumber is the itemnumber the reserve is on
1095
1096 $newstatus is the new status.
1097
1098 =cut
1099
1100 sub ModReserveStatus {
1101
1102     #first : check if we have a reservation for this item .
1103     my ($itemnumber, $newstatus) = @_;
1104     my $dbh = C4::Context->dbh;
1105
1106     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1107     my $sth_set = $dbh->prepare($query);
1108     $sth_set->execute( $newstatus, $itemnumber );
1109
1110     my $item = Koha::Items->find($itemnumber);
1111     if ( $item->location && $item->location eq 'CART'
1112         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1113         && $newstatus ) {
1114       CartToShelf( $itemnumber );
1115     }
1116 }
1117
1118 =head2 ModReserveAffect
1119
1120   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
1121
1122 This function affect an item and a status for a given reserve, either fetched directly
1123 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1124 is given, only first reserve returned is affected, which is ok for anything but
1125 multi-item holds.
1126
1127 if $transferToDo is not set, then the status is set to "Waiting" as well.
1128 otherwise, a transfer is on the way, and the end of the transfer will
1129 take care of the waiting status
1130
1131 =cut
1132
1133 sub ModReserveAffect {
1134     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
1135     my $dbh = C4::Context->dbh;
1136
1137     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1138     # attached to $itemnumber
1139     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1140     $sth->execute($itemnumber);
1141     my ($biblionumber) = $sth->fetchrow;
1142
1143     # get request - need to find out if item is already
1144     # waiting in order to not send duplicate hold filled notifications
1145
1146     my $hold;
1147     # Find hold by id if we have it
1148     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1149     # Find item level hold for this item if there is one
1150     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1151     # Find record level hold if there is no item level hold
1152     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1153
1154     return unless $hold;
1155
1156     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1157
1158     $hold->itemnumber($itemnumber);
1159     $hold->set_waiting($transferToDo);
1160
1161     if( !$transferToDo ){
1162         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1163         my $transfers = Koha::Item::Transfers->search({
1164             itemnumber => $itemnumber,
1165             datearrived => undef
1166         });
1167         while( my $transfer = $transfers->next ){
1168             $transfer->datearrived( dt_from_string() )->store;
1169         };
1170     }
1171
1172
1173     _FixPriority( { biblionumber => $biblionumber } );
1174     my $item = Koha::Items->find($itemnumber);
1175     if ( $item->location && $item->location eq 'CART'
1176         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1177       CartToShelf( $itemnumber );
1178     }
1179
1180     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1181         if C4::Context->preference('HoldsLog');
1182
1183     return;
1184 }
1185
1186 =head2 ModReserveCancelAll
1187
1188   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1189
1190 function to cancel reserv,check other reserves, and transfer document if it's necessary
1191
1192 =cut
1193
1194 sub ModReserveCancelAll {
1195     my $messages;
1196     my $nextreservinfo;
1197     my ( $itemnumber, $borrowernumber ) = @_;
1198
1199     #step 1 : cancel the reservation
1200     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1201     return unless $holds->count;
1202     $holds->next->cancel;
1203
1204     #step 2 launch the subroutine of the others reserves
1205     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1206
1207     return ( $messages, $nextreservinfo->{borrowernumber} );
1208 }
1209
1210 =head2 ModReserveMinusPriority
1211
1212   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1213
1214 Reduce the values of queued list
1215
1216 =cut
1217
1218 sub ModReserveMinusPriority {
1219     my ( $itemnumber, $reserve_id ) = @_;
1220
1221     #first step update the value of the first person on reserv
1222     my $dbh   = C4::Context->dbh;
1223     my $query = "
1224         UPDATE reserves
1225         SET    priority = 0 , itemnumber = ?
1226         WHERE  reserve_id = ?
1227     ";
1228     my $sth_upd = $dbh->prepare($query);
1229     $sth_upd->execute( $itemnumber, $reserve_id );
1230     # second step update all others reserves
1231     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1232 }
1233
1234 =head2 IsAvailableForItemLevelRequest
1235
1236   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1237
1238 Checks whether a given item record is available for an
1239 item-level hold request.  An item is available if
1240
1241 * it is not lost AND
1242 * it is not damaged AND
1243 * it is not withdrawn AND
1244 * a waiting or in transit reserve is placed on
1245 * does not have a not for loan value > 0
1246
1247 Need to check the issuingrules onshelfholds column,
1248 if this is set items on the shelf can be placed on hold
1249
1250 Note that IsAvailableForItemLevelRequest() does not
1251 check if the staff operator is authorized to place
1252 a request on the item - in particular,
1253 this routine does not check IndependentBranches
1254 and canreservefromotherbranches.
1255
1256 =cut
1257
1258 sub IsAvailableForItemLevelRequest {
1259     my $item                = shift;
1260     my $patron              = shift;
1261     my $pickup_branchcode   = shift;
1262     # items_any_available is precalculated status passed from request.pl when set of items
1263     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1264     my $items_any_available = shift;
1265
1266     my $dbh = C4::Context->dbh;
1267     # must check the notforloan setting of the itemtype
1268     # FIXME - a lot of places in the code do this
1269     #         or something similar - need to be
1270     #         consolidated
1271     my $itemtype = $item->effective_itemtype;
1272     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1273
1274     return 0 if
1275         $notforloan_per_itemtype ||
1276         $item->itemlost        ||
1277         $item->notforloan > 0  ||
1278         $item->withdrawn        ||
1279         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1280
1281     if ($pickup_branchcode) {
1282         my $destination = Koha::Libraries->find($pickup_branchcode);
1283         return 0 unless $destination;
1284         return 0 unless $destination->pickup_location;
1285         return 0 unless $item->can_be_transferred( { to => $destination } );
1286         my $reserves_control_branch =
1287             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1288         my $branchitemrule =
1289             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1290         my $home_library = Koka::Libraries->find( {branchcode => $item->homebranch} );
1291         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1292     }
1293
1294     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1295
1296     if ( $on_shelf_holds == 1 ) {
1297         return 1;
1298     } elsif ( $on_shelf_holds == 2 ) {
1299
1300         # if we have this param predefined from outer caller sub, we just need
1301         # to return it, so we saving from having loop inside other loop:
1302         return  $items_any_available ? 0 : 1
1303             if defined $items_any_available;
1304
1305         my $any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
1306         return $any_available ? 0 : 1;
1307     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1308         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1309     }
1310 }
1311
1312 =head2 ItemsAnyAvailableAndNotRestricted
1313
1314   ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblionumber, patron => $patron });
1315
1316 This function checks all items for specified biblionumber (numeric) against patron (object)
1317 and returns true (1) if at least one item available for loan/check out/present/not held
1318 and also checks other parameters logic which not restricts item for hold at all (for ex.
1319 AllowHoldsOnDamagedItems or 'holdallowed' own/sibling library)
1320
1321 =cut
1322
1323 sub ItemsAnyAvailableAndNotRestricted {
1324     my $param = shift;
1325
1326     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1327
1328     foreach my $i (@items) {
1329         my $reserves_control_branch =
1330             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1331         my $branchitemrule =
1332             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1333         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1334
1335         # we can return (end the loop) when first one found:
1336         return 1
1337             unless $i->itemlost
1338             || $i->notforloan > 0
1339             || $i->withdrawn
1340             || $i->onloan
1341             || IsItemOnHoldAndFound( $i->id )
1342             || ( $i->damaged
1343                  && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1344             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1345             || $branchitemrule->{holdallowed} == 1 && $param->{patron}->branchcode ne $i->homebranch
1346             || $branchitemrule->{holdallowed} == 3 && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } );
1347     }
1348
1349     return 0;
1350 }
1351
1352 =head2 AlterPriority
1353
1354   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1355
1356 This function changes a reserve's priority up, down, to the top, or to the bottom.
1357 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1358
1359 =cut
1360
1361 sub AlterPriority {
1362     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1363
1364     my $hold = Koha::Holds->find( $reserve_id );
1365     return unless $hold;
1366
1367     if ( $hold->cancellationdate ) {
1368         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1369         return;
1370     }
1371
1372     if ( $where eq 'up' ) {
1373       return unless $prev_priority;
1374       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1375     } elsif ( $where eq 'down' ) {
1376       return unless $next_priority;
1377       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1378     } elsif ( $where eq 'top' ) {
1379       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1380     } elsif ( $where eq 'bottom' ) {
1381       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1382     }
1383
1384     # FIXME Should return the new priority
1385 }
1386
1387 =head2 ToggleLowestPriority
1388
1389   ToggleLowestPriority( $borrowernumber, $biblionumber );
1390
1391 This function sets the lowestPriority field to true if is false, and false if it is true.
1392
1393 =cut
1394
1395 sub ToggleLowestPriority {
1396     my ( $reserve_id ) = @_;
1397
1398     my $dbh = C4::Context->dbh;
1399
1400     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1401     $sth->execute( $reserve_id );
1402
1403     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1404 }
1405
1406 =head2 ToggleSuspend
1407
1408   ToggleSuspend( $reserve_id );
1409
1410 This function sets the suspend field to true if is false, and false if it is true.
1411 If the reserve is currently suspended with a suspend_until date, that date will
1412 be cleared when it is unsuspended.
1413
1414 =cut
1415
1416 sub ToggleSuspend {
1417     my ( $reserve_id, $suspend_until ) = @_;
1418
1419     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1420
1421     my $hold = Koha::Holds->find( $reserve_id );
1422
1423     if ( $hold->is_suspended ) {
1424         $hold->resume()
1425     } else {
1426         $hold->suspend_hold( $suspend_until );
1427     }
1428 }
1429
1430 =head2 SuspendAll
1431
1432   SuspendAll(
1433       borrowernumber   => $borrowernumber,
1434       [ biblionumber   => $biblionumber, ]
1435       [ suspend_until  => $suspend_until, ]
1436       [ suspend        => $suspend ]
1437   );
1438
1439   This function accepts a set of hash keys as its parameters.
1440   It requires either borrowernumber or biblionumber, or both.
1441
1442   suspend_until is wholly optional.
1443
1444 =cut
1445
1446 sub SuspendAll {
1447     my %params = @_;
1448
1449     my $borrowernumber = $params{'borrowernumber'} || undef;
1450     my $biblionumber   = $params{'biblionumber'}   || undef;
1451     my $suspend_until  = $params{'suspend_until'}  || undef;
1452     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1453
1454     $suspend_until = eval { dt_from_string($suspend_until) }
1455       if ( defined($suspend_until) );
1456
1457     return unless ( $borrowernumber || $biblionumber );
1458
1459     my $params;
1460     $params->{found}          = undef;
1461     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1462     $params->{biblionumber}   = $biblionumber if $biblionumber;
1463
1464     my @holds = Koha::Holds->search($params);
1465
1466     if ($suspend) {
1467         map { $_->suspend_hold($suspend_until) } @holds;
1468     }
1469     else {
1470         map { $_->resume() } @holds;
1471     }
1472 }
1473
1474
1475 =head2 _FixPriority
1476
1477   _FixPriority({
1478     reserve_id => $reserve_id,
1479     [rank => $rank,]
1480     [ignoreSetLowestRank => $ignoreSetLowestRank]
1481   });
1482
1483   or
1484
1485   _FixPriority({ biblionumber => $biblionumber});
1486
1487 This routine adjusts the priority of a hold request and holds
1488 on the same bib.
1489
1490 In the first form, where a reserve_id is passed, the priority of the
1491 hold is set to supplied rank, and other holds for that bib are adjusted
1492 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1493 is supplied, all of the holds on that bib have their priority adjusted
1494 as if the second form had been used.
1495
1496 In the second form, where a biblionumber is passed, the holds on that
1497 bib (that are not captured) are sorted in order of increasing priority,
1498 then have reserves.priority set so that the first non-captured hold
1499 has its priority set to 1, the second non-captured hold has its priority
1500 set to 2, and so forth.
1501
1502 In both cases, holds that have the lowestPriority flag on are have their
1503 priority adjusted to ensure that they remain at the end of the line.
1504
1505 Note that the ignoreSetLowestRank parameter is meant to be used only
1506 when _FixPriority calls itself.
1507
1508 =cut
1509
1510 sub _FixPriority {
1511     my ( $params ) = @_;
1512     my $reserve_id = $params->{reserve_id};
1513     my $rank = $params->{rank} // '';
1514     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1515     my $biblionumber = $params->{biblionumber};
1516
1517     my $dbh = C4::Context->dbh;
1518
1519     my $hold;
1520     if ( $reserve_id ) {
1521         $hold = Koha::Holds->find( $reserve_id );
1522         if (!defined $hold){
1523             # may have already been checked out and hold fulfilled
1524             $hold = Koha::Old::Holds->find( $reserve_id );
1525         }
1526         return unless $hold;
1527     }
1528
1529     unless ( $biblionumber ) { # FIXME This is a very weird API
1530         $biblionumber = $hold->biblionumber;
1531     }
1532
1533     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1534         $hold->cancel;
1535     }
1536     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1537
1538         # make sure priority for waiting or in-transit items is 0
1539         my $query = "
1540             UPDATE reserves
1541             SET    priority = 0
1542             WHERE reserve_id = ?
1543             AND found IN ('W', 'T')
1544         ";
1545         my $sth = $dbh->prepare($query);
1546         $sth->execute( $reserve_id );
1547     }
1548     my @priority;
1549
1550     # get whats left
1551     my $query = "
1552         SELECT reserve_id, borrowernumber, reservedate
1553         FROM   reserves
1554         WHERE  biblionumber   = ?
1555           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1556         ORDER BY priority ASC
1557     ";
1558     my $sth = $dbh->prepare($query);
1559     $sth->execute( $biblionumber );
1560     while ( my $line = $sth->fetchrow_hashref ) {
1561         push( @priority,     $line );
1562     }
1563
1564     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1565     # To find the matching index
1566     my $i;
1567     my $key = -1;    # to allow for 0 to be a valid result
1568     for ( $i = 0 ; $i < @priority ; $i++ ) {
1569         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1570             $key = $i;    # save the index
1571             last;
1572         }
1573     }
1574
1575     # if index exists in array then move it to new position
1576     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1577         my $new_rank = $rank -
1578           1;    # $new_rank is what you want the new index to be in the array
1579         my $moving_item = splice( @priority, $key, 1 );
1580         splice( @priority, $new_rank, 0, $moving_item );
1581     }
1582
1583     # now fix the priority on those that are left....
1584     $query = "
1585         UPDATE reserves
1586         SET    priority = ?
1587         WHERE  reserve_id = ?
1588     ";
1589     $sth = $dbh->prepare($query);
1590     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1591         $sth->execute(
1592             $j + 1,
1593             $priority[$j]->{'reserve_id'}
1594         );
1595     }
1596
1597     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1598     $sth->execute();
1599
1600     unless ( $ignoreSetLowestRank ) {
1601       while ( my $res = $sth->fetchrow_hashref() ) {
1602         _FixPriority({
1603             reserve_id => $res->{'reserve_id'},
1604             rank => '999999',
1605             ignoreSetLowestRank => 1
1606         });
1607       }
1608     }
1609 }
1610
1611 =head2 _Findgroupreserve
1612
1613   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1614
1615 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1616 first match found.  If neither, then we look for non-holds-queue based holds.
1617 Lookahead is the number of days to look in advance.
1618
1619 C<&_Findgroupreserve> returns :
1620 C<@results> is an array of references-to-hash whose keys are mostly
1621 fields from the reserves table of the Koha database, plus
1622 C<biblioitemnumber>.
1623
1624 This routine with either return:
1625 1 - Item specific holds from the holds queue
1626 2 - Title level holds from the holds queue
1627 3 - All holds for this biblionumber
1628
1629 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1630
1631 =cut
1632
1633 sub _Findgroupreserve {
1634     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1635     my $dbh   = C4::Context->dbh;
1636
1637     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1638     # check for exact targeted match
1639     my $item_level_target_query = qq{
1640         SELECT reserves.biblionumber        AS biblionumber,
1641                reserves.borrowernumber      AS borrowernumber,
1642                reserves.reservedate         AS reservedate,
1643                reserves.branchcode          AS branchcode,
1644                reserves.cancellationdate    AS cancellationdate,
1645                reserves.found               AS found,
1646                reserves.reservenotes        AS reservenotes,
1647                reserves.priority            AS priority,
1648                reserves.timestamp           AS timestamp,
1649                biblioitems.biblioitemnumber AS biblioitemnumber,
1650                reserves.itemnumber          AS itemnumber,
1651                reserves.reserve_id          AS reserve_id,
1652                reserves.itemtype            AS itemtype
1653         FROM reserves
1654         JOIN biblioitems USING (biblionumber)
1655         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1656         WHERE found IS NULL
1657         AND priority > 0
1658         AND item_level_request = 1
1659         AND itemnumber = ?
1660         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1661         AND suspend = 0
1662         ORDER BY priority
1663     };
1664     my $sth = $dbh->prepare($item_level_target_query);
1665     $sth->execute($itemnumber, $lookahead||0);
1666     my @results;
1667     if ( my $data = $sth->fetchrow_hashref ) {
1668         push( @results, $data )
1669           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1670     }
1671     return @results if @results;
1672
1673     # check for title-level targeted match
1674     my $title_level_target_query = qq{
1675         SELECT reserves.biblionumber        AS biblionumber,
1676                reserves.borrowernumber      AS borrowernumber,
1677                reserves.reservedate         AS reservedate,
1678                reserves.branchcode          AS branchcode,
1679                reserves.cancellationdate    AS cancellationdate,
1680                reserves.found               AS found,
1681                reserves.reservenotes        AS reservenotes,
1682                reserves.priority            AS priority,
1683                reserves.timestamp           AS timestamp,
1684                biblioitems.biblioitemnumber AS biblioitemnumber,
1685                reserves.itemnumber          AS itemnumber,
1686                reserves.reserve_id          AS reserve_id,
1687                reserves.itemtype            AS itemtype
1688         FROM reserves
1689         JOIN biblioitems USING (biblionumber)
1690         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1691         WHERE found IS NULL
1692         AND priority > 0
1693         AND item_level_request = 0
1694         AND hold_fill_targets.itemnumber = ?
1695         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1696         AND suspend = 0
1697         ORDER BY priority
1698     };
1699     $sth = $dbh->prepare($title_level_target_query);
1700     $sth->execute($itemnumber, $lookahead||0);
1701     @results = ();
1702     if ( my $data = $sth->fetchrow_hashref ) {
1703         push( @results, $data )
1704           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1705     }
1706     return @results if @results;
1707
1708     my $query = qq{
1709         SELECT reserves.biblionumber               AS biblionumber,
1710                reserves.borrowernumber             AS borrowernumber,
1711                reserves.reservedate                AS reservedate,
1712                reserves.waitingdate                AS waitingdate,
1713                reserves.branchcode                 AS branchcode,
1714                reserves.cancellationdate           AS cancellationdate,
1715                reserves.found                      AS found,
1716                reserves.reservenotes               AS reservenotes,
1717                reserves.priority                   AS priority,
1718                reserves.timestamp                  AS timestamp,
1719                reserves.itemnumber                 AS itemnumber,
1720                reserves.reserve_id                 AS reserve_id,
1721                reserves.itemtype                   AS itemtype
1722         FROM reserves
1723         WHERE reserves.biblionumber = ?
1724           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1725           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1726           AND suspend = 0
1727           ORDER BY priority
1728     };
1729     $sth = $dbh->prepare($query);
1730     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1731     @results = ();
1732     while ( my $data = $sth->fetchrow_hashref ) {
1733         push( @results, $data )
1734           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1735     }
1736     return @results;
1737 }
1738
1739 =head2 _koha_notify_reserve
1740
1741   _koha_notify_reserve( $hold->reserve_id );
1742
1743 Sends a notification to the patron that their hold has been filled (through
1744 ModReserveAffect, _not_ ModReserveFill)
1745
1746 The letter code for this notice may be found using the following query:
1747
1748     select distinct letter_code
1749     from message_transports
1750     inner join message_attributes using (message_attribute_id)
1751     where message_name = 'Hold_Filled'
1752
1753 This will probably sipmly be 'HOLD', but because it is defined in the database,
1754 it is subject to addition or change.
1755
1756 The following tables are availalbe witin the notice:
1757
1758     branches
1759     borrowers
1760     biblio
1761     biblioitems
1762     reserves
1763     items
1764
1765 =cut
1766
1767 sub _koha_notify_reserve {
1768     my $reserve_id = shift;
1769     my $hold = Koha::Holds->find($reserve_id);
1770     my $borrowernumber = $hold->borrowernumber;
1771
1772     my $patron = Koha::Patrons->find( $borrowernumber );
1773
1774     # Try to get the borrower's email address
1775     my $to_address = $patron->notice_email_address;
1776
1777     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1778             borrowernumber => $borrowernumber,
1779             message_name => 'Hold_Filled'
1780     } );
1781
1782     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1783
1784     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1785
1786     my %letter_params = (
1787         module => 'reserves',
1788         branchcode => $hold->branchcode,
1789         lang => $patron->lang,
1790         tables => {
1791             'branches'       => $library,
1792             'borrowers'      => $patron->unblessed,
1793             'biblio'         => $hold->biblionumber,
1794             'biblioitems'    => $hold->biblionumber,
1795             'reserves'       => $hold->unblessed,
1796             'items'          => $hold->itemnumber,
1797         },
1798     );
1799
1800     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1801     my $send_notification = sub {
1802         my ( $mtt, $letter_code ) = (@_);
1803         return unless defined $letter_code;
1804         $letter_params{letter_code} = $letter_code;
1805         $letter_params{message_transport_type} = $mtt;
1806         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1807         unless ($letter) {
1808             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1809             return;
1810         }
1811
1812         C4::Letters::EnqueueLetter( {
1813             letter => $letter,
1814             borrowernumber => $borrowernumber,
1815             from_address => $admin_email_address,
1816             message_transport_type => $mtt,
1817         } );
1818     };
1819
1820     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1821         next if (
1822                ( $mtt eq 'email' and not $to_address ) # No email address
1823             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1824             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1825         );
1826
1827         &$send_notification($mtt, $letter_code);
1828         $notification_sent++;
1829     }
1830     #Making sure that a print notification is sent if no other transport types can be utilized.
1831     if (! $notification_sent) {
1832         &$send_notification('print', 'HOLD');
1833     }
1834
1835 }
1836
1837 =head2 _ShiftPriorityByDateAndPriority
1838
1839   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1840
1841 This increments the priority of all reserves after the one
1842 with either the lowest date after C<$reservedate>
1843 or the lowest priority after C<$priority>.
1844
1845 It effectively makes room for a new reserve to be inserted with a certain
1846 priority, which is returned.
1847
1848 This is most useful when the reservedate can be set by the user.  It allows
1849 the new reserve to be placed before other reserves that have a later
1850 reservedate.  Since priority also is set by the form in reserves/request.pl
1851 the sub accounts for that too.
1852
1853 =cut
1854
1855 sub _ShiftPriorityByDateAndPriority {
1856     my ( $biblio, $resdate, $new_priority ) = @_;
1857
1858     my $dbh = C4::Context->dbh;
1859     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1860     my $sth = $dbh->prepare( $query );
1861     $sth->execute( $biblio, $resdate, $new_priority );
1862     my $min_priority = $sth->fetchrow;
1863     # if no such matches are found, $new_priority remains as original value
1864     $new_priority = $min_priority if ( $min_priority );
1865
1866     # Shift the priority up by one; works in conjunction with the next SQL statement
1867     $query = "UPDATE reserves
1868               SET priority = priority+1
1869               WHERE biblionumber = ?
1870               AND borrowernumber = ?
1871               AND reservedate = ?
1872               AND found IS NULL";
1873     my $sth_update = $dbh->prepare( $query );
1874
1875     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1876     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1877     $sth = $dbh->prepare( $query );
1878     $sth->execute( $new_priority, $biblio );
1879     while ( my $row = $sth->fetchrow_hashref ) {
1880         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1881     }
1882
1883     return $new_priority;  # so the caller knows what priority they wind up receiving
1884 }
1885
1886 =head2 MoveReserve
1887
1888   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1889
1890 Use when checking out an item to handle reserves
1891 If $cancelreserve boolean is set to true, it will remove existing reserve
1892
1893 =cut
1894
1895 sub MoveReserve {
1896     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1897
1898     $cancelreserve //= 0;
1899
1900     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1901     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1902     return unless $res;
1903
1904     my $biblionumber     =  $res->{biblionumber};
1905
1906     if ($res->{borrowernumber} == $borrowernumber) {
1907         ModReserveFill($res);
1908     }
1909     else {
1910         # warn "Reserved";
1911         # The item is reserved by someone else.
1912         # Find this item in the reserves
1913
1914         my $borr_res  = Koha::Holds->search({
1915             borrowernumber => $borrowernumber,
1916             biblionumber   => $biblionumber,
1917         },{
1918             order_by       => 'priority'
1919         })->next();
1920
1921         if ( $borr_res ) {
1922             # The item is reserved by the current patron
1923             ModReserveFill($borr_res->unblessed);
1924         }
1925
1926         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1927             RevertWaitingStatus({ itemnumber => $itemnumber });
1928         }
1929         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1930             my $hold = Koha::Holds->find( $res->{reserve_id} );
1931             $hold->cancel;
1932         }
1933     }
1934 }
1935
1936 =head2 MergeHolds
1937
1938   MergeHolds($dbh,$to_biblio, $from_biblio);
1939
1940 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1941
1942 =cut
1943
1944 sub MergeHolds {
1945     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1946     my $sth = $dbh->prepare(
1947         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1948     );
1949     $sth->execute($from_biblio);
1950     if ( my $data = $sth->fetchrow_hashref() ) {
1951
1952         # holds exist on old record, if not we don't need to do anything
1953         $sth = $dbh->prepare(
1954             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1955         $sth->execute( $to_biblio, $from_biblio );
1956
1957         # Reorder by date
1958         # don't reorder those already waiting
1959
1960         $sth = $dbh->prepare(
1961 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1962         );
1963         my $upd_sth = $dbh->prepare(
1964 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1965         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1966         );
1967         $sth->execute( $to_biblio, 'W', 'T' );
1968         my $priority = 1;
1969         while ( my $reserve = $sth->fetchrow_hashref() ) {
1970             $upd_sth->execute(
1971                 $priority,                    $to_biblio,
1972                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1973                 $reserve->{'itemnumber'}
1974             );
1975             $priority++;
1976         }
1977     }
1978 }
1979
1980 =head2 RevertWaitingStatus
1981
1982   RevertWaitingStatus({ itemnumber => $itemnumber });
1983
1984   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1985
1986   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1987           item level hold, even if it was only a bibliolevel hold to
1988           begin with. This is because we can no longer know if a hold
1989           was item-level or bib-level after a hold has been set to
1990           waiting status.
1991
1992 =cut
1993
1994 sub RevertWaitingStatus {
1995     my ( $params ) = @_;
1996     my $itemnumber = $params->{'itemnumber'};
1997
1998     return unless ( $itemnumber );
1999
2000     my $dbh = C4::Context->dbh;
2001
2002     ## Get the waiting reserve we want to revert
2003     my $hold = Koha::Holds->search(
2004         {
2005             itemnumber => $itemnumber,
2006             found => { not => undef },
2007         }
2008     )->next;
2009
2010     ## Increment the priority of all other non-waiting
2011     ## reserves for this bib record
2012     my $holds = Koha::Holds->search({ biblionumber => $hold->biblionumber, priority => { '>' => 0 } })
2013                            ->update({ priority => \'priority + 1' }, { no_triggers => 1 });
2014
2015     ## Fix up the currently waiting reserve
2016     $hold->set(
2017         {
2018             priority    => 1,
2019             found       => undef,
2020             waitingdate => undef,
2021             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2022         }
2023     )->store();
2024
2025     _FixPriority( { biblionumber => $hold->biblionumber } );
2026
2027     return $hold;
2028 }
2029
2030 =head2 ReserveSlip
2031
2032 ReserveSlip(
2033     {
2034         branchcode     => $branchcode,
2035         borrowernumber => $borrowernumber,
2036         biblionumber   => $biblionumber,
2037         [ itemnumber   => $itemnumber, ]
2038         [ barcode      => $barcode, ]
2039     }
2040   )
2041
2042 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2043
2044 The letter code will be HOLD_SLIP, and the following tables are
2045 available within the slip:
2046
2047     reserves
2048     branches
2049     borrowers
2050     biblio
2051     biblioitems
2052     items
2053
2054 =cut
2055
2056 sub ReserveSlip {
2057     my ($args) = @_;
2058     my $branchcode     = $args->{branchcode};
2059     my $reserve_id = $args->{reserve_id};
2060
2061     my $hold = Koha::Holds->find($reserve_id);
2062     return unless $hold;
2063
2064     my $patron = $hold->borrower;
2065     my $reserve = $hold->unblessed;
2066
2067     return  C4::Letters::GetPreparedLetter (
2068         module => 'circulation',
2069         letter_code => 'HOLD_SLIP',
2070         branchcode => $branchcode,
2071         lang => $patron->lang,
2072         tables => {
2073             'reserves'    => $reserve,
2074             'branches'    => $reserve->{branchcode},
2075             'borrowers'   => $reserve->{borrowernumber},
2076             'biblio'      => $reserve->{biblionumber},
2077             'biblioitems' => $reserve->{biblionumber},
2078             'items'       => $reserve->{itemnumber},
2079         },
2080     );
2081 }
2082
2083 =head2 GetReservesControlBranch
2084
2085   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2086
2087   Return the branchcode to be used to determine which reserves
2088   policy applies to a transaction.
2089
2090   C<$item> is a hashref for an item. Only 'homebranch' is used.
2091
2092   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2093
2094 =cut
2095
2096 sub GetReservesControlBranch {
2097     my ( $item, $borrower ) = @_;
2098
2099     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2100
2101     my $branchcode =
2102         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2103       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2104       :                                              undef;
2105
2106     return $branchcode;
2107 }
2108
2109 =head2 CalculatePriority
2110
2111     my $p = CalculatePriority($biblionumber, $resdate);
2112
2113 Calculate priority for a new reserve on biblionumber, placing it at
2114 the end of the line of all holds whose start date falls before
2115 the current system time and that are neither on the hold shelf
2116 or in transit.
2117
2118 The reserve date parameter is optional; if it is supplied, the
2119 priority is based on the set of holds whose start date falls before
2120 the parameter value.
2121
2122 After calculation of this priority, it is recommended to call
2123 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2124 AddReserves.
2125
2126 =cut
2127
2128 sub CalculatePriority {
2129     my ( $biblionumber, $resdate ) = @_;
2130
2131     my $sql = q{
2132         SELECT COUNT(*) FROM reserves
2133         WHERE biblionumber = ?
2134         AND   priority > 0
2135         AND   (found IS NULL OR found = '')
2136     };
2137     #skip found==W or found==T (waiting or transit holds)
2138     if( $resdate ) {
2139         $sql.= ' AND ( reservedate <= ? )';
2140     }
2141     else {
2142         $sql.= ' AND ( reservedate < NOW() )';
2143     }
2144     my $dbh = C4::Context->dbh();
2145     my @row = $dbh->selectrow_array(
2146         $sql,
2147         undef,
2148         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2149     );
2150
2151     return @row ? $row[0]+1 : 1;
2152 }
2153
2154 =head2 IsItemOnHoldAndFound
2155
2156     my $bool = IsItemFoundHold( $itemnumber );
2157
2158     Returns true if the item is currently on hold
2159     and that hold has a non-null found status ( W, T, etc. )
2160
2161 =cut
2162
2163 sub IsItemOnHoldAndFound {
2164     my ($itemnumber) = @_;
2165
2166     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2167
2168     my $found = $rs->count(
2169         {
2170             itemnumber => $itemnumber,
2171             found      => { '!=' => undef }
2172         }
2173     );
2174
2175     return $found;
2176 }
2177
2178 =head2 GetMaxPatronHoldsForRecord
2179
2180 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2181
2182 For multiple holds on a given record for a given patron, the max
2183 number of record level holds that a patron can be placed is the highest
2184 value of the holds_per_record rule for each item if the record for that
2185 patron. This subroutine finds and returns the highest holds_per_record
2186 rule value for a given patron id and record id.
2187
2188 =cut
2189
2190 sub GetMaxPatronHoldsForRecord {
2191     my ( $borrowernumber, $biblionumber ) = @_;
2192
2193     my $patron = Koha::Patrons->find($borrowernumber);
2194     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2195
2196     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2197
2198     my $categorycode = $patron->categorycode;
2199     my $branchcode;
2200     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2201
2202     my $max = 0;
2203     foreach my $item (@items) {
2204         my $itemtype = $item->effective_itemtype();
2205
2206         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2207
2208         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2209         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2210         $max = $holds_per_record if $holds_per_record > $max;
2211     }
2212
2213     return $max;
2214 }
2215
2216 =head2 GetHoldRule
2217
2218 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2219
2220 Returns the matching hold related issuingrule fields for a given
2221 patron category, itemtype, and library.
2222
2223 =cut
2224
2225 sub GetHoldRule {
2226     my ( $categorycode, $itemtype, $branchcode ) = @_;
2227
2228     my $reservesallowed = Koha::CirculationRules->get_effective_rule(
2229         {
2230             itemtype     => $itemtype,
2231             categorycode => $categorycode,
2232             branchcode   => $branchcode,
2233             rule_name    => 'reservesallowed',
2234             order_by     => {
2235                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2236             }
2237         }
2238     );
2239
2240     my $rules;
2241     if ( $reservesallowed ) {
2242         $rules->{reservesallowed} = $reservesallowed->rule_value;
2243         $rules->{itemtype}        = $reservesallowed->itemtype;
2244         $rules->{categorycode}    = $reservesallowed->categorycode;
2245         $rules->{branchcode}      = $reservesallowed->branchcode;
2246     }
2247
2248     my $holds_per_x_rules = Koha::CirculationRules->get_effective_rules(
2249         {
2250             itemtype     => $itemtype,
2251             categorycode => $categorycode,
2252             branchcode   => $branchcode,
2253             rules        => ['holds_per_record', 'holds_per_day'],
2254             order_by     => {
2255                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2256             }
2257         }
2258     );
2259     $rules->{holds_per_record} = $holds_per_x_rules->{holds_per_record};
2260     $rules->{holds_per_day} = $holds_per_x_rules->{holds_per_day};
2261
2262     return $rules;
2263 }
2264
2265 =head1 AUTHOR
2266
2267 Koha Development Team <http://koha-community.org/>
2268
2269 =cut
2270
2271 1;