misc/export_records.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use MARC::File::XML;
  21 use List::MoreUtils qw(uniq);
  22 use Getopt::Long;
  23 use Pod::Usage;
  24
  25 use Koha::Script;
  26 use C4::Auth;
  27 use C4::Context;
  28 use C4::Record;
  29
  30 use Koha::Biblioitems;
  31 use Koha::Database;
  32 use Koha::CsvProfiles;
  33 use Koha::Exporter::Record;
  34 use Koha::DateUtils qw( dt_from_string output_pref );
  35
  36 my (
  37     $output_format,
  38     $timestamp,
  39     $dont_export_items,
  40     $csv_profile_id,
  41     $deleted_barcodes,
  42     $clean,
  43     $filename,
  44     $record_type,
  45     $id_list_file,
  46     $starting_authid,
  47     $ending_authid,
  48     $authtype,
  49     $starting_biblionumber,
  50     $ending_biblionumber,
  51     $itemtype,
  52     $starting_callnumber,
  53     $ending_callnumber,
  54     $start_accession,
  55     $end_accession,
  56     $marc_conditions,
  57     $help
  58 );
  59
  60 GetOptions(
  61     'format=s'                => \$output_format,
  62     'date=s'                  => \$timestamp,
  63     'dont_export_items'       => \$dont_export_items,
  64     'csv_profile_id=s'        => \$csv_profile_id,
  65     'deleted_barcodes'        => \$deleted_barcodes,
  66     'clean'                   => \$clean,
  67     'filename=s'              => \$filename,
  68     'record-type=s'           => \$record_type,
  69     'id_list_file=s'          => \$id_list_file,
  70     'starting_authid=s'       => \$starting_authid,
  71     'ending_authid=s'         => \$ending_authid,
  72     'authtype=s'              => \$authtype,
  73     'starting_biblionumber=s' => \$starting_biblionumber,
  74     'ending_biblionumber=s'   => \$ending_biblionumber,
  75     'itemtype=s'              => \$itemtype,
  76     'starting_callnumber=s'   => \$starting_callnumber,
  77     'ending_callnumber=s'     => \$ending_callnumber,
  78     'start_accession=s'       => \$start_accession,
  79     'end_accession=s'         => \$end_accession,
  80     'marc_conditions=s'       => \$marc_conditions,
  81     'h|help|?'                => \$help
  82 ) || pod2usage(1);
  83
  84 if ($help) {
  85     pod2usage(1);
  86 }
  87
  88 $filename ||= 'koha.mrc';
  89 $output_format ||= 'iso2709';
  90 $record_type ||= 'bibs';
  91
  92 # Retrocompatibility for the format parameter
  93 $output_format = 'iso2709' if $output_format eq 'marc';
  94
  95 if ( $output_format eq 'csv' and $record_type eq 'auths' ) {
  96     pod2usage(q|CSV output is only available for biblio records|);
  97 }
  98
  99 if ( $output_format eq 'csv' and not $csv_profile_id ) {
 100     pod2usage(q|Define a csv profile to export in CSV|);
 101 }
 102
 103 if ( $timestamp and $record_type ne 'bibs' ) {
 104     pod2usage(q|--timestamp can only be used with biblios|);
 105 }
 106
 107 if ( $record_type ne 'bibs' and $record_type ne 'auths' ) {
 108     pod2usage(q|--record_type is not valid|);
 109 }
 110
 111 if ( $deleted_barcodes and $record_type ne 'bibs' ) {
 112     pod2usage(q|--deleted_barcodes can only be used with biblios|);
 113 }
 114
 115 $start_accession = dt_from_string( $start_accession ) if $start_accession;
 116 $end_accession   = dt_from_string( $end_accession )   if $end_accession;
 117
 118 # Parse marc conditions
 119 my @marc_conditions;
 120 if ($marc_conditions) {
 121     foreach my $condition (split(/,\s*/, $marc_conditions)) {
 122         if ($condition =~ /^(\d{3})([\w\d]?)(=|(?:!=)|>|<)([^,]+)$/) {
 123             push @marc_conditions, [$1, $2, $3, $4];
 124         }
 125         elsif ($condition =~ /^(exists|not_exists)\((\d{3})([\w\d]?)\)$/) {
 126             push @marc_conditions, [$2, $3, $1 eq 'exists' ? '?' : '!?'];
 127         }
 128         else {
 129             die("Invalid condititon: $condition");
 130         }
 131     }
 132 }
 133
 134 my $dbh = C4::Context->dbh;
 135
 136 # Redirect stdout
 137 open STDOUT, '>', $filename if $filename;
 138
 139
 140 my @record_ids;
 141
 142 $timestamp = ($timestamp) ? output_pref({ dt => dt_from_string($timestamp), dateformat => 'iso', dateonly => 0, }): '';
 143
 144 if ( $record_type eq 'bibs' ) {
 145     if ( $timestamp ) {
 146         push @record_ids, $_->{biblionumber} for @{
 147             $dbh->selectall_arrayref(q| (
 148                 SELECT biblio_metadata.biblionumber
 149                 FROM biblio_metadata
 150                   LEFT JOIN items USING(biblionumber)
 151                 WHERE biblio_metadata.timestamp >= ?
 152                   OR items.timestamp >= ?
 153             ) UNION (
 154                 SELECT biblio_metadata.biblionumber
 155                 FROM biblio_metadata
 156                   LEFT JOIN deleteditems USING(biblionumber)
 157                 WHERE biblio_metadata.timestamp >= ?
 158                   OR deleteditems.timestamp >= ?
 159             ) |, { Slice => {} }, ( $timestamp ) x 4 );
 160         };
 161     } else {
 162         my $conditions = {
 163             ( $starting_biblionumber or $ending_biblionumber )
 164                 ? (
 165                     "me.biblionumber" => {
 166                         ( $starting_biblionumber ? ( '>=' => $starting_biblionumber ) : () ),
 167                         ( $ending_biblionumber   ? ( '<=' => $ending_biblionumber   ) : () ),
 168                     }
 169                 )
 170                 : (),
 171             ( $starting_callnumber or $ending_callnumber )
 172                 ? (
 173                     callnumber => {
 174                         ( $starting_callnumber ? ( '>=' => $starting_callnumber ) : () ),
 175                         ( $ending_callnumber   ? ( '<=' => $ending_callnumber   ) : () ),
 176                     }
 177                 )
 178                 : (),
 179             ( $start_accession or $end_accession )
 180                 ? (
 181                     dateaccessioned => {
 182                         ( $start_accession ? ( '>=' => $start_accession ) : () ),
 183                         ( $end_accession   ? ( '<=' => $end_accession   ) : () ),
 184                     }
 185                 )
 186                 : (),
 187             ( $itemtype
 188                 ?
 189                   C4::Context->preference('item-level_itypes')
 190                     ? ( 'items.itype' => $itemtype )
 191                     : ( 'me.itemtype' => $itemtype )
 192                 : ()
 193             ),
 194
 195         };
 196         my $biblioitems = Koha::Biblioitems->search( $conditions, { join => 'items' } );
 197         while ( my $biblioitem = $biblioitems->next ) {
 198             push @record_ids, $biblioitem->biblionumber;
 199         }
 200     }
 201 }
 202 elsif ( $record_type eq 'auths' ) {
 203     my $conditions = {
 204         ( $starting_authid or $ending_authid )
 205             ? (
 206                 authid => {
 207                     ( $starting_authid ? ( '>=' => $starting_authid ) : () ),
 208                     ( $ending_authid   ? ( '<=' => $ending_authid   ) : () ),
 209                 }
 210             )
 211             : (),
 212         ( $authtype ? ( authtypecode => $authtype ) : () ),
 213     };
 214     # Koha::MetadataRecord::Authority is not a Koha::Object...
 215     my $authorities = Koha::Database->new->schema->resultset('AuthHeader')->search( $conditions );
 216     @record_ids = map { $_->authid } $authorities->all;
 217 }
 218
 219 @record_ids = uniq @record_ids;
 220 if ( @record_ids and $id_list_file ) {
 221     open my $fh, '<', $id_list_file or die "Cannot open file $id_list_file ($!)";
 222     my @filter_record_ids = <$fh>;
 223     @filter_record_ids = map { my $id = $_; $id =~ s/[\r\n]*$//; $id } @filter_record_ids;
 224     # intersection
 225     my %record_ids = map { $_ => 1 } @record_ids;
 226     @record_ids = grep $record_ids{$_}, @filter_record_ids;
 227 }
 228
 229 if ($deleted_barcodes) {
 230     for my $record_id ( @record_ids ) {
 231         my $barcode = $dbh->selectall_arrayref(q|
 232             SELECT DISTINCT barcode
 233             FROM deleteditems
 234             WHERE deleteditems.biblionumber = ?
 235         |, { Slice => {} }, $record_id );
 236         say $_->{barcode} for @$barcode;
 237     }
 238 }
 239 else {
 240     Koha::Exporter::Record::export(
 241         {   record_type        => $record_type,
 242             record_ids         => \@record_ids,
 243             record_conditions  => @marc_conditions ? \@marc_conditions : undef,
 244             format             => $output_format,
 245             csv_profile_id     => $csv_profile_id,
 246             export_items       => (not $dont_export_items),
 247             clean              => $clean || 0,
 248         }
 249     );
 250 }
 251 exit;
 252
 253
 254 =head1 NAME
 255
 256 export records - This script exports record (biblios or authorities)
 257
 258 =head1 SYNOPSIS
 259
 260 export_records.pl [-h|--help] [--format=format] [--date=datetime] [--record-type=TYPE] [--dont_export_items] [--deleted_barcodes] [--clean] [--id_list_file=PATH] --filename=outputfile
 261
 262 =head1 OPTIONS
 263
 264 =over
 265
 266 =item B<-h|--help>
 267
 268 Print a brief help message.
 269
 270 =item B<--format>
 271
 272  --format=FORMAT        FORMAT is either 'xml', 'csv' (biblio records only) or 'marc' (default).
 273
 274 =item B<--date>
 275
 276  --date=DATETIME        DATETIME should be entered as the 'dateformat' syspref is
 277                         set (dd/mm/yyyy[ hh:mm:ss] for metric, yyyy-mm-dd[ hh:mm:ss] for iso,
 278                         mm/dd/yyyy[ hh:mm:ss] for us) records exported are the ones that
 279                         have been modified since DATETIME.
 280
 281 =item B<--record-type>
 282
 283  --record-type=TYPE     TYPE is 'bibs' or 'auths'.
 284
 285 =item B<--dont_export_items>
 286
 287  --dont_export_items    If enabled, the item infos won't be exported.
 288
 289 =item B<--csv_profile_id>
 290
 291  --csv_profile_id=ID    Generate a CSV file with the given CSV profile id (see tools/csv-profiles.pl)
 292                         This can only be used to export biblio records.
 293
 294 =item B<--deleted_barcodes>
 295
 296  --deleted_barcodes     If used, a list of barcodes of items deleted since DATE
 297                         is produced (or from all deleted items if no date is
 298                         specified). Used only if TYPE is 'bibs'.
 299
 300 =item B<--clean>
 301
 302  --clean                removes NSE/NSB.
 303
 304 =item B<--id_list_file>
 305
 306  --id_list_file=PATH    PATH is a path to a file containing a list of
 307                         IDs (biblionumber or authid) with one ID per line.
 308                         This list works as a filter; it is compatible with
 309                         other parameters for selecting records.
 310
 311 =item B<--filename>
 312
 313  --filename=FILENAME   FILENAME used to export the data.
 314
 315 =item B<--starting_authid>
 316
 317  --starting_authid=ID  Export authorities with authid >= ID
 318
 319 =item B<--ending_authid>
 320
 321  --ending_authid=ID    Export authorities with authid <= ID
 322
 323 =item B<--authtype>
 324
 325  --authtype=AUTHTYPE   Export authorities from the given AUTHTYPE
 326
 327 =item B<--starting_biblionumber>
 328
 329  --starting_biblionumber=ID  Export biblio with biblionumber >= ID
 330
 331 =item B<--ending_biblionumber>
 332
 333  --ending_biblionumber=ID    Export biblio with biblionumber <= ID
 334
 335 =item B<--itemtype>
 336
 337  --itemtype=ITEMTYPE         Export biblio from the given ITEMTYPE
 338
 339 =item B<--starting_callnumber>
 340
 341  --starting_callnumber=CALLNUMBER Export biblio with callnumber >=CALLNUMBER
 342
 343 =item B<--ending_callnumber>
 344
 345  --ending_callnumber=CALLNUMBER Export biblio with callnumber <=CALLNUMBER
 346
 347 =item B<--start_accession>
 348
 349  --starting_accession=DATE      Export biblio with an item accessionned after DATE
 350
 351 =item B<--end_accession>
 352
 353  --end_accession=DATE           Export biblio with an item accessionned after DATE
 354
 355 =item B<--marc_conditions>
 356
 357  --marc_conditions=CONDITIONS   Only include biblios with MARC data matching CONDITIONS.
 358                                 CONDITIONS is on the format: <marc_target><binary_operator><value>,
 359                                 or <unary_operation>(<marc_target>).
 360                                 with multiple conditions separated by commas (,).
 361                                 For example: --marc_conditions="035a!=(EXAMPLE)123,041a=swe".
 362                                 Multiple conditions are all required to match.
 363                                 If <marc_target> has multiple values all values
 364                                 are also required to match.
 365                                 Valid operators are: = (equal to), != (not equal to),
 366                                 > (great than) and < (less than).
 367
 368                                 Two unary operations are also supported:
 369                                 exists(<marc_target>) and not_exists(<marc_target>).
 370                                 For example: --marc_conditions="exists(035a)".
 371
 372                                 "exists(<marc_target)" will include marc records where
 373                                 <marc_target> exists regardless of target value, and
 374                                 "exists(<marc_target>)" will include marc records where
 375                                 no <marc_target> exists.
 376
 377 =back
 378
 379 =head1 AUTHOR
 380
 381 Koha Development Team
 382
 383 =head1 COPYRIGHT
 384
 385 Copyright Koha Team
 386
 387 =head1 LICENSE
 388
 389 This file is part of Koha.
 390
 391 Koha is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software
 392 Foundation; either version 3 of the License, or (at your option) any later version.
 393
 394 You should have received a copy of the GNU General Public License along
 395 with Koha; if not, write to the Free Software Foundation, Inc.,
 396 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
 397
 398 =cut