Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  17 # Suite 330, Boston, MA  02111-1307 USA
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (qw( dt_from_string output_pref));
  30
  31 =head1 DateUtils
  32
  33 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  34
  35 =head1 DESCRIPTION
  36
  37 Koha has historically only used dates not datetimes and been content to
  38 handle these as strings. It also has confused formatting with actual dates
  39 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  40
  41 =cut
  42
  43 =head2 dt_ftom_string
  44
  45 $dt = dt_from_string($date_string, [$format, $timezone ]);
  46
  47 Passed a date string returns a DateTime object format and timezone default
  48 to the system preferences. If the date string is empty DateTime->now is returned
  49
  50 =cut
  51
  52 sub dt_from_string {
  53     my ( $date_string, $date_format, $tz ) = @_;
  54     if ( !$tz ) {
  55         $tz = C4::Context->tz;
  56     }
  57     if ( !$date_format ) {
  58         $date_format = C4::Context->preference('dateformat');
  59     }
  60     if ($date_string) {
  61         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  62             return $date_string;
  63         }
  64
  65         if ( $date_format eq 'metric' ) {
  66             $date_string =~ s#-#/#g;
  67             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  68             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  69         } else {
  70             if ( $date_format eq 'iso' ) {
  71                 $date_string =~ s/-00/-01/;
  72                 if ( $date_string =~ m/^0000-00/ ) {
  73                     return;               # invalid date in db
  74                 }
  75             } elsif ( $date_format eq 'us' ) {
  76                 $date_string =~ s[-00-][-01-];
  77             } elsif ( $date_format eq 'sql' ) {
  78                 $date_string =~
  79 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  80                 $date_string =~ s/00T/01T/;
  81             }
  82         }
  83         return DateTime::Format::DateParse->parse_datetime( $date_string,
  84             $tz->name() );
  85     }
  86     return DateTime->now( time_zone => $tz );
  87
  88 }
  89
  90 =head2 output_pref
  91
  92 $date_string = output_pref($dt, [$format] );
  93
  94 Returns a string containing the time & date formatted as per the C4::Context setting
  95
  96 A second parameter allows overriding of the syspref value. This is for testing only
  97 In usage use the DateTime objects own methods for non standard formatting
  98
  99 =cut
 100
 101 sub output_pref {
 102     my $dt         = shift;
 103     my $force_pref = shift;    # if testing we want to override Context
 104     my $pref =
 105       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 106     given ($pref) {
 107         when (/^iso/) {
 108             return $dt->strftime('%Y-%m-%d %H:%M');
 109         }
 110         when (/^metric/) {
 111             return $dt->strftime('%d/%m/%Y %H:%M');
 112         }
 113         when (/^us/) {
 114             return $dt->strftime('%m/%d/%Y %H:%M');
 115         }
 116         default {
 117             return $dt->strftime('%Y-%m-%d %H:%M');
 118         }
 119
 120     }
 121     return;
 122 }
 123
 124 1;