C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::Account::Lines;
  56 use Koha::Account::Offsets;
  57 use Koha::Config::SysPrefs;
  58 use Koha::Charges::Fees;
  59 use Koha::Util::SystemPreferences;
  60 use Koha::Checkouts::ReturnClaims;
  61 use Carp;
  62 use List::MoreUtils qw( uniq any );
  63 use Scalar::Util qw( looks_like_number );
  64 use Try::Tiny;
  65 use Date::Calc qw(
  66   Today
  67   Today_and_Now
  68   Add_Delta_YM
  69   Add_Delta_DHMS
  70   Date_to_Days
  71   Day_of_Week
  72   Add_Delta_Days
  73 );
  74 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  75
  76 BEGIN {
  77         require Exporter;
  78         @ISA    = qw(Exporter);
  79
  80         # FIXME subs that should probably be elsewhere
  81         push @EXPORT, qw(
  82                 &barcodedecode
  83         &LostItem
  84         &ReturnLostItem
  85         &GetPendingOnSiteCheckouts
  86         );
  87
  88         # subs to deal with issuing a book
  89         push @EXPORT, qw(
  90                 &CanBookBeIssued
  91                 &CanBookBeRenewed
  92                 &AddIssue
  93                 &AddRenewal
  94                 &GetRenewCount
  95         &GetSoonestRenewDate
  96         &GetLatestAutoRenewDate
  97                 &GetIssuingCharges
  98         &GetBranchBorrowerCircRule
  99         &GetBranchItemRule
 100                 &GetBiblioIssues
 101                 &GetOpenIssue
 102         &CheckIfIssuedToPatron
 103         &IsItemIssued
 104         GetTopIssues
 105         );
 106
 107         # subs to deal with returns
 108         push @EXPORT, qw(
 109                 &AddReturn
 110         &MarkIssueReturned
 111         );
 112
 113         # subs to deal with transfers
 114         push @EXPORT, qw(
 115                 &transferbook
 116                 &GetTransfers
 117                 &GetTransfersFromTo
 118                 &updateWrongTransfer
 119                 &DeleteTransfer
 120                 &IsBranchTransferAllowed
 121                 &CreateBranchTransferLimit
 122                 &DeleteBranchTransferLimits
 123         &TransferSlip
 124         );
 125
 126     # subs to deal with offline circulation
 127     push @EXPORT, qw(
 128       &GetOfflineOperations
 129       &GetOfflineOperation
 130       &AddOfflineOperation
 131       &DeleteOfflineOperation
 132       &ProcessOfflineOperation
 133     );
 134 }
 135
 136 =head1 NAME
 137
 138 C4::Circulation - Koha circulation module
 139
 140 =head1 SYNOPSIS
 141
 142 use C4::Circulation;
 143
 144 =head1 DESCRIPTION
 145
 146 The functions in this module deal with circulation, issues, and
 147 returns, as well as general information about the library.
 148 Also deals with inventory.
 149
 150 =head1 FUNCTIONS
 151
 152 =head2 barcodedecode
 153
 154   $str = &barcodedecode($barcode, [$filter]);
 155
 156 Generic filter function for barcode string.
 157 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 158 Will do some manipulation of the barcode for systems that deliver a barcode
 159 to circulation.pl that differs from the barcode stored for the item.
 160 For proper functioning of this filter, calling the function on the
 161 correct barcode string (items.barcode) should return an unaltered barcode.
 162
 163 The optional $filter argument is to allow for testing or explicit
 164 behavior that ignores the System Pref.  Valid values are the same as the
 165 System Pref options.
 166
 167 =cut
 168
 169 # FIXME -- the &decode fcn below should be wrapped into this one.
 170 # FIXME -- these plugins should be moved out of Circulation.pm
 171 #
 172 sub barcodedecode {
 173     my ($barcode, $filter) = @_;
 174     my $branch = C4::Context::mybranch();
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 decode
 214
 215   $str = &decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 255                                             $barcode, $ignore_reserves, $trigger);
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$newbranch> is the code for the branch to which the item should be transferred.
 260
 261 C<$barcode> is the barcode of the item to be transferred.
 262
 263 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 264 Otherwise, if an item is reserved, the transfer fails.
 265
 266 C<$trigger> is the enum value for what triggered the transfer.
 267
 268 Returns three values:
 269
 270 =over
 271
 272 =item $dotransfer
 273
 274 is true if the transfer was successful.
 275
 276 =item $messages
 277
 278 is a reference-to-hash which may have any of the following keys:
 279
 280 =over
 281
 282 =item C<BadBarcode>
 283
 284 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 285
 286 =item C<DestinationEqualsHolding>
 287
 288 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 289
 290 =item C<WasReturned>
 291
 292 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 293
 294 =item C<ResFound>
 295
 296 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 297
 298 =item C<WasTransferred>
 299
 300 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 301
 302 =back
 303
 304 =back
 305
 306 =cut
 307
 308 sub transferbook {
 309     my ( $tbr, $barcode, $ignoreRs, $trigger ) = @_;
 310     my $messages;
 311     my $dotransfer      = 1;
 312     my $item = Koha::Items->find( { barcode => $barcode } );
 313
 314     # bad barcode..
 315     unless ( $item ) {
 316         $messages->{'BadBarcode'} = $barcode;
 317         $dotransfer = 0;
 318         return ( $dotransfer, $messages );
 319     }
 320
 321     my $itemnumber = $item->itemnumber;
 322     # get branches of book...
 323     my $hbr = $item->homebranch;
 324     my $fbr = $item->holdingbranch;
 325
 326     # if using Branch Transfer Limits
 327     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 328         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 329         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 330             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 331                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 332                 $dotransfer = 0;
 333             }
 334         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 335             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 336             $dotransfer = 0;
 337         }
 338     }
 339
 340     # can't transfer book if is already there....
 341     if ( $fbr eq $tbr ) {
 342         $messages->{'DestinationEqualsHolding'} = 1;
 343         $dotransfer = 0;
 344     }
 345
 346     # check if it is still issued to someone, return it...
 347     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 348     if ( $issue ) {
 349         AddReturn( $barcode, $fbr );
 350         $messages->{'WasReturned'} = $issue->borrowernumber;
 351     }
 352
 353     # find reserves.....
 354     # That'll save a database query.
 355     my ( $resfound, $resrec, undef ) =
 356       CheckReserves( $itemnumber );
 357     if ( $resfound and not $ignoreRs ) {
 358         $resrec->{'ResFound'} = $resfound;
 359         $messages->{'ResFound'} = $resrec;
 360         $dotransfer = 1;
 361     }
 362
 363     #actually do the transfer....
 364     if ($dotransfer) {
 365         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 366
 367         # don't need to update MARC anymore, we do it in batch now
 368         $messages->{'WasTransfered'} = 1;
 369
 370     }
 371     ModDateLastSeen( $itemnumber );
 372     return ( $dotransfer, $messages );
 373 }
 374
 375
 376 sub TooMany {
 377     my $borrower        = shift;
 378     my $item_object = shift;
 379     my $params = shift;
 380     my $onsite_checkout = $params->{onsite_checkout} || 0;
 381     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 382     my $cat_borrower    = $borrower->{'categorycode'};
 383     my $dbh             = C4::Context->dbh;
 384         my $branch;
 385         # Get which branchcode we need
 386     $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 387     my $type = $item_object->effective_itemtype;
 388
 389     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 390     $type_object = Koha::ItemTypes->find( $type );
 391     $parent_type = $type_object->parent_type if $type_object;
 392     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 393     # Find any children if we are a parent_type;
 394
 395     # given branch, patron category, and item type, determine
 396     # applicable issuing rule
 397
 398     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 399         {
 400             categorycode => $cat_borrower,
 401             itemtype     => $parent_type,
 402             branchcode   => $branch,
 403             rule_name    => 'maxissueqty',
 404         }
 405     ) if $parent_type;
 406     # If the parent rule is for default type we discount it
 407     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 408
 409     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 410         {
 411             categorycode => $cat_borrower,
 412             itemtype     => $type,
 413             branchcode   => $branch,
 414             rule_name    => 'maxissueqty',
 415         }
 416     );
 417
 418
 419     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 420         {
 421             categorycode => $cat_borrower,
 422             itemtype     => $type,
 423             branchcode   => $branch,
 424             rule_name    => 'maxonsiteissueqty',
 425         }
 426     );
 427
 428
 429     # if a rule is found and has a loan limit set, count
 430     # how many loans the patron already has that meet that
 431     # rule
 432     if (defined($maxissueqty_rule) and defined($maxissueqty_rule->rule_value)) {
 433
 434         my @bind_params;
 435         my $count_query = "";
 436
 437         if (C4::Context->preference('item-level_itypes')) {
 438             $count_query .= q|SELECT COALESCE( SUM( IF(items.itype = '| .$type . q|',1,0) ), 0) as type_total, COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts|;
 439         } else{
 440             $count_query .= q|SELECT COALESCE(SUM( IF(biblioitems.itemtype = '| .$type . q|',1,0) ), 0) as type_total, COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts|;
 441         }
 442
 443         $count_query .= q|
 444             FROM issues
 445             JOIN items USING (itemnumber)
 446         |;
 447
 448         my $rule_itemtype = $maxissueqty_rule->itemtype;
 449         unless ($rule_itemtype) {
 450             # matching rule has the default item type, so count only
 451             # those existing loans that don't fall under a more
 452             # specific rule
 453             my $issuing_itemtypes_query  = q{
 454                 SELECT itemtype FROM circulation_rules
 455                 WHERE branchcode = ?
 456                 AND   (categorycode = ? OR categorycode = ?)
 457                 AND   itemtype IS NOT NULL
 458                 AND   rule_name = 'maxissueqty'
 459             };
 460             if (C4::Context->preference('item-level_itypes')) {
 461                 $count_query .= " WHERE items.itype NOT IN ( $issuing_itemtypes_query )";
 462             } else {
 463                 $count_query .= " WHERE biblioitems.itemtype NOT IN ( $issuing_itemtypes_query )";
 464             }
 465             push @bind_params, $maxissueqty_rule->branchcode;
 466             push @bind_params, $maxissueqty_rule->categorycode;
 467             push @bind_params, $cat_borrower;
 468         } else {
 469             my @types;
 470             if ( $parent_maxissueqty_rule ) {
 471             # if we have a parent item type then we count loans of the
 472             # specific item type or its siblings or parent
 473                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 474                 @types = $children->get_column('itemtype');
 475                 push @types, $parent_type;
 476             } elsif ( $child_types ) {
 477             # If we are a parent type, we need to count all child types and our own type
 478                 @types = $child_types->get_column('itemtype');
 479                 push @types, $type; # And don't forget to count our own types
 480             } else { push @types, $type; } # Otherwise only count the specific itemtype
 481             my $types_param = ( '?,' ) x @types;
 482             $types_param =~ s/,$//;
 483             if (C4::Context->preference('item-level_itypes')) {
 484                 $count_query .= " WHERE items.itype IN (" . $types_param . ")";
 485             } else {
 486                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 487                                   WHERE biblioitems.itemtype IN (" . $types_param . ")";
 488             }
 489             push @bind_params, @types;
 490         }
 491
 492         $count_query .= " AND borrowernumber = ? ";
 493         push @bind_params, $borrower->{'borrowernumber'};
 494         my $rule_branch = $maxissueqty_rule->branchcode;
 495         if ($rule_branch) {
 496             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 497                 $count_query .= " AND issues.branchcode = ? ";
 498                 push @bind_params, $rule_branch;
 499             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 500                 ; # if branch is the patron's home branch, then count all loans by patron
 501             } else {
 502                 $count_query .= " AND items.homebranch = ? ";
 503                 push @bind_params, $rule_branch;
 504             }
 505         }
 506
 507         my ( $checkout_count_type, $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 508
 509         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 510
 511         # If parent rules exists
 512         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 513             my $max_checkouts_allowed = $parent_maxissueqty_rule->rule_value;
 514
 515             my $qty_over = _check_max_qty({
 516                 checkout_count => $checkout_count,
 517                 onsite_checkout_count => $onsite_checkout_count,
 518                 onsite_checkout => $onsite_checkout,
 519                 max_checkouts_allowed => $max_checkouts_allowed,
 520                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 521                 switch_onsite_checkout       => $switch_onsite_checkout
 522             });
 523             return $qty_over if defined $qty_over;
 524
 525
 526            # If the parent rule is less than or equal to the child, we only need check the parent
 527            if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 528                my $max_checkouts_allowed = $maxissueqty_rule->rule_value;
 529                my $qty_over = _check_max_qty({
 530                    checkout_count => $checkout_count_type,
 531                    onsite_checkout_count => $onsite_checkout_count,
 532                    onsite_checkout => $onsite_checkout,
 533                    max_checkouts_allowed => $max_checkouts_allowed,
 534                    max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 535                    switch_onsite_checkout       => $switch_onsite_checkout
 536                });
 537                return $qty_over if defined $qty_over;
 538            }
 539
 540         } else {
 541             my $max_checkouts_allowed = $maxissueqty_rule->rule_value;
 542             my $qty_over = _check_max_qty({
 543                 checkout_count => $checkout_count,
 544                 onsite_checkout_count => $onsite_checkout_count,
 545                 onsite_checkout => $onsite_checkout,
 546                 max_checkouts_allowed => $max_checkouts_allowed,
 547                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 548                 switch_onsite_checkout       => $switch_onsite_checkout
 549             });
 550             return $qty_over if defined $qty_over;
 551         }
 552
 553
 554     }
 555
 556     # Now count total loans against the limit for the branch
 557     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 558     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 559         my @bind_params = ();
 560         my $branch_count_query = q|
 561             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 562             FROM issues
 563             JOIN items USING (itemnumber)
 564             WHERE borrowernumber = ?
 565         |;
 566         push @bind_params, $borrower->{borrowernumber};
 567
 568         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 569             $branch_count_query .= " AND issues.branchcode = ? ";
 570             push @bind_params, $branch;
 571         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 572             ; # if branch is the patron's home branch, then count all loans by patron
 573         } else {
 574             $branch_count_query .= " AND items.homebranch = ? ";
 575             push @bind_params, $branch;
 576         }
 577         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 578         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 579         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 580
 581         my $qty_over = _check_max_qty({
 582             checkout_count => $checkout_count,
 583             onsite_checkout_count => $onsite_checkout_count,
 584             onsite_checkout => $onsite_checkout,
 585             max_checkouts_allowed => $max_checkouts_allowed,
 586             max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 587             switch_onsite_checkout       => $switch_onsite_checkout
 588         });
 589         return $qty_over if defined $qty_over;
 590
 591     }
 592
 593     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 594         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 595     }
 596
 597     # OK, the patron can issue !!!
 598     return;
 599 }
 600
 601 sub _check_max_qty {
 602     my $params = shift;
 603     my $checkout_count = $params->{checkout_count};
 604     my $onsite_checkout_count = $params->{onsite_checkout_count};
 605     my $onsite_checkout = $params->{onsite_checkout};
 606     my $max_checkouts_allowed = $params->{max_checkouts_allowed};
 607     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 608     my $switch_onsite_checkout = $params->{switch_onsite_checkout};
 609
 610     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 611         if( $max_onsite_checkouts_allowed eq '' ){ return;}
 612         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 613             return {
 614                 reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 615                 count => $onsite_checkout_count,
 616                 max_allowed => $max_onsite_checkouts_allowed,
 617             }
 618         }
 619     }
 620     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 621         if( $max_checkouts_allowed eq '' ){ return;}
 622         my $delta = $switch_onsite_checkout ? 1 : 0;
 623         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 624             return {
 625                 reason => 'TOO_MANY_CHECKOUTS',
 626                 count => $checkout_count,
 627                 max_allowed => $max_checkouts_allowed,
 628             };
 629         }
 630     } elsif ( not $onsite_checkout ) {
 631         if( $max_checkouts_allowed eq '' ){ return;}
 632         if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 633             return {
 634                 reason => 'TOO_MANY_CHECKOUTS',
 635                 count => $checkout_count - $onsite_checkout_count,
 636                 max_allowed => $max_checkouts_allowed,
 637             };
 638         }
 639     }
 640
 641     return;
 642 }
 643
 644 =head2 CanBookBeIssued
 645
 646   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 647                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 648
 649 Check if a book can be issued.
 650
 651 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 652
 653 IMPORTANT: The assumption by users of this routine is that causes blocking
 654 the issue are keyed by uppercase labels and other returned
 655 data is keyed in lower case!
 656
 657 =over 4
 658
 659 =item C<$patron> is a Koha::Patron
 660
 661 =item C<$barcode> is the bar code of the book being issued.
 662
 663 =item C<$duedates> is a DateTime object.
 664
 665 =item C<$inprocess> boolean switch
 666
 667 =item C<$ignore_reserves> boolean switch
 668
 669 =item C<$params> Hashref of additional parameters
 670
 671 Available keys:
 672     override_high_holds - Ignore high holds
 673     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 674
 675 =back
 676
 677 Returns :
 678
 679 =over 4
 680
 681 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 682 Possible values are :
 683
 684 =back
 685
 686 =head3 INVALID_DATE
 687
 688 sticky due date is invalid
 689
 690 =head3 GNA
 691
 692 borrower gone with no address
 693
 694 =head3 CARD_LOST
 695
 696 borrower declared it's card lost
 697
 698 =head3 DEBARRED
 699
 700 borrower debarred
 701
 702 =head3 UNKNOWN_BARCODE
 703
 704 barcode unknown
 705
 706 =head3 NOT_FOR_LOAN
 707
 708 item is not for loan
 709
 710 =head3 WTHDRAWN
 711
 712 item withdrawn.
 713
 714 =head3 RESTRICTED
 715
 716 item is restricted (set by ??)
 717
 718 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 719 could be prevented, but ones that can be overriden by the operator.
 720
 721 Possible values are :
 722
 723 =head3 DEBT
 724
 725 borrower has debts.
 726
 727 =head3 RENEW_ISSUE
 728
 729 renewing, not issuing
 730
 731 =head3 ISSUED_TO_ANOTHER
 732
 733 issued to someone else.
 734
 735 =head3 RESERVED
 736
 737 reserved for someone else.
 738
 739 =head3 INVALID_DATE
 740
 741 sticky due date is invalid or due date in the past
 742
 743 =head3 TOO_MANY
 744
 745 if the borrower borrows to much things
 746
 747 =cut
 748
 749 sub CanBookBeIssued {
 750     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 751     my %needsconfirmation;    # filled with problems that needs confirmations
 752     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 753     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 754     my %messages;             # filled with information messages that should be displayed.
 755
 756     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 757     my $override_high_holds = $params->{override_high_holds} || 0;
 758
 759     my $item_object = Koha::Items->find({barcode => $barcode });
 760
 761     # MANDATORY CHECKS - unless item exists, nothing else matters
 762     unless ( $item_object ) {
 763         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 764     }
 765     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 766
 767     my $item_unblessed = $item_object->unblessed; # Transition...
 768     my $issue = $item_object->checkout;
 769     my $biblio = $item_object->biblio;
 770
 771     my $biblioitem = $biblio->biblioitem;
 772     my $effective_itemtype = $item_object->effective_itemtype;
 773     my $dbh             = C4::Context->dbh;
 774     my $patron_unblessed = $patron->unblessed;
 775
 776     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 777     #
 778     # DUE DATE is OK ? -- should already have checked.
 779     #
 780     if ($duedate && ref $duedate ne 'DateTime') {
 781         $duedate = dt_from_string($duedate);
 782     }
 783     my $now = dt_from_string();
 784     unless ( $duedate ) {
 785         my $issuedate = $now->clone();
 786
 787         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 788
 789         # Offline circ calls AddIssue directly, doesn't run through here
 790         #  So issuingimpossible should be ok.
 791     }
 792
 793     my $fees = Koha::Charges::Fees->new(
 794         {
 795             patron    => $patron,
 796             library   => $circ_library,
 797             item      => $item_object,
 798             to_date   => $duedate,
 799         }
 800     );
 801
 802     if ($duedate) {
 803         my $today = $now->clone();
 804         $today->truncate( to => 'minute');
 805         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 806             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 807         }
 808     } else {
 809             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 810     }
 811
 812     #
 813     # BORROWER STATUS
 814     #
 815     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 816         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 817         &UpdateStats({
 818                      branch => C4::Context->userenv->{'branch'},
 819                      type => 'localuse',
 820                      itemnumber => $item_object->itemnumber,
 821                      itemtype => $effective_itemtype,
 822                      borrowernumber => $patron->borrowernumber,
 823                      ccode => $item_object->ccode}
 824                     );
 825         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 826         return( { STATS => 1 }, {});
 827     }
 828
 829     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 830         $issuingimpossible{GNA} = 1;
 831     }
 832
 833     if ( $patron->lost && $patron->lost == 1 ) {
 834         $issuingimpossible{CARD_LOST} = 1;
 835     }
 836     if ( $patron->is_debarred ) {
 837         $issuingimpossible{DEBARRED} = 1;
 838     }
 839
 840     if ( $patron->is_expired ) {
 841         $issuingimpossible{EXPIRED} = 1;
 842     }
 843
 844     #
 845     # BORROWER STATUS
 846     #
 847
 848     # DEBTS
 849     my $account = $patron->account;
 850     my $balance = $account->balance;
 851     my $non_issues_charges = $account->non_issues_charges;
 852     my $other_charges = $balance - $non_issues_charges;
 853
 854     my $amountlimit = C4::Context->preference("noissuescharge");
 855     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 856     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 857
 858     # Check the debt of this patrons guarantees
 859     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 860     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 861     if ( defined $no_issues_charge_guarantees ) {
 862         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 863         my $guarantees_non_issues_charges;
 864         foreach my $g ( @guarantees ) {
 865             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 866         }
 867
 868         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 869             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 870         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 871             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 872         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 873             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         }
 875     }
 876
 877     if ( C4::Context->preference("IssuingInProcess") ) {
 878         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 879             $issuingimpossible{DEBT} = $non_issues_charges;
 880         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 881             $needsconfirmation{DEBT} = $non_issues_charges;
 882         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 883             $needsconfirmation{DEBT} = $non_issues_charges;
 884         }
 885     }
 886     else {
 887         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 888             $needsconfirmation{DEBT} = $non_issues_charges;
 889         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 890             $issuingimpossible{DEBT} = $non_issues_charges;
 891         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 892             $needsconfirmation{DEBT} = $non_issues_charges;
 893         }
 894     }
 895
 896     if ($balance > 0 && $other_charges > 0) {
 897         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 898     }
 899
 900     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 901     $patron_unblessed = $patron->unblessed;
 902
 903     if ( my $debarred_date = $patron->is_debarred ) {
 904          # patron has accrued fine days or has a restriction. $count is a date
 905         if ($debarred_date eq '9999-12-31') {
 906             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 907         }
 908         else {
 909             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 910         }
 911     } elsif ( my $num_overdues = $patron->has_overdues ) {
 912         ## patron has outstanding overdue loans
 913         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 914             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 915         }
 916         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 917             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 918         }
 919     }
 920
 921     #
 922     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 923     #
 924     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 925
 926         # Already issued to current borrower.
 927         # If it is an on-site checkout if it can be switched to a normal checkout
 928         # or ask whether the loan should be renewed
 929
 930         if ( $issue->onsite_checkout
 931                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 932             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 933         } else {
 934             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 935                 $patron->borrowernumber,
 936                 $item_object->itemnumber,
 937             );
 938             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 939                 if ( $renewerror eq 'onsite_checkout' ) {
 940                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 941                 }
 942                 else {
 943                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 944                 }
 945             }
 946             else {
 947                 $needsconfirmation{RENEW_ISSUE} = 1;
 948             }
 949         }
 950     }
 951     elsif ( $issue ) {
 952
 953         # issued to someone else
 954
 955         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 956
 957         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 958
 959         unless ( $can_be_returned ) {
 960             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 961             $issuingimpossible{branch_to_return} = $message;
 962         } else {
 963             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 964                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 965             } else {
 966             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 967             $needsconfirmation{issued_firstname} = $patron->firstname;
 968             $needsconfirmation{issued_surname} = $patron->surname;
 969             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 970             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 971             }
 972         }
 973     }
 974
 975     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 976     #
 977     my $switch_onsite_checkout = (
 978           C4::Context->preference('SwitchOnSiteCheckouts')
 979       and $issue
 980       and $issue->onsite_checkout
 981       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 982     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 983     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 984     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 985         if ( $toomany->{max_allowed} == 0 ) {
 986             $needsconfirmation{PATRON_CANT} = 1;
 987         }
 988         if ( C4::Context->preference("AllowTooManyOverride") ) {
 989             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 990             $needsconfirmation{current_loan_count} = $toomany->{count};
 991             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 992         } else {
 993             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 994             $issuingimpossible{current_loan_count} = $toomany->{count};
 995             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 996         }
 997     }
 998
 999     #
1000     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1001     #
1002     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1003     my $wants_check = $patron->wants_check_for_previous_checkout;
1004     $needsconfirmation{PREVISSUE} = 1
1005         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1006
1007     #
1008     # ITEM CHECKING
1009     #
1010     if ( $item_object->notforloan )
1011     {
1012         if(!C4::Context->preference("AllowNotForLoanOverride")){
1013             $issuingimpossible{NOT_FOR_LOAN} = 1;
1014             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1015         }else{
1016             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1017             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1018         }
1019     }
1020     else {
1021         # we have to check itemtypes.notforloan also
1022         if (C4::Context->preference('item-level_itypes')){
1023             # this should probably be a subroutine
1024             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1025             $sth->execute($effective_itemtype);
1026             my $notforloan=$sth->fetchrow_hashref();
1027             if ($notforloan->{'notforloan'}) {
1028                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1029                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1030                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1031                 } else {
1032                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1033                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1034                 }
1035             }
1036         }
1037         else {
1038             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1039             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1040                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1041                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1042                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1043                 } else {
1044                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1045                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1046                 }
1047             }
1048         }
1049     }
1050     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1051     {
1052         $issuingimpossible{WTHDRAWN} = 1;
1053     }
1054     if (   $item_object->restricted
1055         && $item_object->restricted == 1 )
1056     {
1057         $issuingimpossible{RESTRICTED} = 1;
1058     }
1059     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1060         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1061         my $code = $av->count ? $av->next->lib : '';
1062         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1063         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1064     }
1065     if ( C4::Context->preference("IndependentBranches") ) {
1066         my $userenv = C4::Context->userenv;
1067         unless ( C4::Context->IsSuperLibrarian() ) {
1068             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1069             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1070                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1071                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1072             }
1073             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1074               if ( $patron->branchcode ne $userenv->{branch} );
1075         }
1076     }
1077
1078     #
1079     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1080     #
1081     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1082     if ($rentalConfirmation) {
1083         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1084
1085         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1086         if ($itemtype_object) {
1087             my $accumulate_charge = $fees->accumulate_rentalcharge();
1088             if ( $accumulate_charge > 0 ) {
1089                 $rentalCharge += $accumulate_charge;
1090             }
1091         }
1092
1093         if ( $rentalCharge > 0 ) {
1094             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1095         }
1096     }
1097
1098     unless ( $ignore_reserves ) {
1099         # See if the item is on reserve.
1100         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1101         if ($restype) {
1102             my $resbor = $res->{'borrowernumber'};
1103             if ( $resbor ne $patron->borrowernumber ) {
1104                 my $patron = Koha::Patrons->find( $resbor );
1105                 if ( $restype eq "Waiting" )
1106                 {
1107                     # The item is on reserve and waiting, but has been
1108                     # reserved by some other patron.
1109                     $needsconfirmation{RESERVE_WAITING} = 1;
1110                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1111                     $needsconfirmation{'ressurname'} = $patron->surname;
1112                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1113                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1114                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1115                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1116                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1117                 }
1118                 elsif ( $restype eq "Reserved" ) {
1119                     # The item is on reserve for someone else.
1120                     $needsconfirmation{RESERVED} = 1;
1121                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1122                     $needsconfirmation{'ressurname'} = $patron->surname;
1123                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1124                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1125                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1126                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1127                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1128                 }
1129             }
1130         }
1131     }
1132
1133     ## CHECK AGE RESTRICTION
1134     my $agerestriction  = $biblioitem->agerestriction;
1135     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1136     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1137         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1138             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1139         }
1140         else {
1141             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1142         }
1143     }
1144
1145     ## check for high holds decreasing loan period
1146     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1147         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1148
1149         if ( $check->{exceeded} ) {
1150             if ($override_high_holds) {
1151                 $alerts{HIGHHOLDS} = {
1152                     num_holds  => $check->{outstanding},
1153                     duration   => $check->{duration},
1154                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1155                 };
1156             }
1157             else {
1158                 $needsconfirmation{HIGHHOLDS} = {
1159                     num_holds  => $check->{outstanding},
1160                     duration   => $check->{duration},
1161                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1162                 };
1163             }
1164         }
1165     }
1166
1167     if (
1168         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1169         # don't do the multiple loans per bib check if we've
1170         # already determined that we've got a loan on the same item
1171         !$issuingimpossible{NO_MORE_RENEWALS} &&
1172         !$needsconfirmation{RENEW_ISSUE}
1173     ) {
1174         # Check if borrower has already issued an item from the same biblio
1175         # Only if it's not a subscription
1176         my $biblionumber = $item_object->biblionumber;
1177         require C4::Serials;
1178         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1179         unless ($is_a_subscription) {
1180             # FIXME Should be $patron->checkouts($args);
1181             my $checkouts = Koha::Checkouts->search(
1182                 {
1183                     borrowernumber => $patron->borrowernumber,
1184                     biblionumber   => $biblionumber,
1185                 },
1186                 {
1187                     join => 'item',
1188                 }
1189             );
1190             # if we get here, we don't already have a loan on this item,
1191             # so if there are any loans on this bib, ask for confirmation
1192             if ( $checkouts->count ) {
1193                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1194             }
1195         }
1196     }
1197
1198     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1199 }
1200
1201 =head2 CanBookBeReturned
1202
1203   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1204
1205 Check whether the item can be returned to the provided branch
1206
1207 =over 4
1208
1209 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1210
1211 =item C<$branch> is the branchcode where the return is taking place
1212
1213 =back
1214
1215 Returns:
1216
1217 =over 4
1218
1219 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1220
1221 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1222
1223 =back
1224
1225 =cut
1226
1227 sub CanBookBeReturned {
1228   my ($item, $branch) = @_;
1229   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1230
1231   # assume return is allowed to start
1232   my $allowed = 1;
1233   my $message;
1234
1235   # identify all cases where return is forbidden
1236   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1237      $allowed = 0;
1238      $message = $item->{'homebranch'};
1239   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1240      $allowed = 0;
1241      $message = $item->{'holdingbranch'};
1242   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1243      $allowed = 0;
1244      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1245   }
1246
1247   return ($allowed, $message);
1248 }
1249
1250 =head2 CheckHighHolds
1251
1252     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1253     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1254     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1255
1256 =cut
1257
1258 sub checkHighHolds {
1259     my ( $item, $borrower ) = @_;
1260     my $branchcode = _GetCircControlBranch( $item, $borrower );
1261     my $item_object = Koha::Items->find( $item->{itemnumber} );
1262
1263     my $return_data = {
1264         exceeded    => 0,
1265         outstanding => 0,
1266         duration    => 0,
1267         due_date    => undef,
1268     };
1269
1270     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1271
1272     if ( $holds->count() ) {
1273         $return_data->{outstanding} = $holds->count();
1274
1275         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1276         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1277         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1278
1279         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1280
1281         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1282
1283             # static means just more than a given number of holds on the record
1284
1285             # If the number of holds is less than the threshold, we can stop here
1286             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1287                 return $return_data;
1288             }
1289         }
1290         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1291
1292             # dynamic means X more than the number of holdable items on the record
1293
1294             # let's get the items
1295             my @items = $holds->next()->biblio()->items()->as_list;
1296
1297             # Remove any items with status defined to be ignored even if the would not make item unholdable
1298             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1299                 @items = grep { !$_->$status } @items;
1300             }
1301
1302             # Remove any items that are not holdable for this patron
1303             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1304
1305             my $items_count = scalar @items;
1306
1307             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1308
1309             # If the number of holds is less than the count of items we have
1310             # plus the number of holds allowed above that count, we can stop here
1311             if ( $holds->count() <= $threshold ) {
1312                 return $return_data;
1313             }
1314         }
1315
1316         my $issuedate = dt_from_string();
1317
1318         my $itype = $item_object->effective_itemtype;
1319         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1320             {
1321                 categorycode => $borrower->{categorycode},
1322                 itemtype     => $itype,
1323                 branchcode   => $branchcode,
1324             }
1325         );
1326         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1327
1328         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1329
1330         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1331
1332         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1333         $reduced_datedue->set_hour($orig_due->hour);
1334         $reduced_datedue->set_minute($orig_due->minute);
1335         $reduced_datedue->truncate( to => 'minute' );
1336
1337         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1338             $return_data->{exceeded} = 1;
1339             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1340             $return_data->{due_date} = $reduced_datedue;
1341         }
1342     }
1343
1344     return $return_data;
1345 }
1346
1347 =head2 AddIssue
1348
1349   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1350
1351 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1352
1353 =over 4
1354
1355 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1356
1357 =item C<$barcode> is the barcode of the item being issued.
1358
1359 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1360 Calculated if empty.
1361
1362 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1363
1364 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1365 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1366
1367 AddIssue does the following things :
1368
1369   - step 01: check that there is a borrowernumber & a barcode provided
1370   - check for RENEWAL (book issued & being issued to the same patron)
1371       - renewal YES = Calculate Charge & renew
1372       - renewal NO  =
1373           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1374           * RESERVE PLACED ?
1375               - fill reserve if reserve to this patron
1376               - cancel reserve or not, otherwise
1377           * TRANSFERT PENDING ?
1378               - complete the transfert
1379           * ISSUE THE BOOK
1380
1381 =back
1382
1383 =cut
1384
1385 sub AddIssue {
1386     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1387
1388     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1389     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1390     my $auto_renew = $params && $params->{auto_renew};
1391     my $dbh          = C4::Context->dbh;
1392     my $barcodecheck = CheckValidBarcode($barcode);
1393
1394     my $issue;
1395
1396     if ( $datedue && ref $datedue ne 'DateTime' ) {
1397         $datedue = dt_from_string($datedue);
1398     }
1399
1400     # $issuedate defaults to today.
1401     if ( !defined $issuedate ) {
1402         $issuedate = dt_from_string();
1403     }
1404     else {
1405         if ( ref $issuedate ne 'DateTime' ) {
1406             $issuedate = dt_from_string($issuedate);
1407
1408         }
1409     }
1410
1411     # Stop here if the patron or barcode doesn't exist
1412     if ( $borrower && $barcode && $barcodecheck ) {
1413         # find which item we issue
1414         my $item_object = Koha::Items->find({ barcode => $barcode })
1415           or return;    # if we don't get an Item, abort.
1416         my $item_unblessed = $item_object->unblessed;
1417
1418         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1419
1420         # get actual issuing if there is one
1421         my $actualissue = $item_object->checkout;
1422
1423         # check if we just renew the issue.
1424         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1425                 and not $switch_onsite_checkout ) {
1426             $datedue = AddRenewal(
1427                 $borrower->{'borrowernumber'},
1428                 $item_object->itemnumber,
1429                 $branchcode,
1430                 $datedue,
1431                 $issuedate,    # here interpreted as the renewal date
1432             );
1433         }
1434         else {
1435             unless ($datedue) {
1436                 my $itype = $item_object->effective_itemtype;
1437                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1438
1439             }
1440             $datedue->truncate( to => 'minute' );
1441
1442             my $patron = Koha::Patrons->find( $borrower );
1443             my $library = Koha::Libraries->find( $branchcode );
1444             my $fees = Koha::Charges::Fees->new(
1445                 {
1446                     patron    => $patron,
1447                     library   => $library,
1448                     item      => $item_object,
1449                     to_date   => $datedue,
1450                 }
1451             );
1452
1453             # it's NOT a renewal
1454             if ( $actualissue and not $switch_onsite_checkout ) {
1455                 # This book is currently on loan, but not to the person
1456                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1457                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1458                 return unless $allowed;
1459                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1460             }
1461
1462             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1463
1464             # Starting process for transfer job (checking transfert and validate it if we have one)
1465             my ($datesent) = GetTransfers( $item_object->itemnumber );
1466             if ($datesent) {
1467                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1468                 my $sth = $dbh->prepare(
1469                     "UPDATE branchtransfers
1470                         SET datearrived = now(),
1471                         tobranch = ?,
1472                         comments = 'Forced branchtransfer'
1473                     WHERE itemnumber= ? AND datearrived IS NULL"
1474                 );
1475                 $sth->execute( C4::Context->userenv->{'branch'},
1476                     $item_object->itemnumber );
1477             }
1478
1479             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1480             unless ($auto_renew) {
1481                 my $rule = Koha::CirculationRules->get_effective_rule(
1482                     {
1483                         categorycode => $borrower->{categorycode},
1484                         itemtype     => $item_object->effective_itemtype,
1485                         branchcode   => $branchcode,
1486                         rule_name    => 'auto_renew'
1487                     }
1488                 );
1489
1490                 $auto_renew = $rule->rule_value if $rule;
1491             }
1492
1493             # Record in the database the fact that the book was issued.
1494             unless ($datedue) {
1495                 my $itype = $item_object->effective_itemtype;
1496                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1497
1498             }
1499             $datedue->truncate( to => 'minute' );
1500
1501             my $issue_attributes = {
1502                 borrowernumber  => $borrower->{'borrowernumber'},
1503                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1504                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1505                 branchcode      => C4::Context->userenv->{'branch'},
1506                 onsite_checkout => $onsite_checkout,
1507                 auto_renew      => $auto_renew ? 1 : 0,
1508             };
1509
1510             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1511             if ($issue) {
1512                 $issue->set($issue_attributes)->store;
1513             }
1514             else {
1515                 $issue = Koha::Checkout->new(
1516                     {
1517                         itemnumber => $item_object->itemnumber,
1518                         %$issue_attributes,
1519                     }
1520                 )->store;
1521             }
1522             if ( $item_object->location && $item_object->location eq 'CART'
1523                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1524             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1525                 CartToShelf( $item_object->itemnumber );
1526             }
1527
1528             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1529                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1530             }
1531
1532             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1533             if ( $item_object->itemlost ) {
1534                 my $refund = 1;
1535                 my $no_refund_after_days = C4::Context->preference('NoRefundOnLostReturnedItemsAge');
1536                 if ($no_refund_after_days) {
1537                     my $today = dt_from_string();
1538                     my $lost_age_in_days =
1539                       dt_from_string( $item_object->itemlost_on )
1540                       ->delta_days($today)
1541                       ->in_units('days');
1542
1543                     $refund = 0 unless ( $lost_age_in_days < $no_refund_after_days );
1544                 }
1545
1546                 if (
1547                     $refund && Koha::CirculationRules->get_lostreturn_policy(
1548                         {
1549                             return_branch => C4::Context->userenv->{branch},
1550                             item          => $item_object
1551                         }
1552                     )
1553                   )
1554                 {
1555                     _FixAccountForLostAndFound( $item_object->itemnumber, undef,
1556                         $item_object->barcode );
1557                 }
1558             }
1559
1560             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1561             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1562             $item_object->itemlost(0);
1563             $item_object->onloan($datedue->ymd());
1564             $item_object->datelastborrowed( dt_from_string()->ymd() );
1565             $item_object->store({log_action => 0});
1566             ModDateLastSeen( $item_object->itemnumber );
1567
1568             # If it costs to borrow this book, charge it to the patron's account.
1569             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1570             if ( $charge && $charge > 0 ) {
1571                 AddIssuingCharge( $issue, $charge, 'RENT' );
1572             }
1573
1574             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1575             if ( $itemtype_object ) {
1576                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1577                 if ( $accumulate_charge > 0 ) {
1578                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1579                     $charge += $accumulate_charge;
1580                     $item_unblessed->{charge} = $charge;
1581                 }
1582             }
1583
1584             # Record the fact that this book was issued.
1585             &UpdateStats(
1586                 {
1587                     branch => C4::Context->userenv->{'branch'},
1588                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1589                     amount         => $charge,
1590                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1591                     itemnumber     => $item_object->itemnumber,
1592                     itemtype       => $item_object->effective_itemtype,
1593                     location       => $item_object->location,
1594                     borrowernumber => $borrower->{'borrowernumber'},
1595                     ccode          => $item_object->ccode,
1596                 }
1597             );
1598
1599             # Send a checkout slip.
1600             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1601             my %conditions        = (
1602                 branchcode   => $branchcode,
1603                 categorycode => $borrower->{categorycode},
1604                 item_type    => $item_object->effective_itemtype,
1605                 notification => 'CHECKOUT',
1606             );
1607             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1608                 SendCirculationAlert(
1609                     {
1610                         type     => 'CHECKOUT',
1611                         item     => $item_object->unblessed,
1612                         borrower => $borrower,
1613                         branch   => $branchcode,
1614                     }
1615                 );
1616             }
1617             logaction(
1618                 "CIRCULATION", "ISSUE",
1619                 $borrower->{'borrowernumber'},
1620                 $item_object->itemnumber,
1621             ) if C4::Context->preference("IssueLog");
1622
1623             Koha::Plugins->call('after_circ_action', {
1624                 action  => 'checkout',
1625                 payload => {
1626                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1627                     checkout => $issue->get_from_storage
1628                 }
1629             });
1630         }
1631     }
1632     return $issue;
1633 }
1634
1635 =head2 GetLoanLength
1636
1637   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1638
1639 Get loan length for an itemtype, a borrower type and a branch
1640
1641 =cut
1642
1643 sub GetLoanLength {
1644     my ( $categorycode, $itemtype, $branchcode ) = @_;
1645
1646     # Set search precedences
1647     my @params = (
1648         {
1649             categorycode => $categorycode,
1650             itemtype     => $itemtype,
1651             branchcode   => $branchcode,
1652         },
1653         {
1654             categorycode => $categorycode,
1655             itemtype     => undef,
1656             branchcode   => $branchcode,
1657         },
1658         {
1659             categorycode => undef,
1660             itemtype     => $itemtype,
1661             branchcode   => $branchcode,
1662         },
1663         {
1664             categorycode => undef,
1665             itemtype     => undef,
1666             branchcode   => $branchcode,
1667         },
1668         {
1669             categorycode => $categorycode,
1670             itemtype     => $itemtype,
1671             branchcode   => undef,
1672         },
1673         {
1674             categorycode => $categorycode,
1675             itemtype     => undef,
1676             branchcode   => undef,
1677         },
1678         {
1679             categorycode => undef,
1680             itemtype     => $itemtype,
1681             branchcode   => undef,
1682         },
1683         {
1684             categorycode => undef,
1685             itemtype     => undef,
1686             branchcode   => undef,
1687         },
1688     );
1689
1690     # Initialize default values
1691     my $rules = {
1692         issuelength   => 0,
1693         renewalperiod => 0,
1694         lengthunit    => 'days',
1695     };
1696
1697     # Search for rules!
1698     foreach my $rule_name (qw( issuelength renewalperiod lengthunit )) {
1699         foreach my $params (@params) {
1700             my $rule = Koha::CirculationRules->search(
1701                 {
1702                     rule_name => $rule_name,
1703                     %$params,
1704                 }
1705             )->next();
1706
1707             if ($rule) {
1708                 $rules->{$rule_name} = $rule->rule_value;
1709                 last;
1710             }
1711         }
1712     }
1713
1714     return $rules;
1715 }
1716
1717
1718 =head2 GetHardDueDate
1719
1720   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1721
1722 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1723
1724 =cut
1725
1726 sub GetHardDueDate {
1727     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1728
1729     my $rules = Koha::CirculationRules->get_effective_rules(
1730         {
1731             categorycode => $borrowertype,
1732             itemtype     => $itemtype,
1733             branchcode   => $branchcode,
1734             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1735         }
1736     );
1737
1738     if ( defined( $rules->{hardduedate} ) ) {
1739         if ( $rules->{hardduedate} ) {
1740             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1741         }
1742         else {
1743             return ( undef, undef );
1744         }
1745     }
1746 }
1747
1748 =head2 GetBranchBorrowerCircRule
1749
1750   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1751
1752 Retrieves circulation rule attributes that apply to the given
1753 branch and patron category, regardless of item type.
1754 The return value is a hashref containing the following key:
1755
1756 patron_maxissueqty - maximum number of loans that a
1757 patron of the given category can have at the given
1758 branch.  If the value is undef, no limit.
1759
1760 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1761 patron of the given category can have at the given
1762 branch.  If the value is undef, no limit.
1763
1764 This will check for different branch/category combinations in the following order:
1765 branch and category
1766 branch only
1767 category only
1768 default branch and category
1769
1770 If no rule has been found in the database, it will default to
1771 the buillt in rule:
1772
1773 patron_maxissueqty - undef
1774 patron_maxonsiteissueqty - undef
1775
1776 C<$branchcode> and C<$categorycode> should contain the
1777 literal branch code and patron category code, respectively - no
1778 wildcards.
1779
1780 =cut
1781
1782 sub GetBranchBorrowerCircRule {
1783     my ( $branchcode, $categorycode ) = @_;
1784
1785     # Initialize default values
1786     my $rules = {
1787         patron_maxissueqty       => undef,
1788         patron_maxonsiteissueqty => undef,
1789     };
1790
1791     # Search for rules!
1792     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1793         my $rule = Koha::CirculationRules->get_effective_rule(
1794             {
1795                 categorycode => $categorycode,
1796                 itemtype     => undef,
1797                 branchcode   => $branchcode,
1798                 rule_name    => $rule_name,
1799             }
1800         );
1801
1802         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1803     }
1804
1805     return $rules;
1806 }
1807
1808 =head2 GetBranchItemRule
1809
1810   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1811
1812 Retrieves circulation rule attributes that apply to the given
1813 branch and item type, regardless of patron category.
1814
1815 The return value is a hashref containing the following keys:
1816
1817 holdallowed => Hold policy for this branch and itemtype. Possible values:
1818   0: No holds allowed.
1819   1: Holds allowed only by patrons that have the same homebranch as the item.
1820   2: Holds allowed from any patron.
1821
1822 returnbranch => branch to which to return item.  Possible values:
1823   noreturn: do not return, let item remain where checked in (floating collections)
1824   homebranch: return to item's home branch
1825   holdingbranch: return to issuer branch
1826
1827 This searches branchitemrules in the following order:
1828
1829   * Same branchcode and itemtype
1830   * Same branchcode, itemtype '*'
1831   * branchcode '*', same itemtype
1832   * branchcode and itemtype '*'
1833
1834 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1835
1836 =cut
1837
1838 sub GetBranchItemRule {
1839     my ( $branchcode, $itemtype ) = @_;
1840
1841     # Search for rules!
1842     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1843         {
1844             branchcode => $branchcode,
1845             itemtype => $itemtype,
1846             rule_name => 'holdallowed',
1847         }
1848     );
1849     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1850         {
1851             branchcode => $branchcode,
1852             itemtype => $itemtype,
1853             rule_name => 'hold_fulfillment_policy',
1854         }
1855     );
1856     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1857         {
1858             branchcode => $branchcode,
1859             itemtype => $itemtype,
1860             rule_name => 'returnbranch',
1861         }
1862     );
1863
1864     # built-in default circulation rule
1865     my $rules;
1866     $rules->{holdallowed} = defined $holdallowed_rule
1867         ? $holdallowed_rule->rule_value
1868         : 2;
1869     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1870         ? $hold_fulfillment_policy_rule->rule_value
1871         : 'any';
1872     $rules->{returnbranch} = defined $returnbranch_rule
1873         ? $returnbranch_rule->rule_value
1874         : 'homebranch';
1875
1876     return $rules;
1877 }
1878
1879 =head2 AddReturn
1880
1881   ($doreturn, $messages, $iteminformation, $borrower) =
1882       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1883
1884 Returns a book.
1885
1886 =over 4
1887
1888 =item C<$barcode> is the bar code of the book being returned.
1889
1890 =item C<$branch> is the code of the branch where the book is being returned.
1891
1892 =item C<$exemptfine> indicates that overdue charges for the item will be
1893 removed. Optional.
1894
1895 =item C<$return_date> allows the default return date to be overridden
1896 by the given return date. Optional.
1897
1898 =back
1899
1900 C<&AddReturn> returns a list of four items:
1901
1902 C<$doreturn> is true iff the return succeeded.
1903
1904 C<$messages> is a reference-to-hash giving feedback on the operation.
1905 The keys of the hash are:
1906
1907 =over 4
1908
1909 =item C<BadBarcode>
1910
1911 No item with this barcode exists. The value is C<$barcode>.
1912
1913 =item C<NotIssued>
1914
1915 The book is not currently on loan. The value is C<$barcode>.
1916
1917 =item C<withdrawn>
1918
1919 This book has been withdrawn/cancelled. The value should be ignored.
1920
1921 =item C<Wrongbranch>
1922
1923 This book has was returned to the wrong branch.  The value is a hashref
1924 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1925 contain the branchcode of the incorrect and correct return library, respectively.
1926
1927 =item C<ResFound>
1928
1929 The item was reserved. The value is a reference-to-hash whose keys are
1930 fields from the reserves table of the Koha database, and
1931 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1932 either C<Waiting>, C<Reserved>, or 0.
1933
1934 =item C<WasReturned>
1935
1936 Value 1 if return is successful.
1937
1938 =item C<NeedsTransfer>
1939
1940 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1941
1942 =back
1943
1944 C<$iteminformation> is a reference-to-hash, giving information about the
1945 returned item from the issues table.
1946
1947 C<$borrower> is a reference-to-hash, giving information about the
1948 patron who last borrowed the book.
1949
1950 =cut
1951
1952 sub AddReturn {
1953     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1954
1955     if ($branch and not Koha::Libraries->find($branch)) {
1956         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1957         undef $branch;
1958     }
1959     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1960     my $return_date_specified = !!$return_date;
1961     $return_date //= dt_from_string();
1962     my $messages;
1963     my $patron;
1964     my $doreturn       = 1;
1965     my $validTransfert = 0;
1966     my $stat_type = 'return';
1967
1968     # get information on item
1969     my $item = Koha::Items->find({ barcode => $barcode });
1970     unless ($item) {
1971         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1972     }
1973
1974     my $itemnumber = $item->itemnumber;
1975     my $itemtype = $item->effective_itemtype;
1976
1977     my $issue  = $item->checkout;
1978     if ( $issue ) {
1979         $patron = $issue->patron
1980             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1981                 . Dumper($issue->unblessed) . "\n";
1982     } else {
1983         $messages->{'NotIssued'} = $barcode;
1984         $item->onloan(undef)->store if defined $item->onloan;
1985
1986         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1987         $doreturn = 0;
1988         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1989         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1990         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1991            $messages->{'LocalUse'} = 1;
1992            $stat_type = 'localuse';
1993         }
1994     }
1995
1996         # full item data, but no borrowernumber or checkout info (no issue)
1997     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1998         # get the proper branch to which to return the item
1999     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2000         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2001     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2002
2003     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2004     my $patron_unblessed = $patron ? $patron->unblessed : {};
2005
2006     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
2007     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2008     if ($update_loc_rules) {
2009         if (defined $update_loc_rules->{_ALL_}) {
2010             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2011             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2012             if ( $item->location ne $update_loc_rules->{_ALL_}) {
2013                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2014                 $item->location($update_loc_rules->{_ALL_})->store;
2015             }
2016         }
2017         else {
2018             foreach my $key ( keys %$update_loc_rules ) {
2019                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2020                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2021                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2022                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2023                     $item->location($update_loc_rules->{$key})->store;
2024                     last;
2025                 }
2026             }
2027         }
2028     }
2029
2030     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2031     if ($yaml) {
2032         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2033         my $rules;
2034         eval { $rules = YAML::Load($yaml); };
2035         if ($@) {
2036             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2037         }
2038         else {
2039             foreach my $key ( keys %$rules ) {
2040                 if ( $item->notforloan eq $key ) {
2041                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2042                     $item->notforloan($rules->{$key})->store({ log_action => 0 });
2043                     last;
2044                 }
2045             }
2046         }
2047     }
2048
2049     # check if the return is allowed at this branch
2050     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2051     unless ($returnallowed){
2052         $messages->{'Wrongbranch'} = {
2053             Wrongbranch => $branch,
2054             Rightbranch => $message
2055         };
2056         $doreturn = 0;
2057         return ( $doreturn, $messages, $issue, $patron_unblessed);
2058     }
2059
2060     if ( $item->withdrawn ) { # book has been cancelled
2061         $messages->{'withdrawn'} = 1;
2062         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2063     }
2064
2065     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2066         $doreturn = 0;
2067     }
2068
2069     # case of a return of document (deal with issues and holdingbranch)
2070     if ($doreturn) {
2071         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2072         $patron or warn "AddReturn without current borrower";
2073
2074         if ($patron) {
2075             eval {
2076                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
2077             };
2078             unless ( $@ ) {
2079                 if (
2080                     (
2081                         C4::Context->preference('CalculateFinesOnReturn')
2082                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2083                     )
2084                     && !$item->itemlost
2085                   )
2086                 {
2087                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2088                 }
2089             } else {
2090                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
2091
2092                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2093             }
2094
2095             # FIXME is the "= 1" right?  This could be the borrower hash.
2096             $messages->{'WasReturned'} = 1;
2097
2098         }
2099
2100         $item->onloan(undef)->store({ log_action => 0 });
2101     }
2102
2103     # the holdingbranch is updated if the document is returned to another location.
2104     # this is always done regardless of whether the item was on loan or not
2105     my $item_holding_branch = $item->holdingbranch;
2106     if ($item->holdingbranch ne $branch) {
2107         $item->holdingbranch($branch)->store;
2108     }
2109
2110     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2111     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
2112
2113     # check if we have a transfer for this document
2114     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2115
2116     # if we have a transfer to do, we update the line of transfers with the datearrived
2117     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2118     if ($datesent) {
2119         if ( $tobranch eq $branch ) {
2120             my $sth = C4::Context->dbh->prepare(
2121                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2122             );
2123             $sth->execute( $item->itemnumber );
2124         } else {
2125             $messages->{'WrongTransfer'}     = $tobranch;
2126             $messages->{'WrongTransferItem'} = $item->itemnumber;
2127         }
2128         $validTransfert = 1;
2129     }
2130
2131     # fix up the accounts.....
2132     if ( $item->itemlost ) {
2133         $messages->{'WasLost'} = 1;
2134         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2135             my $refund = 1;
2136             my $no_refund_after_days = C4::Context->preference('NoRefundOnLostReturnedItemsAge');
2137             if ($no_refund_after_days) {
2138                 my $today = dt_from_string();
2139                 my $lost_age_in_days =
2140                   dt_from_string( $item->itemlost_on )
2141                   ->delta_days($today)
2142                   ->in_units('days');
2143
2144                 $refund = 0 unless ( $lost_age_in_days < $no_refund_after_days );
2145             }
2146
2147             if (
2148                 $refund &&
2149                 Koha::CirculationRules->get_lostreturn_policy(
2150                     {
2151                         return_branch => C4::Context->userenv->{branch},
2152                         item          => $item,
2153                     }
2154                   )
2155               )
2156             {
2157                 _FixAccountForLostAndFound( $item->itemnumber,
2158                     $borrowernumber, $barcode );
2159                 $messages->{'LostItemFeeRefunded'} = 1;
2160             }
2161         }
2162     }
2163
2164     # fix up the overdues in accounts...
2165     if ($borrowernumber) {
2166         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2167         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2168
2169         if ( $issue and $issue->is_overdue($return_date) ) {
2170         # fix fine days
2171             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2172             if ($reminder){
2173                 $messages->{'PrevDebarred'} = $debardate;
2174             } else {
2175                 $messages->{'Debarred'} = $debardate if $debardate;
2176             }
2177         # there's no overdue on the item but borrower had been previously debarred
2178         } elsif ( $issue->date_due and $patron->debarred ) {
2179              if ( $patron->debarred eq "9999-12-31") {
2180                 $messages->{'ForeverDebarred'} = $patron->debarred;
2181              } else {
2182                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2183                   $borrower_debar_dt->truncate(to => 'day');
2184                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2185                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2186                       $messages->{'PrevDebarred'} = $patron->debarred;
2187                   }
2188              }
2189         }
2190     }
2191
2192     # find reserves.....
2193     # launch the Checkreserves routine to find any holds
2194     my ($resfound, $resrec);
2195     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2196     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2197     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2198     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2199         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2200         $resfound = 'Reserved';
2201         $resrec = $hold->unblessed;
2202     }
2203     if ($resfound) {
2204           $resrec->{'ResFound'} = $resfound;
2205         $messages->{'ResFound'} = $resrec;
2206     }
2207
2208     # Record the fact that this book was returned.
2209     UpdateStats({
2210         branch         => $branch,
2211         type           => $stat_type,
2212         itemnumber     => $itemnumber,
2213         itemtype       => $itemtype,
2214         location       => $item->location,
2215         borrowernumber => $borrowernumber,
2216         ccode          => $item->ccode,
2217     });
2218
2219     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2220     if ( $patron ) {
2221         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2222         my %conditions = (
2223             branchcode   => $branch,
2224             categorycode => $patron->categorycode,
2225             item_type    => $itemtype,
2226             notification => 'CHECKIN',
2227         );
2228         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2229             SendCirculationAlert({
2230                 type     => 'CHECKIN',
2231                 item     => $item->unblessed,
2232                 borrower => $patron->unblessed,
2233                 branch   => $branch,
2234             });
2235         }
2236
2237         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2238             if C4::Context->preference("ReturnLog");
2239         }
2240
2241     # Check if this item belongs to a biblio record that is attached to an
2242     # ILL request, if it is we need to update the ILL request's status
2243     if (C4::Context->preference('CirculateILL')) {
2244         my $request = Koha::Illrequests->find(
2245             { biblio_id => $item->biblio->biblionumber }
2246         );
2247         $request->status('RET') if $request;
2248     }
2249
2250     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2251     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2252         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2253         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2254             (C4::Context->preference("UseBranchTransferLimits") and
2255              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2256            )) {
2257             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2258             $debug and warn "item: " . Dumper($item->unblessed);
2259             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger);
2260             $messages->{'WasTransfered'} = 1;
2261         } else {
2262             $messages->{'NeedsTransfer'} = $returnbranch;
2263             $messages->{'TransferTrigger'} = $transfer_trigger;
2264         }
2265     }
2266
2267     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2268         my $claims = Koha::Checkouts::ReturnClaims->search(
2269            {
2270                itemnumber => $item->id,
2271                resolution => undef,
2272            }
2273         );
2274
2275         if ( $claims->count ) {
2276             $messages->{ReturnClaims} = $claims;
2277         }
2278     }
2279
2280     if ( $doreturn and $issue ) {
2281         my $checkin = Koha::Old::Checkouts->find($issue->id);
2282
2283         Koha::Plugins->call('after_circ_action', {
2284             action  => 'checkin',
2285             payload => {
2286                 checkout=> $checkin
2287             }
2288         });
2289     }
2290
2291     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2292 }
2293
2294 =head2 MarkIssueReturned
2295
2296   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2297
2298 Unconditionally marks an issue as being returned by
2299 moving the C<issues> row to C<old_issues> and
2300 setting C<returndate> to the current date.
2301
2302 if C<$returndate> is specified (in iso format), it is used as the date
2303 of the return.
2304
2305 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2306 the old_issue is immediately anonymised
2307
2308 Ideally, this function would be internal to C<C4::Circulation>,
2309 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2310 and offline_circ/process_koc.pl.
2311
2312 =cut
2313
2314 sub MarkIssueReturned {
2315     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2316
2317     # Retrieve the issue
2318     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2319
2320     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2321
2322     my $issue_id = $issue->issue_id;
2323
2324     my $anonymouspatron;
2325     if ( $privacy && $privacy == 2 ) {
2326         # The default of 0 will not work due to foreign key constraints
2327         # The anonymisation will fail if AnonymousPatron is not a valid entry
2328         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2329         # Note that a warning should appear on the about page (System information tab).
2330         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2331         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2332             unless Koha::Patrons->find( $anonymouspatron );
2333     }
2334
2335     my $schema = Koha::Database->schema;
2336
2337     # FIXME Improve the return value and handle it from callers
2338     $schema->txn_do(sub {
2339
2340         my $patron = Koha::Patrons->find( $borrowernumber );
2341
2342         # Update the returndate value
2343         if ( $returndate ) {
2344             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2345         }
2346         else {
2347             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2348         }
2349
2350         # Create the old_issues entry
2351         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2352
2353         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2354         if ( $privacy && $privacy == 2) {
2355             $old_checkout->borrowernumber($anonymouspatron)->store;
2356         }
2357
2358         # And finally delete the issue
2359         $issue->delete;
2360
2361         $issue->item->onloan(undef)->store({ log_action => 0 });
2362
2363         if ( C4::Context->preference('StoreLastBorrower') ) {
2364             my $item = Koha::Items->find( $itemnumber );
2365             $item->last_returned_by( $patron );
2366         }
2367
2368         # Remove any OVERDUES related debarment if the borrower has no overdues
2369         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2370           && $patron->debarred
2371           && !$patron->has_overdues
2372           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2373         ) {
2374             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2375         }
2376
2377     });
2378
2379     return $issue_id;
2380 }
2381
2382 =head2 _debar_user_on_return
2383
2384     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2385
2386 C<$borrower> borrower hashref
2387
2388 C<$item> item hashref
2389
2390 C<$datedue> date due DateTime object
2391
2392 C<$returndate> DateTime object representing the return time
2393
2394 Internal function, called only by AddReturn that calculates and updates
2395  the user fine days, and debars them if necessary.
2396
2397 Should only be called for overdue returns
2398
2399 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2400 to ease testing.
2401
2402 =cut
2403
2404 sub _calculate_new_debar_dt {
2405     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2406
2407     my $branchcode = _GetCircControlBranch( $item, $borrower );
2408     my $circcontrol = C4::Context->preference('CircControl');
2409     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2410         {   categorycode => $borrower->{categorycode},
2411             itemtype     => $item->{itype},
2412             branchcode   => $branchcode,
2413             rules => [
2414                 'finedays',
2415                 'lengthunit',
2416                 'firstremind',
2417                 'maxsuspensiondays',
2418                 'suspension_chargeperiod',
2419             ]
2420         }
2421     );
2422     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2423     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2424     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2425
2426     return unless $finedays;
2427
2428     # finedays is in days, so hourly loans must multiply by 24
2429     # thus 1 hour late equals 1 day suspension * finedays rate
2430     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2431
2432     # grace period is measured in the same units as the loan
2433     my $grace =
2434       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2435
2436     my $deltadays = DateTime::Duration->new(
2437         days => $chargeable_units
2438     );
2439
2440     if ( $deltadays->subtract($grace)->is_positive() ) {
2441         my $suspension_days = $deltadays * $finedays;
2442
2443         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2444             # No need to / 1 and do not consider / 0
2445             $suspension_days = DateTime::Duration->new(
2446                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2447             );
2448         }
2449
2450         # If the max suspension days is < than the suspension days
2451         # the suspension days is limited to this maximum period.
2452         my $max_sd = $issuing_rule->{maxsuspensiondays};
2453         if ( defined $max_sd && $max_sd ne '' ) {
2454             $max_sd = DateTime::Duration->new( days => $max_sd );
2455             $suspension_days = $max_sd
2456               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2457         }
2458
2459         my ( $has_been_extended );
2460         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2461             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2462             if ( $debarment ) {
2463                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2464                 $has_been_extended = 1;
2465             }
2466         }
2467
2468         my $new_debar_dt;
2469         # Use the calendar or not to calculate the debarment date
2470         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2471             my $calendar = Koha::Calendar->new(
2472                 branchcode => $branchcode,
2473                 days_mode  => 'Calendar'
2474             );
2475             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2476         }
2477         else {
2478             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2479         }
2480         return $new_debar_dt;
2481     }
2482     return;
2483 }
2484
2485 sub _debar_user_on_return {
2486     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2487
2488     $return_date //= dt_from_string();
2489
2490     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2491
2492     return unless $new_debar_dt;
2493
2494     Koha::Patron::Debarments::AddUniqueDebarment({
2495         borrowernumber => $borrower->{borrowernumber},
2496         expiration     => $new_debar_dt->ymd(),
2497         type           => 'SUSPENSION',
2498     });
2499     # if borrower was already debarred but does not get an extra debarment
2500     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2501     my ($new_debarment_str, $is_a_reminder);
2502     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2503         $is_a_reminder = 1;
2504         $new_debarment_str = $borrower->{debarred};
2505     } else {
2506         $new_debarment_str = $new_debar_dt->ymd();
2507     }
2508     # FIXME Should return a DateTime object
2509     return $new_debarment_str, $is_a_reminder;
2510 }
2511
2512 =head2 _FixOverduesOnReturn
2513
2514    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2515
2516 C<$borrowernumber> borrowernumber
2517
2518 C<$itemnumber> itemnumber
2519
2520 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2521
2522 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2523
2524 Internal function
2525
2526 =cut
2527
2528 sub _FixOverduesOnReturn {
2529     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2530     unless( $borrowernumber ) {
2531         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2532         return;
2533     }
2534     unless( $item ) {
2535         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2536         return;
2537     }
2538     unless( $status ) {
2539         warn "_FixOverduesOnReturn() not supplied valid status";
2540         return;
2541     }
2542
2543     my $schema = Koha::Database->schema;
2544
2545     my $result = $schema->txn_do(
2546         sub {
2547             # check for overdue fine
2548             my $accountlines = Koha::Account::Lines->search(
2549                 {
2550                     borrowernumber  => $borrowernumber,
2551                     itemnumber      => $item,
2552                     debit_type_code => 'OVERDUE',
2553                     status          => 'UNRETURNED'
2554                 }
2555             );
2556             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2557
2558             my $accountline = $accountlines->next;
2559             my $payments = $accountline->credits;
2560
2561             my $amountoutstanding = $accountline->amountoutstanding;
2562             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2563                 $accountline->delete;
2564             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2565                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2566                 my $credit = $account->add_credit(
2567                     {
2568                         amount     => $amountoutstanding,
2569                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2570                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2571                         interface  => C4::Context->interface,
2572                         type       => 'FORGIVEN',
2573                         item_id    => $item
2574                     }
2575                 );
2576
2577                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2578
2579                 if (C4::Context->preference("FinesLog")) {
2580                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2581                 }
2582
2583                 $accountline->status('FORGIVEN');
2584                 $accountline->store();
2585             } else {
2586                 $accountline->status($status);
2587                 $accountline->store();
2588
2589             }
2590         }
2591     );
2592
2593     return $result;
2594 }
2595
2596 =head2 _FixAccountForLostAndFound
2597
2598   &_FixAccountForLostAndFound($itemnumber, [$borrowernumber, $barcode]);
2599
2600 Finds the most recent lost item charge for this item and refunds the borrower
2601 appropriatly, taking into account any payments or writeoffs already applied
2602 against the charge.
2603
2604 Internal function, not exported, called only by AddReturn.
2605
2606 =cut
2607
2608 sub _FixAccountForLostAndFound {
2609     my $itemnumber     = shift or return;
2610     my $borrowernumber = @_ ? shift : undef;
2611     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2612
2613     my $credit;
2614
2615     # check for charge made for lost book
2616     my $accountlines = Koha::Account::Lines->search(
2617         {
2618             itemnumber      => $itemnumber,
2619             debit_type_code => 'LOST',
2620             status          => [ undef, { '<>' => 'FOUND' } ]
2621         },
2622         {
2623             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2624         }
2625     );
2626
2627     return unless $accountlines->count > 0;
2628     my $accountline     = $accountlines->next;
2629     my $total_to_refund = 0;
2630
2631     return unless $accountline->borrowernumber;
2632     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2633     return unless $patron; # Patron has been deleted, nobody to credit the return to
2634
2635     my $account = $patron->account;
2636
2637     # Use cases
2638     if ( $accountline->amount > $accountline->amountoutstanding ) {
2639         # some amount has been cancelled. collect the offsets that are not writeoffs
2640         # this works because the only way to subtract from this kind of a debt is
2641         # using the UI buttons 'Pay' and 'Write off'
2642         my $credits_offsets = Koha::Account::Offsets->search({
2643             debit_id  => $accountline->id,
2644             credit_id => { '!=' => undef }, # it is not the debit itself
2645             type      => { '!=' => 'Writeoff' },
2646             amount    => { '<'  => 0 } # credits are negative on the DB
2647         });
2648
2649         $total_to_refund = ( $credits_offsets->count > 0 )
2650                             ? $credits_offsets->total * -1 # credits are negative on the DB
2651                             : 0;
2652     }
2653
2654     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2655
2656     if ( $credit_total > 0 ) {
2657         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2658         $credit = $account->add_credit(
2659             {
2660                 amount      => $credit_total,
2661                 description => 'Item found ' . $item_id,
2662                 type        => 'LOST_FOUND',
2663                 interface   => C4::Context->interface,
2664                 library_id  => $branchcode,
2665                 item_id     => $itemnumber
2666             }
2667         );
2668
2669         $credit->apply( { debits => [ $accountline ] } );
2670     }
2671
2672     # Update the account status
2673     $accountline->discard_changes->status('FOUND');
2674     $accountline->store;
2675
2676     $accountline->item->paidfor('')->store({ log_action => 0 });
2677
2678     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2679         $account->reconcile_balance;
2680     }
2681
2682     return ($credit) ? $credit->id : undef;
2683 }
2684
2685 =head2 _GetCircControlBranch
2686
2687    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2688
2689 Internal function :
2690
2691 Return the library code to be used to determine which circulation
2692 policy applies to a transaction.  Looks up the CircControl and
2693 HomeOrHoldingBranch system preferences.
2694
2695 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2696
2697 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2698
2699 =cut
2700
2701 sub _GetCircControlBranch {
2702     my ($item, $borrower) = @_;
2703     my $circcontrol = C4::Context->preference('CircControl');
2704     my $branch;
2705
2706     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2707         $branch= C4::Context->userenv->{'branch'};
2708     } elsif ($circcontrol eq 'PatronLibrary') {
2709         $branch=$borrower->{branchcode};
2710     } else {
2711         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2712         $branch = $item->{$branchfield};
2713         # default to item home branch if holdingbranch is used
2714         # and is not defined
2715         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2716             $branch = $item->{homebranch};
2717         }
2718     }
2719     return $branch;
2720 }
2721
2722 =head2 GetOpenIssue
2723
2724   $issue = GetOpenIssue( $itemnumber );
2725
2726 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2727
2728 C<$itemnumber> is the item's itemnumber
2729
2730 Returns a hashref
2731
2732 =cut
2733
2734 sub GetOpenIssue {
2735   my ( $itemnumber ) = @_;
2736   return unless $itemnumber;
2737   my $dbh = C4::Context->dbh;
2738   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2739   $sth->execute( $itemnumber );
2740   return $sth->fetchrow_hashref();
2741
2742 }
2743
2744 =head2 GetBiblioIssues
2745
2746   $issues = GetBiblioIssues($biblionumber);
2747
2748 this function get all issues from a biblionumber.
2749
2750 Return:
2751 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2752 tables issues and the firstname,surname & cardnumber from borrowers.
2753
2754 =cut
2755
2756 sub GetBiblioIssues {
2757     my $biblionumber = shift;
2758     return unless $biblionumber;
2759     my $dbh   = C4::Context->dbh;
2760     my $query = "
2761         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2762         FROM issues
2763             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2764             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2765             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2766             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2767         WHERE biblio.biblionumber = ?
2768         UNION ALL
2769         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2770         FROM old_issues
2771             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2772             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2773             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2774             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2775         WHERE biblio.biblionumber = ?
2776         ORDER BY timestamp
2777     ";
2778     my $sth = $dbh->prepare($query);
2779     $sth->execute($biblionumber, $biblionumber);
2780
2781     my @issues;
2782     while ( my $data = $sth->fetchrow_hashref ) {
2783         push @issues, $data;
2784     }
2785     return \@issues;
2786 }
2787
2788 =head2 GetUpcomingDueIssues
2789
2790   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2791
2792 =cut
2793
2794 sub GetUpcomingDueIssues {
2795     my $params = shift;
2796
2797     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2798     my $dbh = C4::Context->dbh;
2799
2800     my $statement = <<END_SQL;
2801 SELECT *
2802 FROM (
2803     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2804     FROM issues
2805     LEFT JOIN items USING (itemnumber)
2806     LEFT OUTER JOIN branches USING (branchcode)
2807     WHERE returndate is NULL
2808 ) tmp
2809 WHERE days_until_due >= 0 AND days_until_due <= ?
2810 END_SQL
2811
2812     my @bind_parameters = ( $params->{'days_in_advance'} );
2813
2814     my $sth = $dbh->prepare( $statement );
2815     $sth->execute( @bind_parameters );
2816     my $upcoming_dues = $sth->fetchall_arrayref({});
2817
2818     return $upcoming_dues;
2819 }
2820
2821 =head2 CanBookBeRenewed
2822
2823   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2824
2825 Find out whether a borrowed item may be renewed.
2826
2827 C<$borrowernumber> is the borrower number of the patron who currently
2828 has the item on loan.
2829
2830 C<$itemnumber> is the number of the item to renew.
2831
2832 C<$override_limit>, if supplied with a true value, causes
2833 the limit on the number of times that the loan can be renewed
2834 (as controlled by the item type) to be ignored. Overriding also allows
2835 to renew sooner than "No renewal before" and to manually renew loans
2836 that are automatically renewed.
2837
2838 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2839 item must currently be on loan to the specified borrower; renewals
2840 must be allowed for the item's type; and the borrower must not have
2841 already renewed the loan. $error will contain the reason the renewal can not proceed
2842
2843 =cut
2844
2845 sub CanBookBeRenewed {
2846     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2847
2848     my $dbh    = C4::Context->dbh;
2849     my $renews = 1;
2850     my $auto_renew = 0;
2851
2852     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2853     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2854     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2855     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2856
2857     my $patron = $issue->patron or return;
2858
2859     # override_limit will override anything else except on_reserve
2860     unless ( $override_limit ){
2861         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2862         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2863             {
2864                 categorycode => $patron->categorycode,
2865                 itemtype     => $item->effective_itemtype,
2866                 branchcode   => $branchcode,
2867                 rules => [
2868                     'renewalsallowed',
2869                     'no_auto_renewal_after',
2870                     'no_auto_renewal_after_hard_limit',
2871                     'lengthunit',
2872                     'norenewalbefore',
2873                 ]
2874             }
2875         );
2876
2877         return ( 0, "too_many" )
2878           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2879
2880         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2881         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2882         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2883         my $restricted  = $patron->is_debarred;
2884         my $hasoverdues = $patron->has_overdues;
2885
2886         if ( $restricted and $restrictionblockrenewing ) {
2887             return ( 0, 'restriction');
2888         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2889             return ( 0, 'overdue');
2890         }
2891
2892         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2893
2894             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2895                 return ( 0, 'auto_account_expired' );
2896             }
2897
2898             if ( defined $issuing_rule->{no_auto_renewal_after}
2899                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2900                 # Get issue_date and add no_auto_renewal_after
2901                 # If this is greater than today, it's too late for renewal.
2902                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2903                 $maximum_renewal_date->add(
2904                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2905                 );
2906                 my $now = dt_from_string;
2907                 if ( $now >= $maximum_renewal_date ) {
2908                     return ( 0, "auto_too_late" );
2909                 }
2910             }
2911             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2912                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2913                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2914                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2915                     return ( 0, "auto_too_late" );
2916                 }
2917             }
2918
2919             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2920                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2921                 my $amountoutstanding =
2922                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2923                   ? $patron->account->balance
2924                   : $patron->account->outstanding_debits->total_outstanding;
2925                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2926                     return ( 0, "auto_too_much_oweing" );
2927                 }
2928             }
2929         }
2930
2931         if ( defined $issuing_rule->{norenewalbefore}
2932             and $issuing_rule->{norenewalbefore} ne "" )
2933         {
2934
2935             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2936             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2937                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2938
2939             # Depending on syspref reset the exact time, only check the date
2940             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2941                 and $issuing_rule->{lengthunit} eq 'days' )
2942             {
2943                 $soonestrenewal->truncate( to => 'day' );
2944             }
2945
2946             if ( $soonestrenewal > dt_from_string() )
2947             {
2948                 return ( 0, "auto_too_soon" ) if $issue->auto_renew && $patron->autorenew_checkouts;
2949                 return ( 0, "too_soon" );
2950             }
2951             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2952                 $auto_renew = 1;
2953             }
2954         }
2955
2956         # Fallback for automatic renewals:
2957         # If norenewalbefore is undef, don't renew before due date.
2958         if ( $issue->auto_renew && !$auto_renew && $patron->autorenew_checkouts ) {
2959             my $now = dt_from_string;
2960             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2961                 $auto_renew = 1;
2962             } else {
2963                 return ( 0, "auto_too_soon" );
2964             }
2965         }
2966     }
2967
2968     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2969
2970     # This item can fill one or more unfilled reserve, can those unfilled reserves
2971     # all be filled by other available items?
2972     if ( $resfound
2973         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2974     {
2975         my $schema = Koha::Database->new()->schema();
2976
2977         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2978         if ($item_holds) {
2979             # There is an item level hold on this item, no other item can fill the hold
2980             $resfound = 1;
2981         }
2982         else {
2983
2984             # Get all other items that could possibly fill reserves
2985             my @itemnumbers = $schema->resultset('Item')->search(
2986                 {
2987                     biblionumber => $resrec->{biblionumber},
2988                     onloan       => undef,
2989                     notforloan   => 0,
2990                     -not         => { itemnumber => $itemnumber }
2991                 },
2992                 { columns => 'itemnumber' }
2993             )->get_column('itemnumber')->all();
2994
2995             # Get all other reserves that could have been filled by this item
2996             my @borrowernumbers;
2997             while (1) {
2998                 my ( $reserve_found, $reserve, undef ) =
2999                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
3000
3001                 if ($reserve_found) {
3002                     push( @borrowernumbers, $reserve->{borrowernumber} );
3003                 }
3004                 else {
3005                     last;
3006                 }
3007             }
3008
3009             # If the count of the union of the lists of reservable items for each borrower
3010             # is equal or greater than the number of borrowers, we know that all reserves
3011             # can be filled with available items. We can get the union of the sets simply
3012             # by pushing all the elements onto an array and removing the duplicates.
3013             my @reservable;
3014             my %patrons;
3015             ITEM: foreach my $itemnumber (@itemnumbers) {
3016                 my $item = Koha::Items->find( $itemnumber );
3017                 next if IsItemOnHoldAndFound( $itemnumber );
3018                 for my $borrowernumber (@borrowernumbers) {
3019                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
3020                     next unless IsAvailableForItemLevelRequest($item, $patron);
3021                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
3022
3023                     push @reservable, $itemnumber;
3024                     if (@reservable >= @borrowernumbers) {
3025                         $resfound = 0;
3026                         last ITEM;
3027                     }
3028                     last;
3029                 }
3030             }
3031         }
3032     }
3033     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
3034     return ( 0, "auto_renew" ) if $auto_renew && !$override_limit; # 0 if auto-renewal should not succeed
3035
3036     return ( 1, undef );
3037 }
3038
3039 =head2 AddRenewal
3040
3041   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
3042
3043 Renews a loan.
3044
3045 C<$borrowernumber> is the borrower number of the patron who currently
3046 has the item.
3047
3048 C<$itemnumber> is the number of the item to renew.
3049
3050 C<$branch> is the library where the renewal took place (if any).
3051            The library that controls the circ policies for the renewal is retrieved from the issues record.
3052
3053 C<$datedue> can be a DateTime object used to set the due date.
3054
3055 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3056 this parameter is not supplied, lastreneweddate is set to the current date.
3057
3058 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3059 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3060 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3061 syspref)
3062
3063 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3064 from the book's item type.
3065
3066 =cut
3067
3068 sub AddRenewal {
3069     my $borrowernumber  = shift;
3070     my $itemnumber      = shift or return;
3071     my $branch          = shift;
3072     my $datedue         = shift;
3073     my $lastreneweddate = shift || dt_from_string();
3074     my $skipfinecalc    = shift;
3075
3076     my $item_object   = Koha::Items->find($itemnumber) or return;
3077     my $biblio = $item_object->biblio;
3078     my $issue  = $item_object->checkout;
3079     my $item_unblessed = $item_object->unblessed;
3080
3081     my $dbh = C4::Context->dbh;
3082
3083     return unless $issue;
3084
3085     $borrowernumber ||= $issue->borrowernumber;
3086
3087     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3088         carp 'Invalid date passed to AddRenewal.';
3089         return;
3090     }
3091
3092     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3093     my $patron_unblessed = $patron->unblessed;
3094
3095     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3096
3097     my $schema = Koha::Database->schema;
3098     $schema->txn_do(sub{
3099
3100         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3101             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3102         }
3103         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3104
3105         # If the due date wasn't specified, calculate it by adding the
3106         # book's loan length to today's date or the current due date
3107         # based on the value of the RenewalPeriodBase syspref.
3108         my $itemtype = $item_object->effective_itemtype;
3109         unless ($datedue) {
3110
3111             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3112                                             dt_from_string( $issue->date_due, 'sql' ) :
3113                                             dt_from_string();
3114             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3115         }
3116
3117         my $fees = Koha::Charges::Fees->new(
3118             {
3119                 patron    => $patron,
3120                 library   => $circ_library,
3121                 item      => $item_object,
3122                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3123                 to_date   => dt_from_string($datedue),
3124             }
3125         );
3126
3127         # Update the issues record to have the new due date, and a new count
3128         # of how many times it has been renewed.
3129         my $renews = ( $issue->renewals || 0 ) + 1;
3130         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
3131                                 WHERE borrowernumber=?
3132                                 AND itemnumber=?"
3133         );
3134
3135         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
3136
3137         # Update the renewal count on the item, and tell zebra to reindex
3138         $renews = ( $item_object->renewals || 0 ) + 1;
3139         $item_object->renewals($renews);
3140         $item_object->onloan($datedue);
3141         $item_object->store({ log_action => 0 });
3142
3143         # Charge a new rental fee, if applicable
3144         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3145         if ( $charge > 0 ) {
3146             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3147         }
3148
3149         # Charge a new accumulate rental fee, if applicable
3150         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3151         if ( $itemtype_object ) {
3152             my $accumulate_charge = $fees->accumulate_rentalcharge();
3153             if ( $accumulate_charge > 0 ) {
3154                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3155             }
3156             $charge += $accumulate_charge;
3157         }
3158
3159         # Send a renewal slip according to checkout alert preferencei
3160         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3161             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3162             my %conditions        = (
3163                 branchcode   => $branch,
3164                 categorycode => $patron->categorycode,
3165                 item_type    => $itemtype,
3166                 notification => 'CHECKOUT',
3167             );
3168             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3169                 SendCirculationAlert(
3170                     {
3171                         type     => 'RENEWAL',
3172                         item     => $item_unblessed,
3173                         borrower => $patron->unblessed,
3174                         branch   => $branch,
3175                     }
3176                 );
3177             }
3178         }
3179
3180         # Remove any OVERDUES related debarment if the borrower has no overdues
3181         if ( $patron
3182           && $patron->is_debarred
3183           && ! $patron->has_overdues
3184           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3185         ) {
3186             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3187         }
3188
3189         # Add the renewal to stats
3190         UpdateStats(
3191             {
3192                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3193                 type           => 'renew',
3194                 amount         => $charge,
3195                 itemnumber     => $itemnumber,
3196                 itemtype       => $itemtype,
3197                 location       => $item_object->location,
3198                 borrowernumber => $borrowernumber,
3199                 ccode          => $item_object->ccode,
3200             }
3201         );
3202
3203         #Log the renewal
3204         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3205
3206         Koha::Plugins->call('after_circ_action', {
3207             action  => 'renewal',
3208             payload => {
3209                 checkout  => $issue->get_from_storage
3210             }
3211         });
3212     });
3213
3214     return $datedue;
3215 }
3216
3217 sub GetRenewCount {
3218     # check renewal status
3219     my ( $bornum, $itemno ) = @_;
3220     my $dbh           = C4::Context->dbh;
3221     my $renewcount    = 0;
3222     my $renewsallowed = 0;
3223     my $renewsleft    = 0;
3224
3225     my $patron = Koha::Patrons->find( $bornum );
3226     my $item   = Koha::Items->find($itemno);
3227
3228     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3229
3230     # Look in the issues table for this item, lent to this borrower,
3231     # and not yet returned.
3232
3233     # FIXME - I think this function could be redone to use only one SQL call.
3234     my $sth = $dbh->prepare(
3235         "select * from issues
3236                                 where (borrowernumber = ?)
3237                                 and (itemnumber = ?)"
3238     );
3239     $sth->execute( $bornum, $itemno );
3240     my $data = $sth->fetchrow_hashref;
3241     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3242     # $item and $borrower should be calculated
3243     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3244
3245     my $rule = Koha::CirculationRules->get_effective_rule(
3246         {
3247             categorycode => $patron->categorycode,
3248             itemtype     => $item->effective_itemtype,
3249             branchcode   => $branchcode,
3250             rule_name    => 'renewalsallowed',
3251         }
3252     );
3253
3254     $renewsallowed = $rule ? $rule->rule_value : 0;
3255     $renewsleft    = $renewsallowed - $renewcount;
3256     if($renewsleft < 0){ $renewsleft = 0; }
3257     return ( $renewcount, $renewsallowed, $renewsleft );
3258 }
3259
3260 =head2 GetSoonestRenewDate
3261
3262   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3263
3264 Find out the soonest possible renew date of a borrowed item.
3265
3266 C<$borrowernumber> is the borrower number of the patron who currently
3267 has the item on loan.
3268
3269 C<$itemnumber> is the number of the item to renew.
3270
3271 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3272 renew date, based on the value "No renewal before" of the applicable
3273 issuing rule. Returns the current date if the item can already be
3274 renewed, and returns undefined if the borrower, loan, or item
3275 cannot be found.
3276
3277 =cut
3278
3279 sub GetSoonestRenewDate {
3280     my ( $borrowernumber, $itemnumber ) = @_;
3281
3282     my $dbh = C4::Context->dbh;
3283
3284     my $item      = Koha::Items->find($itemnumber)      or return;
3285     my $itemissue = $item->checkout or return;
3286
3287     $borrowernumber ||= $itemissue->borrowernumber;
3288     my $patron = Koha::Patrons->find( $borrowernumber )
3289       or return;
3290
3291     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3292     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3293         {   categorycode => $patron->categorycode,
3294             itemtype     => $item->effective_itemtype,
3295             branchcode   => $branchcode,
3296             rules => [
3297                 'norenewalbefore',
3298                 'lengthunit',
3299             ]
3300         }
3301     );
3302
3303     my $now = dt_from_string;
3304     return $now unless $issuing_rule;
3305
3306     if ( defined $issuing_rule->{norenewalbefore}
3307         and $issuing_rule->{norenewalbefore} ne "" )
3308     {
3309         my $soonestrenewal =
3310           dt_from_string( $itemissue->date_due )->subtract(
3311             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3312
3313         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3314             and $issuing_rule->{lengthunit} eq 'days' )
3315         {
3316             $soonestrenewal->truncate( to => 'day' );
3317         }
3318         return $soonestrenewal if $now < $soonestrenewal;
3319     }
3320     return $now;
3321 }
3322
3323 =head2 GetLatestAutoRenewDate
3324
3325   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3326
3327 Find out the latest possible auto renew date of a borrowed item.
3328
3329 C<$borrowernumber> is the borrower number of the patron who currently
3330 has the item on loan.
3331
3332 C<$itemnumber> is the number of the item to renew.
3333
3334 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3335 auto renew date, based on the value "No auto renewal after" and the "No auto
3336 renewal after (hard limit) of the applicable issuing rule.
3337 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3338 or item cannot be found.
3339
3340 =cut
3341
3342 sub GetLatestAutoRenewDate {
3343     my ( $borrowernumber, $itemnumber ) = @_;
3344
3345     my $dbh = C4::Context->dbh;
3346
3347     my $item      = Koha::Items->find($itemnumber)  or return;
3348     my $itemissue = $item->checkout                 or return;
3349
3350     $borrowernumber ||= $itemissue->borrowernumber;
3351     my $patron = Koha::Patrons->find( $borrowernumber )
3352       or return;
3353
3354     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3355     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3356         {
3357             categorycode => $patron->categorycode,
3358             itemtype     => $item->effective_itemtype,
3359             branchcode   => $branchcode,
3360             rules => [
3361                 'no_auto_renewal_after',
3362                 'no_auto_renewal_after_hard_limit',
3363                 'lengthunit',
3364             ]
3365         }
3366     );
3367
3368     return unless $circulation_rules;
3369     return
3370       if ( not $circulation_rules->{no_auto_renewal_after}
3371             or $circulation_rules->{no_auto_renewal_after} eq '' )
3372       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3373              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3374
3375     my $maximum_renewal_date;
3376     if ( $circulation_rules->{no_auto_renewal_after} ) {
3377         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3378         $maximum_renewal_date->add(
3379             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3380         );
3381     }
3382
3383     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3384         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3385         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3386     }
3387     return $maximum_renewal_date;
3388 }
3389
3390
3391 =head2 GetIssuingCharges
3392
3393   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3394
3395 Calculate how much it would cost for a given patron to borrow a given
3396 item, including any applicable discounts.
3397
3398 C<$itemnumber> is the item number of item the patron wishes to borrow.
3399
3400 C<$borrowernumber> is the patron's borrower number.
3401
3402 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3403 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3404 if it's a video).
3405
3406 =cut
3407
3408 sub GetIssuingCharges {
3409
3410     # calculate charges due
3411     my ( $itemnumber, $borrowernumber ) = @_;
3412     my $charge = 0;
3413     my $dbh    = C4::Context->dbh;
3414     my $item_type;
3415
3416     # Get the book's item type and rental charge (via its biblioitem).
3417     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3418         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3419     $charge_query .= (C4::Context->preference('item-level_itypes'))
3420         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3421         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3422
3423     $charge_query .= ' WHERE items.itemnumber =?';
3424
3425     my $sth = $dbh->prepare($charge_query);
3426     $sth->execute($itemnumber);
3427     if ( my $item_data = $sth->fetchrow_hashref ) {
3428         $item_type = $item_data->{itemtype};
3429         $charge    = $item_data->{rentalcharge};
3430         my $branch = C4::Context::mybranch();
3431         my $patron = Koha::Patrons->find( $borrowernumber );
3432         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3433         if ($discount) {
3434             # We may have multiple rules so get the most specific
3435             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3436         }
3437         if ($charge) {
3438             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3439         }
3440     }
3441
3442     return ( $charge, $item_type );
3443 }
3444
3445 # Select most appropriate discount rule from those returned
3446 sub _get_discount_from_rule {
3447     my ($categorycode, $branchcode, $itemtype) = @_;
3448
3449     # Set search precedences
3450     my @params = (
3451         {
3452             branchcode   => $branchcode,
3453             itemtype     => $itemtype,
3454             categorycode => $categorycode,
3455         },
3456         {
3457             branchcode   => undef,
3458             categorycode => $categorycode,
3459             itemtype     => $itemtype,
3460         },
3461         {
3462             branchcode   => $branchcode,
3463             categorycode => $categorycode,
3464             itemtype     => undef,
3465         },
3466         {
3467             branchcode   => undef,
3468             categorycode => $categorycode,
3469             itemtype     => undef,
3470         },
3471     );
3472
3473     foreach my $params (@params) {
3474         my $rule = Koha::CirculationRules->search(
3475             {
3476                 rule_name => 'rentaldiscount',
3477                 %$params,
3478             }
3479         )->next();
3480
3481         return $rule->rule_value if $rule;
3482     }
3483
3484     # none of the above
3485     return 0;
3486 }
3487
3488 =head2 AddIssuingCharge
3489
3490   &AddIssuingCharge( $checkout, $charge, $type )
3491
3492 =cut
3493
3494 sub AddIssuingCharge {
3495     my ( $checkout, $charge, $type ) = @_;
3496
3497     # FIXME What if checkout does not exist?
3498
3499     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3500     my $accountline = $account->add_debit(
3501         {
3502             amount      => $charge,
3503             note        => undef,
3504             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3505             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3506             interface   => C4::Context->interface,
3507             type        => $type,
3508             item_id     => $checkout->itemnumber,
3509             issue_id    => $checkout->issue_id,
3510         }
3511     );
3512 }
3513
3514 =head2 GetTransfers
3515
3516   GetTransfers($itemnumber);
3517
3518 =cut
3519
3520 sub GetTransfers {
3521     my ($itemnumber) = @_;
3522
3523     my $dbh = C4::Context->dbh;
3524
3525     my $query = '
3526         SELECT datesent,
3527                frombranch,
3528                tobranch,
3529                branchtransfer_id
3530         FROM branchtransfers
3531         WHERE itemnumber = ?
3532           AND datearrived IS NULL
3533         ';
3534     my $sth = $dbh->prepare($query);
3535     $sth->execute($itemnumber);
3536     my @row = $sth->fetchrow_array();
3537     return @row;
3538 }
3539
3540 =head2 GetTransfersFromTo
3541
3542   @results = GetTransfersFromTo($frombranch,$tobranch);
3543
3544 Returns the list of pending transfers between $from and $to branch
3545
3546 =cut
3547
3548 sub GetTransfersFromTo {
3549     my ( $frombranch, $tobranch ) = @_;
3550     return unless ( $frombranch && $tobranch );
3551     my $dbh   = C4::Context->dbh;
3552     my $query = "
3553         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3554         FROM   branchtransfers
3555         WHERE  frombranch=?
3556           AND  tobranch=?
3557           AND datearrived IS NULL
3558     ";
3559     my $sth = $dbh->prepare($query);
3560     $sth->execute( $frombranch, $tobranch );
3561     my @gettransfers;
3562
3563     while ( my $data = $sth->fetchrow_hashref ) {
3564         push @gettransfers, $data;
3565     }
3566     return (@gettransfers);
3567 }
3568
3569 =head2 DeleteTransfer
3570
3571   &DeleteTransfer($itemnumber);
3572
3573 =cut
3574
3575 sub DeleteTransfer {
3576     my ($itemnumber) = @_;
3577     return unless $itemnumber;
3578     my $dbh          = C4::Context->dbh;
3579     my $sth          = $dbh->prepare(
3580         "DELETE FROM branchtransfers
3581          WHERE itemnumber=?
3582          AND datearrived IS NULL "
3583     );
3584     return $sth->execute($itemnumber);
3585 }
3586
3587 =head2 SendCirculationAlert
3588
3589 Send out a C<check-in> or C<checkout> alert using the messaging system.
3590
3591 B<Parameters>:
3592
3593 =over 4
3594
3595 =item type
3596
3597 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3598
3599 =item item
3600
3601 Hashref of information about the item being checked in or out.
3602
3603 =item borrower
3604
3605 Hashref of information about the borrower of the item.
3606
3607 =item branch
3608
3609 The branchcode from where the checkout or check-in took place.
3610
3611 =back
3612
3613 B<Example>:
3614
3615     SendCirculationAlert({
3616         type     => 'CHECKOUT',
3617         item     => $item,
3618         borrower => $borrower,
3619         branch   => $branch,
3620     });
3621
3622 =cut
3623
3624 sub SendCirculationAlert {
3625     my ($opts) = @_;
3626     my ($type, $item, $borrower, $branch) =
3627         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3628     my %message_name = (
3629         CHECKIN  => 'Item_Check_in',
3630         CHECKOUT => 'Item_Checkout',
3631         RENEWAL  => 'Item_Checkout',
3632     );
3633     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3634         borrowernumber => $borrower->{borrowernumber},
3635         message_name   => $message_name{$type},
3636     });
3637     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3638
3639     my $schema = Koha::Database->new->schema;
3640     my @transports = keys %{ $borrower_preferences->{transports} };
3641
3642     # From the MySQL doc:
3643     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3644     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3645     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3646     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3647
3648     for my $mtt (@transports) {
3649         my $letter =  C4::Letters::GetPreparedLetter (
3650             module => 'circulation',
3651             letter_code => $type,
3652             branchcode => $branch,
3653             message_transport_type => $mtt,
3654             lang => $borrower->{lang},
3655             tables => {
3656                 $issues_table => $item->{itemnumber},
3657                 'items'       => $item->{itemnumber},
3658                 'biblio'      => $item->{biblionumber},
3659                 'biblioitems' => $item->{biblionumber},
3660                 'borrowers'   => $borrower,
3661                 'branches'    => $branch,
3662             }
3663         ) or next;
3664
3665         $schema->storage->txn_begin;
3666         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3667         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3668         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3669         unless ( $message ) {
3670             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3671             C4::Message->enqueue($letter, $borrower, $mtt);
3672         } else {
3673             $message->append($letter);
3674             $message->update;
3675         }
3676         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3677         $schema->storage->txn_commit;
3678     }
3679
3680     return;
3681 }
3682
3683 =head2 updateWrongTransfer
3684
3685   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3686
3687 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3688
3689 =cut
3690
3691 sub updateWrongTransfer {
3692         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3693         my $dbh = C4::Context->dbh;
3694 # first step validate the actual line of transfert .
3695         my $sth =
3696                 $dbh->prepare(
3697                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3698                 );
3699                 $sth->execute($FromLibrary,$itemNumber);
3700
3701 # second step create a new line of branchtransfer to the right location .
3702         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3703
3704 #third step changing holdingbranch of item
3705     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3706 }
3707
3708 =head2 CalcDateDue
3709
3710 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3711
3712 this function calculates the due date given the start date and configured circulation rules,
3713 checking against the holidays calendar as per the daysmode circulation rule.
3714 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3715 C<$itemtype>  = itemtype code of item in question
3716 C<$branch>  = location whose calendar to use
3717 C<$borrower> = Borrower object
3718 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3719
3720 =cut
3721
3722 sub CalcDateDue {
3723     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3724
3725     $isrenewal ||= 0;
3726
3727     # loanlength now a href
3728     my $loanlength =
3729             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3730
3731     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3732             ? qq{renewalperiod}
3733             : qq{issuelength};
3734
3735     my $datedue;
3736     if ( $startdate ) {
3737         if (ref $startdate ne 'DateTime' ) {
3738             $datedue = dt_from_string($datedue);
3739         } else {
3740             $datedue = $startdate->clone;
3741         }
3742     } else {
3743         $datedue = dt_from_string()->truncate( to => 'minute' );
3744     }
3745
3746
3747     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3748         {
3749             categorycode => $borrower->{categorycode},
3750             itemtype     => $itemtype,
3751             branchcode   => $branch,
3752         }
3753     );
3754
3755     # calculate the datedue as normal
3756     if ( $daysmode eq 'Days' )
3757     {    # ignoring calendar
3758         if ( $loanlength->{lengthunit} eq 'hours' ) {
3759             $datedue->add( hours => $loanlength->{$length_key} );
3760         } else {    # days
3761             $datedue->add( days => $loanlength->{$length_key} );
3762             $datedue->set_hour(23);
3763             $datedue->set_minute(59);
3764         }
3765     } else {
3766         my $dur;
3767         if ($loanlength->{lengthunit} eq 'hours') {
3768             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3769         }
3770         else { # days
3771             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3772         }
3773         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3774         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3775         if ($loanlength->{lengthunit} eq 'days') {
3776             $datedue->set_hour(23);
3777             $datedue->set_minute(59);
3778         }
3779     }
3780
3781     # if Hard Due Dates are used, retrieve them and apply as necessary
3782     my ( $hardduedate, $hardduedatecompare ) =
3783       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3784     if ($hardduedate) {    # hardduedates are currently dates
3785         $hardduedate->truncate( to => 'minute' );
3786         $hardduedate->set_hour(23);
3787         $hardduedate->set_minute(59);
3788         my $cmp = DateTime->compare( $hardduedate, $datedue );
3789
3790 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3791 # if the calculated date is before the 'after' Hard Due Date (floor), override
3792 # if the hard due date is set to 'exactly', overrride
3793         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3794             $datedue = $hardduedate->clone;
3795         }
3796
3797         # in all other cases, keep the date due as it is
3798
3799     }
3800
3801     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3802     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3803         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3804         if( $expiry_dt ) { #skip empty expiry date..
3805             $expiry_dt->set( hour => 23, minute => 59);
3806             my $d1= $datedue->clone->set_time_zone('floating');
3807             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3808                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3809             }
3810         }
3811         if ( $daysmode ne 'Days' ) {
3812           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3813           if ( $calendar->is_holiday($datedue) ) {
3814               # Don't return on a closed day
3815               $datedue = $calendar->prev_open_days( $datedue, 1 );
3816           }
3817         }
3818     }
3819
3820     return $datedue;
3821 }
3822
3823
3824 sub CheckValidBarcode{
3825 my ($barcode) = @_;
3826 my $dbh = C4::Context->dbh;
3827 my $query=qq|SELECT count(*)
3828              FROM items
3829              WHERE barcode=?
3830             |;
3831 my $sth = $dbh->prepare($query);
3832 $sth->execute($barcode);
3833 my $exist=$sth->fetchrow ;
3834 return $exist;
3835 }
3836
3837 =head2 IsBranchTransferAllowed
3838
3839   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3840
3841 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3842
3843 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3844 Koha::Item->can_be_transferred.
3845
3846 =cut
3847
3848 sub IsBranchTransferAllowed {
3849         my ( $toBranch, $fromBranch, $code ) = @_;
3850
3851         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3852
3853         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3854         my $dbh = C4::Context->dbh;
3855
3856         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3857         $sth->execute( $toBranch, $fromBranch, $code );
3858         my $limit = $sth->fetchrow_hashref();
3859
3860         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3861         if ( $limit->{'limitId'} ) {
3862                 return 0;
3863         } else {
3864                 return 1;
3865         }
3866 }
3867
3868 =head2 CreateBranchTransferLimit
3869
3870   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3871
3872 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3873
3874 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3875
3876 =cut
3877
3878 sub CreateBranchTransferLimit {
3879    my ( $toBranch, $fromBranch, $code ) = @_;
3880    return unless defined($toBranch) && defined($fromBranch);
3881    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3882
3883    my $dbh = C4::Context->dbh;
3884
3885    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3886    return $sth->execute( $code, $toBranch, $fromBranch );
3887 }
3888
3889 =head2 DeleteBranchTransferLimits
3890
3891     my $result = DeleteBranchTransferLimits($frombranch);
3892
3893 Deletes all the library transfer limits for one library.  Returns the
3894 number of limits deleted, 0e0 if no limits were deleted, or undef if
3895 no arguments are supplied.
3896
3897 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3898     fromBranch => $fromBranch
3899     })->delete.
3900
3901 =cut
3902
3903 sub DeleteBranchTransferLimits {
3904     my $branch = shift;
3905     return unless defined $branch;
3906     my $dbh    = C4::Context->dbh;
3907     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3908     return $sth->execute($branch);
3909 }
3910
3911 sub ReturnLostItem{
3912     my ( $borrowernumber, $itemnum ) = @_;
3913     MarkIssueReturned( $borrowernumber, $itemnum );
3914 }
3915
3916
3917 sub LostItem{
3918     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3919
3920     unless ( $mark_lost_from ) {
3921         # Temporary check to avoid regressions
3922         die q|LostItem called without $mark_lost_from, check the API.|;
3923     }
3924
3925     my $mark_returned;
3926     if ( $force_mark_returned ) {
3927         $mark_returned = 1;
3928     } else {
3929         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3930         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3931     }
3932
3933     my $dbh = C4::Context->dbh();
3934     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3935                            FROM issues
3936                            JOIN items USING (itemnumber)
3937                            JOIN biblio USING (biblionumber)
3938                            WHERE issues.itemnumber=?");
3939     $sth->execute($itemnumber);
3940     my $issues=$sth->fetchrow_hashref();
3941
3942     # If a borrower lost the item, add a replacement cost to the their record
3943     if ( my $borrowernumber = $issues->{borrowernumber} ){
3944         my $patron = Koha::Patrons->find( $borrowernumber );
3945
3946         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3947         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3948
3949         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3950             C4::Accounts::chargelostitem(
3951                 $borrowernumber,
3952                 $itemnumber,
3953                 $issues->{'replacementprice'},
3954                 sprintf( "%s %s %s",
3955                     $issues->{'title'}          || q{},
3956                     $issues->{'barcode'}        || q{},
3957                     $issues->{'itemcallnumber'} || q{},
3958                 ),
3959             );
3960             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3961             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3962         }
3963
3964         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3965     }
3966
3967     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3968     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3969         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store;
3970     }
3971     my $transferdeleted = DeleteTransfer($itemnumber);
3972 }
3973
3974 sub GetOfflineOperations {
3975     my $dbh = C4::Context->dbh;
3976     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3977     $sth->execute(C4::Context->userenv->{'branch'});
3978     my $results = $sth->fetchall_arrayref({});
3979     return $results;
3980 }
3981
3982 sub GetOfflineOperation {
3983     my $operationid = shift;
3984     return unless $operationid;
3985     my $dbh = C4::Context->dbh;
3986     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3987     $sth->execute( $operationid );
3988     return $sth->fetchrow_hashref;
3989 }
3990
3991 sub AddOfflineOperation {
3992     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3993     my $dbh = C4::Context->dbh;
3994     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3995     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3996     return "Added.";
3997 }
3998
3999 sub DeleteOfflineOperation {
4000     my $dbh = C4::Context->dbh;
4001     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4002     $sth->execute( shift );
4003     return "Deleted.";
4004 }
4005
4006 sub ProcessOfflineOperation {
4007     my $operation = shift;
4008
4009     my $report;
4010     if ( $operation->{action} eq 'return' ) {
4011         $report = ProcessOfflineReturn( $operation );
4012     } elsif ( $operation->{action} eq 'issue' ) {
4013         $report = ProcessOfflineIssue( $operation );
4014     } elsif ( $operation->{action} eq 'payment' ) {
4015         $report = ProcessOfflinePayment( $operation );
4016     }
4017
4018     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4019
4020     return $report;
4021 }
4022
4023 sub ProcessOfflineReturn {
4024     my $operation = shift;
4025
4026     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4027
4028     if ( $item ) {
4029         my $itemnumber = $item->itemnumber;
4030         my $issue = GetOpenIssue( $itemnumber );
4031         if ( $issue ) {
4032             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4033             ModDateLastSeen( $itemnumber, $leave_item_lost );
4034             MarkIssueReturned(
4035                 $issue->{borrowernumber},
4036                 $itemnumber,
4037                 $operation->{timestamp},
4038             );
4039             $item->renewals(0);
4040             $item->onloan(undef);
4041             $item->store({ log_action => 0 });
4042             return "Success.";
4043         } else {
4044             return "Item not issued.";
4045         }
4046     } else {
4047         return "Item not found.";
4048     }
4049 }
4050
4051 sub ProcessOfflineIssue {
4052     my $operation = shift;
4053
4054     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4055
4056     if ( $patron ) {
4057         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4058         unless ($item) {
4059             return "Barcode not found.";
4060         }
4061         my $itemnumber = $item->itemnumber;
4062         my $issue = GetOpenIssue( $itemnumber );
4063
4064         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4065             MarkIssueReturned(
4066                 $issue->{borrowernumber},
4067                 $itemnumber,
4068                 $operation->{timestamp},
4069             );
4070         }
4071         AddIssue(
4072             $patron->unblessed,
4073             $operation->{'barcode'},
4074             undef,
4075             1,
4076             $operation->{timestamp},
4077             undef,
4078         );
4079         return "Success.";
4080     } else {
4081         return "Borrower not found.";
4082     }
4083 }
4084
4085 sub ProcessOfflinePayment {
4086     my $operation = shift;
4087
4088     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4089
4090     $patron->account->pay(
4091         {
4092             amount     => $operation->{amount},
4093             library_id => $operation->{branchcode},
4094             interface  => 'koc'
4095         }
4096     );
4097
4098     return "Success.";
4099 }
4100
4101 =head2 TransferSlip
4102
4103   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4104
4105   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4106
4107 =cut
4108
4109 sub TransferSlip {
4110     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4111
4112     my $item =
4113       $itemnumber
4114       ? Koha::Items->find($itemnumber)
4115       : Koha::Items->find( { barcode => $barcode } );
4116
4117     $item or return;
4118
4119     return C4::Letters::GetPreparedLetter (
4120         module => 'circulation',
4121         letter_code => 'TRANSFERSLIP',
4122         branchcode => $branch,
4123         tables => {
4124             'branches'    => $to_branch,
4125             'biblio'      => $item->biblionumber,
4126             'items'       => $item->unblessed,
4127         },
4128     );
4129 }
4130
4131 =head2 CheckIfIssuedToPatron
4132
4133   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4134
4135   Return 1 if any record item is issued to patron, otherwise return 0
4136
4137 =cut
4138
4139 sub CheckIfIssuedToPatron {
4140     my ($borrowernumber, $biblionumber) = @_;
4141
4142     my $dbh = C4::Context->dbh;
4143     my $query = q|
4144         SELECT COUNT(*) FROM issues
4145         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4146         WHERE items.biblionumber = ?
4147         AND issues.borrowernumber = ?
4148     |;
4149     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4150     return 1 if $is_issued;
4151     return;
4152 }
4153
4154 =head2 IsItemIssued
4155
4156   IsItemIssued( $itemnumber )
4157
4158   Return 1 if the item is on loan, otherwise return 0
4159
4160 =cut
4161
4162 sub IsItemIssued {
4163     my $itemnumber = shift;
4164     my $dbh = C4::Context->dbh;
4165     my $sth = $dbh->prepare(q{
4166         SELECT COUNT(*)
4167         FROM issues
4168         WHERE itemnumber = ?
4169     });
4170     $sth->execute($itemnumber);
4171     return $sth->fetchrow;
4172 }
4173
4174 =head2 GetAgeRestriction
4175
4176   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4177   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4178
4179   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4180   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4181
4182 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4183 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4184 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4185          Negative days mean the borrower has gone past the age restriction age.
4186
4187 =cut
4188
4189 sub GetAgeRestriction {
4190     my ($record_restrictions, $borrower) = @_;
4191     my $markers = C4::Context->preference('AgeRestrictionMarker');
4192
4193     return unless $record_restrictions;
4194     # Split $record_restrictions to something like FSK 16 or PEGI 6
4195     my @values = split ' ', uc($record_restrictions);
4196     return unless @values;
4197
4198     # Search first occurrence of one of the markers
4199     my @markers = split /\|/, uc($markers);
4200     return unless @markers;
4201
4202     my $index            = 0;
4203     my $restriction_year = 0;
4204     for my $value (@values) {
4205         $index++;
4206         for my $marker (@markers) {
4207             $marker =~ s/^\s+//;    #remove leading spaces
4208             $marker =~ s/\s+$//;    #remove trailing spaces
4209             if ( $marker eq $value ) {
4210                 if ( $index <= $#values ) {
4211                     $restriction_year += $values[$index];
4212                 }
4213                 last;
4214             }
4215             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4216
4217                 # Perhaps it is something like "K16" (as in Finland)
4218                 $restriction_year += $1;
4219                 last;
4220             }
4221         }
4222         last if ( $restriction_year > 0 );
4223     }
4224
4225     #Check if the borrower is age restricted for this material and for how long.
4226     if ($restriction_year && $borrower) {
4227         if ( $borrower->{'dateofbirth'} ) {
4228             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4229             $alloweddate[0] += $restriction_year;
4230
4231             #Prevent runime eror on leap year (invalid date)
4232             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4233                 $alloweddate[2] = 28;
4234             }
4235
4236             #Get how many days the borrower has to reach the age restriction
4237             my @Today = split /-/, dt_from_string()->ymd();
4238             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4239             #Negative days means the borrower went past the age restriction age
4240             return ($restriction_year, $daysToAgeRestriction);
4241         }
4242     }
4243
4244     return ($restriction_year);
4245 }
4246
4247
4248 =head2 GetPendingOnSiteCheckouts
4249
4250 =cut
4251
4252 sub GetPendingOnSiteCheckouts {
4253     my $dbh = C4::Context->dbh;
4254     return $dbh->selectall_arrayref(q|
4255         SELECT
4256           items.barcode,
4257           items.biblionumber,
4258           items.itemnumber,
4259           items.itemnotes,
4260           items.itemcallnumber,
4261           items.location,
4262           issues.date_due,
4263           issues.branchcode,
4264           issues.date_due < NOW() AS is_overdue,
4265           biblio.author,
4266           biblio.title,
4267           borrowers.firstname,
4268           borrowers.surname,
4269           borrowers.cardnumber,
4270           borrowers.borrowernumber
4271         FROM items
4272         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4273         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4274         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4275         WHERE issues.onsite_checkout = 1
4276     |, { Slice => {} } );
4277 }
4278
4279 sub GetTopIssues {
4280     my ($params) = @_;
4281
4282     my ($count, $branch, $itemtype, $ccode, $newness)
4283         = @$params{qw(count branch itemtype ccode newness)};
4284
4285     my $dbh = C4::Context->dbh;
4286     my $query = q{
4287         SELECT * FROM (
4288         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4289           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4290           i.ccode, SUM(i.issues) AS count
4291         FROM biblio b
4292         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4293         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4294     };
4295
4296     my (@where_strs, @where_args);
4297
4298     if ($branch) {
4299         push @where_strs, 'i.homebranch = ?';
4300         push @where_args, $branch;
4301     }
4302     if ($itemtype) {
4303         if (C4::Context->preference('item-level_itypes')){
4304             push @where_strs, 'i.itype = ?';
4305             push @where_args, $itemtype;
4306         } else {
4307             push @where_strs, 'bi.itemtype = ?';
4308             push @where_args, $itemtype;
4309         }
4310     }
4311     if ($ccode) {
4312         push @where_strs, 'i.ccode = ?';
4313         push @where_args, $ccode;
4314     }
4315     if ($newness) {
4316         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4317         push @where_args, $newness;
4318     }
4319
4320     if (@where_strs) {
4321         $query .= 'WHERE ' . join(' AND ', @where_strs);
4322     }
4323
4324     $query .= q{
4325         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4326           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4327           i.ccode
4328         ORDER BY count DESC
4329     };
4330
4331     $query .= q{ ) xxx WHERE count > 0 };
4332     $count = int($count);
4333     if ($count > 0) {
4334         $query .= "LIMIT $count";
4335     }
4336
4337     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4338
4339     return @$rows;
4340 }
4341
4342 =head2 Internal methods
4343
4344 =cut
4345
4346 sub _CalculateAndUpdateFine {
4347     my ($params) = @_;
4348
4349     my $borrower    = $params->{borrower};
4350     my $item        = $params->{item};
4351     my $issue       = $params->{issue};
4352     my $return_date = $params->{return_date};
4353
4354     unless ($borrower) { carp "No borrower passed in!" && return; }
4355     unless ($item)     { carp "No item passed in!"     && return; }
4356     unless ($issue)    { carp "No issue passed in!"    && return; }
4357
4358     my $datedue = dt_from_string( $issue->date_due );
4359
4360     # we only need to calculate and change the fines if we want to do that on return
4361     # Should be on for hourly loans
4362     my $control = C4::Context->preference('CircControl');
4363     my $control_branchcode =
4364         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4365       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4366       :                                     $issue->branchcode;
4367
4368     my $date_returned = $return_date ? $return_date : dt_from_string();
4369
4370     my ( $amount, $unitcounttotal, $unitcount  ) =
4371       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4372
4373     if ( C4::Context->preference('finesMode') eq 'production' ) {
4374         if ( $amount > 0 ) {
4375             C4::Overdues::UpdateFine({
4376                 issue_id       => $issue->issue_id,
4377                 itemnumber     => $issue->itemnumber,
4378                 borrowernumber => $issue->borrowernumber,
4379                 amount         => $amount,
4380                 due            => output_pref($datedue),
4381             });
4382         }
4383         elsif ($return_date) {
4384
4385             # Backdated returns may have fines that shouldn't exist,
4386             # so in this case, we need to drop those fines to 0
4387
4388             C4::Overdues::UpdateFine({
4389                 issue_id       => $issue->issue_id,
4390                 itemnumber     => $issue->itemnumber,
4391                 borrowernumber => $issue->borrowernumber,
4392                 amount         => 0,
4393                 due            => output_pref($datedue),
4394             });
4395         }
4396     }
4397 }
4398
4399 sub _item_denied_renewal {
4400     my ($params) = @_;
4401
4402     my $item = $params->{item};
4403     return unless $item;
4404
4405     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4406     return unless $denyingrules;
4407     foreach my $field (keys %$denyingrules) {
4408         my $val = $item->$field;
4409         if( !defined $val) {
4410             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4411                 return 1;
4412             }
4413         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4414            # If the results matches the values in the syspref
4415            # We return true if match found
4416             return 1;
4417         }
4418     }
4419     return 0;
4420 }
4421
4422 1;
4423
4424 __END__
4425
4426 =head1 AUTHOR
4427
4428 Koha Development Team <http://koha-community.org/>
4429
4430 =cut