tools/csv-profiles.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 # Copyright 2015 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 =head1 NAME
  22
  23 csv-profile.pl : Defines a CSV export profile
  24
  25 =head1 SYNOPSIS
  26
  27 =cut
  28
  29 =head1 DESCRIPTION
  30
  31 This script allow the user to define a new profile for CSV export
  32
  33 =head1 FUNCTIONS
  34
  35 =cut
  36
  37 use Modern::Perl;
  38 use Encode;
  39
  40 use C4::Auth;
  41 use C4::Context;
  42 use C4::Output;
  43 use CGI qw ( -utf8 );
  44 use C4::Koha;
  45 use Koha::CsvProfiles;
  46
  47 my $input            = new CGI;
  48 my $export_format_id = $input->param('export_format_id');
  49 my $op               = $input->param('op') || 'list';
  50 my @messages;
  51
  52 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  53     {   template_name   => "tools/csv-profiles.tt",
  54         query           => $input,
  55         type            => "intranet",
  56         authnotrequired => 0,
  57         flagsrequired   => { tools => 'manage_csv_profiles' },
  58         debug           => 1,
  59     }
  60 );
  61
  62 # Getting available encodings list
  63 $template->param( encodings => [ Encode->encodings ] );
  64
  65 if ( $op eq 'add_form' ) {
  66     my $csv_profile;
  67     if ($export_format_id) {
  68         $csv_profile = Koha::CsvProfiles->find($export_format_id);
  69     }
  70     $template->param( csv_profile => $csv_profile, );
  71 } elsif ( $op eq 'add_validate' ) {
  72     my $profile     = $input->param("profile");
  73     my $description = $input->param("description");
  74     my $type        = $input->param("type");
  75     my $used_for    =
  76         $type eq "marc"
  77       ? $input->param("used_for_marc")
  78       : $input->param("used_for_sql");
  79     my $content =
  80         $type eq "marc"
  81       ? $input->param("marc_content")
  82       : $input->param("sql_content");
  83     my $csv_separator      = $input->param("csv_separator");
  84     my $field_separator    = $input->param("field_separator");
  85     my $subfield_separator = $input->param("subfield_separator");
  86     my $encoding           = $input->param("encoding");
  87     my $staff_only         = $input->param("staff_only") ? 1 : 0;
  88
  89     if ($export_format_id) {
  90         my $csv_profile = Koha::CsvProfiles->find($export_format_id)
  91             or die "Something went wrong! This export_format_id does not match any existing CSV profile.";
  92         $csv_profile->profile($profile);
  93         $csv_profile->description($description);
  94         $csv_profile->content($content);
  95         $csv_profile->csv_separator($csv_separator);
  96         $csv_profile->field_separator($field_separator);
  97         $csv_profile->subfield_separator($subfield_separator);
  98         $csv_profile->encoding($encoding);
  99         $csv_profile->type($type);
 100         $csv_profile->used_for($used_for);
 101         $csv_profile->staff_only($staff_only);
 102         eval { $csv_profile->store; };
 103
 104         if ($@) {
 105             push @messages, { type => 'error', code => 'error_on_update' };
 106         } else {
 107             push @messages, { type => 'message', code => 'success_on_update' };
 108         }
 109     } else {
 110         my $csv_profile = Koha::CsvProfile->new(
 111             {   profile            => $profile,
 112                 description        => $description,
 113                 content            => $content,
 114                 csv_separator      => $csv_separator,
 115                 field_separator    => $field_separator,
 116                 subfield_separator => $subfield_separator,
 117                 encoding           => $encoding,
 118                 type               => $type,
 119                 used_for           => $used_for,
 120                 staff_only         => $staff_only
 121             }
 122         );
 123         eval { $csv_profile->store; };
 124         if ($@) {
 125             push @messages, { type => 'error', code => 'error_on_insert' };
 126         } else {
 127             push @messages, { type => 'message', code => 'success_on_insert' };
 128         }
 129     }
 130     $op = 'list';
 131 } elsif ( $op eq 'delete_confirm' ) {
 132     my $csv_profile = Koha::CsvProfiles->find($export_format_id);
 133     $template->param( csv_profile => $csv_profile, );
 134 } elsif ( $op eq 'delete_confirmed' ) {
 135     my $csv_profile = Koha::CsvProfiles->find($export_format_id);
 136     my $deleted = eval { $csv_profile->delete; };
 137
 138     if ( $@ or not $deleted ) {
 139         push @messages, { type => 'error', code => 'error_on_delete' };
 140     } else {
 141         push @messages, { type => 'message', code => 'success_on_delete' };
 142     }
 143     $op = 'list';
 144 }
 145
 146 if ( $op eq 'list' ) {
 147     my $csv_profiles = Koha::CsvProfiles->search;
 148     $template->param( csv_profiles => $csv_profiles, );
 149 }
 150
 151 $template->param(
 152     messages => \@messages,
 153     op       => $op,
 154 );
 155
 156 output_html_with_http_headers $input, $cookie, $template->output;