misc/add_date_fields_to_marc_records.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 BEGIN {
  21     use FindBin;
  22     eval { require "$FindBin::Bin/../kohalib.pl" };
  23 }
  24
  25 use Getopt::Long;
  26 use Pod::Usage;
  27 use MARC::Field;
  28
  29 use C4::Biblio;
  30 use Koha::DateUtils qw( dt_from_string );
  31
  32 my ( $verbose, $help, $confirm, $where, @fields, $unless_exists_field );
  33 my $dbh = C4::Context->dbh;
  34
  35 GetOptions(
  36     'help|h'    => \$help,
  37     'verbose|v' => \$verbose,
  38     'confirm|c' => \$confirm,
  39     'where=s'   => \$where,
  40     'field=s@'  => \@fields,
  41     'unless-exists=s' => \$unless_exists_field,
  42 ) || podusage(1);
  43
  44 pod2usage(1) if $help;
  45 pod2usage("Parameter field is mandatory") unless @fields;
  46
  47 my @fields_to_add;
  48 my $dt = dt_from_string;    # Could be an option of the script
  49 for my $field (@fields) {
  50     my ( $f_sf, $value )    = split '=',  $field;
  51     my ( $tag,  $subfield ) = split '\$', $f_sf;
  52     push @fields_to_add,
  53       MARC::Field->new( $tag, '', '', $subfield => $dt->strftime($value) );
  54 }
  55
  56 say "Confirm flag not passed, running in dry-run mode..." unless $confirm;
  57 if ($verbose) {
  58     say "The following MARC fields will be added:";
  59     say "\t" . $_->as_formatted for @fields_to_add;
  60 }
  61
  62 $where = $where ? "WHERE $where" : '';
  63 my $sth =
  64   $dbh->prepare("SELECT biblionumber, frameworkcode FROM biblio $where");
  65 $sth->execute();
  66
  67 while ( my ( $biblionumber, $frameworkcode ) = $sth->fetchrow_array ) {
  68     my $marc_record =
  69       C4::Biblio::GetMarcBiblio( { biblionumber => $biblionumber } );
  70     next unless $marc_record;
  71     if ( $unless_exists_field ) {
  72         my ( $tag,  $subfield ) = split '\$', $unless_exists_field;
  73         next if $marc_record->subfield($tag, $subfield);
  74     }
  75     $marc_record->append_fields(@fields_to_add);
  76     if ($confirm) {
  77         my $modified =
  78           C4::Biblio::ModBiblio( $marc_record, $biblionumber, $frameworkcode );
  79         say "Bibliographic record $biblionumber has been modified"
  80           if $verbose and $modified;
  81     }
  82     elsif ($verbose) {
  83         say "Bibliographic record $biblionumber would have been modified";
  84     }
  85 }
  86
  87 =head1 NAME
  88
  89 add_date_fields_to_marc_records.pl
  90
  91 =head1 SYNOPSIS
  92
  93   perl add_date_fields_to_marc_records.pl --help
  94
  95   perl add_date_fields_to_marc_records.pl --field='905$a=0/%Y' --field='905$a=1/%Y/%b-%m' --field='905$a=2/%Y/%b-%m/%d' --unless-exists='905$a' --verbose --confirm
  96
  97   perl add_date_fields_to_marc_records.pl --field='905$a=0/%Y' --field='905$a=1/%Y/%b-%m' --field='905$a=2/%Y/%b-%m/%d' --unless-exists='905$a' --where "biblionumber=42" --verbose --confirm
  98
  99 =head1 DESCRIPTION
 100
 101 Add some MARC fields to bibliographic records.
 102
 103 The replacement tokens are the ones used by strftime.
 104
 105 =head1 OPTIONS
 106
 107 =over 8
 108
 109 =item B<--help>
 110
 111 Prints this help
 112
 113 =item B<--verbose>
 114
 115 Verbose mode.
 116
 117 =item B<--confirm>
 118
 119 Confirmation flag, the script will be running in dry-run mode if set not.
 120
 121 =item B<--where>
 122
 123 Limits the search on bibliographic records with a user-specified WHERE clause.
 124
 125 Only the columns from the biblio table are available.
 126
 127 =item B<--field>
 128
 129 Fields to add to the bibliographic records.
 130
 131 Must be formatted as 'tag' $ 'subfield' = 'value'
 132
 133 For instance:
 134
 135 905$a=0/%Y will add a new field 905$a with the value '0/2019' (if run in 2019)
 136
 137 905$a=2/%Y/%b-%m/%d'will a a new field 905$a with the value '2/2019/Mar-03/13' if run on March 13th 2019
 138
 139 =item B<--unless-exists>
 140
 141 Will only create the new fields if this field does not exist
 142
 143 =back
 144
 145 =cut