Koha/UploadedFile.pm

   1 package Koha::UploadedFile;
   2
   3 # Copyright Rijksmuseum 2016
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21 use File::Spec;
  22
  23 use parent qw(Koha::Object);
  24
  25 =head1 NAME
  26
  27 Koha::UploadedFile - Koha::Object class for single uploaded file
  28
  29 =head1 SYNOPSIS
  30
  31     use Koha::UploadedFile;
  32
  33     # store record in uploaded_files
  34     my $upload = Koha::UploadedFile->new({ [columns and values] });
  35
  36     # get a file handle on an uploaded_file
  37     my $fh = $upload->file_handle;
  38
  39     # get full path
  40     my $path = $upload->full_path;
  41
  42     # delete uploaded file
  43     $upload->delete;
  44
  45 =head1 DESCRIPTION
  46
  47 Allows regular CRUD operations on uploaded_files via Koha::Object / DBIx.
  48
  49 The delete method also takes care of deleting files. The full_path method
  50 returns a fully qualified path for an upload.
  51
  52 Additional methods include: file_handle, httpheaders.
  53
  54 =head1 METHODS
  55
  56 =head2 INSTANCE METHODS
  57
  58 =head3 delete
  59
  60 Delete uploaded file.
  61 It deletes not only the record, but also the actual file (unless you pass
  62 the keep_file parameter).
  63
  64 Returns number of deleted records (1 or 0E0), or -1 for unknown.
  65 Please keep in mind that a deleted record does not automatically imply a
  66 deleted file; a warning may have been raised.
  67 (TODO: Use exceptions.)
  68
  69 =cut
  70
  71 sub delete {
  72     my ( $self, $params ) = @_;
  73
  74     my $name = $self->filename;
  75     my $file = $self->full_path;
  76
  77     my $retval = $self->SUPER::delete;
  78     if( !defined($retval) ) { # undef is Unknown (-1)
  79         $retval = -1;
  80     } elsif( $retval eq '0' ) { # 0 => 0E0
  81         $retval = "0E0";
  82     } elsif( $retval !~ /^(0E0|1)$/ ) { # Unknown too
  83         $retval = -1;
  84     }
  85     return $retval if $params->{keep_file};
  86
  87     if( ! -e $file ) {
  88         warn "Removing record for $name within category ".
  89             $self->uploadcategorycode. ", but file was missing.";
  90     } elsif( ! unlink($file) ) {
  91         warn "Problem while deleting: $file";
  92     }
  93     return $retval;
  94 }
  95
  96 =head3 full_path
  97
  98 Returns the fully qualified path name for an uploaded file.
  99
 100 =cut
 101
 102 sub full_path {
 103     my ( $self ) = @_;
 104     my $path = File::Spec->catfile(
 105         $self->permanent
 106             ? $self->permanent_directory
 107             : C4::Context->temporary_directory,
 108         $self->dir,
 109         $self->hashvalue. '_'. $self->filename,
 110     );
 111     return $path;
 112 }
 113
 114 =head3 file_handle
 115
 116 Returns a file handle for an uploaded file.
 117
 118 =cut
 119
 120 sub file_handle {
 121     my ( $self ) = @_;
 122     $self->{_file_handle} = IO::File->new( $self->full_path, "r" );
 123     return if !$self->{_file_handle};
 124     $self->{_file_handle}->binmode;
 125     return $self->{_file_handle};
 126 }
 127
 128 =head3 httpheaders
 129
 130 httpheaders returns http headers for a retrievable upload.
 131
 132 Will be extended by report 14282
 133
 134 =cut
 135
 136 sub httpheaders {
 137     my ( $self ) = @_;
 138     if( $self->filename =~ /\.pdf$/ ) {
 139         return (
 140             '-type'       => 'application/pdf',
 141             'Content-Disposition' => 'inline; filename='.$self->filename,
 142         );
 143     } else {
 144         return (
 145             '-type'       => 'application/octet-stream',
 146             '-attachment' => $self->filename,
 147         );
 148     }
 149 }
 150
 151 =head2 CLASS METHODS
 152
 153 =head3 permanent_directory
 154
 155 Returns root directory for permanent storage
 156
 157 =cut
 158
 159 sub permanent_directory {
 160     my ( $class ) = @_;
 161     return C4::Context->config('upload_path');
 162 }
 163
 164 =head3 _type
 165
 166 Returns name of corresponding DBIC resultset
 167
 168 =cut
 169
 170 sub _type {
 171     return 'UploadedFile';
 172 }
 173
 174 =head1 AUTHOR
 175
 176 Marcel de Rooy (Rijksmuseum)
 177
 178 Koha Development Team
 179
 180 =cut
 181
 182 1;