C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp;
  22
  23 use C4::Debug;
  24 use C4::Context;
  25 use C4::Members::Attributes;
  26 use C4::Members::Messaging;
  27 use C4::Auth qw(checkpw_internal);
  28 use Koha::Patrons;
  29 use Koha::AuthUtils qw(hash_password);
  30 use List::MoreUtils qw( any );
  31 use Net::LDAP;
  32 use Net::LDAP::Filter;
  33
  34 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  35
  36 BEGIN {
  37         require Exporter;
  38         @ISA    = qw(Exporter);
  39         @EXPORT = qw( checkpw_ldap );
  40 }
  41
  42 # Redefine checkpw_ldap:
  43 # connect to LDAP (named or anonymous)
  44 # ~ retrieves $userid from KOHA_CONF mapping
  45 # ~ then compares $password with userPassword
  46 # ~ then gets the LDAP entry
  47 # ~ and calls the memberadd if necessary
  48
  49 sub ldapserver_error {
  50         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  51 }
  52
  53 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  54 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  55 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  56 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  57 my $base      = $ldap->{base}           or die ldapserver_error('base');
  58 $ldapname     = $ldap->{user}           ;
  59 $ldappassword = $ldap->{pass}           ;
  60 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  61 my @mapkeys = keys %mapping;
  62 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  63 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  65
  66 my %categorycode_conversions;
  67 my $default_categorycode;
  68 if(defined $ldap->{categorycode_mapping}) {
  69     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  70     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  71         $categorycode_conversions{$cat->{value}} = $cat->{content};
  72     }
  73 }
  74
  75 my %config = (
  76     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  77     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  78        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  79 );
  80
  81 sub description {
  82         my $result = shift or return;
  83         return "LDAP error #" . $result->code
  84                         . ": " . $result->error_name . "\n"
  85                         . "# " . $result->error_text . "\n";
  86 }
  87
  88 sub search_method {
  89     my $db     = shift or return;
  90     my $userid = shift or return;
  91         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  92         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  93         my $search = $db->search(
  94                   base => $base,
  95                 filter => $filter,
  96                 # attrs => ['*'],
  97     );
  98     die "LDAP search failed to return object : " . $search->error if $search->code;
  99
 100         my $count = $search->count;
 101         if ($search->code > 0) {
 102                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 103                 return 0;
 104         }
 105     if ($count == 0) {
 106         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 107         return 0;
 108     }
 109     return $search;
 110 }
 111
 112 sub checkpw_ldap {
 113     my ($dbh, $userid, $password) = @_;
 114     my @hosts = split(',', $prefhost);
 115     my $db = Net::LDAP->new(\@hosts);
 116     unless ( $db ) {
 117         warn "LDAP connexion failed";
 118         return 0;
 119     }
 120
 121         #$debug and $db->debug(5);
 122     my $userldapentry;
 123
 124     # first, LDAP authentication
 125     if ( $ldap->{auth_by_bind} ) {
 126         my $principal_name;
 127         if ( $config{anonymous} ) {
 128
 129             # Perform an anonymous bind
 130             my $res = $db->bind;
 131             if ( $res->code ) {
 132                 warn "Anonymous LDAP bind failed: " . description($res);
 133                 return 0;
 134             }
 135
 136             # Perform a LDAP search for the given username
 137             my $search = search_method( $db, $userid )
 138               or return 0;    # warnings are in the sub
 139             $userldapentry = $search->shift_entry;
 140             $principal_name = $userldapentry->dn;
 141         }
 142         else {
 143             $principal_name = $ldap->{principal_name};
 144             if ( $principal_name and $principal_name =~ /\%/ ) {
 145                 $principal_name = sprintf( $principal_name, $userid );
 146             }
 147             else {
 148                 $principal_name = $userid;
 149             }
 150         }
 151
 152         # Perform a LDAP bind for the given username using the matched DN
 153         my $res = $db->bind( $principal_name, password => $password );
 154         if ( $res->code ) {
 155             if ( $config{anonymous} ) {
 156                 # With anonymous_bind approach we can be sure we have found the correct user
 157                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 158                 # or password changed). We should not fall back to local accounts in this case.
 159                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 160                 return -1;
 161             } else {
 162                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 163                 # at all, and thus we should fall back to local logins to restore previous behaviour
 164                 # see bug 12831
 165                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 166                 return 0;
 167             }
 168         }
 169         if ( !defined($userldapentry)
 170             && ( $config{update} or $config{replicate} ) )
 171         {
 172             my $search = search_method( $db, $userid ) or return 0;
 173             $userldapentry = $search->shift_entry;
 174         }
 175     } else {
 176         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 177                 if ($res->code) {               # connection refused
 178                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 179                         return 0;
 180                 }
 181         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 182         # Handle multiple branches. Same login exists several times in different branches.
 183         my $bind_ok = 0;
 184         while (my $entry = $search->shift_entry) {
 185             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 186             unless ($user_ldap_bind_ret->code) {
 187                 $userldapentry = $entry;
 188                 $bind_ok = 1;
 189                 last;
 190             }
 191         }
 192
 193         unless ($bind_ok) {
 194             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 195             return -1;
 196         }
 197
 198
 199     }
 200
 201     # To get here, LDAP has accepted our user's login attempt.
 202     # But we still have work to do.  See perldoc below for detailed breakdown.
 203
 204     my (%borrower);
 205         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 206
 207     if (( $borrowernumber and $config{update}   ) or
 208         (!$borrowernumber and $config{replicate})   ) {
 209         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 210         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 211     }
 212
 213     if ($borrowernumber) {
 214         if ($config{update}) { # A1, B1
 215             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 216             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 217         } else { # C1, D1
 218             # maybe update just the password?
 219                 return(1, $cardnumber, $local_userid);
 220         }
 221     } elsif ($config{replicate}) { # A2, C2
 222         my @columns = Koha::Patrons->columns;
 223         my $patron = Koha::Patron->new(
 224             {
 225                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 226             }
 227         )->store;
 228         die "Insert of new patron failed" unless $patron;
 229         $borrowernumber = $patron->borrowernumber;
 230         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 231    } else {
 232         return 0;   # B2, D2
 233     }
 234     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 235         my $attribute_types = Koha::Patron::Attribute::Types->filter_by_branch_limitations;
 236         while ( my $attribute_type = $attribute_types->next ) {
 237             my $code = $attribute_type->code;
 238             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 239                 next;
 240             }
 241             my $patron = Koha::Patrons->find($borrowernumber);
 242             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 243                 eval {
 244                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 245                     $patron->extended_attributes([$attribute]);
 246                 };
 247                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 248                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 249                 }
 250             }
 251         }
 252     }
 253     return(1, $cardnumber, $userid);
 254 }
 255
 256 # Pass LDAP entry object and local cardnumber (userid).
 257 # Returns borrower hash.
 258 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 259 # Ensure that mandatory fields are correctly filled!
 260 #
 261 sub ldap_entry_2_hash {
 262         my $userldapentry = shift;
 263         my %borrower = ( cardnumber => shift );
 264         my %memberhash;
 265         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 266         if ($debug) {
 267                 foreach (keys %$userldapentry) {
 268                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 269                 }
 270         }
 271         my $x = $userldapentry->{attrs} or return;
 272         foreach (keys %$x) {
 273                 $memberhash{$_} = join ' ', @{$x->{$_}};
 274                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 275         }
 276         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 277                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 278         foreach my $key (keys %mapping) {
 279                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 280                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 281                 unless (defined $data) {
 282             $data = $mapping{$key}->{content} || undef;
 283                 }
 284         $borrower{$key} = $data;
 285         }
 286         $borrower{initials} = $memberhash{initials} ||
 287                 ( substr($borrower{'firstname'},0,1)
 288                 . substr($borrower{ 'surname' },0,1)
 289                 . " ");
 290
 291     # categorycode conversions
 292     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 293         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 294     }
 295     elsif($default_categorycode) {
 296         $borrower{categorycode} = $default_categorycode;
 297     }
 298
 299         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 300         my $dbh = C4::Context->dbh;
 301         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 302         $sth->execute( uc($borrower{'categorycode'}) );
 303         unless ( my $row = $sth->fetchrow_hashref ) {
 304                 my $default = $mapping{'categorycode'}->{content};
 305                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 306                 $borrower{'categorycode'} = $default
 307         }
 308
 309         return %borrower;
 310 }
 311
 312 sub exists_local {
 313         my $arg = shift;
 314         my $dbh = C4::Context->dbh;
 315         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 316
 317         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 318         $sth->execute($arg);
 319         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 320         ($sth->rows == 1) and return $sth->fetchrow;
 321
 322         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 323         $sth->execute($arg);
 324         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 325         ($sth->rows == 1) and return $sth->fetchrow;
 326         return 0;
 327 }
 328
 329 # This function performs a password update, given the userid, borrowerid,
 330 # and digested password. It will verify that things are correct and return the
 331 # borrowers cardnumber. The idea is that it is used to keep the local
 332 # passwords in sync with the LDAP passwords.
 333 #
 334 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 335 #
 336 # Note: if the LDAP config has the update_password tag set to a false value,
 337 # then this will not update the password, it will simply return the cardnumber.
 338 sub _do_changepassword {
 339     my ($userid, $borrowerid, $password) = @_;
 340
 341     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 342
 343         # We don't store the password in the database
 344         my $sth = C4::Context->dbh->prepare(
 345             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 346         $sth->execute($borrowerid);
 347         die "Unable to access borrowernumber "
 348             . "with userid=$userid, "
 349             . "borrowernumber=$borrowerid"
 350           if !$sth->rows;
 351         my ($cardnum) = $sth->fetchrow;
 352         $sth = C4::Context->dbh->prepare(
 353             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 354         $sth->execute($borrowerid);
 355         return $cardnum;
 356     }
 357
 358     my $digest = hash_password($password);
 359     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 360     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 361
 362     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 363     return $cardnum if $ok;
 364
 365     warn "Password mismatch after update to borrowernumber=$borrowerid";
 366     return;
 367 }
 368
 369 sub update_local {
 370     my $userid     = shift or croak "No userid";
 371     my $password   = shift or croak "No password";
 372     my $borrowerid = shift or croak "No borrowerid";
 373     my $borrower   = shift or croak "No borrower record";
 374
 375     # skip extended patron attributes in 'borrowers' attribute update
 376     my @keys = keys %$borrower;
 377     if (C4::Context->preference('ExtendedPatronAttributes')) {
 378         my $attribute_types = Koha::Patron::Attribute::Types->filter_by_branch_limitations;
 379         while ( my $attribute_type = $attribute_types->next ) {
 380            my $code = $attribute_type->code;
 381            @keys = grep { $_ ne $code } @keys;
 382            $debug and printf STDERR "ignoring extended patron attribute '%s' in update_local()\n", $code;
 383         }
 384     }
 385
 386     my $dbh = C4::Context->dbh;
 387     my $query = "UPDATE  borrowers\nSET     " .
 388         join(',', map {"$_=?"} @keys) .
 389         "\nWHERE   borrowernumber=? ";
 390     my $sth = $dbh->prepare($query);
 391     if ($debug) {
 392         print STDERR $query, "\n",
 393             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 394         print STDERR "\nuserid = $userid\n";
 395     }
 396     $sth->execute(
 397         ((map {$borrower->{$_}} @keys), $borrowerid)
 398     );
 399
 400     # MODIFY PASSWORD/LOGIN if password was mapped
 401     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 402 }
 403
 404 1;
 405 __END__
 406
 407 =head1 NAME
 408
 409 C4::Auth - Authenticates Koha users
 410
 411 =head1 SYNOPSIS
 412
 413   use C4::Auth_with_ldap;
 414
 415 =head1 LDAP Configuration
 416
 417     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 418         working LDAP servers.
 419         To use it :
 420            * Modify ldapserver element in KOHA_CONF
 421            * Establish field mapping in <mapping> element.
 422
 423         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 424         the username would match the "uid" field, and the password should match the "userpassword" field.
 425
 426         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 427         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 428
 429         mysql> show COLUMNS from borrowers;
 430                 +---------------------+--------------+------+-----+---------+----------------+
 431                 | Field               | Type         | Null | Key | Default | Extra          |
 432                 +---------------------+--------------+------+-----+---------+----------------+
 433                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 434                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 435                 | surname             | mediumtext   | NO   |     | NULL    |                |
 436                 | firstname           | text         | YES  |     | NULL    |                |
 437                 | title               | mediumtext   | YES  |     | NULL    |                |
 438                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 439                 | initials            | text         | YES  |     | NULL    |                |
 440                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 441                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 442                 | address             | mediumtext   | NO   |     | NULL    |                |
 443                 | address2            | text         | YES  |     | NULL    |                |
 444                 | city                | mediumtext   | NO   |     | NULL    |                |
 445                 | state               | mediumtext   | YES  |     | NULL    |                |
 446                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 447                 | country             | text         | YES  |     | NULL    |                |
 448                 | email               | mediumtext   | YES  |     | NULL    |                |
 449                 | phone               | text         | YES  |     | NULL    |                |
 450                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 451                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 452                 | emailpro            | text         | YES  |     | NULL    |                |
 453                 | phonepro            | text         | YES  |     | NULL    |                |
 454                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 455                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 456                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 457                 | B_address2          | text         | YES  |     | NULL    |                |
 458                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 459                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 460                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 461                 | B_country           | text         | YES  |     | NULL    |                |
 462                 | B_email             | text         | YES  |     | NULL    |                |
 463                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 464                 | dateofbirth         | date         | YES  |     | NULL    |                |
 465                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 466                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 467                 | dateenrolled        | date         | YES  |     | NULL    |                |
 468                 | dateexpiry          | date         | YES  |     | NULL    |                |
 469                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 470                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 471                 | debarred            | date         | YES  |     | NULL    |                |
 472                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 473                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 474                 | contactfirstname    | text         | YES  |     | NULL    |                |
 475                 | contacttitle        | text         | YES  |     | NULL    |                |
 476                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 477                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 478                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 479                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 480                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 481                 | password            | varchar(30)  | YES  |     | NULL    |                |
 482                 | flags               | int(11)      | YES  |     | NULL    |                |
 483                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 484                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 485                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 486                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 487                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 488                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 489                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 490                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 491                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 492                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 493                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 494                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 495                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 496                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 497                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 498                 | privacy             | int(11)      | NO   |     | 1       |                |
 499                 +---------------------+--------------+------+-----+---------+----------------+
 500                 66 rows in set (0.00 sec)
 501                 Where Null="NO", the field is required.
 502
 503 =head1 KOHA_CONF and field mapping
 504
 505 Example XML stanza for LDAP configuration in KOHA_CONF.
 506
 507  <config>
 508   ...
 509   <useldapserver>1</useldapserver>
 510   <!-- LDAP SERVER (optional) -->
 511   <ldapserver id="ldapserver">
 512     <hostname>localhost</hostname>
 513     <base>dc=metavore,dc=com</base>
 514     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 515     <pass>metavore</pass>          <!-- password, if not anonymous -->
 516     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 517     <update>1</update>             <!-- update existing users in Koha database -->
 518     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 519                                         password comparison, e.g., to use Active Directory -->
 520     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 521                                             an anonymous bind, even when auth_by_bind is on -->
 522     <principal_name>%s@my_domain.com</principal_name>
 523                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 524                                         Not used with anonymous_bind. -->
 525     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 526                                               synced to the local database -->
 527     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 528       <firstname    is="givenname"      ></firstname>
 529       <surname      is="sn"             ></surname>
 530       <address      is="postaladdress"  ></address>
 531       <city         is="l"              >Athens, OH</city>
 532       <zipcode      is="postalcode"     ></zipcode>
 533       <branchcode   is="branch"         >MAIN</branchcode>
 534       <userid       is="uid"            ></userid>
 535       <password     is="userpassword"   ></password>
 536       <email        is="mail"           ></email>
 537       <categorycode is="employeetype"   >PT</categorycode>
 538       <phone        is="telephonenumber"></phone>
 539     </mapping>
 540   </ldapserver>
 541  </config>
 542
 543 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 544 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 545 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 546 patron).
 547
 548 =head1 CONFIGURATION
 549
 550 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 551 your configuration and the presence of a matching Koha user in your local DB:
 552
 553                          LOCAL_USER
 554  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 555    A1      1       1        1      OK : We're updating them anyway.
 556    A2      1       1        0      OK : We're adding them anyway.
 557    B1      1       0        1      OK : We update them.
 558    B2      1       0        0     FAIL: We cannot add new user.
 559    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 560    C2      0       1        0      OK : We add the new user.
 561    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 562    D2      0       0        0     FAIL: We cannot add new user.
 563
 564 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 565 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 566 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 567
 568 If you choose NOT to update local users, the borrowers table will not be affected at all.
 569 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 570 the local table never contained the LDAP values.
 571
 572 =head2 auth_by_bind
 573
 574 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 575
 576 =head2 principal_name
 577
 578 Provides an optional sprintf-style format for manipulating the userid before the bind.
 579 Even though the userPrincipalName is one intended target, any uniquely identifying
 580 attribute that the server allows to be used for binding could be used.
 581
 582 Currently, principal_name only operates when auth_by_bind is enabled.
 583
 584 =head2 update_password
 585
 586 If this tag is left out or set to a true value, then the user's LDAP password
 587 will be stored (hashed) in the local Koha database. If you don't want this
 588 to happen, then set the value of this to '0'. Note that if passwords are not
 589 stored locally, and the connection to the LDAP system fails, then the users
 590 will not be able to log in at all.
 591
 592 =head2 Active Directory
 593
 594 The auth_by_bind and principal_name settings are recommended for Active Directory.
 595
 596 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 597 we would typically under openldap.  Instead of:
 598
 599     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 600
 601 We might get:
 602
 603     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 604
 605 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 606 in Koha userids.  But the userPrincipalName should be consistent, something like:
 607
 608     userPrincipalName: barnes.7@my_company.com
 609
 610 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 611 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 612 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 613 like this:
 614     <principal_name>%s@core.my_company.com</principal_name>
 615
 616 The user of the previous example, barnes.7, would then attempt to bind as:
 617     barnes.7@core.my_company.com
 618
 619 =head1 SEE ALSO
 620
 621 CGI(3)
 622
 623 Net::LDAP()
 624
 625 XML::Simple()
 626
 627 Digest::MD5(3)
 628
 629 sprintf()
 630
 631 =cut
 632
 633 # For reference, here's an important difference in the data structure we rely on.
 634 # ========================================
 635 # Using attrs instead of {asn}->attributes
 636 # ========================================
 637 #
 638 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 639 #       LDAP key: ->{             cn}->{           sss} = sss
 640 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 641 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 642 #
 643 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 644 #       LDAP key: ->{      givenname}->{Steve} = Steve
 645 #