opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use JSON;
  23 use List::MoreUtils qw( any each_array uniq );
  24 use String::Random qw( random_string );
  25
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::Members;
  29 use C4::Members::Attributes qw( GetBorrowerAttributes );
  30 use C4::Form::MessagingPreferences;
  31 use Koha::AuthUtils;
  32 use Koha::Patrons;
  33 use Koha::Patron::Consent;
  34 use Koha::Patron::Modification;
  35 use Koha::Patron::Modifications;
  36 use C4::Scrubber;
  37 use Email::Valid;
  38 use Koha::DateUtils;
  39 use Koha::Libraries;
  40 use Koha::Patron::Attribute::Types;
  41 use Koha::Patron::Attributes;
  42 use Koha::Patron::Images;
  43 use Koha::Patron::Modification;
  44 use Koha::Patron::Modifications;
  45 use Koha::Patrons;
  46 use Koha::Token;
  47
  48 my $cgi = new CGI;
  49 my $dbh = C4::Context->dbh;
  50
  51 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  52     {
  53         template_name   => "opac-memberentry.tt",
  54         type            => "opac",
  55         query           => $cgi,
  56         authnotrequired => 1,
  57     }
  58 );
  59
  60 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  61 {
  62     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  63     exit;
  64 }
  65
  66 my $action = $cgi->param('action') || q{};
  67 if ( $action eq q{} ) {
  68     if ($borrowernumber) {
  69         $action = 'edit';
  70     }
  71     else {
  72         $action = 'new';
  73     }
  74 }
  75
  76 my $mandatory = GetMandatoryFields($action);
  77
  78 my @libraries = Koha::Libraries->search;
  79 if ( my @libraries_to_display = split '\|', C4::Context->preference('PatronSelfRegistrationLibraryList') ) {
  80     @libraries = map { my $b = $_; my $branchcode = $_->branchcode; grep( /^$branchcode$/, @libraries_to_display ) ? $b : () } @libraries;
  81 }
  82 my ( $min, $max ) = C4::Members::get_cardnumber_length();
  83 if ( defined $min ) {
  84      $template->param(
  85          minlength_cardnumber => $min,
  86          maxlength_cardnumber => $max
  87      );
  88  }
  89
  90 $template->param(
  91     action            => $action,
  92     hidden            => GetHiddenFields( $mandatory, $action ),
  93     mandatory         => $mandatory,
  94     libraries         => \@libraries,
  95     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  96 );
  97
  98 my $attributes = ParsePatronAttributes($borrowernumber,$cgi);
  99 my $conflicting_attribute = 0;
 100
 101 foreach my $attr (@$attributes) {
 102     unless ( C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber) ) {
 103         my $attr_info = C4::Members::AttributeTypes->fetch($attr->{code});
 104         $template->param(
 105             extended_unique_id_failed_code => $attr->{code},
 106             extended_unique_id_failed_value => $attr->{value},
 107             extended_unique_id_failed_description => $attr_info->description()
 108         );
 109         $conflicting_attribute = 1;
 110     }
 111 }
 112
 113 if ( $action eq 'create' ) {
 114
 115     my %borrower = ParseCgiForBorrower($cgi);
 116
 117     %borrower = DelEmptyFields(%borrower);
 118
 119     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
 120     my $invalidformfields = CheckForInvalidFields(\%borrower);
 121     delete $borrower{'password2'};
 122     my $cardnumber_error_code;
 123     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
 124         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
 125         # spurious length warning.
 126         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
 127     }
 128
 129     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code || $conflicting_attribute ) {
 130         if ( $cardnumber_error_code == 1 ) {
 131             $template->param( cardnumber_already_exists => 1 );
 132         } elsif ( $cardnumber_error_code == 2 ) {
 133             $template->param( cardnumber_wrong_length => 1 );
 134         }
 135
 136         $template->param(
 137             empty_mandatory_fields => \@empty_mandatory_fields,
 138             invalid_form_fields    => $invalidformfields,
 139             borrower               => \%borrower
 140         );
 141         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 142     }
 143     elsif (
 144         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 145     {
 146         $template->param(
 147             failed_captcha => 1,
 148             borrower       => \%borrower
 149         );
 150         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 151     }
 152     else {
 153         if (
 154             C4::Context->boolean_preference(
 155                 'PatronSelfRegistrationVerifyByEmail')
 156           )
 157         {
 158             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 159                 {
 160                     template_name   => "opac-registration-email-sent.tt",
 161                     type            => "opac",
 162                     query           => $cgi,
 163                     authnotrequired => 1,
 164                 }
 165             );
 166             $template->param( 'email' => $borrower{'email'} );
 167
 168             my $verification_token = md5_hex( time().{}.rand().{}.$$ );
 169             while ( Koha::Patron::Modifications->search( { verification_token => $verification_token } )->count() ) {
 170                 $verification_token = md5_hex( time().{}.rand().{}.$$ );
 171             }
 172
 173             $borrower{password}          = Koha::AuthUtils::generate_password unless $borrower{password};
 174             $borrower{verification_token} = $verification_token;
 175
 176             Koha::Patron::Modification->new( \%borrower )->store();
 177
 178             #Send verification email
 179             my $letter = C4::Letters::GetPreparedLetter(
 180                 module      => 'members',
 181                 letter_code => 'OPAC_REG_VERIFY',
 182                 lang        => 'default', # Patron does not have a preferred language defined yet
 183                 tables      => {
 184                     borrower_modifications => $verification_token,
 185                 },
 186             );
 187
 188             C4::Letters::EnqueueLetter(
 189                 {
 190                     letter                 => $letter,
 191                     message_transport_type => 'email',
 192                     to_address             => $borrower{'email'},
 193                     from_address =>
 194                       C4::Context->preference('KohaAdminEmailAddress'),
 195                 }
 196             );
 197         }
 198         else {
 199             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 200                 {
 201                     template_name   => "opac-registration-confirmation.tt",
 202                     type            => "opac",
 203                     query           => $cgi,
 204                     authnotrequired => 1,
 205                 }
 206             );
 207
 208             $borrower{categorycode}     ||= C4::Context->preference('PatronSelfRegistrationDefaultCategory');
 209             $borrower{password}         ||= Koha::AuthUtils::generate_password;
 210             my $consent_dt = delete $borrower{gdpr_proc_consent};
 211             my $patron = Koha::Patron->new( \%borrower )->store;
 212             Koha::Patron::Consent->new({ borrowernumber => $patron->borrowernumber, type => 'GDPR_PROCESSING', given_on => $consent_dt })->store if $consent_dt;
 213             if ( $patron ) {
 214                 C4::Members::Attributes::SetBorrowerAttributes( $patron->borrowernumber, $attributes );
 215                 if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
 216                     C4::Form::MessagingPreferences::handle_form_action(
 217                         $cgi,
 218                         { borrowernumber => $patron->borrowernumber },
 219                         $template,
 220                         1,
 221                         C4::Context->preference('PatronSelfRegistrationDefaultCategory')
 222                     );
 223                 }
 224
 225                 $template->param( password_cleartext => $patron->plain_text_password );
 226                 $template->param( borrower => $patron->unblessed );
 227             } else {
 228                 # FIXME Handle possible errors here
 229             }
 230             $template->param(
 231                 PatronSelfRegistrationAdditionalInstructions =>
 232                   C4::Context->preference(
 233                     'PatronSelfRegistrationAdditionalInstructions')
 234             );
 235         }
 236     }
 237 }
 238 elsif ( $action eq 'update' ) {
 239
 240     my $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 241     die "Wrong CSRF token"
 242         unless Koha::Token->new->check_csrf({
 243             session_id => scalar $cgi->cookie('CGISESSID'),
 244             token  => scalar $cgi->param('csrf_token'),
 245         });
 246
 247     my %borrower = ParseCgiForBorrower($cgi);
 248     $borrower{borrowernumber} = $borrowernumber;
 249
 250     my %borrower_changes = DelEmptyFields(%borrower);
 251     my @empty_mandatory_fields =
 252       CheckMandatoryFields( \%borrower_changes, $action );
 253     my $invalidformfields = CheckForInvalidFields(\%borrower);
 254
 255     # Send back the data to the template
 256     %borrower = ( %$borrower, %borrower );
 257
 258     if (@empty_mandatory_fields || @$invalidformfields) {
 259         $template->param(
 260             empty_mandatory_fields => \@empty_mandatory_fields,
 261             invalid_form_fields    => $invalidformfields,
 262             borrower               => \%borrower,
 263             csrf_token             => Koha::Token->new->generate_csrf({
 264                 session_id => scalar $cgi->cookie('CGISESSID'),
 265             }),
 266         );
 267         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ) );
 268
 269         $template->param( action => 'edit' );
 270     }
 271     else {
 272         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 273         my $extended_attributes_changes = FilterUnchangedAttributes( $borrowernumber, $attributes );
 274
 275         if ( %borrower_changes || scalar @{$extended_attributes_changes} > 0 ) {
 276             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 277                 {
 278                     template_name   => "opac-memberentry-update-submitted.tt",
 279                     type            => "opac",
 280                     query           => $cgi,
 281                     authnotrequired => 1,
 282                 }
 283             );
 284
 285             $borrower_changes{borrowernumber} = $borrowernumber;
 286             $borrower_changes{extended_attributes} = to_json($extended_attributes_changes);
 287
 288             Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber })->delete;
 289
 290             my $m = Koha::Patron::Modification->new( \%borrower_changes )->store();
 291
 292             my $patron = Koha::Patrons->find( $borrowernumber );
 293             $template->param( borrower => $patron->unblessed );
 294         }
 295         else {
 296             my $patron = Koha::Patrons->find( $borrowernumber );
 297             $template->param(
 298                 action => 'edit',
 299                 nochanges => 1,
 300                 borrower => $patron->unblessed,
 301                 patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ),
 302                 csrf_token => Koha::Token->new->generate_csrf({
 303                     session_id => scalar $cgi->cookie('CGISESSID'),
 304                 }),
 305             );
 306         }
 307     }
 308 }
 309 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 310     my $patron = Koha::Patrons->find( $borrowernumber );
 311     my $borrower = $patron->unblessed;
 312
 313     $template->param(
 314         borrower  => $borrower,
 315         guarantor => scalar Koha::Patrons->find($borrowernumber)->guarantor(),
 316         hidden => GetHiddenFields( $mandatory, 'edit' ),
 317         csrf_token => Koha::Token->new->generate_csrf({
 318             session_id => scalar $cgi->cookie('CGISESSID'),
 319         }),
 320     );
 321
 322     if (C4::Context->preference('OPACpatronimages')) {
 323         $template->param( display_patron_image => 1 ) if $patron->image;
 324     }
 325
 326     $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber ) );
 327 } else {
 328     # Render self-registration page
 329     $template->param( patron_attribute_classes => GeneratePatronAttributesForm() );
 330 }
 331
 332 my $captcha = random_string("CCCCC");
 333
 334 $template->param(
 335     captcha        => $captcha,
 336     captcha_digest => md5_base64($captcha)
 337 );
 338
 339 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 340
 341 sub GetHiddenFields {
 342     my ( $mandatory, $action ) = @_;
 343     my %hidden_fields;
 344
 345     my $BorrowerUnwantedField = $action eq 'edit' || $action eq 'update' ?
 346       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 347       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 348
 349     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 350     foreach (@fields) {
 351         next unless m/\w/o;
 352         #Don't hide mandatory fields
 353         next if $mandatory->{$_};
 354         $hidden_fields{$_} = 1;
 355     }
 356
 357     return \%hidden_fields;
 358 }
 359
 360 sub GetMandatoryFields {
 361     my ($action) = @_;
 362
 363     my %mandatory_fields;
 364
 365     my $BorrowerMandatoryField =
 366       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 367
 368     my @fields = split( /\|/, $BorrowerMandatoryField );
 369
 370     foreach (@fields) {
 371         $mandatory_fields{$_} = 1;
 372     }
 373
 374     if ( $action eq 'create' || $action eq 'new' ) {
 375         $mandatory_fields{'email'} = 1
 376           if C4::Context->boolean_preference(
 377             'PatronSelfRegistrationVerifyByEmail');
 378     }
 379
 380     return \%mandatory_fields;
 381 }
 382
 383 sub CheckMandatoryFields {
 384     my ( $borrower, $action ) = @_;
 385
 386     my @empty_mandatory_fields;
 387
 388     my $mandatory_fields = GetMandatoryFields($action);
 389     delete $mandatory_fields->{'cardnumber'};
 390
 391     foreach my $key ( keys %$mandatory_fields ) {
 392         push( @empty_mandatory_fields, $key )
 393           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 394     }
 395
 396     return @empty_mandatory_fields;
 397 }
 398
 399 sub CheckForInvalidFields {
 400     my $borrower = shift;
 401     my @invalidFields;
 402     if ($borrower->{'email'}) {
 403         unless ( Email::Valid->address($borrower->{'email'}) ) {
 404             push(@invalidFields, "email");
 405         } elsif ( C4::Context->preference("PatronSelfRegistrationEmailMustBeUnique") ) {
 406             my $patrons_with_same_email = Koha::Patrons->search( # FIXME Should be search_limited?
 407                 {
 408                     email => $borrower->{email},
 409                     (
 410                         exists $borrower->{borrowernumber}
 411                         ? ( borrowernumber =>
 412                               { '!=' => $borrower->{borrowernumber} } )
 413                         : ()
 414                     )
 415                 }
 416             )->count;
 417             if ( $patrons_with_same_email ) {
 418                 push @invalidFields, "duplicate_email";
 419             }
 420         }
 421     }
 422     if ($borrower->{'emailpro'}) {
 423         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 424     }
 425     if ($borrower->{'B_email'}) {
 426         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 427     }
 428     if ( defined $borrower->{'password'}
 429         and $borrower->{'password'} ne $borrower->{'password2'} )
 430     {
 431         push( @invalidFields, "password_match" );
 432     }
 433     if ( $borrower->{'password'} ) {
 434         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $borrower->{password} );
 435           unless ( $is_valid ) {
 436               push @invalidFields, 'password_too_short' if $error eq 'too_short';
 437               push @invalidFields, 'password_too_weak' if $error eq 'too_weak';
 438               push @invalidFields, 'password_has_whitespaces' if $error eq 'has_whitespaces';
 439           }
 440     }
 441
 442     return \@invalidFields;
 443 }
 444
 445 sub ParseCgiForBorrower {
 446     my ($cgi) = @_;
 447
 448     my $scrubber = C4::Scrubber->new();
 449     my %borrower;
 450
 451     foreach my $field ( $cgi->param ) {
 452         if ( $field =~ '^borrower_' ) {
 453             my ($key) = substr( $field, 9 );
 454             if ( $field !~ '^borrower_password' ) {
 455                 $borrower{$key} = $scrubber->scrub( scalar $cgi->param($field) );
 456             } else {
 457                 # Allow html characters for passwords
 458                 $borrower{$key} = $cgi->param($field);
 459             }
 460         }
 461     }
 462
 463     my $dob_dt;
 464     $dob_dt = eval { dt_from_string( $borrower{'dateofbirth'} ); }
 465         if ( $borrower{'dateofbirth'} );
 466
 467     if ( $dob_dt ) {
 468         $borrower{'dateofbirth'} = output_pref ( { dt => $dob_dt, dateonly => 1, dateformat => 'iso' } );
 469     }
 470     else {
 471         # Trigger validation
 472         $borrower{'dateofbirth'} = undef;
 473     }
 474
 475     # Replace checkbox 'agreed' by datetime in gdpr_proc_consent
 476     $borrower{gdpr_proc_consent} = dt_from_string if  $borrower{gdpr_proc_consent} && $borrower{gdpr_proc_consent} eq 'agreed';
 477
 478     return %borrower;
 479 }
 480
 481 sub DelUnchangedFields {
 482     my ( $borrowernumber, %new_data ) = @_;
 483
 484     my $patron = Koha::Patrons->find( $borrowernumber );
 485     my $current_data = $patron->unblessed;
 486
 487     foreach my $key ( keys %new_data ) {
 488         if ( $current_data->{$key} eq $new_data{$key} ) {
 489             delete $new_data{$key};
 490         }
 491     }
 492
 493     return %new_data;
 494 }
 495
 496 sub DelEmptyFields {
 497     my (%borrower) = @_;
 498
 499     foreach my $key ( keys %borrower ) {
 500         delete $borrower{$key} unless $borrower{$key};
 501     }
 502
 503     return %borrower;
 504 }
 505
 506 sub FilterUnchangedAttributes {
 507     my ( $borrowernumber, $entered_attributes ) = @_;
 508
 509     my @patron_attributes = grep {$_->opac_editable} Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 510
 511     my $patron_attribute_types;
 512     foreach my $attr (@patron_attributes) {
 513         $patron_attribute_types->{ $attr->code } += 1;
 514     }
 515
 516     my $passed_attribute_types;
 517     foreach my $attr (@{ $entered_attributes }) {
 518         $passed_attribute_types->{ $attr->{ code } } += 1;
 519     }
 520
 521     my @changed_attributes;
 522
 523     # Loop through the current patron attributes
 524     foreach my $attribute_type ( keys %{ $patron_attribute_types } ) {
 525         if ( $patron_attribute_types->{ $attribute_type } !=  $passed_attribute_types->{ $attribute_type } ) {
 526             # count differs, overwrite all attributes for given type
 527             foreach my $attr (@{ $entered_attributes }) {
 528                 push @changed_attributes, $attr
 529                     if $attr->{ code } eq $attribute_type;
 530             }
 531         } else {
 532             # count matches, check values
 533             my $changes = 0;
 534             foreach my $attr (grep { $_->code eq $attribute_type } @patron_attributes) {
 535                 $changes = 1
 536                     unless any { $_->{ value } eq $attr->attribute } @{ $entered_attributes };
 537                 last if $changes;
 538             }
 539
 540             if ( $changes ) {
 541                 foreach my $attr (@{ $entered_attributes }) {
 542                     push @changed_attributes, $attr
 543                         if $attr->{ code } eq $attribute_type;
 544                 }
 545             }
 546         }
 547     }
 548
 549     # Loop through passed attributes, looking for new ones
 550     foreach my $attribute_type ( keys %{ $passed_attribute_types } ) {
 551         if ( !defined $patron_attribute_types->{ $attribute_type } ) {
 552             # YAY, new stuff
 553             foreach my $attr (grep { $_->{code} eq $attribute_type } @{ $entered_attributes }) {
 554                 push @changed_attributes, $attr;
 555             }
 556         }
 557     }
 558
 559     return \@changed_attributes;
 560 }
 561
 562 sub GeneratePatronAttributesForm {
 563     my ( $borrowernumber, $entered_attributes ) = @_;
 564
 565     # Get all attribute types and the values for this patron (if applicable)
 566     my @types = grep { $_->opac_editable() or $_->opac_display }
 567         Koha::Patron::Attribute::Types->search()->as_list();
 568     if ( scalar(@types) == 0 ) {
 569         return [];
 570     }
 571
 572     my @displayable_attributes = grep { $_->opac_display }
 573         Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 574
 575     my %attr_values = ();
 576
 577     # Build the attribute values list either from the passed values
 578     # or taken from the patron itself
 579     if ( defined $entered_attributes ) {
 580         foreach my $attr (@$entered_attributes) {
 581             push @{ $attr_values{ $attr->{code} } }, $attr->{value};
 582         }
 583     }
 584     elsif ( defined $borrowernumber ) {
 585         my @editable_attributes = grep { $_->opac_editable } @displayable_attributes;
 586         foreach my $attr (@editable_attributes) {
 587             push @{ $attr_values{ $attr->code } }, $attr->attribute;
 588         }
 589     }
 590
 591     # Add the non-editable attributes (that don't come from the form)
 592     foreach my $attr ( grep { !$_->opac_editable } @displayable_attributes ) {
 593         push @{ $attr_values{ $attr->code } }, $attr->attribute;
 594     }
 595
 596     # Find all existing classes
 597     my @classes = sort( uniq( map { $_->class } @types ) );
 598     my %items_by_class;
 599
 600     foreach my $attr_type (@types) {
 601         push @{ $items_by_class{ $attr_type->class() } }, {
 602             type => $attr_type,
 603             # If editable, make sure there's at least one empty entry,
 604             # to make the template's job easier
 605             values => $attr_values{ $attr_type->code() } || ['']
 606         }
 607             unless !defined $attr_values{ $attr_type->code() }
 608                     and !$attr_type->opac_editable;
 609     }
 610
 611     # Finally, build a list of containing classes
 612     my @class_loop;
 613     foreach my $class (@classes) {
 614         next unless ( $items_by_class{$class} );
 615
 616         my $av = Koha::AuthorisedValues->search(
 617             { category => 'PA_CLASS', authorised_value => $class } );
 618
 619         my $lib = $av->count ? $av->next->opac_description : $class;
 620
 621         push @class_loop,
 622             {
 623             class => $class,
 624             items => $items_by_class{$class},
 625             lib   => $lib,
 626             };
 627     }
 628
 629     return \@class_loop;
 630 }
 631
 632 sub ParsePatronAttributes {
 633     my ( $borrowernumber, $cgi ) = @_;
 634
 635     my @codes  = $cgi->multi_param('patron_attribute_code');
 636     my @values = $cgi->multi_param('patron_attribute_value');
 637
 638     my @editable_attribute_types
 639         = map { $_->code } Koha::Patron::Attribute::Types->search({ opac_editable => 1 });
 640
 641     my $ea = each_array( @codes, @values );
 642     my @attributes;
 643
 644     my $delete_candidates = {};
 645
 646     while ( my ( $code, $value ) = $ea->() ) {
 647         if ( any { $_ eq $code } @editable_attribute_types ) {
 648             # It is an editable attribute
 649             if ( !defined($value) or $value eq '' ) {
 650                 $delete_candidates->{$code} = 1
 651                     unless $delete_candidates->{$code};
 652             }
 653             else {
 654                 # we've got a value
 655                 push @attributes, { code => $code, value => $value };
 656
 657                 # 'code' is no longer a delete candidate
 658                 delete $delete_candidates->{$code}
 659                     if defined $delete_candidates->{$code};
 660             }
 661         }
 662     }
 663
 664     foreach my $code ( keys %{$delete_candidates} ) {
 665         if ( Koha::Patron::Attributes->search({
 666                 borrowernumber => $borrowernumber, code => $code })->count > 0 )
 667         {
 668             push @attributes, { code => $code, value => '' }
 669                 unless any { $_->{code} eq $code } @attributes;
 670         }
 671     }
 672
 673     return \@attributes;
 674 }
 675
 676
 677 1;