reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use C4::Branch;
  32 use CGI qw ( -utf8 );
  33 use List::MoreUtils qw/uniq/;
  34 use Date::Calc qw/Date_to_Days/;
  35 use C4::Output;
  36 use C4::Auth;
  37 use C4::Reserves;
  38 use C4::Biblio;
  39 use C4::Items;
  40 use C4::Koha;
  41 use C4::Circulation;
  42 use Koha::DateUtils;
  43 use C4::Utils::DataTables::Members;
  44 use C4::Members;
  45 use C4::Search;         # enabled_staff_search_views
  46 use Koha::DateUtils;
  47 use Koha::Holds;
  48 use Koha::Libraries;
  49
  50 my $dbh = C4::Context->dbh;
  51 my $input = new CGI;
  52 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  53     {
  54         template_name   => "reserve/request.tt",
  55         query           => $input,
  56         type            => "intranet",
  57         authnotrequired => 0,
  58         flagsrequired   => { reserveforothers => 'place_holds' },
  59     }
  60 );
  61
  62 my $multihold = $input->param('multi_hold');
  63 $template->param(multi_hold => $multihold);
  64 my $showallitems = $input->param('showallitems');
  65
  66 # get Branches and Itemtypes
  67 my $branches = GetBranches();
  68 my $itemtypes = GetItemTypes();
  69
  70 my $userbranch = '';
  71 if (C4::Context->userenv && C4::Context->userenv->{'branch'}) {
  72     $userbranch = C4::Context->userenv->{'branch'};
  73 }
  74
  75
  76 # Select borrowers infos
  77 my $findborrower = $input->param('findborrower');
  78 $findborrower = '' unless defined $findborrower;
  79 $findborrower =~ s|,| |g;
  80 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  81 my $messageborrower;
  82 my $warnings;
  83 my $messages;
  84 my $exceeded_maxreserves;
  85
  86 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  87 my $action = $input->param('action');
  88 $action ||= q{};
  89
  90 if ( $action eq 'move' ) {
  91   my $where = $input->param('where');
  92   my $reserve_id = $input->param('reserve_id');
  93   AlterPriority( $where, $reserve_id );
  94 } elsif ( $action eq 'cancel' ) {
  95   my $reserve_id = $input->param('reserve_id');
  96   CancelReserve({ reserve_id => $reserve_id });
  97 } elsif ( $action eq 'setLowestPriority' ) {
  98   my $reserve_id = $input->param('reserve_id');
  99   ToggleLowestPriority( $reserve_id );
 100 } elsif ( $action eq 'toggleSuspend' ) {
 101   my $reserve_id = $input->param('reserve_id');
 102   my $suspend_until  = $input->param('suspend_until');
 103   ToggleSuspend( $reserve_id, $suspend_until );
 104 }
 105
 106 if ($findborrower) {
 107     my $borrower = C4::Members::GetMember( cardnumber => $findborrower );
 108     if ( $borrower ) {
 109         $borrowernumber_hold = $borrower->{borrowernumber};
 110     } else {
 111         my $dt_params = { iDisplayLength => -1 };
 112         my $results = C4::Utils::DataTables::Members::search(
 113             {
 114                 searchmember => $findborrower,
 115                 dt_params => $dt_params,
 116             }
 117         );
 118         my $borrowers = $results->{patrons};
 119         if ( scalar @$borrowers == 1 ) {
 120             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 121         } elsif ( @$borrowers ) {
 122             $template->param( borrowers => $borrowers );
 123         } else {
 124             $messageborrower = "'$findborrower'";
 125         }
 126     }
 127 }
 128
 129 my @biblionumbers = ();
 130 my $biblionumbers = $input->param('biblionumbers');
 131 if ($multihold) {
 132     @biblionumbers = split '/', $biblionumbers;
 133 } else {
 134     push @biblionumbers, $input->multi_param('biblionumber');
 135 }
 136
 137
 138 # If we have the borrowernumber because we've performed an action, then we
 139 # don't want to try to place another reserve.
 140 if ($borrowernumber_hold && !$action) {
 141     my $borrowerinfo = GetMember( borrowernumber => $borrowernumber_hold );
 142     my $diffbranch;
 143
 144     # we check the reserves of the borrower, and if he can reserv a document
 145     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 146
 147     my $reserves_count =
 148       GetReserveCount( $borrowerinfo->{'borrowernumber'} );
 149
 150     my $new_reserves_count = scalar( @biblionumbers );
 151
 152     my $maxreserves = C4::Context->preference('maxreserves');
 153     if ( $maxreserves
 154         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 155     {
 156         my $new_reserves_allowed =
 157             $maxreserves - $reserves_count > 0
 158           ? $maxreserves - $reserves_count
 159           : 0;
 160         $warnings             = 1;
 161         $exceeded_maxreserves = 1;
 162         $template->param(
 163             new_reserves_allowed => $new_reserves_allowed,
 164             new_reserves_count   => $new_reserves_count,
 165             reserves_count       => $reserves_count,
 166             maxreserves          => $maxreserves,
 167         );
 168     }
 169
 170     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 171     my $expiry_date = $borrowerinfo->{dateexpiry};
 172     my $expiry = 0; # flag set if patron account has expired
 173     if ($expiry_date and $expiry_date ne '0000-00-00' and
 174         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 175         $expiry = 1;
 176     }
 177
 178     # check if the borrower make the reserv in a different branch
 179     if ( $borrowerinfo->{'branchcode'} ne C4::Context->userenv->{'branch'} ) {
 180         $diffbranch = 1;
 181     }
 182
 183     my $is_debarred = Koha::Patrons->find( $borrowerinfo->{borrowernumber} )->is_debarred;
 184     $template->param(
 185                 borrowernumber      => $borrowerinfo->{'borrowernumber'},
 186                 borrowersurname     => $borrowerinfo->{'surname'},
 187                 borrowerfirstname   => $borrowerinfo->{'firstname'},
 188                 borrowerstreetaddress   => $borrowerinfo->{'address'},
 189                 borrowercity        => $borrowerinfo->{'city'},
 190                 borrowerphone       => $borrowerinfo->{'phone'},
 191                 borrowermobile      => $borrowerinfo->{'mobile'},
 192                 borrowerfax         => $borrowerinfo->{'fax'},
 193                 borrowerphonepro    => $borrowerinfo->{'phonepro'},
 194                 borroweremail       => $borrowerinfo->{'email'},
 195                 borroweremailpro    => $borrowerinfo->{'emailpro'},
 196                 borrowercategory    => $borrowerinfo->{'category'},
 197                 cardnumber          => $borrowerinfo->{'cardnumber'},
 198                 expiry              => $expiry,
 199                 diffbranch          => $diffbranch,
 200                 messages            => $messages,
 201                 warnings            => $warnings,
 202                 restricted          => $is_debarred,
 203                 amount_outstanding  => GetMemberAccountRecords($borrowerinfo->{borrowernumber}),
 204     );
 205 }
 206
 207 $template->param( messageborrower => $messageborrower );
 208
 209 # FIXME launch another time GetMember perhaps until
 210 my $borrowerinfo = GetMember( borrowernumber => $borrowernumber_hold );
 211
 212 my $itemdata_enumchron = 0;
 213 my @biblioloop = ();
 214 foreach my $biblionumber (@biblionumbers) {
 215     next unless $biblionumber =~ m|^\d+$|;
 216
 217     my %biblioloopiter = ();
 218
 219     my $dat = GetBiblioData($biblionumber);
 220
 221     my $canReserve = CanBookBeReserved( $borrowerinfo->{borrowernumber}, $biblionumber );
 222     $canReserve //= '';
 223     if ( $canReserve eq 'OK' ) {
 224
 225         #All is OK and we can continue
 226     }
 227     elsif ( $canReserve eq 'tooManyReserves' ) {
 228         $exceeded_maxreserves = 1;
 229     }
 230     elsif ( $canReserve eq 'ageRestricted' ) {
 231         $template->param( $canReserve => 1 );
 232         $biblioloopiter{$canReserve} = 1;
 233     }
 234     else {
 235         $biblioloopiter{$canReserve} = 1;
 236     }
 237
 238     my $force_hold_level;
 239     if ( $borrowerinfo->{borrowernumber} ) {
 240         # For multiple holds per record, if a patron has previously placed a hold,
 241         # the patron can only place more holds of the same type. That is, if the
 242         # patron placed a record level hold, all the holds the patron places must
 243         # be record level. If the patron placed an item level hold, all holds
 244         # the patron places must be item level
 245         my $holds = Koha::Holds->search(
 246             {
 247                 borrowernumber => $borrowerinfo->{borrowernumber},
 248                 biblionumber   => $biblionumber,
 249                 found          => undef,
 250             }
 251         );
 252         $force_hold_level = $holds->forced_hold_level();
 253         $biblioloopiter{force_hold_level} = $force_hold_level;
 254         $template->param( force_hold_level => $force_hold_level );
 255
 256         # For a librarian to be able to place multiple record holds for a patron for a record,
 257         # we must find out what the maximum number of holds they can place for the patron is
 258         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $borrowerinfo->{borrowernumber}, $biblionumber );
 259         $max_holds_for_record = $max_holds_for_record - $holds->count();
 260         $biblioloopiter{max_holds_for_record} = $max_holds_for_record;
 261         $template->param( max_holds_for_record => $max_holds_for_record );
 262     }
 263
 264     # Check to see if patron is allowed to place holds on records where the
 265     # patron already has an item from that record checked out
 266     my $alreadypossession;
 267     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 268         && CheckIfIssuedToPatron( $borrowerinfo->{borrowernumber}, $biblionumber ) )
 269     {
 270         $template->param( alreadypossession => $alreadypossession, );
 271     }
 272
 273
 274     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 275     my $totalcount = $count;
 276
 277     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 278     # make priorities options
 279
 280     my @optionloop;
 281     for ( 1 .. $count + 1 ) {
 282         push(
 283              @optionloop,
 284              {
 285               num      => $_,
 286               selected => ( $_ == $count + 1 ),
 287              }
 288             );
 289     }
 290     # adding a fixed value for priority options
 291     my $fixedRank = $count+1;
 292
 293     my %itemnumbers_of_biblioitem;
 294     my @itemnumbers;
 295
 296     ## $items is array of 'item' table numbers
 297     if (my $items = get_itemnumbers_of($biblionumber)->{$biblionumber}){
 298         @itemnumbers  = @$items;
 299     }
 300     my @hostitems = get_hostitemnumbers_of($biblionumber);
 301     if (@hostitems){
 302         $template->param('hostitemsflag' => 1);
 303         push(@itemnumbers, @hostitems);
 304     }
 305
 306     if (!@itemnumbers) {
 307         $template->param('noitems' => 1);
 308         $biblioloopiter{noitems} = 1;
 309     }
 310
 311     ## Hash of item number to 'item' table fields
 312     my $iteminfos_of = GetItemInfosOf(@itemnumbers);
 313
 314     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 315     ## when by definition all of the itemnumber have the same biblioitemnumber
 316     foreach my $itemnumber (@itemnumbers) {
 317         my $biblioitemnumber = $iteminfos_of->{$itemnumber}->{biblioitemnumber};
 318         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 319     }
 320
 321     ## Should be same as biblionumber
 322     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 323
 324     my $notforloan_label_of = get_notforloan_label_of();
 325
 326     ## Hash of biblioitemnumber to 'biblioitem' table records
 327     my $biblioiteminfos_of  = GetBiblioItemInfosOf(@biblioitemnumbers);
 328
 329     my @bibitemloop;
 330
 331     my @available_itemtypes;
 332     foreach my $biblioitemnumber (@biblioitemnumbers) {
 333         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 334         my $num_available = 0;
 335         my $num_override  = 0;
 336         my $hiddencount   = 0;
 337
 338         $biblioitem->{force_hold_level} = $force_hold_level;
 339
 340         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 341             $biblioitem->{hostitemsflag} = 1;
 342         }
 343
 344         $biblioloopiter{description} = $biblioitem->{description};
 345         $biblioloopiter{itypename}   = $biblioitem->{description};
 346         if ( $biblioitem->{itemtype} ) {
 347
 348             $biblioitem->{description} =
 349               $itemtypes->{ $biblioitem->{itemtype} }{description};
 350
 351             $biblioloopiter{imageurl} =
 352               getitemtypeimagelocation( 'intranet',
 353                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 354         }
 355
 356         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 357             my $item = $iteminfos_of->{$itemnumber};
 358
 359             $item->{force_hold_level} = $force_hold_level;
 360
 361             unless (C4::Context->preference('item-level_itypes')) {
 362                 $item->{itype} = $biblioitem->{itemtype};
 363             }
 364
 365             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 366             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 367             $item->{homebranchname} = $branches->{ $item->{homebranch} }{branchname};
 368
 369             # if the holdingbranch is different than the homebranch, we show the
 370             # holdingbranch of the document too
 371             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 372                 $item->{holdingbranchname} =
 373                   $branches->{ $item->{holdingbranch} }{branchname};
 374             }
 375
 376                 if($item->{biblionumber} ne $biblionumber){
 377                         $item->{hostitemsflag}=1;
 378                         $item->{hosttitle} = GetBiblioData($item->{biblionumber})->{title};
 379                 }
 380
 381             # if the item is currently on loan, we display its return date and
 382             # change the background color
 383             my $issues= GetItemIssue($itemnumber);
 384             if ( $issues->{'date_due'} ) {
 385                 $item->{date_due} = $issues->{date_due_sql};
 386                 $item->{backgroundcolor} = 'onloan';
 387             }
 388
 389             # checking reserve
 390             my ($reservedate,$reservedfor,$expectedAt,$reserve_id,$wait) = GetReservesFromItemnumber($itemnumber);
 391             if ( defined $reservedate ) {
 392                 my $ItemBorrowerReserveInfo = GetMember( borrowernumber => $reservedfor );
 393
 394                 $item->{backgroundcolor} = 'reserved';
 395                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $reservedate ), dateonly => 1 });
 396                 $item->{ReservedForBorrowernumber}     = $reservedfor;
 397                 $item->{ReservedForSurname}     = $ItemBorrowerReserveInfo->{'surname'};
 398                 $item->{ReservedForFirstname}     = $ItemBorrowerReserveInfo->{'firstname'};
 399                 $item->{ExpectedAtLibrary}     = $branches->{$expectedAt}{branchname};
 400                 $item->{waitingdate} = $wait;
 401             }
 402
 403             # Management of the notforloan document
 404             if ( $item->{notforloan} ) {
 405                 $item->{backgroundcolor} = 'other';
 406                 $item->{notforloanvalue} =
 407                   $notforloan_label_of->{ $item->{notforloan} };
 408             }
 409
 410             # Management of lost or long overdue items
 411             if ( $item->{itemlost} ) {
 412
 413                 # FIXME localized strings should never be in Perl code
 414                 $item->{message} =
 415                   $item->{itemlost} == 1 ? "(lost)"
 416                     : $item->{itemlost} == 2 ? "(long overdue)"
 417                       : "";
 418                 $item->{backgroundcolor} = 'other';
 419                 if (GetHideLostItemsPreference($borrowernumber) && !$showallitems) {
 420                     $item->{hide} = 1;
 421                     $hiddencount++;
 422                 }
 423             }
 424
 425             # Check the transit status
 426             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 427               GetTransfers($itemnumber);
 428
 429             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 430                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 431                 $item->{transfertfrom} =
 432                   $branches->{$transfertfrom}{branchname};
 433                 $item->{transfertto} = $branches->{$transfertto}{branchname};
 434                 $item->{nocancel} = 1;
 435             }
 436
 437             # If there is no loan, return and transfer, we show a checkbox.
 438             $item->{notforloan} ||= 0;
 439
 440             # if independent branches is on we need to check if the person can reserve
 441             # for branches they arent logged in to
 442             if ( C4::Context->preference("IndependentBranches") ) {
 443                 if (! C4::Context->preference("canreservefromotherbranches")){
 444                     # cant reserve items so need to check if item homebranch and userenv branch match if not we cant reserve
 445                     my $userenv = C4::Context->userenv;
 446                     unless ( C4::Context->IsSuperLibrarian ) {
 447                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 448                     }
 449                 }
 450             }
 451
 452             my $branch = C4::Circulation::_GetCircControlBranch($item, $borrowerinfo);
 453
 454             my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 455
 456             $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 457
 458             my $can_item_be_reserved = CanItemBeReserved( $borrowerinfo->{borrowernumber}, $itemnumber );
 459             $item->{not_holdable} = $can_item_be_reserved unless ( $can_item_be_reserved eq 'OK' );
 460
 461             if (
 462                    !$item->{cantreserve}
 463                 && !$exceeded_maxreserves
 464                 && IsAvailableForItemLevelRequest($item, $borrowerinfo)
 465                 && $can_item_be_reserved eq 'OK'
 466               )
 467             {
 468                 $item->{available} = 1;
 469                 $num_available++;
 470
 471                 push( @available_itemtypes, $item->{itype} );
 472             }
 473             elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 474                 # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 475                 $item->{override} = 1;
 476                 $num_override++;
 477             }
 478
 479             # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 480
 481             # Show serial enumeration when needed
 482             if ($item->{enumchron}) {
 483                 $itemdata_enumchron = 1;
 484             }
 485
 486             push @{ $biblioitem->{itemloop} }, $item;
 487         }
 488
 489         if ( $num_override == scalar( @{ $biblioitem->{itemloop} } ) ) { # That is, if all items require an override
 490             $template->param( override_required => 1 );
 491         } elsif ( $num_available == 0 ) {
 492             $template->param( none_available => 1 );
 493             $biblioloopiter{warn} = 1;
 494             $biblioloopiter{none_avail} = 1;
 495         }
 496         $template->param( hiddencount => $hiddencount);
 497
 498         push @bibitemloop, $biblioitem;
 499     }
 500
 501     @available_itemtypes = uniq( @available_itemtypes );
 502     $template->param( available_itemtypes => \@available_itemtypes );
 503
 504     # existingreserves building
 505     my @reserveloop;
 506     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 507     foreach my $res (
 508         sort {
 509             my $a_found = $a->found() || '';
 510             my $b_found = $a->found() || '';
 511             $a_found cmp $b_found;
 512         } @reserves
 513       )
 514     {
 515         my %reserve;
 516         my @optionloop;
 517         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 518             push(
 519                 @optionloop,
 520                 {
 521                     num      => $i,
 522                     selected => ( $i == $res->priority() ),
 523                 }
 524             );
 525         }
 526
 527         if ( $res->is_found() ) {
 528             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 529             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 530             $reserve{'barcodenumber'} = $res->item()->barcode();
 531             $reserve{'wbrcode'}       = $res->branchcode();
 532             $reserve{'itemnumber'}    = $res->itemnumber();
 533             $reserve{'wbrname'}       = $res->branch()->branchname();
 534
 535             if ( $reserve{'holdingbranch'} eq $reserve{'wbrcode'} ) {
 536
 537                 # Just because the holdingbranch matches the reserve branch doesn't mean the item
 538                 # has arrived at the destination, check for an open transfer for the item as well
 539                 my ( $transfertwhen, $transfertfrom, $transferto ) =
 540                   C4::Circulation::GetTransfers( $res->itemnumber() );
 541                 if ( not $transferto or $transferto ne $res->branchcode() ) {
 542                     $reserve{'atdestination'} = 1;
 543                 }
 544             }
 545
 546             # set found to 1 if reserve is waiting for patron pickup
 547             $reserve{'found'}     = $res->is_found();
 548             $reserve{'intransit'} = $res->is_in_transit();
 549         }
 550         elsif ( $res->priority() > 0 ) {
 551             if ( my $item = $res->item() )  {
 552                 $reserve{'itemnumber'}      = $item->id();
 553                 $reserve{'barcodenumber'}   = $item->barcode();
 554                 $reserve{'item_level_hold'} = 1;
 555             }
 556         }
 557
 558         #     get borrowers reserve info
 559         if ( C4::Context->preference('HidePatronName') ) {
 560             $reserve{'hidename'}   = 1;
 561             $reserve{'cardnumber'} = $res->borrower()->cardnumber();
 562         }
 563         $reserve{'expirationdate'} = output_pref( { dt => dt_from_string( $res->expirationdate ), dateonly => 1 } )
 564           unless ( !defined( $res->expirationdate ) || $res->expirationdate eq '0000-00-00' );
 565         $reserve{'date'}           = output_pref( { dt => dt_from_string( $res->reservedate ), dateonly => 1 } );
 566         $reserve{'borrowernumber'} = $res->borrowernumber();
 567         $reserve{'biblionumber'}   = $res->biblionumber();
 568         $reserve{'borrowernumber'} = $res->borrowernumber();
 569         $reserve{'firstname'}      = $res->borrower()->firstname();
 570         $reserve{'surname'}        = $res->borrower()->surname();
 571         $reserve{'notes'}          = $res->reservenotes();
 572         $reserve{'waiting_date'}   = $res->waitingdate();
 573         $reserve{'waiting_until'}  = $res->is_waiting() ? $res->waiting_expires_on() : undef;
 574         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 575         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 576         $reserve{'priority'}       = $res->priority();
 577         $reserve{'lowestPriority'} = $res->lowestPriority();
 578         $reserve{'optionloop'}     = \@optionloop;
 579         $reserve{'suspend'}        = $res->suspend();
 580         $reserve{'suspend_until'}  = $res->suspend_until();
 581         $reserve{'reserve_id'}     = $res->reserve_id();
 582         $reserve{itemtype}         = $res->itemtype();
 583
 584         if ( C4::Context->preference('IndependentBranches') && $flags->{'superlibrarian'} != 1 ) {
 585             $reserve{'branchloop'} = [ Koha::Libraries->find( $res->branchcode() ) ];
 586         }
 587         else {
 588             $reserve{'branchloop'} = GetBranchesLoop( $res->branchcode() );
 589         }
 590
 591         push( @reserveloop, \%reserve );
 592     }
 593
 594     # get the time for the form name...
 595     my $time = time();
 596
 597     $template->param(
 598                      branchloop  => GetBranchesLoop($userbranch),
 599                      time        => $time,
 600                      fixedRank   => $fixedRank,
 601                     );
 602
 603     # display infos
 604     $template->param(
 605                      optionloop        => \@optionloop,
 606                      bibitemloop       => \@bibitemloop,
 607                      itemdata_enumchron => $itemdata_enumchron,
 608                      date              => $date,
 609                      biblionumber      => $biblionumber,
 610                      findborrower      => $findborrower,
 611                      title             => $dat->{title},
 612                      author            => $dat->{author},
 613                      holdsview => 1,
 614                      C4::Search::enabled_staff_search_views,
 615                     );
 616     if (defined $borrowerinfo && exists $borrowerinfo->{'branchcode'}) {
 617         $template->param(
 618                      borrower_branchname => $branches->{$borrowerinfo->{'branchcode'}}->{'branchname'},
 619                      borrower_branchcode => $borrowerinfo->{'branchcode'},
 620         );
 621     }
 622
 623     $biblioloopiter{biblionumber} = $biblionumber;
 624     $biblioloopiter{title} = $dat->{title};
 625     $biblioloopiter{rank} = $fixedRank;
 626     $biblioloopiter{reserveloop} = \@reserveloop;
 627
 628     if (@reserveloop) {
 629         $template->param( reserveloop => \@reserveloop );
 630     }
 631
 632     push @biblioloop, \%biblioloopiter;
 633 }
 634
 635 $template->param( biblioloop => \@biblioloop );
 636 $template->param( biblionumbers => $biblionumbers );
 637 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 638
 639 if ($multihold) {
 640     $template->param( multi_hold => 1 );
 641 }
 642
 643 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 644     $template->param( reserve_in_future => 1 );
 645 }
 646
 647 $template->param(
 648     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 649     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 650 );
 651
 652 # printout the page
 653 output_html_with_http_headers $input, $cookie, $template->output;
 654
 655 sub sort_borrowerlist {
 656     my $borrowerslist = shift;
 657     my $ref           = [];
 658     push @{$ref}, sort {
 659         uc( $a->{surname} . $a->{firstname} ) cmp
 660           uc( $b->{surname} . $b->{firstname} )
 661     } @{$borrowerslist};
 662     return $ref;
 663 }