C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio;
  28 use C4::Circulation;
  29 use C4::Context;
  30 use C4::Items;
  31 use C4::Letters;
  32 use C4::Log;
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::Biblios;
  37 use Koha::Calendar;
  38 use Koha::CirculationRules;
  39 use Koha::Database;
  40 use Koha::DateUtils;
  41 use Koha::Hold;
  42 use Koha::Holds;
  43 use Koha::ItemTypes;
  44 use Koha::Items;
  45 use Koha::Libraries;
  46 use Koha::Old::Hold;
  47 use Koha::Patrons;
  48
  49 use Carp;
  50 use Data::Dumper;
  51 use List::MoreUtils qw( firstidx any );
  52
  53 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  54
  55 =head1 NAME
  56
  57 C4::Reserves - Koha functions for dealing with reservation.
  58
  59 =head1 SYNOPSIS
  60
  61   use C4::Reserves;
  62
  63 =head1 DESCRIPTION
  64
  65 This modules provides somes functions to deal with reservations.
  66
  67   Reserves are stored in reserves table.
  68   The following columns contains important values :
  69   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  70              =0      : then the reserve is being dealed
  71   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  72             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  73             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  74             F(inished) : the reserve has been completed, and is done
  75   - itemnumber : empty : the reserve is still unaffected to an item
  76                  filled: the reserve is attached to an item
  77   The complete workflow is :
  78   ==== 1st use case ====
  79   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  80   a library having it run "transfertodo", and clic on the list
  81          if there is no transfer to do, the reserve waiting
  82          patron can pick it up                                    P =0, F=W,    I=filled
  83          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  84            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  85   The patron borrow the book                                      P =0, F=F,    I=filled
  86
  87   ==== 2nd use case ====
  88   patron requests a document, a given item,
  89     If pickup is holding branch                                   P =0, F=W,   I=filled
  90     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  91         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  92   The patron borrow the book                                      P =0, F=F,    I=filled
  93
  94 =head1 FUNCTIONS
  95
  96 =cut
  97
  98 BEGIN {
  99     require Exporter;
 100     @ISA = qw(Exporter);
 101     @EXPORT = qw(
 102         &AddReserve
 103
 104         &GetReserveStatus
 105
 106         &GetOtherReserves
 107
 108         &ModReserveFill
 109         &ModReserveAffect
 110         &ModReserve
 111         &ModReserveStatus
 112         &ModReserveCancelAll
 113         &ModReserveMinusPriority
 114         &MoveReserve
 115
 116         &CheckReserves
 117         &CanBookBeReserved
 118         &CanItemBeReserved
 119         &CanReserveBeCanceledFromOpac
 120         &CancelExpiredReserves
 121
 122         &AutoUnsuspendReserves
 123
 124         &IsAvailableForItemLevelRequest
 125         ItemsAnyAvailableForHold
 126
 127         &AlterPriority
 128         &ToggleLowestPriority
 129
 130         &ReserveSlip
 131         &ToggleSuspend
 132         &SuspendAll
 133
 134         &GetReservesControlBranch
 135
 136         IsItemOnHoldAndFound
 137
 138         GetMaxPatronHoldsForRecord
 139     );
 140     @EXPORT_OK = qw( MergeHolds );
 141 }
 142
 143 =head2 AddReserve
 144
 145     AddReserve(
 146         {
 147             branch           => $branchcode,
 148             borrowernumber   => $borrowernumber,
 149             biblionumber     => $biblionumber,
 150             priority         => $priority,
 151             reservation_date => $reservation_date,
 152             expiration_date  => $expiration_date,
 153             notes            => $notes,
 154             title            => $title,
 155             itemnumber       => $itemnumber,
 156             found            => $found,
 157             itemtype         => $itemtype,
 158         }
 159     );
 160
 161 Adds reserve and generates HOLDPLACED message.
 162
 163 The following tables are available witin the HOLDPLACED message:
 164
 165     branches
 166     borrowers
 167     biblio
 168     biblioitems
 169     items
 170     reserves
 171
 172 =cut
 173
 174 sub AddReserve {
 175     my ($params)       = @_;
 176     my $branch         = $params->{branchcode};
 177     my $borrowernumber = $params->{borrowernumber};
 178     my $biblionumber   = $params->{biblionumber};
 179     my $priority       = $params->{priority};
 180     my $resdate        = $params->{reservation_date};
 181     my $expdate        = $params->{expiration_date};
 182     my $notes          = $params->{notes};
 183     my $title          = $params->{title};
 184     my $checkitem      = $params->{itemnumber};
 185     my $found          = $params->{found};
 186     my $itemtype       = $params->{itemtype};
 187
 188     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 189         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 190
 191     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 192
 193     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 194     # of the document, we force the value $priority and $found .
 195     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 196         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 197
 198         if (
 199             # If item is already checked out, it cannot be set waiting
 200             !$item->onloan
 201
 202             # The item can't be waiting if it needs a transfer
 203             && $item->holdingbranch eq $branch
 204
 205             # Similarly, if in transit it can't be waiting
 206             && !$item->get_transfer
 207
 208             # If we can't hold damaged items, and it is damaged, it can't be waiting
 209             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 210
 211             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 212             && !$item->current_holds->count )
 213         {
 214             $priority = 0;
 215             $found = 'W';
 216         }
 217     }
 218
 219     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 220
 221         # Make room in reserves for this before those of a later reserve date
 222         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 223     }
 224
 225     my $waitingdate;
 226
 227     # If the reserv had the waiting status, we had the value of the resdate
 228     if ( $found && $found eq 'W' ) {
 229         $waitingdate = $resdate;
 230     }
 231
 232     # Don't add itemtype limit if specific item is selected
 233     $itemtype = undef if $checkitem;
 234
 235     # updates take place here
 236     my $hold = Koha::Hold->new(
 237         {
 238             borrowernumber => $borrowernumber,
 239             biblionumber   => $biblionumber,
 240             reservedate    => $resdate,
 241             branchcode     => $branch,
 242             priority       => $priority,
 243             reservenotes   => $notes,
 244             itemnumber     => $checkitem,
 245             found          => $found,
 246             waitingdate    => $waitingdate,
 247             expirationdate => $expdate,
 248             itemtype       => $itemtype,
 249             item_level_hold => $checkitem ? 1 : 0,
 250         }
 251     )->store();
 252     $hold->set_waiting() if $found && $found eq 'W';
 253
 254     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 255         if C4::Context->preference('HoldsLog');
 256
 257     my $reserve_id = $hold->id();
 258
 259     # add a reserve fee if needed
 260     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 261         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 262         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 263     }
 264
 265     _FixPriority({ biblionumber => $biblionumber});
 266
 267     # Send e-mail to librarian if syspref is active
 268     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 269         my $patron = Koha::Patrons->find( $borrowernumber );
 270         my $library = $patron->library;
 271         if ( my $letter =  C4::Letters::GetPreparedLetter (
 272             module => 'reserves',
 273             letter_code => 'HOLDPLACED',
 274             branchcode => $branch,
 275             lang => $patron->lang,
 276             tables => {
 277                 'branches'    => $library->unblessed,
 278                 'borrowers'   => $patron->unblessed,
 279                 'biblio'      => $biblionumber,
 280                 'biblioitems' => $biblionumber,
 281                 'items'       => $checkitem,
 282                 'reserves'    => $hold->unblessed,
 283             },
 284         ) ) {
 285
 286             my $branch_email_address = $library->inbound_email_address;
 287
 288             C4::Letters::EnqueueLetter(
 289                 {
 290                     letter                 => $letter,
 291                     borrowernumber         => $borrowernumber,
 292                     message_transport_type => 'email',
 293                     to_address             => $branch_email_address,
 294                 }
 295             );
 296         }
 297     }
 298
 299     return $reserve_id;
 300 }
 301
 302 =head2 CanBookBeReserved
 303
 304   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode)
 305   if ($canReserve eq 'OK') { #We can reserve this Item! }
 306
 307 See CanItemBeReserved() for possible return values.
 308
 309 =cut
 310
 311 sub CanBookBeReserved{
 312     my ($borrowernumber, $biblionumber, $pickup_branchcode) = @_;
 313
 314     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 315     #get items linked via host records
 316     my @hostitems = get_hostitemnumbers_of($biblionumber);
 317     if (@hostitems){
 318         push (@itemnumbers, @hostitems);
 319     }
 320
 321     my $canReserve = { status => '' };
 322     foreach my $itemnumber (@itemnumbers) {
 323         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode );
 324         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 325     }
 326     return $canReserve;
 327 }
 328
 329 =head2 CanItemBeReserved
 330
 331   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode)
 332   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 333
 334 @RETURNS { status => OK },              if the Item can be reserved.
 335          { status => ageRestricted },   if the Item is age restricted for this borrower.
 336          { status => damaged },         if the Item is damaged.
 337          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 338          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 339          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 340          { status => notReservable },   if holds on this item are not allowed
 341          { status => libraryNotFound },   if given branchcode is not an existing library
 342          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 343          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 344          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 345
 346 =cut
 347
 348 sub CanItemBeReserved {
 349     my ( $borrowernumber, $itemnumber, $pickup_branchcode ) = @_;
 350
 351     my $dbh = C4::Context->dbh;
 352     my $ruleitemtype;    # itemtype of the matching issuing rule
 353     my $allowedreserves  = 0; # Total number of holds allowed across all records
 354     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 355     my $holds_per_day;        # Default to unlimited
 356
 357     # we retrieve borrowers and items informations #
 358     # item->{itype} will come for biblioitems if necessery
 359     my $item       = Koha::Items->find($itemnumber);
 360     my $biblio     = $item->biblio;
 361     my $patron = Koha::Patrons->find( $borrowernumber );
 362     my $borrower = $patron->unblessed;
 363
 364     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 365     return { status =>'damaged' }
 366       if ( $item->damaged
 367         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 368
 369     # Check for the age restriction
 370     my ( $ageRestriction, $daysToAgeRestriction ) =
 371       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 372     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 373
 374     # Check that the patron doesn't have an item level hold on this item already
 375     return { status =>'itemAlreadyOnHold' }
 376       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 377
 378     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 379
 380     my $querycount = q{
 381         SELECT count(*) AS count
 382           FROM reserves
 383      LEFT JOIN items USING (itemnumber)
 384      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 385      LEFT JOIN borrowers USING (borrowernumber)
 386          WHERE borrowernumber = ?
 387     };
 388
 389     my $branchcode  = "";
 390     my $branchfield = "reserves.branchcode";
 391
 392     if ( $controlbranch eq "ItemHomeLibrary" ) {
 393         $branchfield = "items.homebranch";
 394         $branchcode  = $item->homebranch;
 395     }
 396     elsif ( $controlbranch eq "PatronLibrary" ) {
 397         $branchfield = "borrowers.branchcode";
 398         $branchcode  = $borrower->{branchcode};
 399     }
 400
 401     # we retrieve rights
 402     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->effective_itemtype, $branchcode ) ) {
 403         $ruleitemtype     = $rights->{itemtype};
 404         $allowedreserves  = $rights->{reservesallowed} // $allowedreserves;
 405         $holds_per_record = $rights->{holds_per_record} // $holds_per_record;
 406         $holds_per_day    = $rights->{holds_per_day};
 407     }
 408     else {
 409         $ruleitemtype = undef;
 410     }
 411
 412     my $holds = Koha::Holds->search(
 413         {
 414             borrowernumber => $borrowernumber,
 415             biblionumber   => $item->biblionumber,
 416         }
 417     );
 418     if (   defined $holds_per_record && $holds_per_record ne ''
 419         && $holds->count() >= $holds_per_record ) {
 420         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 421     }
 422
 423     my $today_holds = Koha::Holds->search({
 424         borrowernumber => $borrowernumber,
 425         reservedate    => dt_from_string->date
 426     });
 427
 428     if (   defined $holds_per_day && $holds_per_day ne ''
 429         && $today_holds->count() >= $holds_per_day )
 430     {
 431         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 432     }
 433
 434     # we retrieve count
 435
 436     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 437
 438     # If using item-level itypes, fall back to the record
 439     # level itemtype if the hold has no associated item
 440     $querycount .=
 441       C4::Context->preference('item-level_itypes')
 442       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 443       : " AND biblioitems.itemtype = ?"
 444       if defined $ruleitemtype;
 445
 446     my $sthcount = $dbh->prepare($querycount);
 447
 448     if ( defined $ruleitemtype ) {
 449         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 450     }
 451     else {
 452         $sthcount->execute( $borrowernumber, $branchcode );
 453     }
 454
 455     my $reservecount = "0";
 456     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 457         $reservecount = $rowcount->{count};
 458     }
 459
 460     # we check if it's ok or not
 461     if (   defined  $allowedreserves && $allowedreserves ne ''
 462         && $reservecount >= $allowedreserves ) {
 463         return { status => 'tooManyReserves', limit => $allowedreserves };
 464     }
 465
 466     # Now we need to check hold limits by patron category
 467     my $rule = Koha::CirculationRules->get_effective_rule(
 468         {
 469             categorycode => $borrower->{categorycode},
 470             branchcode   => $branchcode,
 471             rule_name    => 'max_holds',
 472         }
 473     );
 474     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 475         my $total_holds_count = Koha::Holds->search(
 476             {
 477                 borrowernumber => $borrower->{borrowernumber}
 478             }
 479         )->count();
 480
 481         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 482     }
 483
 484     my $reserves_control_branch =
 485       GetReservesControlBranch( $item->unblessed(), $borrower );
 486     my $branchitemrule =
 487       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 488
 489     if ( $branchitemrule->{holdallowed} == 0 ) {
 490         return { status => 'notReservable' };
 491     }
 492
 493     if (   $branchitemrule->{holdallowed} == 1
 494         && $borrower->{branchcode} ne $item->homebranch )
 495     {
 496         return { status => 'cannotReserveFromOtherBranches' };
 497     }
 498
 499     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 500     if ( $branchitemrule->{holdallowed} == 3) {
 501         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 502             return { status => 'branchNotInHoldGroup' };
 503         }
 504     }
 505
 506     # If reservecount is ok, we check item branch if IndependentBranches is ON
 507     # and canreservefromotherbranches is OFF
 508     if ( C4::Context->preference('IndependentBranches')
 509         and !C4::Context->preference('canreservefromotherbranches') )
 510     {
 511         if ( $item->homebranch ne $borrower->{branchcode} ) {
 512             return { status => 'cannotReserveFromOtherBranches' };
 513         }
 514     }
 515
 516     if ($pickup_branchcode) {
 517         my $destination = Koha::Libraries->find({
 518             branchcode => $pickup_branchcode,
 519         });
 520
 521         unless ($destination) {
 522             return { status => 'libraryNotFound' };
 523         }
 524         unless ($destination->pickup_location) {
 525             return { status => 'libraryNotPickupLocation' };
 526         }
 527         unless ($item->can_be_transferred({ to => $destination })) {
 528             return { status => 'cannotBeTransferred' };
 529         }
 530         unless ($branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 531             return { status => 'pickupNotInHoldGroup' };
 532         }
 533         unless ($branchitemrule->{hold_fulfillment_policy} ne 'patrongroup' || Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 534             return { status => 'pickupNotInHoldGroup' };
 535         }
 536     }
 537
 538     return { status => 'OK' };
 539 }
 540
 541 =head2 CanReserveBeCanceledFromOpac
 542
 543     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 544
 545     returns 1 if reserve can be cancelled by user from OPAC.
 546     First check if reserve belongs to user, next checks if reserve is not in
 547     transfer or waiting status
 548
 549 =cut
 550
 551 sub CanReserveBeCanceledFromOpac {
 552     my ($reserve_id, $borrowernumber) = @_;
 553
 554     return unless $reserve_id and $borrowernumber;
 555     my $reserve = Koha::Holds->find($reserve_id);
 556
 557     return 0 unless $reserve->borrowernumber == $borrowernumber;
 558     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 559
 560     return 1;
 561
 562 }
 563
 564 =head2 GetOtherReserves
 565
 566   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 567
 568 Check queued list of this document and check if this document must be transferred
 569
 570 =cut
 571
 572 sub GetOtherReserves {
 573     my ($itemnumber) = @_;
 574     my $messages;
 575     my $nextreservinfo;
 576     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 577     if ($checkreserves) {
 578         my $item = Koha::Items->find($itemnumber);
 579         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 580             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 581             #minus priorities of others reservs
 582             ModReserveMinusPriority(
 583                 $itemnumber,
 584                 $checkreserves->{'reserve_id'},
 585             );
 586
 587             #launch the subroutine dotransfer
 588             C4::Items::ModItemTransfer(
 589                 $itemnumber,
 590                 $item->holdingbranch,
 591                 $checkreserves->{'branchcode'},
 592                 'Reserve'
 593               ),
 594               ;
 595         }
 596
 597      #step 2b : case of a reservation on the same branch, set the waiting status
 598         else {
 599             $messages->{'waiting'} = 1;
 600             ModReserveMinusPriority(
 601                 $itemnumber,
 602                 $checkreserves->{'reserve_id'},
 603             );
 604             ModReserveStatus($itemnumber,'W');
 605         }
 606
 607         $nextreservinfo = $checkreserves->{'borrowernumber'};
 608     }
 609
 610     return ( $messages, $nextreservinfo );
 611 }
 612
 613 =head2 ChargeReserveFee
 614
 615     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 616
 617     Charge the fee for a reserve (if $fee > 0)
 618
 619 =cut
 620
 621 sub ChargeReserveFee {
 622     my ( $borrowernumber, $fee, $title ) = @_;
 623     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 624     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 625         {
 626             amount       => $fee,
 627             description  => $title,
 628             note         => undef,
 629             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 630             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 631             interface    => C4::Context->interface,
 632             invoice_type => undef,
 633             type         => 'RESERVE',
 634             item_id      => undef
 635         }
 636     );
 637 }
 638
 639 =head2 GetReserveFee
 640
 641     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 642
 643     Calculate the fee for a reserve (if applicable).
 644
 645 =cut
 646
 647 sub GetReserveFee {
 648     my ( $borrowernumber, $biblionumber ) = @_;
 649     my $borquery = qq{
 650 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 651     };
 652     my $issue_qry = qq{
 653 SELECT COUNT(*) FROM items
 654 LEFT JOIN issues USING (itemnumber)
 655 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 656     };
 657     my $holds_qry = qq{
 658 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 659     };
 660
 661     my $dbh = C4::Context->dbh;
 662     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 663     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 664     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 665         # This is a reconstruction of the old code:
 666         # Compare number of items with items issued, and optionally check holds
 667         # If not all items are issued and there are no holds: charge no fee
 668         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 669         my ( $notissued, $reserved );
 670         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 671             ( $biblionumber ) );
 672         if( $notissued ) {
 673             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 674                 ( $biblionumber, $borrowernumber ) );
 675             $fee = 0 if $reserved == 0;
 676         }
 677     }
 678     return $fee;
 679 }
 680
 681 =head2 GetReserveStatus
 682
 683   $reservestatus = GetReserveStatus($itemnumber);
 684
 685 Takes an itemnumber and returns the status of the reserve placed on it.
 686 If several reserves exist, the reserve with the lower priority is given.
 687
 688 =cut
 689
 690 ## FIXME: I don't think this does what it thinks it does.
 691 ## It only ever checks the first reserve result, even though
 692 ## multiple reserves for that bib can have the itemnumber set
 693 ## the sub is only used once in the codebase.
 694 sub GetReserveStatus {
 695     my ($itemnumber) = @_;
 696
 697     my $dbh = C4::Context->dbh;
 698
 699     my ($sth, $found, $priority);
 700     if ( $itemnumber ) {
 701         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 702         $sth->execute($itemnumber);
 703         ($found, $priority) = $sth->fetchrow_array;
 704     }
 705
 706     if(defined $found) {
 707         return 'Waiting'  if $found eq 'W' and $priority == 0;
 708         return 'Finished' if $found eq 'F';
 709     }
 710
 711     return 'Reserved' if defined $priority && $priority > 0;
 712
 713     return ''; # empty string here will remove need for checking undef, or less log lines
 714 }
 715
 716 =head2 CheckReserves
 717
 718   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 719   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 720   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 721
 722 Find a book in the reserves.
 723
 724 C<$itemnumber> is the book's item number.
 725 C<$lookahead> is the number of days to look in advance for future reserves.
 726
 727 As I understand it, C<&CheckReserves> looks for the given item in the
 728 reserves. If it is found, that's a match, and C<$status> is set to
 729 C<Waiting>.
 730
 731 Otherwise, it finds the most important item in the reserves with the
 732 same biblio number as this book (I'm not clear on this) and returns it
 733 with C<$status> set to C<Reserved>.
 734
 735 C<&CheckReserves> returns a two-element list:
 736
 737 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 738
 739 C<$reserve> is the reserve item that matched. It is a
 740 reference-to-hash whose keys are mostly the fields of the reserves
 741 table in the Koha database.
 742
 743 =cut
 744
 745 sub CheckReserves {
 746     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 747     my $dbh = C4::Context->dbh;
 748     my $sth;
 749     my $select;
 750     if (C4::Context->preference('item-level_itypes')){
 751         $select = "
 752            SELECT items.biblionumber,
 753            items.biblioitemnumber,
 754            itemtypes.notforloan,
 755            items.notforloan AS itemnotforloan,
 756            items.itemnumber,
 757            items.damaged,
 758            items.homebranch,
 759            items.holdingbranch
 760            FROM   items
 761            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 762            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 763         ";
 764     }
 765     else {
 766         $select = "
 767            SELECT items.biblionumber,
 768            items.biblioitemnumber,
 769            itemtypes.notforloan,
 770            items.notforloan AS itemnotforloan,
 771            items.itemnumber,
 772            items.damaged,
 773            items.homebranch,
 774            items.holdingbranch
 775            FROM   items
 776            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 777            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 778         ";
 779     }
 780
 781     if ($item) {
 782         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 783         $sth->execute($item);
 784     }
 785     else {
 786         $sth = $dbh->prepare("$select WHERE barcode = ?");
 787         $sth->execute($barcode);
 788     }
 789     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 790     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 791     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 792
 793     return unless $itemnumber; # bail if we got nothing.
 794     # if item is not for loan it cannot be reserved either.....
 795     # except where items.notforloan < 0 :  This indicates the item is holdable.
 796     return if  ( $notforloan_per_item > 0 ) or $notforloan_per_itemtype;
 797
 798     # Find this item in the reserves
 799     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 800
 801     # $priority and $highest are used to find the most important item
 802     # in the list returned by &_Findgroupreserve. (The lower $priority,
 803     # the more important the item.)
 804     # $highest is the most important item we've seen so far.
 805     my $highest;
 806     if (scalar @reserves) {
 807         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 808         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 809         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 810
 811         my $priority = 10000000;
 812         foreach my $res (@reserves) {
 813             if ( $res->{'itemnumber'} && $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 814                 if ($res->{'found'} eq 'W') {
 815                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 816                 } else {
 817                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 818                 }
 819             } else {
 820                 my $patron;
 821                 my $item;
 822                 my $local_hold_match;
 823
 824                 if ($LocalHoldsPriority) {
 825                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 826                     $item = Koha::Items->find($itemnumber);
 827
 828                     my $local_holds_priority_item_branchcode =
 829                       $item->$LocalHoldsPriorityItemControl;
 830                     my $local_holds_priority_patron_branchcode =
 831                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 832                       ? $res->{branchcode}
 833                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 834                       ? $patron->branchcode
 835                       : undef;
 836                     $local_hold_match =
 837                       $local_holds_priority_item_branchcode eq
 838                       $local_holds_priority_patron_branchcode;
 839                 }
 840
 841                 # See if this item is more important than what we've got so far
 842                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 843                     $item ||= Koha::Items->find($itemnumber);
 844                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 845                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 846                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 847                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 848                     next if ($branchitemrule->{'holdallowed'} == 0);
 849                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 850                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 851                     next if (($branchitemrule->{'holdallowed'} == 3) && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 852                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 853                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 854                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 855                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 856                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 857                     $priority = $res->{'priority'};
 858                     $highest  = $res;
 859                     last if $local_hold_match;
 860                 }
 861             }
 862         }
 863     }
 864
 865     # If we get this far, then no exact match was found.
 866     # We return the most important (i.e. next) reservation.
 867     if ($highest) {
 868         $highest->{'itemnumber'} = $item;
 869         return ( "Reserved", $highest, \@reserves );
 870     }
 871
 872     return ( '' );
 873 }
 874
 875 =head2 CancelExpiredReserves
 876
 877   CancelExpiredReserves();
 878
 879 Cancels all reserves with an expiration date from before today.
 880
 881 =cut
 882
 883 sub CancelExpiredReserves {
 884     my $today = dt_from_string();
 885     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 886     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 887
 888     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 889     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 890     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 891
 892     # FIXME To move to Koha::Holds->search_expired (?)
 893     my $holds = Koha::Holds->search( $params );
 894
 895     while ( my $hold = $holds->next ) {
 896         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 897
 898         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 899
 900         my $cancel_params = {};
 901         if ( $hold->found eq 'W' ) {
 902             $cancel_params->{charge_cancel_fee} = 1;
 903         }
 904         $hold->cancel( $cancel_params );
 905     }
 906 }
 907
 908 =head2 AutoUnsuspendReserves
 909
 910   AutoUnsuspendReserves();
 911
 912 Unsuspends all suspended reserves with a suspend_until date from before today.
 913
 914 =cut
 915
 916 sub AutoUnsuspendReserves {
 917     my $today = dt_from_string();
 918
 919     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 920
 921     map { $_->resume() } @holds;
 922 }
 923
 924 =head2 ModReserve
 925
 926   ModReserve({ rank => $rank,
 927                reserve_id => $reserve_id,
 928                branchcode => $branchcode
 929                [, itemnumber => $itemnumber ]
 930                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 931               });
 932
 933 Change a hold request's priority or cancel it.
 934
 935 C<$rank> specifies the effect of the change.  If C<$rank>
 936 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 937 request alone when changing its priority in the holds queue
 938 for a bib.
 939
 940 If C<$rank> is 'del', the hold request is cancelled.
 941
 942 If C<$rank> is an integer greater than zero, the priority of
 943 the request is set to that value.  Since priority != 0 means
 944 that the item is not waiting on the hold shelf, setting the
 945 priority to a non-zero value also sets the request's found
 946 status and waiting date to NULL.
 947
 948 The optional C<$itemnumber> parameter is used only when
 949 C<$rank> is a non-zero integer; if supplied, the itemnumber
 950 of the hold request is set accordingly; if omitted, the itemnumber
 951 is cleared.
 952
 953 B<FIXME:> Note that the forgoing can have the effect of causing
 954 item-level hold requests to turn into title-level requests.  This
 955 will be fixed once reserves has separate columns for requested
 956 itemnumber and supplying itemnumber.
 957
 958 =cut
 959
 960 sub ModReserve {
 961     my ( $params ) = @_;
 962
 963     my $rank = $params->{'rank'};
 964     my $reserve_id = $params->{'reserve_id'};
 965     my $branchcode = $params->{'branchcode'};
 966     my $itemnumber = $params->{'itemnumber'};
 967     my $suspend_until = $params->{'suspend_until'};
 968     my $borrowernumber = $params->{'borrowernumber'};
 969     my $biblionumber = $params->{'biblionumber'};
 970
 971     return if $rank eq "W";
 972     return if $rank eq "n";
 973
 974     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 975
 976     my $hold;
 977     unless ( $reserve_id ) {
 978         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 979         return unless $holds->count; # FIXME Should raise an exception
 980         $hold = $holds->next;
 981         $reserve_id = $hold->reserve_id;
 982     }
 983
 984     $hold ||= Koha::Holds->find($reserve_id);
 985
 986     if ( $rank eq "del" ) {
 987         $hold->cancel;
 988     }
 989     elsif ($rank =~ /^\d+/ and $rank > 0) {
 990         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
 991             if C4::Context->preference('HoldsLog');
 992
 993         my $properties = {
 994             priority    => $rank,
 995             branchcode  => $branchcode,
 996             itemnumber  => $itemnumber,
 997             found       => undef,
 998             waitingdate => undef
 999         };
1000         if (exists $params->{reservedate}) {
1001             $properties->{reservedate} = $params->{reservedate} || undef;
1002         }
1003         if (exists $params->{expirationdate}) {
1004             $properties->{expirationdate} = $params->{expirationdate} || undef;
1005         }
1006
1007         $hold->set($properties)->store();
1008
1009         if ( defined( $suspend_until ) ) {
1010             if ( $suspend_until ) {
1011                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1012                 $hold->suspend_hold( $suspend_until );
1013             } else {
1014                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1015                 # If the hold is not suspended, this does nothing.
1016                 $hold->set( { suspend_until => undef } )->store();
1017             }
1018         }
1019
1020         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1021     }
1022 }
1023
1024 =head2 ModReserveFill
1025
1026   &ModReserveFill($reserve);
1027
1028 Fill a reserve. If I understand this correctly, this means that the
1029 reserved book has been found and given to the patron who reserved it.
1030
1031 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1032 whose keys are fields from the reserves table in the Koha database.
1033
1034 =cut
1035
1036 sub ModReserveFill {
1037     my ($res) = @_;
1038     my $reserve_id = $res->{'reserve_id'};
1039
1040     my $hold = Koha::Holds->find($reserve_id);
1041     # get the priority on this record....
1042     my $priority = $hold->priority;
1043
1044     # update the hold statuses, no need to store it though, we will be deleting it anyway
1045     $hold->set(
1046         {
1047             found    => 'F',
1048             priority => 0,
1049         }
1050     );
1051
1052     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1053     Koha::Old::Hold->new( $hold->unblessed() )->store();
1054
1055     $hold->delete();
1056
1057     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1058         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1059         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1060     }
1061
1062     # now fix the priority on the others (if the priority wasn't
1063     # already sorted!)....
1064     unless ( $priority == 0 ) {
1065         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1066     }
1067 }
1068
1069 =head2 ModReserveStatus
1070
1071   &ModReserveStatus($itemnumber, $newstatus);
1072
1073 Update the reserve status for the active (priority=0) reserve.
1074
1075 $itemnumber is the itemnumber the reserve is on
1076
1077 $newstatus is the new status.
1078
1079 =cut
1080
1081 sub ModReserveStatus {
1082
1083     #first : check if we have a reservation for this item .
1084     my ($itemnumber, $newstatus) = @_;
1085     my $dbh = C4::Context->dbh;
1086
1087     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1088     my $sth_set = $dbh->prepare($query);
1089     $sth_set->execute( $newstatus, $itemnumber );
1090
1091     my $item = Koha::Items->find($itemnumber);
1092     if ( $item->location && $item->location eq 'CART'
1093         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1094         && $newstatus ) {
1095       CartToShelf( $itemnumber );
1096     }
1097 }
1098
1099 =head2 ModReserveAffect
1100
1101   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
1102
1103 This function affect an item and a status for a given reserve, either fetched directly
1104 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1105 is given, only first reserve returned is affected, which is ok for anything but
1106 multi-item holds.
1107
1108 if $transferToDo is not set, then the status is set to "Waiting" as well.
1109 otherwise, a transfer is on the way, and the end of the transfer will
1110 take care of the waiting status
1111
1112 =cut
1113
1114 sub ModReserveAffect {
1115     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
1116     my $dbh = C4::Context->dbh;
1117
1118     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1119     # attached to $itemnumber
1120     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1121     $sth->execute($itemnumber);
1122     my ($biblionumber) = $sth->fetchrow;
1123
1124     # get request - need to find out if item is already
1125     # waiting in order to not send duplicate hold filled notifications
1126
1127     my $hold;
1128     # Find hold by id if we have it
1129     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1130     # Find item level hold for this item if there is one
1131     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1132     # Find record level hold if there is no item level hold
1133     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1134
1135     return unless $hold;
1136
1137     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1138
1139     $hold->itemnumber($itemnumber);
1140     $hold->set_waiting($transferToDo);
1141
1142     _koha_notify_reserve( $hold->reserve_id )
1143       if ( !$transferToDo && !$already_on_shelf );
1144
1145     _FixPriority( { biblionumber => $biblionumber } );
1146     my $item = Koha::Items->find($itemnumber);
1147     if ( $item->location && $item->location eq 'CART'
1148         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1149       CartToShelf( $itemnumber );
1150     }
1151
1152     return;
1153 }
1154
1155 =head2 ModReserveCancelAll
1156
1157   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1158
1159 function to cancel reserv,check other reserves, and transfer document if it's necessary
1160
1161 =cut
1162
1163 sub ModReserveCancelAll {
1164     my $messages;
1165     my $nextreservinfo;
1166     my ( $itemnumber, $borrowernumber ) = @_;
1167
1168     #step 1 : cancel the reservation
1169     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1170     return unless $holds->count;
1171     $holds->next->cancel;
1172
1173     #step 2 launch the subroutine of the others reserves
1174     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1175
1176     return ( $messages, $nextreservinfo );
1177 }
1178
1179 =head2 ModReserveMinusPriority
1180
1181   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1182
1183 Reduce the values of queued list
1184
1185 =cut
1186
1187 sub ModReserveMinusPriority {
1188     my ( $itemnumber, $reserve_id ) = @_;
1189
1190     #first step update the value of the first person on reserv
1191     my $dbh   = C4::Context->dbh;
1192     my $query = "
1193         UPDATE reserves
1194         SET    priority = 0 , itemnumber = ?
1195         WHERE  reserve_id = ?
1196     ";
1197     my $sth_upd = $dbh->prepare($query);
1198     $sth_upd->execute( $itemnumber, $reserve_id );
1199     # second step update all others reserves
1200     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1201 }
1202
1203 =head2 IsAvailableForItemLevelRequest
1204
1205   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1206
1207 Checks whether a given item record is available for an
1208 item-level hold request.  An item is available if
1209
1210 * it is not lost AND
1211 * it is not damaged AND
1212 * it is not withdrawn AND
1213 * a waiting or in transit reserve is placed on
1214 * does not have a not for loan value > 0
1215
1216 Need to check the issuingrules onshelfholds column,
1217 if this is set items on the shelf can be placed on hold
1218
1219 Note that IsAvailableForItemLevelRequest() does not
1220 check if the staff operator is authorized to place
1221 a request on the item - in particular,
1222 this routine does not check IndependentBranches
1223 and canreservefromotherbranches.
1224
1225 =cut
1226
1227 sub IsAvailableForItemLevelRequest {
1228     my $item                = shift;
1229     my $patron              = shift;
1230     my $pickup_branchcode   = shift;
1231     # items_any_available is precalculated status passed from request.pl when set of items
1232     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1233     my $items_any_available = shift;
1234
1235     my $dbh = C4::Context->dbh;
1236     # must check the notforloan setting of the itemtype
1237     # FIXME - a lot of places in the code do this
1238     #         or something similar - need to be
1239     #         consolidated
1240     my $itemtype = $item->effective_itemtype;
1241     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1242
1243     return 0 if
1244         $notforloan_per_itemtype ||
1245         $item->itemlost        ||
1246         $item->notforloan > 0  ||
1247         $item->withdrawn        ||
1248         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1249
1250     if ($pickup_branchcode) {
1251         my $destination = Koha::Libraries->find($pickup_branchcode);
1252         return 0 unless $destination;
1253         return 0 unless $destination->pickup_location;
1254         return 0 unless $item->can_be_transferred( { to => $destination } );
1255         my $reserves_control_branch =
1256             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1257         my $branchitemrule =
1258             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1259         my $home_library = Koka::Libraries->find( {branchcode => $item->homebranch} );
1260         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1261     }
1262
1263     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1264
1265     if ( $on_shelf_holds == 1 ) {
1266         return 1;
1267     } elsif ( $on_shelf_holds == 2 ) {
1268
1269         # if we have this param predefined from outer caller sub, we just need
1270         # to return it, so we saving from having loop inside other loop:
1271         return  $items_any_available ? 0 : 1
1272             if defined $items_any_available;
1273
1274         my $any_available = ItemsAnyAvailableForHold( { biblionumber => $item->biblionumber, patron => $patron });
1275         return $any_available ? 0 : 1;
1276     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1277         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1278     }
1279 }
1280
1281 =head2 ItemsAnyAvailableForHold
1282
1283   ItemsAnyAvailableForHold( { biblionumber => $biblionumber, patron => $patron });
1284
1285 This function checks all items for specified biblionumber (num) / patron (object)
1286 and returns true (1) or false (0) depending if any of rules allows at least of
1287 one item to be available for hold including lots of parameters/logic
1288
1289 =cut
1290
1291 sub ItemsAnyAvailableForHold {
1292     my $param = shift;
1293
1294     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1295
1296     my $any_available = 0;
1297
1298     foreach my $i (@items) {
1299         my $reserves_control_branch =
1300             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1301         my $branchitemrule =
1302             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1303         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1304
1305         $any_available = 1
1306             unless $i->itemlost
1307             || $i->notforloan > 0
1308             || $i->withdrawn
1309             || $i->onloan
1310             || IsItemOnHoldAndFound( $i->id )
1311             || ( $i->damaged
1312             && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1313             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1314             || $branchitemrule->{holdallowed} == 1 && $param->{patron}->branchcode ne $i->homebranch
1315             || $branchitemrule->{holdallowed} == 3 && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } );
1316     }
1317
1318     return $any_available;
1319 }
1320
1321 =head2 AlterPriority
1322
1323   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1324
1325 This function changes a reserve's priority up, down, to the top, or to the bottom.
1326 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1327
1328 =cut
1329
1330 sub AlterPriority {
1331     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1332
1333     my $hold = Koha::Holds->find( $reserve_id );
1334     return unless $hold;
1335
1336     if ( $hold->cancellationdate ) {
1337         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1338         return;
1339     }
1340
1341     if ( $where eq 'up' ) {
1342       return unless $prev_priority;
1343       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1344     } elsif ( $where eq 'down' ) {
1345       return unless $next_priority;
1346       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1347     } elsif ( $where eq 'top' ) {
1348       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1349     } elsif ( $where eq 'bottom' ) {
1350       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1351     }
1352
1353     # FIXME Should return the new priority
1354 }
1355
1356 =head2 ToggleLowestPriority
1357
1358   ToggleLowestPriority( $borrowernumber, $biblionumber );
1359
1360 This function sets the lowestPriority field to true if is false, and false if it is true.
1361
1362 =cut
1363
1364 sub ToggleLowestPriority {
1365     my ( $reserve_id ) = @_;
1366
1367     my $dbh = C4::Context->dbh;
1368
1369     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1370     $sth->execute( $reserve_id );
1371
1372     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1373 }
1374
1375 =head2 ToggleSuspend
1376
1377   ToggleSuspend( $reserve_id );
1378
1379 This function sets the suspend field to true if is false, and false if it is true.
1380 If the reserve is currently suspended with a suspend_until date, that date will
1381 be cleared when it is unsuspended.
1382
1383 =cut
1384
1385 sub ToggleSuspend {
1386     my ( $reserve_id, $suspend_until ) = @_;
1387
1388     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1389
1390     my $hold = Koha::Holds->find( $reserve_id );
1391
1392     if ( $hold->is_suspended ) {
1393         $hold->resume()
1394     } else {
1395         $hold->suspend_hold( $suspend_until );
1396     }
1397 }
1398
1399 =head2 SuspendAll
1400
1401   SuspendAll(
1402       borrowernumber   => $borrowernumber,
1403       [ biblionumber   => $biblionumber, ]
1404       [ suspend_until  => $suspend_until, ]
1405       [ suspend        => $suspend ]
1406   );
1407
1408   This function accepts a set of hash keys as its parameters.
1409   It requires either borrowernumber or biblionumber, or both.
1410
1411   suspend_until is wholly optional.
1412
1413 =cut
1414
1415 sub SuspendAll {
1416     my %params = @_;
1417
1418     my $borrowernumber = $params{'borrowernumber'} || undef;
1419     my $biblionumber   = $params{'biblionumber'}   || undef;
1420     my $suspend_until  = $params{'suspend_until'}  || undef;
1421     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1422
1423     $suspend_until = eval { dt_from_string($suspend_until) }
1424       if ( defined($suspend_until) );
1425
1426     return unless ( $borrowernumber || $biblionumber );
1427
1428     my $params;
1429     $params->{found}          = undef;
1430     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1431     $params->{biblionumber}   = $biblionumber if $biblionumber;
1432
1433     my @holds = Koha::Holds->search($params);
1434
1435     if ($suspend) {
1436         map { $_->suspend_hold($suspend_until) } @holds;
1437     }
1438     else {
1439         map { $_->resume() } @holds;
1440     }
1441 }
1442
1443
1444 =head2 _FixPriority
1445
1446   _FixPriority({
1447     reserve_id => $reserve_id,
1448     [rank => $rank,]
1449     [ignoreSetLowestRank => $ignoreSetLowestRank]
1450   });
1451
1452   or
1453
1454   _FixPriority({ biblionumber => $biblionumber});
1455
1456 This routine adjusts the priority of a hold request and holds
1457 on the same bib.
1458
1459 In the first form, where a reserve_id is passed, the priority of the
1460 hold is set to supplied rank, and other holds for that bib are adjusted
1461 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1462 is supplied, all of the holds on that bib have their priority adjusted
1463 as if the second form had been used.
1464
1465 In the second form, where a biblionumber is passed, the holds on that
1466 bib (that are not captured) are sorted in order of increasing priority,
1467 then have reserves.priority set so that the first non-captured hold
1468 has its priority set to 1, the second non-captured hold has its priority
1469 set to 2, and so forth.
1470
1471 In both cases, holds that have the lowestPriority flag on are have their
1472 priority adjusted to ensure that they remain at the end of the line.
1473
1474 Note that the ignoreSetLowestRank parameter is meant to be used only
1475 when _FixPriority calls itself.
1476
1477 =cut
1478
1479 sub _FixPriority {
1480     my ( $params ) = @_;
1481     my $reserve_id = $params->{reserve_id};
1482     my $rank = $params->{rank} // '';
1483     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1484     my $biblionumber = $params->{biblionumber};
1485
1486     my $dbh = C4::Context->dbh;
1487
1488     my $hold;
1489     if ( $reserve_id ) {
1490         $hold = Koha::Holds->find( $reserve_id );
1491         if (!defined $hold){
1492             # may have already been checked out and hold fulfilled
1493             $hold = Koha::Old::Holds->find( $reserve_id );
1494         }
1495         return unless $hold;
1496     }
1497
1498     unless ( $biblionumber ) { # FIXME This is a very weird API
1499         $biblionumber = $hold->biblionumber;
1500     }
1501
1502     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1503         $hold->cancel;
1504     }
1505     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1506
1507         # make sure priority for waiting or in-transit items is 0
1508         my $query = "
1509             UPDATE reserves
1510             SET    priority = 0
1511             WHERE reserve_id = ?
1512             AND found IN ('W', 'T')
1513         ";
1514         my $sth = $dbh->prepare($query);
1515         $sth->execute( $reserve_id );
1516     }
1517     my @priority;
1518
1519     # get whats left
1520     my $query = "
1521         SELECT reserve_id, borrowernumber, reservedate
1522         FROM   reserves
1523         WHERE  biblionumber   = ?
1524           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1525         ORDER BY priority ASC
1526     ";
1527     my $sth = $dbh->prepare($query);
1528     $sth->execute( $biblionumber );
1529     while ( my $line = $sth->fetchrow_hashref ) {
1530         push( @priority,     $line );
1531     }
1532
1533     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1534     # To find the matching index
1535     my $i;
1536     my $key = -1;    # to allow for 0 to be a valid result
1537     for ( $i = 0 ; $i < @priority ; $i++ ) {
1538         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1539             $key = $i;    # save the index
1540             last;
1541         }
1542     }
1543
1544     # if index exists in array then move it to new position
1545     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1546         my $new_rank = $rank -
1547           1;    # $new_rank is what you want the new index to be in the array
1548         my $moving_item = splice( @priority, $key, 1 );
1549         splice( @priority, $new_rank, 0, $moving_item );
1550     }
1551
1552     # now fix the priority on those that are left....
1553     $query = "
1554         UPDATE reserves
1555         SET    priority = ?
1556         WHERE  reserve_id = ?
1557     ";
1558     $sth = $dbh->prepare($query);
1559     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1560         $sth->execute(
1561             $j + 1,
1562             $priority[$j]->{'reserve_id'}
1563         );
1564     }
1565
1566     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1567     $sth->execute();
1568
1569     unless ( $ignoreSetLowestRank ) {
1570       while ( my $res = $sth->fetchrow_hashref() ) {
1571         _FixPriority({
1572             reserve_id => $res->{'reserve_id'},
1573             rank => '999999',
1574             ignoreSetLowestRank => 1
1575         });
1576       }
1577     }
1578 }
1579
1580 =head2 _Findgroupreserve
1581
1582   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1583
1584 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1585 first match found.  If neither, then we look for non-holds-queue based holds.
1586 Lookahead is the number of days to look in advance.
1587
1588 C<&_Findgroupreserve> returns :
1589 C<@results> is an array of references-to-hash whose keys are mostly
1590 fields from the reserves table of the Koha database, plus
1591 C<biblioitemnumber>.
1592
1593 This routine with either return:
1594 1 - Item specific holds from the holds queue
1595 2 - Title level holds from the holds queue
1596 3 - All holds for this biblionumber
1597
1598 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1599
1600 =cut
1601
1602 sub _Findgroupreserve {
1603     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1604     my $dbh   = C4::Context->dbh;
1605
1606     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1607     # check for exact targeted match
1608     my $item_level_target_query = qq{
1609         SELECT reserves.biblionumber        AS biblionumber,
1610                reserves.borrowernumber      AS borrowernumber,
1611                reserves.reservedate         AS reservedate,
1612                reserves.branchcode          AS branchcode,
1613                reserves.cancellationdate    AS cancellationdate,
1614                reserves.found               AS found,
1615                reserves.reservenotes        AS reservenotes,
1616                reserves.priority            AS priority,
1617                reserves.timestamp           AS timestamp,
1618                biblioitems.biblioitemnumber AS biblioitemnumber,
1619                reserves.itemnumber          AS itemnumber,
1620                reserves.reserve_id          AS reserve_id,
1621                reserves.itemtype            AS itemtype
1622         FROM reserves
1623         JOIN biblioitems USING (biblionumber)
1624         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1625         WHERE found IS NULL
1626         AND priority > 0
1627         AND item_level_request = 1
1628         AND itemnumber = ?
1629         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1630         AND suspend = 0
1631         ORDER BY priority
1632     };
1633     my $sth = $dbh->prepare($item_level_target_query);
1634     $sth->execute($itemnumber, $lookahead||0);
1635     my @results;
1636     if ( my $data = $sth->fetchrow_hashref ) {
1637         push( @results, $data )
1638           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1639     }
1640     return @results if @results;
1641
1642     # check for title-level targeted match
1643     my $title_level_target_query = qq{
1644         SELECT reserves.biblionumber        AS biblionumber,
1645                reserves.borrowernumber      AS borrowernumber,
1646                reserves.reservedate         AS reservedate,
1647                reserves.branchcode          AS branchcode,
1648                reserves.cancellationdate    AS cancellationdate,
1649                reserves.found               AS found,
1650                reserves.reservenotes        AS reservenotes,
1651                reserves.priority            AS priority,
1652                reserves.timestamp           AS timestamp,
1653                biblioitems.biblioitemnumber AS biblioitemnumber,
1654                reserves.itemnumber          AS itemnumber,
1655                reserves.reserve_id          AS reserve_id,
1656                reserves.itemtype            AS itemtype
1657         FROM reserves
1658         JOIN biblioitems USING (biblionumber)
1659         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1660         WHERE found IS NULL
1661         AND priority > 0
1662         AND item_level_request = 0
1663         AND hold_fill_targets.itemnumber = ?
1664         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1665         AND suspend = 0
1666         ORDER BY priority
1667     };
1668     $sth = $dbh->prepare($title_level_target_query);
1669     $sth->execute($itemnumber, $lookahead||0);
1670     @results = ();
1671     if ( my $data = $sth->fetchrow_hashref ) {
1672         push( @results, $data )
1673           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1674     }
1675     return @results if @results;
1676
1677     my $query = qq{
1678         SELECT reserves.biblionumber               AS biblionumber,
1679                reserves.borrowernumber             AS borrowernumber,
1680                reserves.reservedate                AS reservedate,
1681                reserves.waitingdate                AS waitingdate,
1682                reserves.branchcode                 AS branchcode,
1683                reserves.cancellationdate           AS cancellationdate,
1684                reserves.found                      AS found,
1685                reserves.reservenotes               AS reservenotes,
1686                reserves.priority                   AS priority,
1687                reserves.timestamp                  AS timestamp,
1688                reserves.itemnumber                 AS itemnumber,
1689                reserves.reserve_id                 AS reserve_id,
1690                reserves.itemtype                   AS itemtype
1691         FROM reserves
1692         WHERE reserves.biblionumber = ?
1693           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1694           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1695           AND suspend = 0
1696           ORDER BY priority
1697     };
1698     $sth = $dbh->prepare($query);
1699     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1700     @results = ();
1701     while ( my $data = $sth->fetchrow_hashref ) {
1702         push( @results, $data )
1703           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1704     }
1705     return @results;
1706 }
1707
1708 =head2 _koha_notify_reserve
1709
1710   _koha_notify_reserve( $hold->reserve_id );
1711
1712 Sends a notification to the patron that their hold has been filled (through
1713 ModReserveAffect, _not_ ModReserveFill)
1714
1715 The letter code for this notice may be found using the following query:
1716
1717     select distinct letter_code
1718     from message_transports
1719     inner join message_attributes using (message_attribute_id)
1720     where message_name = 'Hold_Filled'
1721
1722 This will probably sipmly be 'HOLD', but because it is defined in the database,
1723 it is subject to addition or change.
1724
1725 The following tables are availalbe witin the notice:
1726
1727     branches
1728     borrowers
1729     biblio
1730     biblioitems
1731     reserves
1732     items
1733
1734 =cut
1735
1736 sub _koha_notify_reserve {
1737     my $reserve_id = shift;
1738     my $hold = Koha::Holds->find($reserve_id);
1739     my $borrowernumber = $hold->borrowernumber;
1740
1741     my $patron = Koha::Patrons->find( $borrowernumber );
1742
1743     # Try to get the borrower's email address
1744     my $to_address = $patron->notice_email_address;
1745
1746     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1747             borrowernumber => $borrowernumber,
1748             message_name => 'Hold_Filled'
1749     } );
1750
1751     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1752
1753     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1754
1755     my %letter_params = (
1756         module => 'reserves',
1757         branchcode => $hold->branchcode,
1758         lang => $patron->lang,
1759         tables => {
1760             'branches'       => $library,
1761             'borrowers'      => $patron->unblessed,
1762             'biblio'         => $hold->biblionumber,
1763             'biblioitems'    => $hold->biblionumber,
1764             'reserves'       => $hold->unblessed,
1765             'items'          => $hold->itemnumber,
1766         },
1767     );
1768
1769     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1770     my $send_notification = sub {
1771         my ( $mtt, $letter_code ) = (@_);
1772         return unless defined $letter_code;
1773         $letter_params{letter_code} = $letter_code;
1774         $letter_params{message_transport_type} = $mtt;
1775         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1776         unless ($letter) {
1777             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1778             return;
1779         }
1780
1781         C4::Letters::EnqueueLetter( {
1782             letter => $letter,
1783             borrowernumber => $borrowernumber,
1784             from_address => $admin_email_address,
1785             message_transport_type => $mtt,
1786         } );
1787     };
1788
1789     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1790         next if (
1791                ( $mtt eq 'email' and not $to_address ) # No email address
1792             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1793             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1794         );
1795
1796         &$send_notification($mtt, $letter_code);
1797         $notification_sent++;
1798     }
1799     #Making sure that a print notification is sent if no other transport types can be utilized.
1800     if (! $notification_sent) {
1801         &$send_notification('print', 'HOLD');
1802     }
1803
1804 }
1805
1806 =head2 _ShiftPriorityByDateAndPriority
1807
1808   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1809
1810 This increments the priority of all reserves after the one
1811 with either the lowest date after C<$reservedate>
1812 or the lowest priority after C<$priority>.
1813
1814 It effectively makes room for a new reserve to be inserted with a certain
1815 priority, which is returned.
1816
1817 This is most useful when the reservedate can be set by the user.  It allows
1818 the new reserve to be placed before other reserves that have a later
1819 reservedate.  Since priority also is set by the form in reserves/request.pl
1820 the sub accounts for that too.
1821
1822 =cut
1823
1824 sub _ShiftPriorityByDateAndPriority {
1825     my ( $biblio, $resdate, $new_priority ) = @_;
1826
1827     my $dbh = C4::Context->dbh;
1828     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1829     my $sth = $dbh->prepare( $query );
1830     $sth->execute( $biblio, $resdate, $new_priority );
1831     my $min_priority = $sth->fetchrow;
1832     # if no such matches are found, $new_priority remains as original value
1833     $new_priority = $min_priority if ( $min_priority );
1834
1835     # Shift the priority up by one; works in conjunction with the next SQL statement
1836     $query = "UPDATE reserves
1837               SET priority = priority+1
1838               WHERE biblionumber = ?
1839               AND borrowernumber = ?
1840               AND reservedate = ?
1841               AND found IS NULL";
1842     my $sth_update = $dbh->prepare( $query );
1843
1844     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1845     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1846     $sth = $dbh->prepare( $query );
1847     $sth->execute( $new_priority, $biblio );
1848     while ( my $row = $sth->fetchrow_hashref ) {
1849         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1850     }
1851
1852     return $new_priority;  # so the caller knows what priority they wind up receiving
1853 }
1854
1855 =head2 MoveReserve
1856
1857   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1858
1859 Use when checking out an item to handle reserves
1860 If $cancelreserve boolean is set to true, it will remove existing reserve
1861
1862 =cut
1863
1864 sub MoveReserve {
1865     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1866
1867     $cancelreserve //= 0;
1868
1869     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1870     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1871     return unless $res;
1872
1873     my $biblionumber     =  $res->{biblionumber};
1874
1875     if ($res->{borrowernumber} == $borrowernumber) {
1876         ModReserveFill($res);
1877     }
1878     else {
1879         # warn "Reserved";
1880         # The item is reserved by someone else.
1881         # Find this item in the reserves
1882
1883         my $borr_res  = Koha::Holds->search({
1884             borrowernumber => $borrowernumber,
1885             biblionumber   => $biblionumber,
1886         },{
1887             order_by       => 'priority'
1888         })->next();
1889
1890         if ( $borr_res ) {
1891             # The item is reserved by the current patron
1892             ModReserveFill($borr_res->unblessed);
1893         }
1894
1895         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1896             RevertWaitingStatus({ itemnumber => $itemnumber });
1897         }
1898         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1899             my $hold = Koha::Holds->find( $res->{reserve_id} );
1900             $hold->cancel;
1901         }
1902     }
1903 }
1904
1905 =head2 MergeHolds
1906
1907   MergeHolds($dbh,$to_biblio, $from_biblio);
1908
1909 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1910
1911 =cut
1912
1913 sub MergeHolds {
1914     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1915     my $sth = $dbh->prepare(
1916         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1917     );
1918     $sth->execute($from_biblio);
1919     if ( my $data = $sth->fetchrow_hashref() ) {
1920
1921         # holds exist on old record, if not we don't need to do anything
1922         $sth = $dbh->prepare(
1923             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1924         $sth->execute( $to_biblio, $from_biblio );
1925
1926         # Reorder by date
1927         # don't reorder those already waiting
1928
1929         $sth = $dbh->prepare(
1930 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1931         );
1932         my $upd_sth = $dbh->prepare(
1933 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1934         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1935         );
1936         $sth->execute( $to_biblio, 'W', 'T' );
1937         my $priority = 1;
1938         while ( my $reserve = $sth->fetchrow_hashref() ) {
1939             $upd_sth->execute(
1940                 $priority,                    $to_biblio,
1941                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1942                 $reserve->{'itemnumber'}
1943             );
1944             $priority++;
1945         }
1946     }
1947 }
1948
1949 =head2 RevertWaitingStatus
1950
1951   RevertWaitingStatus({ itemnumber => $itemnumber });
1952
1953   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1954
1955   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1956           item level hold, even if it was only a bibliolevel hold to
1957           begin with. This is because we can no longer know if a hold
1958           was item-level or bib-level after a hold has been set to
1959           waiting status.
1960
1961 =cut
1962
1963 sub RevertWaitingStatus {
1964     my ( $params ) = @_;
1965     my $itemnumber = $params->{'itemnumber'};
1966
1967     return unless ( $itemnumber );
1968
1969     my $dbh = C4::Context->dbh;
1970
1971     ## Get the waiting reserve we want to revert
1972     my $query = "
1973         SELECT * FROM reserves
1974         WHERE itemnumber = ?
1975         AND found IS NOT NULL
1976     ";
1977     my $sth = $dbh->prepare( $query );
1978     $sth->execute( $itemnumber );
1979     my $reserve = $sth->fetchrow_hashref();
1980
1981     my $hold = Koha::Holds->find( $reserve->{reserve_id} ); # TODO Remove the next raw SQL statements and use this instead
1982
1983     ## Increment the priority of all other non-waiting
1984     ## reserves for this bib record
1985     $query = "
1986         UPDATE reserves
1987         SET
1988           priority = priority + 1
1989         WHERE
1990           biblionumber =  ?
1991         AND
1992           priority > 0
1993     ";
1994     $sth = $dbh->prepare( $query );
1995     $sth->execute( $reserve->{'biblionumber'} );
1996
1997     $hold->set(
1998         {
1999             priority    => 1,
2000             found       => undef,
2001             waitingdate => undef,
2002             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2003         }
2004     )->store();
2005
2006     _FixPriority( { biblionumber => $reserve->{biblionumber} } );
2007
2008     return $hold;
2009 }
2010
2011 =head2 ReserveSlip
2012
2013 ReserveSlip(
2014     {
2015         branchcode     => $branchcode,
2016         borrowernumber => $borrowernumber,
2017         biblionumber   => $biblionumber,
2018         [ itemnumber   => $itemnumber, ]
2019         [ barcode      => $barcode, ]
2020     }
2021   )
2022
2023 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2024
2025 The letter code will be HOLD_SLIP, and the following tables are
2026 available within the slip:
2027
2028     reserves
2029     branches
2030     borrowers
2031     biblio
2032     biblioitems
2033     items
2034
2035 =cut
2036
2037 sub ReserveSlip {
2038     my ($args) = @_;
2039     my $branchcode     = $args->{branchcode};
2040     my $borrowernumber = $args->{borrowernumber};
2041     my $biblionumber   = $args->{biblionumber};
2042     my $itemnumber     = $args->{itemnumber};
2043     my $barcode        = $args->{barcode};
2044
2045
2046     my $patron = Koha::Patrons->find($borrowernumber);
2047
2048     my $hold;
2049     if ($itemnumber || $barcode ) {
2050         $itemnumber ||= Koha::Items->find( { barcode => $barcode } )->itemnumber;
2051
2052         $hold = Koha::Holds->search(
2053             {
2054                 biblionumber   => $biblionumber,
2055                 borrowernumber => $borrowernumber,
2056                 itemnumber     => $itemnumber
2057             }
2058         )->next;
2059     }
2060     else {
2061         $hold = Koha::Holds->search(
2062             {
2063                 biblionumber   => $biblionumber,
2064                 borrowernumber => $borrowernumber
2065             }
2066         )->next;
2067     }
2068
2069     return unless $hold;
2070     my $reserve = $hold->unblessed;
2071
2072     return  C4::Letters::GetPreparedLetter (
2073         module => 'circulation',
2074         letter_code => 'HOLD_SLIP',
2075         branchcode => $branchcode,
2076         lang => $patron->lang,
2077         tables => {
2078             'reserves'    => $reserve,
2079             'branches'    => $reserve->{branchcode},
2080             'borrowers'   => $reserve->{borrowernumber},
2081             'biblio'      => $reserve->{biblionumber},
2082             'biblioitems' => $reserve->{biblionumber},
2083             'items'       => $reserve->{itemnumber},
2084         },
2085     );
2086 }
2087
2088 =head2 GetReservesControlBranch
2089
2090   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2091
2092   Return the branchcode to be used to determine which reserves
2093   policy applies to a transaction.
2094
2095   C<$item> is a hashref for an item. Only 'homebranch' is used.
2096
2097   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2098
2099 =cut
2100
2101 sub GetReservesControlBranch {
2102     my ( $item, $borrower ) = @_;
2103
2104     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2105
2106     my $branchcode =
2107         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2108       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2109       :                                              undef;
2110
2111     return $branchcode;
2112 }
2113
2114 =head2 CalculatePriority
2115
2116     my $p = CalculatePriority($biblionumber, $resdate);
2117
2118 Calculate priority for a new reserve on biblionumber, placing it at
2119 the end of the line of all holds whose start date falls before
2120 the current system time and that are neither on the hold shelf
2121 or in transit.
2122
2123 The reserve date parameter is optional; if it is supplied, the
2124 priority is based on the set of holds whose start date falls before
2125 the parameter value.
2126
2127 After calculation of this priority, it is recommended to call
2128 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2129 AddReserves.
2130
2131 =cut
2132
2133 sub CalculatePriority {
2134     my ( $biblionumber, $resdate ) = @_;
2135
2136     my $sql = q{
2137         SELECT COUNT(*) FROM reserves
2138         WHERE biblionumber = ?
2139         AND   priority > 0
2140         AND   (found IS NULL OR found = '')
2141     };
2142     #skip found==W or found==T (waiting or transit holds)
2143     if( $resdate ) {
2144         $sql.= ' AND ( reservedate <= ? )';
2145     }
2146     else {
2147         $sql.= ' AND ( reservedate < NOW() )';
2148     }
2149     my $dbh = C4::Context->dbh();
2150     my @row = $dbh->selectrow_array(
2151         $sql,
2152         undef,
2153         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2154     );
2155
2156     return @row ? $row[0]+1 : 1;
2157 }
2158
2159 =head2 IsItemOnHoldAndFound
2160
2161     my $bool = IsItemFoundHold( $itemnumber );
2162
2163     Returns true if the item is currently on hold
2164     and that hold has a non-null found status ( W, T, etc. )
2165
2166 =cut
2167
2168 sub IsItemOnHoldAndFound {
2169     my ($itemnumber) = @_;
2170
2171     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2172
2173     my $found = $rs->count(
2174         {
2175             itemnumber => $itemnumber,
2176             found      => { '!=' => undef }
2177         }
2178     );
2179
2180     return $found;
2181 }
2182
2183 =head2 GetMaxPatronHoldsForRecord
2184
2185 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2186
2187 For multiple holds on a given record for a given patron, the max
2188 number of record level holds that a patron can be placed is the highest
2189 value of the holds_per_record rule for each item if the record for that
2190 patron. This subroutine finds and returns the highest holds_per_record
2191 rule value for a given patron id and record id.
2192
2193 =cut
2194
2195 sub GetMaxPatronHoldsForRecord {
2196     my ( $borrowernumber, $biblionumber ) = @_;
2197
2198     my $patron = Koha::Patrons->find($borrowernumber);
2199     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2200
2201     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2202
2203     my $categorycode = $patron->categorycode;
2204     my $branchcode;
2205     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2206
2207     my $max = 0;
2208     foreach my $item (@items) {
2209         my $itemtype = $item->effective_itemtype();
2210
2211         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2212
2213         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2214         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2215         $max = $holds_per_record if $holds_per_record > $max;
2216     }
2217
2218     return $max;
2219 }
2220
2221 =head2 GetHoldRule
2222
2223 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2224
2225 Returns the matching hold related issuingrule fields for a given
2226 patron category, itemtype, and library.
2227
2228 =cut
2229
2230 sub GetHoldRule {
2231     my ( $categorycode, $itemtype, $branchcode ) = @_;
2232
2233     my $reservesallowed = Koha::CirculationRules->get_effective_rule(
2234         {
2235             itemtype     => $itemtype,
2236             categorycode => $categorycode,
2237             branchcode   => $branchcode,
2238             rule_name    => 'reservesallowed',
2239             order_by     => {
2240                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2241             }
2242         }
2243     );
2244
2245     my $rules;
2246     if ( $reservesallowed ) {
2247         $rules->{reservesallowed} = $reservesallowed->rule_value;
2248         $rules->{itemtype}        = $reservesallowed->itemtype;
2249         $rules->{categorycode}    = $reservesallowed->categorycode;
2250         $rules->{branchcode}      = $reservesallowed->branchcode;
2251     }
2252
2253     my $holds_per_x_rules = Koha::CirculationRules->get_effective_rules(
2254         {
2255             itemtype     => $itemtype,
2256             categorycode => $categorycode,
2257             branchcode   => $branchcode,
2258             rules        => ['holds_per_record', 'holds_per_day'],
2259             order_by     => {
2260                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2261             }
2262         }
2263     );
2264     $rules->{holds_per_record} = $holds_per_x_rules->{holds_per_record};
2265     $rules->{holds_per_day} = $holds_per_x_rules->{holds_per_day};
2266
2267     return $rules;
2268 }
2269
2270 =head1 AUTHOR
2271
2272 Koha Development Team <http://koha-community.org/>
2273
2274 =cut
2275
2276 1;