C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use DateTime;
  25 use Koha::DateUtils;
  26 use C4::Context;
  27 use C4::Stats;
  28 use C4::Reserves;
  29 use C4::Biblio;
  30 use C4::Items;
  31 use C4::Members;
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Debug;
  36 use C4::Log; # logaction
  37 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits;
  40
  41 use Data::Dumper;
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils;
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::IssuingRules;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments;
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Holds;
  55 use Koha::RefundLostItemFeeRule;
  56 use Koha::RefundLostItemFeeRules;
  57 use Koha::Account::Lines;
  58 use Koha::Account::Offsets;
  59 use Carp;
  60 use List::MoreUtils qw( uniq );
  61 use Scalar::Util qw( looks_like_number );
  62 use Date::Calc qw(
  63   Today
  64   Today_and_Now
  65   Add_Delta_YM
  66   Add_Delta_DHMS
  67   Date_to_Days
  68   Day_of_Week
  69   Add_Delta_Days
  70 );
  71 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  72
  73 BEGIN {
  74         require Exporter;
  75         @ISA    = qw(Exporter);
  76
  77         # FIXME subs that should probably be elsewhere
  78         push @EXPORT, qw(
  79                 &barcodedecode
  80         &LostItem
  81         &ReturnLostItem
  82         &GetPendingOnSiteCheckouts
  83         );
  84
  85         # subs to deal with issuing a book
  86         push @EXPORT, qw(
  87                 &CanBookBeIssued
  88                 &CanBookBeRenewed
  89                 &AddIssue
  90                 &AddRenewal
  91                 &GetRenewCount
  92         &GetSoonestRenewDate
  93         &GetLatestAutoRenewDate
  94                 &GetIssuingCharges
  95         &GetBranchBorrowerCircRule
  96         &GetBranchItemRule
  97                 &GetBiblioIssues
  98                 &GetOpenIssue
  99         &CheckIfIssuedToPatron
 100         &IsItemIssued
 101         GetTopIssues
 102         );
 103
 104         # subs to deal with returns
 105         push @EXPORT, qw(
 106                 &AddReturn
 107         &MarkIssueReturned
 108         );
 109
 110         # subs to deal with transfers
 111         push @EXPORT, qw(
 112                 &transferbook
 113                 &GetTransfers
 114                 &GetTransfersFromTo
 115                 &updateWrongTransfer
 116                 &DeleteTransfer
 117                 &IsBranchTransferAllowed
 118                 &CreateBranchTransferLimit
 119                 &DeleteBranchTransferLimits
 120         &TransferSlip
 121         );
 122
 123     # subs to deal with offline circulation
 124     push @EXPORT, qw(
 125       &GetOfflineOperations
 126       &GetOfflineOperation
 127       &AddOfflineOperation
 128       &DeleteOfflineOperation
 129       &ProcessOfflineOperation
 130     );
 131 }
 132
 133 =head1 NAME
 134
 135 C4::Circulation - Koha circulation module
 136
 137 =head1 SYNOPSIS
 138
 139 use C4::Circulation;
 140
 141 =head1 DESCRIPTION
 142
 143 The functions in this module deal with circulation, issues, and
 144 returns, as well as general information about the library.
 145 Also deals with inventory.
 146
 147 =head1 FUNCTIONS
 148
 149 =head2 barcodedecode
 150
 151   $str = &barcodedecode($barcode, [$filter]);
 152
 153 Generic filter function for barcode string.
 154 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 155 Will do some manipulation of the barcode for systems that deliver a barcode
 156 to circulation.pl that differs from the barcode stored for the item.
 157 For proper functioning of this filter, calling the function on the
 158 correct barcode string (items.barcode) should return an unaltered barcode.
 159
 160 The optional $filter argument is to allow for testing or explicit
 161 behavior that ignores the System Pref.  Valid values are the same as the
 162 System Pref options.
 163
 164 =cut
 165
 166 # FIXME -- the &decode fcn below should be wrapped into this one.
 167 # FIXME -- these plugins should be moved out of Circulation.pm
 168 #
 169 sub barcodedecode {
 170     my ($barcode, $filter) = @_;
 171     my $branch = C4::Context::mybranch();
 172     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 173     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 174         if ($filter eq 'whitespace') {
 175                 $barcode =~ s/\s//g;
 176         } elsif ($filter eq 'cuecat') {
 177                 chomp($barcode);
 178             my @fields = split( /\./, $barcode );
 179             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 180             ($#results == 2) and return $results[2];
 181         } elsif ($filter eq 'T-prefix') {
 182                 if ($barcode =~ /^[Tt](\d)/) {
 183                         (defined($1) and $1 eq '0') and return $barcode;
 184             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 185                 }
 186         return sprintf("T%07d", $barcode);
 187         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 188         # Why drop the nonzero digit after the T?
 189         # Why pass non-digits (or empty string) to "T%07d"?
 190         } elsif ($filter eq 'libsuite8') {
 191                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 192                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 193                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 194                         }else{
 195                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 196                         }
 197                 }
 198     } elsif ($filter eq 'EAN13') {
 199         my $ean = CheckDigits('ean');
 200         if ( $ean->is_valid($barcode) ) {
 201             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 202             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 203         } else {
 204             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 205         }
 206         }
 207     return $barcode;    # return barcode, modified or not
 208 }
 209
 210 =head2 decode
 211
 212   $str = &decode($chunk);
 213
 214 Decodes a segment of a string emitted by a CueCat barcode scanner and
 215 returns it.
 216
 217 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 218 or Javascript based decoding on the client side.
 219
 220 =cut
 221
 222 sub decode {
 223     my ($encoded) = @_;
 224     my $seq =
 225       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 226     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 227     my $l = ( $#s + 1 ) % 4;
 228     if ($l) {
 229         if ( $l == 1 ) {
 230             # warn "Error: Cuecat decode parsing failed!";
 231             return;
 232         }
 233         $l = 4 - $l;
 234         $#s += $l;
 235     }
 236     my $r = '';
 237     while ( $#s >= 0 ) {
 238         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 239         $r .=
 240             chr( ( $n >> 16 ) ^ 67 )
 241          .chr( ( $n >> 8 & 255 ) ^ 67 )
 242          .chr( ( $n & 255 ) ^ 67 );
 243         @s = @s[ 4 .. $#s ];
 244     }
 245     $r = substr( $r, 0, length($r) - $l );
 246     return $r;
 247 }
 248
 249 =head2 transferbook
 250
 251   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 252                                             $barcode, $ignore_reserves);
 253
 254 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 255
 256 C<$newbranch> is the code for the branch to which the item should be transferred.
 257
 258 C<$barcode> is the barcode of the item to be transferred.
 259
 260 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 261 Otherwise, if an item is reserved, the transfer fails.
 262
 263 Returns three values:
 264
 265 =over
 266
 267 =item $dotransfer
 268
 269 is true if the transfer was successful.
 270
 271 =item $messages
 272
 273 is a reference-to-hash which may have any of the following keys:
 274
 275 =over
 276
 277 =item C<BadBarcode>
 278
 279 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 280
 281 =item C<IsPermanent>
 282
 283 The item's home branch is permanent. This doesn't prevent the item from being transferred, though. The value is the code of the item's home branch.
 284
 285 =item C<DestinationEqualsHolding>
 286
 287 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 288
 289 =item C<WasReturned>
 290
 291 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 292
 293 =item C<ResFound>
 294
 295 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 296
 297 =item C<WasTransferred>
 298
 299 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 300
 301 =back
 302
 303 =back
 304
 305 =cut
 306
 307 sub transferbook {
 308     my ( $tbr, $barcode, $ignoreRs ) = @_;
 309     my $messages;
 310     my $dotransfer      = 1;
 311     my $item = Koha::Items->find( { barcode => $barcode } );
 312
 313     # bad barcode..
 314     unless ( $item ) {
 315         $messages->{'BadBarcode'} = $barcode;
 316         $dotransfer = 0;
 317     }
 318
 319     my $itemnumber = $item->itemnumber;
 320     my $issue = GetOpenIssue($itemnumber);
 321     # get branches of book...
 322     my $hbr = $item->homebranch;
 323     my $fbr = $item->holdingbranch;
 324
 325     # if using Branch Transfer Limits
 326     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 327         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 328         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 329             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 330                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 331                 $dotransfer = 0;
 332             }
 333         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 334             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 335             $dotransfer = 0;
 336         }
 337     }
 338
 339     # if is permanent...
 340     # FIXME Is this still used by someone?
 341     # See other FIXME in AddReturn
 342     my $library = Koha::Libraries->find($hbr);
 343     if ( $library and $library->get_categories->search({'me.categorycode' => 'PE'})->count ) {
 344         $messages->{'IsPermanent'} = $hbr;
 345         $dotransfer = 0;
 346     }
 347
 348     # can't transfer book if is already there....
 349     if ( $fbr eq $tbr ) {
 350         $messages->{'DestinationEqualsHolding'} = 1;
 351         $dotransfer = 0;
 352     }
 353
 354     # check if it is still issued to someone, return it...
 355     if ( $issue ) {
 356         AddReturn( $barcode, $fbr );
 357         $messages->{'WasReturned'} = $issue->borrowernumber;
 358     }
 359
 360     # find reserves.....
 361     # That'll save a database query.
 362     my ( $resfound, $resrec, undef ) =
 363       CheckReserves( $itemnumber );
 364     if ( $resfound and not $ignoreRs ) {
 365         $resrec->{'ResFound'} = $resfound;
 366
 367         #         $messages->{'ResFound'} = $resrec;
 368         $dotransfer = 1;
 369     }
 370
 371     #actually do the transfer....
 372     if ($dotransfer) {
 373         ModItemTransfer( $itemnumber, $fbr, $tbr );
 374
 375         # don't need to update MARC anymore, we do it in batch now
 376         $messages->{'WasTransfered'} = 1;
 377
 378     }
 379     ModDateLastSeen( $itemnumber );
 380     return ( $dotransfer, $messages );
 381 }
 382
 383
 384 sub TooMany {
 385     my $borrower        = shift;
 386     my $biblionumber = shift;
 387         my $item                = shift;
 388     my $params = shift;
 389     my $onsite_checkout = $params->{onsite_checkout} || 0;
 390     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 391     my $cat_borrower    = $borrower->{'categorycode'};
 392     my $dbh             = C4::Context->dbh;
 393         my $branch;
 394         # Get which branchcode we need
 395         $branch = _GetCircControlBranch($item,$borrower);
 396         my $type = (C4::Context->preference('item-level_itypes'))
 397                         ? $item->{'itype'}         # item-level
 398                         : $item->{'itemtype'};     # biblio-level
 399
 400     # given branch, patron category, and item type, determine
 401     # applicable issuing rule
 402     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
 403         {   categorycode => $cat_borrower,
 404             itemtype     => $type,
 405             branchcode   => $branch
 406         }
 407     );
 408
 409
 410     # if a rule is found and has a loan limit set, count
 411     # how many loans the patron already has that meet that
 412     # rule
 413     if (defined($issuing_rule) and defined($issuing_rule->maxissueqty)) {
 414         my @bind_params;
 415         my $count_query = q|
 416             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 417             FROM issues
 418             JOIN items USING (itemnumber)
 419         |;
 420
 421         my $rule_itemtype = $issuing_rule->itemtype;
 422         if ($rule_itemtype eq "*") {
 423             # matching rule has the default item type, so count only
 424             # those existing loans that don't fall under a more
 425             # specific rule
 426             if (C4::Context->preference('item-level_itypes')) {
 427                 $count_query .= " WHERE items.itype NOT IN (
 428                                     SELECT itemtype FROM issuingrules
 429                                     WHERE branchcode = ?
 430                                     AND   (categorycode = ? OR categorycode = ?)
 431                                     AND   itemtype <> '*'
 432                                   ) ";
 433             } else {
 434                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 435                                   WHERE biblioitems.itemtype NOT IN (
 436                                     SELECT itemtype FROM issuingrules
 437                                     WHERE branchcode = ?
 438                                     AND   (categorycode = ? OR categorycode = ?)
 439                                     AND   itemtype <> '*'
 440                                   ) ";
 441             }
 442             push @bind_params, $issuing_rule->branchcode;
 443             push @bind_params, $issuing_rule->categorycode;
 444             push @bind_params, $cat_borrower;
 445         } else {
 446             # rule has specific item type, so count loans of that
 447             # specific item type
 448             if (C4::Context->preference('item-level_itypes')) {
 449                 $count_query .= " WHERE items.itype = ? ";
 450             } else {
 451                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 452                                   WHERE biblioitems.itemtype= ? ";
 453             }
 454             push @bind_params, $type;
 455         }
 456
 457         $count_query .= " AND borrowernumber = ? ";
 458         push @bind_params, $borrower->{'borrowernumber'};
 459         my $rule_branch = $issuing_rule->branchcode;
 460         if ($rule_branch ne "*") {
 461             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 462                 $count_query .= " AND issues.branchcode = ? ";
 463                 push @bind_params, $branch;
 464             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 465                 ; # if branch is the patron's home branch, then count all loans by patron
 466             } else {
 467                 $count_query .= " AND items.homebranch = ? ";
 468                 push @bind_params, $branch;
 469             }
 470         }
 471
 472         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 473
 474         my $max_checkouts_allowed = $issuing_rule->maxissueqty;
 475         my $max_onsite_checkouts_allowed = $issuing_rule->maxonsiteissueqty;
 476
 477         if ( $onsite_checkout ) {
 478             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 479                 return {
 480                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 481                     count => $onsite_checkout_count,
 482                     max_allowed => $max_onsite_checkouts_allowed,
 483                 }
 484             }
 485         }
 486         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 487             my $delta = $switch_onsite_checkout ? 1 : 0;
 488             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 489                 return {
 490                     reason => 'TOO_MANY_CHECKOUTS',
 491                     count => $checkout_count,
 492                     max_allowed => $max_checkouts_allowed,
 493                 };
 494             }
 495         } elsif ( not $onsite_checkout ) {
 496             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 497                 return {
 498                     reason => 'TOO_MANY_CHECKOUTS',
 499                     count => $checkout_count - $onsite_checkout_count,
 500                     max_allowed => $max_checkouts_allowed,
 501                 };
 502             }
 503         }
 504     }
 505
 506     # Now count total loans against the limit for the branch
 507     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 508     if (defined($branch_borrower_circ_rule->{maxissueqty})) {
 509         my @bind_params = ();
 510         my $branch_count_query = q|
 511             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 512             FROM issues
 513             JOIN items USING (itemnumber)
 514             WHERE borrowernumber = ?
 515         |;
 516         push @bind_params, $borrower->{borrowernumber};
 517
 518         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 519             $branch_count_query .= " AND issues.branchcode = ? ";
 520             push @bind_params, $branch;
 521         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 522             ; # if branch is the patron's home branch, then count all loans by patron
 523         } else {
 524             $branch_count_query .= " AND items.homebranch = ? ";
 525             push @bind_params, $branch;
 526         }
 527         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 528         my $max_checkouts_allowed = $branch_borrower_circ_rule->{maxissueqty};
 529         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{maxonsiteissueqty};
 530
 531         if ( $onsite_checkout ) {
 532             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 533                 return {
 534                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 535                     count => $onsite_checkout_count,
 536                     max_allowed => $max_onsite_checkouts_allowed,
 537                 }
 538             }
 539         }
 540         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 541             my $delta = $switch_onsite_checkout ? 1 : 0;
 542             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 543                 return {
 544                     reason => 'TOO_MANY_CHECKOUTS',
 545                     count => $checkout_count,
 546                     max_allowed => $max_checkouts_allowed,
 547                 };
 548             }
 549         } elsif ( not $onsite_checkout ) {
 550             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 551                 return {
 552                     reason => 'TOO_MANY_CHECKOUTS',
 553                     count => $checkout_count - $onsite_checkout_count,
 554                     max_allowed => $max_checkouts_allowed,
 555                 };
 556             }
 557         }
 558     }
 559
 560     if ( not defined( $issuing_rule ) and not defined($branch_borrower_circ_rule->{maxissueqty}) ) {
 561         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 562     }
 563
 564     # OK, the patron can issue !!!
 565     return;
 566 }
 567
 568 =head2 CanBookBeIssued
 569
 570   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $borrower,
 571                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 572
 573 Check if a book can be issued.
 574
 575 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 576
 577 IMPORTANT: The assumption by users of this routine is that causes blocking
 578 the issue are keyed by uppercase labels and other returned
 579 data is keyed in lower case!
 580
 581 =over 4
 582
 583 =item C<$borrower> hash with borrower informations (from Koha::Patron->unblessed)
 584
 585 =item C<$barcode> is the bar code of the book being issued.
 586
 587 =item C<$duedates> is a DateTime object.
 588
 589 =item C<$inprocess> boolean switch
 590
 591 =item C<$ignore_reserves> boolean switch
 592
 593 =item C<$params> Hashref of additional parameters
 594
 595 Available keys:
 596     override_high_holds - Ignore high holds
 597     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 598
 599 =back
 600
 601 Returns :
 602
 603 =over 4
 604
 605 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 606 Possible values are :
 607
 608 =back
 609
 610 =head3 INVALID_DATE
 611
 612 sticky due date is invalid
 613
 614 =head3 GNA
 615
 616 borrower gone with no address
 617
 618 =head3 CARD_LOST
 619
 620 borrower declared it's card lost
 621
 622 =head3 DEBARRED
 623
 624 borrower debarred
 625
 626 =head3 UNKNOWN_BARCODE
 627
 628 barcode unknown
 629
 630 =head3 NOT_FOR_LOAN
 631
 632 item is not for loan
 633
 634 =head3 WTHDRAWN
 635
 636 item withdrawn.
 637
 638 =head3 RESTRICTED
 639
 640 item is restricted (set by ??)
 641
 642 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 643 could be prevented, but ones that can be overriden by the operator.
 644
 645 Possible values are :
 646
 647 =head3 DEBT
 648
 649 borrower has debts.
 650
 651 =head3 RENEW_ISSUE
 652
 653 renewing, not issuing
 654
 655 =head3 ISSUED_TO_ANOTHER
 656
 657 issued to someone else.
 658
 659 =head3 RESERVED
 660
 661 reserved for someone else.
 662
 663 =head3 INVALID_DATE
 664
 665 sticky due date is invalid or due date in the past
 666
 667 =head3 TOO_MANY
 668
 669 if the borrower borrows to much things
 670
 671 =cut
 672
 673 sub CanBookBeIssued {
 674     my ( $borrower, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 675     my %needsconfirmation;    # filled with problems that needs confirmations
 676     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 677     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 678     my %messages;             # filled with information messages that should be displayed.
 679
 680     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 681     my $override_high_holds = $params->{override_high_holds} || 0;
 682
 683     my $item = GetItem(undef, $barcode );
 684     my $issue = Koha::Checkouts->find( { itemnumber => $item->{itemnumber} } );
 685         my $biblioitem = GetBiblioItemData($item->{biblioitemnumber});
 686         $item->{'itemtype'}=$item->{'itype'};
 687     my $dbh             = C4::Context->dbh;
 688
 689     # MANDATORY CHECKS - unless item exists, nothing else matters
 690     unless ( $item->{barcode} ) {
 691         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 692     }
 693         return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 694
 695     #
 696     # DUE DATE is OK ? -- should already have checked.
 697     #
 698     if ($duedate && ref $duedate ne 'DateTime') {
 699         $duedate = dt_from_string($duedate);
 700     }
 701     my $now = DateTime->now( time_zone => C4::Context->tz() );
 702     unless ( $duedate ) {
 703         my $issuedate = $now->clone();
 704
 705         my $branch = _GetCircControlBranch($item,$borrower);
 706         my $itype = ( C4::Context->preference('item-level_itypes') ) ? $item->{'itype'} : $biblioitem->{'itemtype'};
 707         $duedate = CalcDateDue( $issuedate, $itype, $branch, $borrower );
 708
 709         # Offline circ calls AddIssue directly, doesn't run through here
 710         #  So issuingimpossible should be ok.
 711     }
 712     if ($duedate) {
 713         my $today = $now->clone();
 714         $today->truncate( to => 'minute');
 715         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 716             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 717         }
 718     } else {
 719             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 720     }
 721
 722     #
 723     # BORROWER STATUS
 724     #
 725     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
 726     if ( $patron->category->category_type eq 'X' && (  $item->{barcode}  )) {
 727         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 728         &UpdateStats({
 729                      branch => C4::Context->userenv->{'branch'},
 730                      type => 'localuse',
 731                      itemnumber => $item->{'itemnumber'},
 732                      itemtype => $item->{'itype'},
 733                      borrowernumber => $borrower->{'borrowernumber'},
 734                      ccode => $item->{'ccode'}}
 735                     );
 736         ModDateLastSeen( $item->{'itemnumber'} );
 737         return( { STATS => 1 }, {});
 738     }
 739
 740     my $flags = C4::Members::patronflags( $borrower );
 741     if ( ref $flags ) {
 742         if ( $flags->{GNA} ) {
 743             $issuingimpossible{GNA} = 1;
 744         }
 745         if ( $flags->{'LOST'} ) {
 746             $issuingimpossible{CARD_LOST} = 1;
 747         }
 748         if ( $flags->{'DBARRED'} ) {
 749             $issuingimpossible{DEBARRED} = 1;
 750         }
 751     }
 752     if ( !defined $borrower->{dateexpiry} || $borrower->{'dateexpiry'} eq '0000-00-00') {
 753         $issuingimpossible{EXPIRED} = 1;
 754     } else {
 755         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'sql', 'floating' );
 756         $expiry_dt->truncate( to => 'day');
 757         my $today = $now->clone()->truncate(to => 'day');
 758         $today->set_time_zone( 'floating' );
 759         if ( DateTime->compare($today, $expiry_dt) == 1 ) {
 760             $issuingimpossible{EXPIRED} = 1;
 761         }
 762     }
 763
 764     #
 765     # BORROWER STATUS
 766     #
 767
 768     # DEBTS
 769     my ($balance, $non_issue_charges, $other_charges) =
 770       C4::Members::GetMemberAccountBalance( $borrower->{'borrowernumber'} );
 771
 772     my $amountlimit = C4::Context->preference("noissuescharge");
 773     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 774     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 775
 776     # Check the debt of this patrons guarantees
 777     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 778     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 779     if ( defined $no_issues_charge_guarantees ) {
 780         my $p = Koha::Patrons->find( $borrower->{borrowernumber} );
 781         my @guarantees = $p->guarantees();
 782         my $guarantees_non_issues_charges;
 783         foreach my $g ( @guarantees ) {
 784             my ( $b, $n, $o ) = C4::Members::GetMemberAccountBalance( $g->id );
 785             $guarantees_non_issues_charges += $n;
 786         }
 787
 788         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 789             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 790         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 791             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 792         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 793             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 794         }
 795     }
 796
 797     if ( C4::Context->preference("IssuingInProcess") ) {
 798         if ( $non_issue_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 799             $issuingimpossible{DEBT} = sprintf( "%.2f", $non_issue_charges );
 800         } elsif ( $non_issue_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 801             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 802         } elsif ( $allfinesneedoverride && $non_issue_charges > 0 && $non_issue_charges <= $amountlimit && !$inprocess ) {
 803             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 804         }
 805     }
 806     else {
 807         if ( $non_issue_charges > $amountlimit && $allowfineoverride ) {
 808             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 809         } elsif ( $non_issue_charges > $amountlimit && !$allowfineoverride) {
 810             $issuingimpossible{DEBT} = sprintf( "%.2f", $non_issue_charges );
 811         } elsif ( $non_issue_charges > 0 && $allfinesneedoverride ) {
 812             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 813         }
 814     }
 815
 816     if ($balance > 0 && $other_charges > 0) {
 817         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 818     }
 819
 820     $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
 821     if ( my $debarred_date = $patron->is_debarred ) {
 822          # patron has accrued fine days or has a restriction. $count is a date
 823         if ($debarred_date eq '9999-12-31') {
 824             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 825         }
 826         else {
 827             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 828         }
 829     } elsif ( my $num_overdues = $patron->has_overdues ) {
 830         ## patron has outstanding overdue loans
 831         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 832             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 833         }
 834         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 835             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 836         }
 837     }
 838
 839     #
 840     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 841     #
 842     if ( $issue && $issue->borrowernumber eq $borrower->{'borrowernumber'} ){
 843
 844         # Already issued to current borrower.
 845         # If it is an on-site checkout if it can be switched to a normal checkout
 846         # or ask whether the loan should be renewed
 847
 848         if ( $issue->onsite_checkout
 849                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 850             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 851         } else {
 852             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 853                 $borrower->{'borrowernumber'},
 854                 $item->{'itemnumber'},
 855             );
 856             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 857                 if ( $renewerror eq 'onsite_checkout' ) {
 858                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 859                 }
 860                 else {
 861                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 862                 }
 863             }
 864             else {
 865                 $needsconfirmation{RENEW_ISSUE} = 1;
 866             }
 867         }
 868     }
 869     elsif ( $issue ) {
 870
 871         # issued to someone else
 872
 873         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 874
 875         my ( $can_be_returned, $message ) = CanBookBeReturned( $item, C4::Context->userenv->{branch} );
 876
 877         unless ( $can_be_returned ) {
 878             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 879             $issuingimpossible{branch_to_return} = $message;
 880         } else {
 881             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 882             $needsconfirmation{issued_firstname} = $patron->firstname;
 883             $needsconfirmation{issued_surname} = $patron->surname;
 884             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 885             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 886         }
 887     }
 888
 889     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 890     #
 891     my $switch_onsite_checkout = (
 892           C4::Context->preference('SwitchOnSiteCheckouts')
 893       and $issue
 894       and $issue->onsite_checkout
 895       and $issue->borrowernumber == $borrower->{'borrowernumber'} ? 1 : 0 );
 896     my $toomany = TooMany( $borrower, $item->{biblionumber}, $item, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 897     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 898     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 899         if ( $toomany->{max_allowed} == 0 ) {
 900             $needsconfirmation{PATRON_CANT} = 1;
 901         }
 902         if ( C4::Context->preference("AllowTooManyOverride") ) {
 903             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 904             $needsconfirmation{current_loan_count} = $toomany->{count};
 905             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 906         } else {
 907             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 908             $issuingimpossible{current_loan_count} = $toomany->{count};
 909             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 910         }
 911     }
 912
 913     #
 914     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 915     #
 916     $patron = Koha::Patrons->find($borrower->{borrowernumber});
 917     my $wants_check = $patron->wants_check_for_previous_checkout;
 918     $needsconfirmation{PREVISSUE} = 1
 919         if ($wants_check and $patron->do_check_for_previous_checkout($item));
 920
 921     #
 922     # ITEM CHECKING
 923     #
 924     if ( $item->{'notforloan'} )
 925     {
 926         if(!C4::Context->preference("AllowNotForLoanOverride")){
 927             $issuingimpossible{NOT_FOR_LOAN} = 1;
 928             $issuingimpossible{item_notforloan} = $item->{'notforloan'};
 929         }else{
 930             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 931             $needsconfirmation{item_notforloan} = $item->{'notforloan'};
 932         }
 933     }
 934     else {
 935         # we have to check itemtypes.notforloan also
 936         if (C4::Context->preference('item-level_itypes')){
 937             # this should probably be a subroutine
 938             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 939             $sth->execute($item->{'itemtype'});
 940             my $notforloan=$sth->fetchrow_hashref();
 941             if ($notforloan->{'notforloan'}) {
 942                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 943                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 944                     $issuingimpossible{itemtype_notforloan} = $item->{'itype'};
 945                 } else {
 946                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 947                     $needsconfirmation{itemtype_notforloan} = $item->{'itype'};
 948                 }
 949             }
 950         }
 951         elsif ($biblioitem->{'notforloan'} == 1){
 952             if (!C4::Context->preference("AllowNotForLoanOverride")) {
 953                 $issuingimpossible{NOT_FOR_LOAN} = 1;
 954                 $issuingimpossible{itemtype_notforloan} = $biblioitem->{'itemtype'};
 955             } else {
 956                 $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 957                 $needsconfirmation{itemtype_notforloan} = $biblioitem->{'itemtype'};
 958             }
 959         }
 960     }
 961     if ( $item->{'withdrawn'} && $item->{'withdrawn'} > 0 )
 962     {
 963         $issuingimpossible{WTHDRAWN} = 1;
 964     }
 965     if (   $item->{'restricted'}
 966         && $item->{'restricted'} == 1 )
 967     {
 968         $issuingimpossible{RESTRICTED} = 1;
 969     }
 970     if ( $item->{'itemlost'} && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 971         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item->{itemlost} });
 972         my $code = $av->count ? $av->next->lib : '';
 973         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 974         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 975     }
 976     if ( C4::Context->preference("IndependentBranches") ) {
 977         my $userenv = C4::Context->userenv;
 978         unless ( C4::Context->IsSuperLibrarian() ) {
 979             if ( $item->{C4::Context->preference("HomeOrHoldingBranch")} ne $userenv->{branch} ){
 980                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 981                 $issuingimpossible{'itemhomebranch'} = $item->{C4::Context->preference("HomeOrHoldingBranch")};
 982             }
 983             $needsconfirmation{BORRNOTSAMEBRANCH} = $borrower->{'branchcode'}
 984               if ( $borrower->{'branchcode'} ne $userenv->{branch} );
 985         }
 986     }
 987     #
 988     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
 989     #
 990     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
 991
 992     if ( $rentalConfirmation ){
 993         my ($rentalCharge) = GetIssuingCharges( $item->{'itemnumber'}, $borrower->{'borrowernumber'} );
 994         if ( $rentalCharge > 0 ){
 995             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
 996         }
 997     }
 998
 999     unless ( $ignore_reserves ) {
1000         # See if the item is on reserve.
1001         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item->{'itemnumber'} );
1002         if ($restype) {
1003             my $resbor = $res->{'borrowernumber'};
1004             if ( $resbor ne $borrower->{'borrowernumber'} ) {
1005                 my $patron = Koha::Patrons->find( $resbor );
1006                 if ( $restype eq "Waiting" )
1007                 {
1008                     # The item is on reserve and waiting, but has been
1009                     # reserved by some other patron.
1010                     $needsconfirmation{RESERVE_WAITING} = 1;
1011                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1012                     $needsconfirmation{'ressurname'} = $patron->surname;
1013                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1014                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1015                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1016                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1017                 }
1018                 elsif ( $restype eq "Reserved" ) {
1019                     # The item is on reserve for someone else.
1020                     $needsconfirmation{RESERVED} = 1;
1021                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1022                     $needsconfirmation{'ressurname'} = $patron->surname;
1023                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1024                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1025                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1026                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1027                 }
1028             }
1029         }
1030     }
1031
1032     ## CHECK AGE RESTRICTION
1033     my $agerestriction  = $biblioitem->{'agerestriction'};
1034     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $borrower );
1035     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1036         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1037             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1038         }
1039         else {
1040             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1041         }
1042     }
1043
1044     ## check for high holds decreasing loan period
1045     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1046         my $check = checkHighHolds( $item, $borrower );
1047
1048         if ( $check->{exceeded} ) {
1049             if ($override_high_holds) {
1050                 $alerts{HIGHHOLDS} = {
1051                     num_holds  => $check->{outstanding},
1052                     duration   => $check->{duration},
1053                     returndate => output_pref( $check->{due_date} ),
1054                 };
1055             }
1056             else {
1057                 $needsconfirmation{HIGHHOLDS} = {
1058                     num_holds  => $check->{outstanding},
1059                     duration   => $check->{duration},
1060                     returndate => output_pref( $check->{due_date} ),
1061                 };
1062             }
1063         }
1064     }
1065
1066     if (
1067         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1068         # don't do the multiple loans per bib check if we've
1069         # already determined that we've got a loan on the same item
1070         !$issuingimpossible{NO_MORE_RENEWALS} &&
1071         !$needsconfirmation{RENEW_ISSUE}
1072     ) {
1073         # Check if borrower has already issued an item from the same biblio
1074         # Only if it's not a subscription
1075         my $biblionumber = $item->{biblionumber};
1076         require C4::Serials;
1077         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1078         unless ($is_a_subscription) {
1079             my $checkouts = Koha::Checkouts->search(
1080                 {
1081                     borrowernumber => $borrower->{borrowernumber},
1082                     biblionumber   => $biblionumber,
1083                 },
1084                 {
1085                     join => 'item',
1086                 }
1087             );
1088             # if we get here, we don't already have a loan on this item,
1089             # so if there are any loans on this bib, ask for confirmation
1090             if ( $checkouts->count ) {
1091                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1092             }
1093         }
1094     }
1095
1096     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1097 }
1098
1099 =head2 CanBookBeReturned
1100
1101   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1102
1103 Check whether the item can be returned to the provided branch
1104
1105 =over 4
1106
1107 =item C<$item> is a hash of item information as returned from GetItem
1108
1109 =item C<$branch> is the branchcode where the return is taking place
1110
1111 =back
1112
1113 Returns:
1114
1115 =over 4
1116
1117 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1118
1119 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1120
1121 =back
1122
1123 =cut
1124
1125 sub CanBookBeReturned {
1126   my ($item, $branch) = @_;
1127   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1128
1129   # assume return is allowed to start
1130   my $allowed = 1;
1131   my $message;
1132
1133   # identify all cases where return is forbidden
1134   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1135      $allowed = 0;
1136      $message = $item->{'homebranch'};
1137   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1138      $allowed = 0;
1139      $message = $item->{'holdingbranch'};
1140   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1141      $allowed = 0;
1142      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1143   }
1144
1145   return ($allowed, $message);
1146 }
1147
1148 =head2 CheckHighHolds
1149
1150     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1151     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1152     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1153
1154 =cut
1155
1156 sub checkHighHolds {
1157     my ( $item, $borrower ) = @_;
1158     my $branch = _GetCircControlBranch( $item, $borrower );
1159     my $item_object = Koha::Items->find( $item->{itemnumber} );
1160
1161     my $return_data = {
1162         exceeded    => 0,
1163         outstanding => 0,
1164         duration    => 0,
1165         due_date    => undef,
1166     };
1167
1168     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1169
1170     if ( $holds->count() ) {
1171         $return_data->{outstanding} = $holds->count();
1172
1173         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1174         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1175         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1176
1177         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1178
1179         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1180
1181             # static means just more than a given number of holds on the record
1182
1183             # If the number of holds is less than the threshold, we can stop here
1184             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1185                 return $return_data;
1186             }
1187         }
1188         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1189
1190             # dynamic means X more than the number of holdable items on the record
1191
1192             # let's get the items
1193             my @items = $holds->next()->biblio()->items();
1194
1195             # Remove any items with status defined to be ignored even if the would not make item unholdable
1196             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1197                 @items = grep { !$_->$status } @items;
1198             }
1199
1200             # Remove any items that are not holdable for this patron
1201             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber ) eq 'OK' } @items;
1202
1203             my $items_count = scalar @items;
1204
1205             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1206
1207             # If the number of holds is less than the count of items we have
1208             # plus the number of holds allowed above that count, we can stop here
1209             if ( $holds->count() <= $threshold ) {
1210                 return $return_data;
1211             }
1212         }
1213
1214         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1215
1216         my $calendar = Koha::Calendar->new( branchcode => $branch );
1217
1218         my $itype = $item_object->effective_itemtype;
1219         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branch, $borrower );
1220
1221         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1222
1223         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1224         $reduced_datedue->set_hour($orig_due->hour);
1225         $reduced_datedue->set_minute($orig_due->minute);
1226         $reduced_datedue->truncate( to => 'minute' );
1227
1228         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1229             $return_data->{exceeded} = 1;
1230             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1231             $return_data->{due_date} = $reduced_datedue;
1232         }
1233     }
1234
1235     return $return_data;
1236 }
1237
1238 =head2 AddIssue
1239
1240   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1241
1242 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1243
1244 =over 4
1245
1246 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1247
1248 =item C<$barcode> is the barcode of the item being issued.
1249
1250 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1251 Calculated if empty.
1252
1253 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1254
1255 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1256 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1257
1258 AddIssue does the following things :
1259
1260   - step 01: check that there is a borrowernumber & a barcode provided
1261   - check for RENEWAL (book issued & being issued to the same patron)
1262       - renewal YES = Calculate Charge & renew
1263       - renewal NO  =
1264           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1265           * RESERVE PLACED ?
1266               - fill reserve if reserve to this patron
1267               - cancel reserve or not, otherwise
1268           * TRANSFERT PENDING ?
1269               - complete the transfert
1270           * ISSUE THE BOOK
1271
1272 =back
1273
1274 =cut
1275
1276 sub AddIssue {
1277     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1278
1279     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1280     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1281     my $auto_renew = $params && $params->{auto_renew};
1282     my $dbh          = C4::Context->dbh;
1283     my $barcodecheck = CheckValidBarcode($barcode);
1284
1285     my $issue;
1286
1287     if ( $datedue && ref $datedue ne 'DateTime' ) {
1288         $datedue = dt_from_string($datedue);
1289     }
1290
1291     # $issuedate defaults to today.
1292     if ( !defined $issuedate ) {
1293         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1294     }
1295     else {
1296         if ( ref $issuedate ne 'DateTime' ) {
1297             $issuedate = dt_from_string($issuedate);
1298
1299         }
1300     }
1301
1302     # Stop here if the patron or barcode doesn't exist
1303     if ( $borrower && $barcode && $barcodecheck ) {
1304         # find which item we issue
1305         my $item = GetItem( '', $barcode )
1306           or return;    # if we don't get an Item, abort.
1307         my $item_object = Koha::Items->find( { barcode => $barcode } );
1308
1309         my $branch = _GetCircControlBranch( $item, $borrower );
1310
1311         # get actual issuing if there is one
1312         my $actualissue = Koha::Checkouts->find( { itemnumber => $item->{itemnumber} } );
1313
1314         # check if we just renew the issue.
1315         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1316                 and not $switch_onsite_checkout ) {
1317             $datedue = AddRenewal(
1318                 $borrower->{'borrowernumber'},
1319                 $item->{'itemnumber'},
1320                 $branch,
1321                 $datedue,
1322                 $issuedate,    # here interpreted as the renewal date
1323             );
1324         }
1325         else {
1326             # it's NOT a renewal
1327             if ( $actualissue and not $switch_onsite_checkout ) {
1328                 # This book is currently on loan, but not to the person
1329                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1330                 my ( $allowed, $message ) = CanBookBeReturned( $item, C4::Context->userenv->{branch} );
1331                 return unless $allowed;
1332                 AddReturn( $item->{'barcode'}, C4::Context->userenv->{'branch'} );
1333             }
1334
1335             MoveReserve( $item->{'itemnumber'}, $borrower->{'borrowernumber'}, $cancelreserve );
1336
1337             # Starting process for transfer job (checking transfert and validate it if we have one)
1338             my ($datesent) = GetTransfers( $item->{'itemnumber'} );
1339             if ($datesent) {
1340                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1341                 my $sth = $dbh->prepare(
1342                     "UPDATE branchtransfers
1343                         SET datearrived = now(),
1344                         tobranch = ?,
1345                         comments = 'Forced branchtransfer'
1346                     WHERE itemnumber= ? AND datearrived IS NULL"
1347                 );
1348                 $sth->execute( C4::Context->userenv->{'branch'},
1349                     $item->{'itemnumber'} );
1350             }
1351
1352             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1353             unless ($auto_renew) {
1354                 my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1355                     {   categorycode => $borrower->{categorycode},
1356                         itemtype     => $item->{itype},
1357                         branchcode   => $branch
1358                     }
1359                 );
1360
1361                 $auto_renew = $issuing_rule->auto_renew if $issuing_rule;
1362             }
1363
1364             # Record in the database the fact that the book was issued.
1365             unless ($datedue) {
1366                 my $itype = $item_object->effective_itemtype;
1367                 $datedue = CalcDateDue( $issuedate, $itype, $branch, $borrower );
1368
1369             }
1370             $datedue->truncate( to => 'minute' );
1371
1372             $issue = Koha::Database->new()->schema()->resultset('Issue')->update_or_create(
1373                 {
1374                     borrowernumber => $borrower->{'borrowernumber'},
1375                     itemnumber     => $item->{'itemnumber'},
1376                     issuedate      => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1377                     date_due       => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1378                     branchcode     => C4::Context->userenv->{'branch'},
1379                     onsite_checkout => $onsite_checkout,
1380                     auto_renew      => $auto_renew ? 1 : 0
1381                 }
1382               );
1383
1384             if ( C4::Context->preference('ReturnToShelvingCart') ) {
1385                 # ReturnToShelvingCart is on, anything issued should be taken off the cart.
1386                 CartToShelf( $item->{'itemnumber'} );
1387             }
1388             $item->{'issues'}++;
1389             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1390                 UpdateTotalIssues( $item->{'biblionumber'}, 1 );
1391             }
1392
1393             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1394             if ( $item->{'itemlost'} ) {
1395                 if (
1396                     Koha::RefundLostItemFeeRules->should_refund(
1397                         {
1398                             current_branch      => C4::Context->userenv->{branch},
1399                             item_home_branch    => $item->{homebranch},
1400                             item_holding_branch => $item->{holdingbranch}
1401                         }
1402                     )
1403                   )
1404                 {
1405                     _FixAccountForLostAndReturned( $item->{'itemnumber'}, undef,
1406                         $item->{'barcode'} );
1407                 }
1408             }
1409
1410             ModItem(
1411                 {
1412                     issues        => $item->{'issues'},
1413                     holdingbranch => C4::Context->userenv->{'branch'},
1414                     itemlost      => 0,
1415                     onloan        => $datedue->ymd(),
1416                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1417                 },
1418                 $item->{'biblionumber'},
1419                 $item->{'itemnumber'}
1420             );
1421             ModDateLastSeen( $item->{'itemnumber'} );
1422
1423            # If it costs to borrow this book, charge it to the patron's account.
1424             my ( $charge, $itemtype ) = GetIssuingCharges( $item->{'itemnumber'}, $borrower->{'borrowernumber'} );
1425             if ( $charge > 0 ) {
1426                 AddIssuingCharge( $item->{'itemnumber'}, $borrower->{'borrowernumber'}, $charge );
1427                 $item->{'charge'} = $charge;
1428             }
1429
1430             # Record the fact that this book was issued.
1431             &UpdateStats(
1432                 {
1433                     branch => C4::Context->userenv->{'branch'},
1434                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1435                     amount         => $charge,
1436                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1437                     itemnumber     => $item->{'itemnumber'},
1438                     itemtype       => $item->{'itype'},
1439                     borrowernumber => $borrower->{'borrowernumber'},
1440                     ccode          => $item->{'ccode'}
1441                 }
1442             );
1443
1444             # Send a checkout slip.
1445             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1446             my %conditions        = (
1447                 branchcode   => $branch,
1448                 categorycode => $borrower->{categorycode},
1449                 item_type    => $item->{itype},
1450                 notification => 'CHECKOUT',
1451             );
1452             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1453                 SendCirculationAlert(
1454                     {
1455                         type     => 'CHECKOUT',
1456                         item     => $item,
1457                         borrower => $borrower,
1458                         branch   => $branch,
1459                     }
1460                 );
1461             }
1462             logaction(
1463                 "CIRCULATION", "ISSUE",
1464                 $borrower->{'borrowernumber'},
1465                 $item->{'itemnumber'}
1466             ) if C4::Context->preference("IssueLog");
1467         }
1468     }
1469     return $issue;
1470 }
1471
1472 =head2 GetLoanLength
1473
1474   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1475
1476 Get loan length for an itemtype, a borrower type and a branch
1477
1478 =cut
1479
1480 sub GetLoanLength {
1481     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1482     my $dbh = C4::Context->dbh;
1483     my $sth = $dbh->prepare(qq{
1484         SELECT issuelength, lengthunit, renewalperiod
1485         FROM issuingrules
1486         WHERE   categorycode=?
1487             AND itemtype=?
1488             AND branchcode=?
1489             AND issuelength IS NOT NULL
1490     });
1491
1492     # try to find issuelength & return the 1st available.
1493     # check with borrowertype, itemtype and branchcode, then without one of those parameters
1494     $sth->execute( $borrowertype, $itemtype, $branchcode );
1495     my $loanlength = $sth->fetchrow_hashref;
1496
1497     return $loanlength
1498       if defined($loanlength) && defined $loanlength->{issuelength};
1499
1500     $sth->execute( $borrowertype, '*', $branchcode );
1501     $loanlength = $sth->fetchrow_hashref;
1502     return $loanlength
1503       if defined($loanlength) && defined $loanlength->{issuelength};
1504
1505     $sth->execute( '*', $itemtype, $branchcode );
1506     $loanlength = $sth->fetchrow_hashref;
1507     return $loanlength
1508       if defined($loanlength) && defined $loanlength->{issuelength};
1509
1510     $sth->execute( '*', '*', $branchcode );
1511     $loanlength = $sth->fetchrow_hashref;
1512     return $loanlength
1513       if defined($loanlength) && defined $loanlength->{issuelength};
1514
1515     $sth->execute( $borrowertype, $itemtype, '*' );
1516     $loanlength = $sth->fetchrow_hashref;
1517     return $loanlength
1518       if defined($loanlength) && defined $loanlength->{issuelength};
1519
1520     $sth->execute( $borrowertype, '*', '*' );
1521     $loanlength = $sth->fetchrow_hashref;
1522     return $loanlength
1523       if defined($loanlength) && defined $loanlength->{issuelength};
1524
1525     $sth->execute( '*', $itemtype, '*' );
1526     $loanlength = $sth->fetchrow_hashref;
1527     return $loanlength
1528       if defined($loanlength) && defined $loanlength->{issuelength};
1529
1530     $sth->execute( '*', '*', '*' );
1531     $loanlength = $sth->fetchrow_hashref;
1532     return $loanlength
1533       if defined($loanlength) && defined $loanlength->{issuelength};
1534
1535     # if no rule is set => 0 day (hardcoded)
1536     return {
1537         issuelength => 0,
1538         renewalperiod => 0,
1539         lengthunit => 'days',
1540     };
1541
1542 }
1543
1544
1545 =head2 GetHardDueDate
1546
1547   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1548
1549 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1550
1551 =cut
1552
1553 sub GetHardDueDate {
1554     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1555
1556     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1557         {   categorycode => $borrowertype,
1558             itemtype     => $itemtype,
1559             branchcode   => $branchcode
1560         }
1561     );
1562
1563
1564     if ( defined( $issuing_rule ) ) {
1565         if ( $issuing_rule->hardduedate ) {
1566             return (dt_from_string($issuing_rule->hardduedate, 'iso'),$issuing_rule->hardduedatecompare);
1567         } else {
1568             return (undef, undef);
1569         }
1570     }
1571 }
1572
1573 =head2 GetBranchBorrowerCircRule
1574
1575   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1576
1577 Retrieves circulation rule attributes that apply to the given
1578 branch and patron category, regardless of item type.
1579 The return value is a hashref containing the following key:
1580
1581 maxissueqty - maximum number of loans that a
1582 patron of the given category can have at the given
1583 branch.  If the value is undef, no limit.
1584
1585 maxonsiteissueqty - maximum of on-site checkouts that a
1586 patron of the given category can have at the given
1587 branch.  If the value is undef, no limit.
1588
1589 This will first check for a specific branch and
1590 category match from branch_borrower_circ_rules.
1591
1592 If no rule is found, it will then check default_branch_circ_rules
1593 (same branch, default category).  If no rule is found,
1594 it will then check default_borrower_circ_rules (default
1595 branch, same category), then failing that, default_circ_rules
1596 (default branch, default category).
1597
1598 If no rule has been found in the database, it will default to
1599 the buillt in rule:
1600
1601 maxissueqty - undef
1602 maxonsiteissueqty - undef
1603
1604 C<$branchcode> and C<$categorycode> should contain the
1605 literal branch code and patron category code, respectively - no
1606 wildcards.
1607
1608 =cut
1609
1610 sub GetBranchBorrowerCircRule {
1611     my ( $branchcode, $categorycode ) = @_;
1612
1613     my $rules;
1614     my $dbh = C4::Context->dbh();
1615     $rules = $dbh->selectrow_hashref( q|
1616         SELECT maxissueqty, maxonsiteissueqty
1617         FROM branch_borrower_circ_rules
1618         WHERE branchcode = ?
1619         AND   categorycode = ?
1620     |, {}, $branchcode, $categorycode ) ;
1621     return $rules if $rules;
1622
1623     # try same branch, default borrower category
1624     $rules = $dbh->selectrow_hashref( q|
1625         SELECT maxissueqty, maxonsiteissueqty
1626         FROM default_branch_circ_rules
1627         WHERE branchcode = ?
1628     |, {}, $branchcode ) ;
1629     return $rules if $rules;
1630
1631     # try default branch, same borrower category
1632     $rules = $dbh->selectrow_hashref( q|
1633         SELECT maxissueqty, maxonsiteissueqty
1634         FROM default_borrower_circ_rules
1635         WHERE categorycode = ?
1636     |, {}, $categorycode ) ;
1637     return $rules if $rules;
1638
1639     # try default branch, default borrower category
1640     $rules = $dbh->selectrow_hashref( q|
1641         SELECT maxissueqty, maxonsiteissueqty
1642         FROM default_circ_rules
1643     |, {} );
1644     return $rules if $rules;
1645
1646     # built-in default circulation rule
1647     return {
1648         maxissueqty => undef,
1649         maxonsiteissueqty => undef,
1650     };
1651 }
1652
1653 =head2 GetBranchItemRule
1654
1655   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1656
1657 Retrieves circulation rule attributes that apply to the given
1658 branch and item type, regardless of patron category.
1659
1660 The return value is a hashref containing the following keys:
1661
1662 holdallowed => Hold policy for this branch and itemtype. Possible values:
1663   0: No holds allowed.
1664   1: Holds allowed only by patrons that have the same homebranch as the item.
1665   2: Holds allowed from any patron.
1666
1667 returnbranch => branch to which to return item.  Possible values:
1668   noreturn: do not return, let item remain where checked in (floating collections)
1669   homebranch: return to item's home branch
1670   holdingbranch: return to issuer branch
1671
1672 This searches branchitemrules in the following order:
1673
1674   * Same branchcode and itemtype
1675   * Same branchcode, itemtype '*'
1676   * branchcode '*', same itemtype
1677   * branchcode and itemtype '*'
1678
1679 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1680
1681 =cut
1682
1683 sub GetBranchItemRule {
1684     my ( $branchcode, $itemtype ) = @_;
1685     my $dbh = C4::Context->dbh();
1686     my $result = {};
1687
1688     my @attempts = (
1689         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1690             FROM branch_item_rules
1691             WHERE branchcode = ?
1692               AND itemtype = ?', $branchcode, $itemtype],
1693         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1694             FROM default_branch_circ_rules
1695             WHERE branchcode = ?', $branchcode],
1696         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1697             FROM default_branch_item_rules
1698             WHERE itemtype = ?', $itemtype],
1699         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1700             FROM default_circ_rules'],
1701     );
1702
1703     foreach my $attempt (@attempts) {
1704         my ($query, @bind_params) = @{$attempt};
1705         my $search_result = $dbh->selectrow_hashref ( $query , {}, @bind_params )
1706           or next;
1707
1708         # Since branch/category and branch/itemtype use the same per-branch
1709         # defaults tables, we have to check that the key we want is set, not
1710         # just that a row was returned
1711         $result->{'holdallowed'}  = $search_result->{'holdallowed'}  unless ( defined $result->{'holdallowed'} );
1712         $result->{'hold_fulfillment_policy'} = $search_result->{'hold_fulfillment_policy'} unless ( defined $result->{'hold_fulfillment_policy'} );
1713         $result->{'returnbranch'} = $search_result->{'returnbranch'} unless ( defined $result->{'returnbranch'} );
1714     }
1715
1716     # built-in default circulation rule
1717     $result->{'holdallowed'} = 2 unless ( defined $result->{'holdallowed'} );
1718     $result->{'hold_fulfillment_policy'} = 'any' unless ( defined $result->{'hold_fulfillment_policy'} );
1719     $result->{'returnbranch'} = 'homebranch' unless ( defined $result->{'returnbranch'} );
1720
1721     return $result;
1722 }
1723
1724 =head2 AddReturn
1725
1726   ($doreturn, $messages, $iteminformation, $borrower) =
1727       &AddReturn( $barcode, $branch [,$exemptfine] [,$dropbox] [,$returndate] );
1728
1729 Returns a book.
1730
1731 =over 4
1732
1733 =item C<$barcode> is the bar code of the book being returned.
1734
1735 =item C<$branch> is the code of the branch where the book is being returned.
1736
1737 =item C<$exemptfine> indicates that overdue charges for the item will be
1738 removed. Optional.
1739
1740 =item C<$dropbox> indicates that the check-in date is assumed to be
1741 yesterday, or the last non-holiday as defined in C4::Calendar .  If
1742 overdue charges are applied and C<$dropbox> is true, the last charge
1743 will be removed.  This assumes that the fines accrual script has run
1744 for _today_. Optional.
1745
1746 =item C<$return_date> allows the default return date to be overridden
1747 by the given return date. Optional.
1748
1749 =back
1750
1751 C<&AddReturn> returns a list of four items:
1752
1753 C<$doreturn> is true iff the return succeeded.
1754
1755 C<$messages> is a reference-to-hash giving feedback on the operation.
1756 The keys of the hash are:
1757
1758 =over 4
1759
1760 =item C<BadBarcode>
1761
1762 No item with this barcode exists. The value is C<$barcode>.
1763
1764 =item C<NotIssued>
1765
1766 The book is not currently on loan. The value is C<$barcode>.
1767
1768 =item C<IsPermanent>
1769
1770 The book's home branch is a permanent collection. If you have borrowed
1771 this book, you are not allowed to return it. The value is the code for
1772 the book's home branch.
1773
1774 =item C<withdrawn>
1775
1776 This book has been withdrawn/cancelled. The value should be ignored.
1777
1778 =item C<Wrongbranch>
1779
1780 This book has was returned to the wrong branch.  The value is a hashref
1781 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1782 contain the branchcode of the incorrect and correct return library, respectively.
1783
1784 =item C<ResFound>
1785
1786 The item was reserved. The value is a reference-to-hash whose keys are
1787 fields from the reserves table of the Koha database, and
1788 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1789 either C<Waiting>, C<Reserved>, or 0.
1790
1791 =item C<WasReturned>
1792
1793 Value 1 if return is successful.
1794
1795 =item C<NeedsTransfer>
1796
1797 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1798
1799 =back
1800
1801 C<$iteminformation> is a reference-to-hash, giving information about the
1802 returned item from the issues table.
1803
1804 C<$borrower> is a reference-to-hash, giving information about the
1805 patron who last borrowed the book.
1806
1807 =cut
1808
1809 sub AddReturn {
1810     my ( $barcode, $branch, $exemptfine, $dropbox, $return_date, $dropboxdate ) = @_;
1811
1812     if ($branch and not Koha::Libraries->find($branch)) {
1813         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1814         undef $branch;
1815     }
1816     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1817     my $messages;
1818     my $patron;
1819     my $doreturn       = 1;
1820     my $validTransfert = 0;
1821     my $stat_type = 'return';
1822
1823     # get information on item
1824     my $item = GetItem( undef, $barcode );
1825     unless ($item) {
1826         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1827     }
1828
1829     my $itemnumber = $item->{ itemnumber };
1830     my $itemtype = $item->{itype}; # GetItem called effective_itemtype
1831
1832     my $issue  = Koha::Checkouts->find( { itemnumber => $itemnumber } );
1833     if ( $issue ) {
1834         $patron = Koha::Patrons->find( $issue->borrowernumber )
1835             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1836                 . Dumper($issue->unblessed) . "\n";
1837     } else {
1838         $messages->{'NotIssued'} = $barcode;
1839         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1840         $doreturn = 0;
1841         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1842         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1843         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1844            $messages->{'LocalUse'} = 1;
1845            $stat_type = 'localuse';
1846         }
1847     }
1848
1849     if ( $item->{'location'} eq 'PROC' ) {
1850         if ( C4::Context->preference("InProcessingToShelvingCart") ) {
1851             $item->{'location'} = 'CART';
1852         }
1853         else {
1854             $item->{location} = $item->{permanent_location};
1855         }
1856
1857         ModItem( $item, $item->{'biblionumber'}, $item->{'itemnumber'} );
1858     }
1859
1860         # full item data, but no borrowernumber or checkout info (no issue)
1861     my $hbr = GetBranchItemRule($item->{'homebranch'}, $item->{'itype'})->{'returnbranch'} || "homebranch";
1862         # get the proper branch to which to return the item
1863     my $returnbranch = $item->{$hbr} || $branch ;
1864         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1865
1866     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1867     my $patron_unblessed = $patron ? $patron->unblessed : {};
1868
1869     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1870     if ($yaml) {
1871         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1872         my $rules;
1873         eval { $rules = YAML::Load($yaml); };
1874         if ($@) {
1875             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1876         }
1877         else {
1878             foreach my $key ( keys %$rules ) {
1879                 if ( $item->{notforloan} eq $key ) {
1880                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->{notforloan}, to => $rules->{$key} };
1881                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber );
1882                     last;
1883                 }
1884             }
1885         }
1886     }
1887
1888
1889     # check if the book is in a permanent collection....
1890     # FIXME -- This 'PE' attribute is largely undocumented.  afaict, there's no user interface that reflects this functionality.
1891     if ( $returnbranch ) {
1892         my $library = Koha::Libraries->find($returnbranch);
1893         if ( $library and $library->get_categories->search({'me.categorycode' => 'PE'})->count ) {
1894             $messages->{'IsPermanent'} = $returnbranch;
1895         }
1896     }
1897
1898     # check if the return is allowed at this branch
1899     my ($returnallowed, $message) = CanBookBeReturned($item, $branch);
1900     unless ($returnallowed){
1901         $messages->{'Wrongbranch'} = {
1902             Wrongbranch => $branch,
1903             Rightbranch => $message
1904         };
1905         $doreturn = 0;
1906         return ( $doreturn, $messages, $issue, $patron_unblessed);
1907     }
1908
1909     if ( $item->{'withdrawn'} ) { # book has been cancelled
1910         $messages->{'withdrawn'} = 1;
1911         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1912     }
1913
1914     if ( $item->{itemlost} and C4::Context->preference("BlockReturnOfLostItems") ) {
1915         $doreturn = 0;
1916     }
1917
1918     # case of a return of document (deal with issues and holdingbranch)
1919     my $today = DateTime->now( time_zone => C4::Context->tz() );
1920
1921     if ($doreturn) {
1922         my $is_overdue;
1923         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1924         $patron or warn "AddReturn without current borrower";
1925                 my $circControlBranch;
1926         if ($dropbox) {
1927             # define circControlBranch only if dropbox mode is set
1928             # don't allow dropbox mode to create an invalid entry in issues (issuedate > today)
1929             # FIXME: check issuedate > returndate, factoring in holidays
1930
1931             $circControlBranch = _GetCircControlBranch($item,$patron_unblessed);
1932             $is_overdue = $issue->is_overdue( $dropboxdate );
1933         } else {
1934             $is_overdue = $issue->is_overdue;
1935         }
1936
1937         if ($patron) {
1938             eval {
1939                 MarkIssueReturned( $borrowernumber, $item->{'itemnumber'},
1940                     $circControlBranch, $return_date, $patron->privacy );
1941             };
1942             unless ( $@ ) {
1943                 if ( ( C4::Context->preference('CalculateFinesOnReturn') && $is_overdue ) || $return_date ) {
1944                     _CalculateAndUpdateFine( { issue => $issue, item => $item, borrower => $patron_unblessed, return_date => $return_date } );
1945                 }
1946             } else {
1947                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1948
1949                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1950             }
1951
1952             # FIXME is the "= 1" right?  This could be the borrower hash.
1953             $messages->{'WasReturned'} = 1;
1954
1955         }
1956
1957         ModItem({ onloan => undef }, $item->{biblionumber}, $item->{'itemnumber'});
1958     }
1959
1960     # the holdingbranch is updated if the document is returned to another location.
1961     # this is always done regardless of whether the item was on loan or not
1962     my $item_holding_branch = $item->{ holdingbranch };
1963     if ($item->{'holdingbranch'} ne $branch) {
1964         UpdateHoldingbranch($branch, $item->{'itemnumber'});
1965         $item->{'holdingbranch'} = $branch; # update item data holdingbranch too
1966     }
1967     ModDateLastSeen( $item->{'itemnumber'} );
1968
1969     # check if we have a transfer for this document
1970     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->{'itemnumber'} );
1971
1972     # if we have a transfer to do, we update the line of transfers with the datearrived
1973     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->{'itemnumber'} );
1974     if ($datesent) {
1975         if ( $tobranch eq $branch ) {
1976             my $sth = C4::Context->dbh->prepare(
1977                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
1978             );
1979             $sth->execute( $item->{'itemnumber'} );
1980             # if we have a reservation with valid transfer, we can set it's status to 'W'
1981             ShelfToCart( $item->{'itemnumber'} ) if ( C4::Context->preference("ReturnToShelvingCart") );
1982             C4::Reserves::ModReserveStatus($item->{'itemnumber'}, 'W');
1983         } else {
1984             $messages->{'WrongTransfer'}     = $tobranch;
1985             $messages->{'WrongTransferItem'} = $item->{'itemnumber'};
1986         }
1987         $validTransfert = 1;
1988     } else {
1989         ShelfToCart( $item->{'itemnumber'} ) if ( C4::Context->preference("ReturnToShelvingCart") );
1990     }
1991
1992     # fix up the accounts.....
1993     if ( $item->{'itemlost'} ) {
1994         $messages->{'WasLost'} = 1;
1995         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
1996             if (
1997                 Koha::RefundLostItemFeeRules->should_refund(
1998                     {
1999                         current_branch      => C4::Context->userenv->{branch},
2000                         item_home_branch    => $item->{homebranch},
2001                         item_holding_branch => $item_holding_branch
2002                     }
2003                 )
2004               )
2005             {
2006                 _FixAccountForLostAndReturned( $item->{'itemnumber'},
2007                     $borrowernumber, $barcode );
2008                 $messages->{'LostItemFeeRefunded'} = 1;
2009             }
2010         }
2011     }
2012
2013     # fix up the overdues in accounts...
2014     if ($borrowernumber) {
2015         my $fix = _FixOverduesOnReturn($borrowernumber, $item->{itemnumber}, $exemptfine, $dropbox);
2016         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->{itemnumber}...) failed!";  # zero is OK, check defined
2017
2018         if ( $issue and $issue->is_overdue ) {
2019         # fix fine days
2020             $today = $dropboxdate if $dropbox;
2021             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item, dt_from_string($issue->date_due), $today );
2022             if ($reminder){
2023                 $messages->{'PrevDebarred'} = $debardate;
2024             } else {
2025                 $messages->{'Debarred'} = $debardate if $debardate;
2026             }
2027         # there's no overdue on the item but borrower had been previously debarred
2028         } elsif ( $issue->date_due and $patron->debarred ) {
2029              if ( $patron->debarred eq "9999-12-31") {
2030                 $messages->{'ForeverDebarred'} = $patron->debarred;
2031              } else {
2032                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2033                   $borrower_debar_dt->truncate(to => 'day');
2034                   my $today_dt = $today->clone()->truncate(to => 'day');
2035                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2036                       $messages->{'PrevDebarred'} = $patron->debarred;
2037                   }
2038              }
2039         }
2040     }
2041
2042     # find reserves.....
2043     # if we don't have a reserve with the status W, we launch the Checkreserves routine
2044     my ($resfound, $resrec);
2045     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2046     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->{'itemnumber'}, undef, $lookahead ) unless ( $item->{'withdrawn'} );
2047     if ($resfound) {
2048           $resrec->{'ResFound'} = $resfound;
2049         $messages->{'ResFound'} = $resrec;
2050     }
2051
2052     # Record the fact that this book was returned.
2053     UpdateStats({
2054         branch         => $branch,
2055         type           => $stat_type,
2056         itemnumber     => $itemnumber,
2057         itemtype       => $itemtype,
2058         borrowernumber => $borrowernumber,
2059         ccode          => $item->{ ccode }
2060     });
2061
2062     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2063     if ( $patron ) {
2064         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2065         my %conditions = (
2066             branchcode   => $branch,
2067             categorycode => $patron->categorycode,
2068             item_type    => $item->{itype},
2069             notification => 'CHECKIN',
2070         );
2071         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2072             SendCirculationAlert({
2073                 type     => 'CHECKIN',
2074                 item     => $item,
2075                 borrower => $patron->unblessed,
2076                 branch   => $branch,
2077             });
2078         }
2079
2080         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->{'itemnumber'})
2081             if C4::Context->preference("ReturnLog");
2082         }
2083
2084     # Remove any OVERDUES related debarment if the borrower has no overdues
2085     if ( $borrowernumber
2086       && $patron->debarred
2087       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2088       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2089       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2090     ) {
2091         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2092     }
2093
2094     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2095     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2096         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2097             (C4::Context->preference("UseBranchTransferLimits") and
2098              ! IsBranchTransferAllowed($branch, $returnbranch, $item->{C4::Context->preference("BranchTransferLimitsType")} )
2099            )) {
2100             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s)", $item->{'itemnumber'},$branch, $returnbranch;
2101             $debug and warn "item: " . Dumper($item);
2102             ModItemTransfer($item->{'itemnumber'}, $branch, $returnbranch);
2103             $messages->{'WasTransfered'} = 1;
2104         } else {
2105             $messages->{'NeedsTransfer'} = $returnbranch;
2106         }
2107     }
2108
2109     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2110 }
2111
2112 =head2 MarkIssueReturned
2113
2114   MarkIssueReturned($borrowernumber, $itemnumber, $dropbox_branch, $returndate, $privacy);
2115
2116 Unconditionally marks an issue as being returned by
2117 moving the C<issues> row to C<old_issues> and
2118 setting C<returndate> to the current date, or
2119 the last non-holiday date of the branccode specified in
2120 C<dropbox_branch> .  Assumes you've already checked that
2121 it's safe to do this, i.e. last non-holiday > issuedate.
2122
2123 if C<$returndate> is specified (in iso format), it is used as the date
2124 of the return. It is ignored when a dropbox_branch is passed in.
2125
2126 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2127 the old_issue is immediately anonymised
2128
2129 Ideally, this function would be internal to C<C4::Circulation>,
2130 not exported, but it is currently needed by one
2131 routine in C<C4::Accounts>.
2132
2133 =cut
2134
2135 sub MarkIssueReturned {
2136     my ( $borrowernumber, $itemnumber, $dropbox_branch, $returndate, $privacy ) = @_;
2137
2138
2139     # Retrieve the issue
2140     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2141     my $issue_id = $issue->issue_id;
2142
2143     my $anonymouspatron;
2144     if ( $privacy == 2 ) {
2145         # The default of 0 will not work due to foreign key constraints
2146         # The anonymisation will fail if AnonymousPatron is not a valid entry
2147         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2148         # Note that a warning should appear on the about page (System information tab).
2149         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2150         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2151             unless Koha::Patrons->find( $anonymouspatron );
2152     }
2153     my $database = Koha::Database->new();
2154     my $schema   = $database->schema;
2155     my $dbh   = C4::Context->dbh;
2156
2157     my $query = 'UPDATE issues SET returndate=';
2158     my @bind;
2159     if ($dropbox_branch) {
2160         my $calendar = Koha::Calendar->new( branchcode => $dropbox_branch );
2161         my $dropboxdate = $calendar->addDate( DateTime->now( time_zone => C4::Context->tz), -1 );
2162         $query .= ' ? ';
2163         push @bind, $dropboxdate->strftime('%Y-%m-%d %H:%M');
2164     } elsif ($returndate) {
2165         $query .= ' ? ';
2166         push @bind, $returndate;
2167     } else {
2168         $query .= ' now() ';
2169     }
2170     $query .= ' WHERE issue_id = ?';
2171     push @bind, $issue_id;
2172
2173     # FIXME Improve the return value and handle it from callers
2174     $schema->txn_do(sub {
2175
2176         # Update the returndate
2177         $dbh->do( $query, undef, @bind );
2178
2179         # We just updated the returndate, so we need to refetch $issue
2180         $issue->discard_changes;
2181
2182         # Create the old_issues entry
2183         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2184
2185         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2186         if ( $privacy == 2) {
2187             $dbh->do(q|UPDATE old_issues SET borrowernumber=? WHERE issue_id = ?|, undef, $anonymouspatron, $old_checkout->issue_id);
2188         }
2189
2190         # And finally delete the issue
2191         $issue->delete;
2192
2193         ModItem( { 'onloan' => undef }, undef, $itemnumber );
2194
2195         if ( C4::Context->preference('StoreLastBorrower') ) {
2196             my $item = Koha::Items->find( $itemnumber );
2197             my $patron = Koha::Patrons->find( $borrowernumber );
2198             $item->last_returned_by( $patron );
2199         }
2200     });
2201
2202     return $issue_id;
2203 }
2204
2205 =head2 _debar_user_on_return
2206
2207     _debar_user_on_return($borrower, $item, $datedue, today);
2208
2209 C<$borrower> borrower hashref
2210
2211 C<$item> item hashref
2212
2213 C<$datedue> date due DateTime object
2214
2215 C<$return_date> DateTime object representing the return time
2216
2217 Internal function, called only by AddReturn that calculates and updates
2218  the user fine days, and debars them if necessary.
2219
2220 Should only be called for overdue returns
2221
2222 =cut
2223
2224 sub _debar_user_on_return {
2225     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2226
2227     my $branchcode = _GetCircControlBranch( $item, $borrower );
2228
2229     my $circcontrol = C4::Context->preference('CircControl');
2230     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2231         {   categorycode => $borrower->{categorycode},
2232             itemtype     => $item->{itype},
2233             branchcode   => $branchcode
2234         }
2235     );
2236     my $finedays = $issuing_rule ? $issuing_rule->finedays : undef;
2237     my $unit     = $issuing_rule ? $issuing_rule->lengthunit : undef;
2238     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2239
2240     if ($finedays) {
2241
2242         # finedays is in days, so hourly loans must multiply by 24
2243         # thus 1 hour late equals 1 day suspension * finedays rate
2244         $finedays = $finedays * 24 if ( $unit eq 'hours' );
2245
2246         # grace period is measured in the same units as the loan
2247         my $grace =
2248           DateTime::Duration->new( $unit => $issuing_rule->firstremind );
2249
2250         my $deltadays = DateTime::Duration->new(
2251             days => $chargeable_units
2252         );
2253         if ( $deltadays->subtract($grace)->is_positive() ) {
2254             my $suspension_days = $deltadays * $finedays;
2255
2256             # If the max suspension days is < than the suspension days
2257             # the suspension days is limited to this maximum period.
2258             my $max_sd = $issuing_rule->maxsuspensiondays;
2259             if ( defined $max_sd ) {
2260                 $max_sd = DateTime::Duration->new( days => $max_sd );
2261                 $suspension_days = $max_sd
2262                   if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2263             }
2264
2265             my ( $has_been_extended, $is_a_reminder );
2266             if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2267                 my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2268                 if ( $debarment ) {
2269                     $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2270                     $has_been_extended = 1;
2271                 }
2272             }
2273
2274             my $new_debar_dt =
2275               $return_date->clone()->add_duration( $suspension_days );
2276
2277             Koha::Patron::Debarments::AddUniqueDebarment({
2278                 borrowernumber => $borrower->{borrowernumber},
2279                 expiration     => $new_debar_dt->ymd(),
2280                 type           => 'SUSPENSION',
2281             });
2282             # if borrower was already debarred but does not get an extra debarment
2283             my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2284             my $new_debarment_str;
2285             if ( $borrower->{debarred} eq $patron->is_debarred ) {
2286                 $is_a_reminder = 1;
2287                 $new_debarment_str = $borrower->{debarred};
2288             } else {
2289                 $new_debarment_str = $new_debar_dt->ymd();
2290             }
2291             # FIXME Should return a DateTime object
2292             return $new_debarment_str, $is_a_reminder;
2293         }
2294     }
2295     return;
2296 }
2297
2298 =head2 _FixOverduesOnReturn
2299
2300    &_FixOverduesOnReturn($brn,$itm, $exemptfine, $dropboxmode);
2301
2302 C<$brn> borrowernumber
2303
2304 C<$itm> itemnumber
2305
2306 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2307 C<$dropboxmode> BOOL -- remove lastincrement on overdue charge associated with this issue.
2308
2309 Internal function, called only by AddReturn
2310
2311 =cut
2312
2313 sub _FixOverduesOnReturn {
2314     my ($borrowernumber, $item);
2315     unless ($borrowernumber = shift) {
2316         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2317         return;
2318     }
2319     unless ($item = shift) {
2320         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2321         return;
2322     }
2323     my ($exemptfine, $dropbox) = @_;
2324     my $dbh = C4::Context->dbh;
2325
2326     # check for overdue fine
2327     my $accountline = Koha::Account::Lines->search(
2328         {
2329             borrowernumber => $borrowernumber,
2330             itemnumber     => $item,
2331             -or            => [
2332                 accounttype => 'FU',
2333                 accounttype => 'O',
2334             ],
2335         }
2336     )->next();
2337     return 0 unless $accountline;    # no warning, there's just nothing to fix
2338
2339     my $uquery;
2340     if ($exemptfine) {
2341         my $amountoutstanding = $accountline->amountoutstanding;
2342
2343         $accountline->accounttype('FFOR');
2344         $accountline->amountoutstanding(0);
2345
2346         Koha::Account::Offset->new(
2347             {
2348                 debit_id => $accountline->id,
2349                 type => 'Forgiven',
2350                 amount => $amountoutstanding * -1,
2351             }
2352         );
2353
2354         if (C4::Context->preference("FinesLog")) {
2355             &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2356         }
2357     } elsif ($dropbox && $accountline->lastincrement) {
2358         my $outstanding = $accountline->amountoutstanding - $accountline->lastincrement;
2359         my $amt = $accountline->amount - $accountline->lastincrement;
2360
2361         Koha::Account::Offset->new(
2362             {
2363                 debit_id => $accountline->id,
2364                 type => 'Dropbox',
2365                 amount => $accountline->lastincrement * -1,
2366             }
2367         );
2368
2369         if ( C4::Context->preference("FinesLog") ) {
2370             &logaction( "FINES", 'MODIFY', $borrowernumber,
2371                 "Dropbox adjustment $amt, item $item" );
2372         }
2373
2374         $accountline->accounttype('F');
2375
2376         if ( $outstanding >= 0 && $amt >= 0 ) {
2377             $accountline->amount($amt);
2378             $accountline->amountoutstanding($outstanding);
2379         }
2380
2381     } else {
2382         $accountline->accounttype('F');
2383     }
2384
2385     return $accountline->store();
2386 }
2387
2388 =head2 _FixAccountForLostAndReturned
2389
2390   &_FixAccountForLostAndReturned($itemnumber, [$borrowernumber, $barcode]);
2391
2392 Calculates the charge for a book lost and returned.
2393
2394 Internal function, not exported, called only by AddReturn.
2395
2396 =cut
2397
2398 sub _FixAccountForLostAndReturned {
2399     my $itemnumber     = shift or return;
2400     my $borrowernumber = @_ ? shift : undef;
2401     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2402
2403     # check for charge made for lost book
2404     my $accountline = Koha::Account::Lines->search(
2405         {
2406             itemnumber  => $itemnumber,
2407             accounttype => { -in => [ 'L', 'Rep', 'W' ] },
2408         },
2409         {
2410             order_by => { -desc => [ 'date', 'accountno' ] }
2411         }
2412     )->next();
2413
2414     return unless $accountline;
2415     return if $accountline->accounttype eq 'W';    # Written off
2416
2417     $accountline->accounttype('LR');
2418     $accountline->store();
2419
2420     my $account = Koha::Account->new( { patron_id => $accountline->borrowernumber } );
2421     my $credit_id = $account->pay(
2422         {
2423             amount       => $accountline->amount,
2424             description  => "Item Returned " . $item_id,
2425             account_type => 'CR',
2426             offset_type  => 'Lost Item Return',
2427             accounlines  => [$accountline],
2428
2429         }
2430     );
2431
2432     ModItem( { paidfor => '' }, undef, $itemnumber );
2433
2434     return $credit_id;
2435 }
2436
2437 =head2 _GetCircControlBranch
2438
2439    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2440
2441 Internal function :
2442
2443 Return the library code to be used to determine which circulation
2444 policy applies to a transaction.  Looks up the CircControl and
2445 HomeOrHoldingBranch system preferences.
2446
2447 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2448
2449 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2450
2451 =cut
2452
2453 sub _GetCircControlBranch {
2454     my ($item, $borrower) = @_;
2455     my $circcontrol = C4::Context->preference('CircControl');
2456     my $branch;
2457
2458     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2459         $branch= C4::Context->userenv->{'branch'};
2460     } elsif ($circcontrol eq 'PatronLibrary') {
2461         $branch=$borrower->{branchcode};
2462     } else {
2463         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2464         $branch = $item->{$branchfield};
2465         # default to item home branch if holdingbranch is used
2466         # and is not defined
2467         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2468             $branch = $item->{homebranch};
2469         }
2470     }
2471     return $branch;
2472 }
2473
2474 =head2 GetOpenIssue
2475
2476   $issue = GetOpenIssue( $itemnumber );
2477
2478 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2479
2480 C<$itemnumber> is the item's itemnumber
2481
2482 Returns a hashref
2483
2484 =cut
2485
2486 sub GetOpenIssue {
2487   my ( $itemnumber ) = @_;
2488   return unless $itemnumber;
2489   my $dbh = C4::Context->dbh;
2490   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2491   $sth->execute( $itemnumber );
2492   return $sth->fetchrow_hashref();
2493
2494 }
2495
2496 =head2 GetBiblioIssues
2497
2498   $issues = GetBiblioIssues($biblionumber);
2499
2500 this function get all issues from a biblionumber.
2501
2502 Return:
2503 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2504 tables issues and the firstname,surname & cardnumber from borrowers.
2505
2506 =cut
2507
2508 sub GetBiblioIssues {
2509     my $biblionumber = shift;
2510     return unless $biblionumber;
2511     my $dbh   = C4::Context->dbh;
2512     my $query = "
2513         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2514         FROM issues
2515             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2516             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2517             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2518             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2519         WHERE biblio.biblionumber = ?
2520         UNION ALL
2521         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2522         FROM old_issues
2523             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2524             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2525             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2526             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2527         WHERE biblio.biblionumber = ?
2528         ORDER BY timestamp
2529     ";
2530     my $sth = $dbh->prepare($query);
2531     $sth->execute($biblionumber, $biblionumber);
2532
2533     my @issues;
2534     while ( my $data = $sth->fetchrow_hashref ) {
2535         push @issues, $data;
2536     }
2537     return \@issues;
2538 }
2539
2540 =head2 GetUpcomingDueIssues
2541
2542   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2543
2544 =cut
2545
2546 sub GetUpcomingDueIssues {
2547     my $params = shift;
2548
2549     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2550     my $dbh = C4::Context->dbh;
2551
2552     my $statement = <<END_SQL;
2553 SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2554 FROM issues
2555 LEFT JOIN items USING (itemnumber)
2556 LEFT OUTER JOIN branches USING (branchcode)
2557 WHERE returndate is NULL
2558 HAVING days_until_due >= 0 AND days_until_due <= ?
2559 END_SQL
2560
2561     my @bind_parameters = ( $params->{'days_in_advance'} );
2562
2563     my $sth = $dbh->prepare( $statement );
2564     $sth->execute( @bind_parameters );
2565     my $upcoming_dues = $sth->fetchall_arrayref({});
2566
2567     return $upcoming_dues;
2568 }
2569
2570 =head2 CanBookBeRenewed
2571
2572   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2573
2574 Find out whether a borrowed item may be renewed.
2575
2576 C<$borrowernumber> is the borrower number of the patron who currently
2577 has the item on loan.
2578
2579 C<$itemnumber> is the number of the item to renew.
2580
2581 C<$override_limit>, if supplied with a true value, causes
2582 the limit on the number of times that the loan can be renewed
2583 (as controlled by the item type) to be ignored. Overriding also allows
2584 to renew sooner than "No renewal before" and to manually renew loans
2585 that are automatically renewed.
2586
2587 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2588 item must currently be on loan to the specified borrower; renewals
2589 must be allowed for the item's type; and the borrower must not have
2590 already renewed the loan. $error will contain the reason the renewal can not proceed
2591
2592 =cut
2593
2594 sub CanBookBeRenewed {
2595     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2596
2597     my $dbh    = C4::Context->dbh;
2598     my $renews = 1;
2599
2600     my $item      = GetItem($itemnumber)      or return ( 0, 'no_item' );
2601     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return ( 0, 'no_checkout' );
2602     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2603
2604     $borrowernumber ||= $issue->borrowernumber;
2605     my $patron = Koha::Patrons->find( $borrowernumber )
2606       or return;
2607
2608     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2609
2610     # This item can fill one or more unfilled reserve, can those unfilled reserves
2611     # all be filled by other available items?
2612     if ( $resfound
2613         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2614     {
2615         my $schema = Koha::Database->new()->schema();
2616
2617         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2618         if ($item_holds) {
2619             # There is an item level hold on this item, no other item can fill the hold
2620             $resfound = 1;
2621         }
2622         else {
2623
2624             # Get all other items that could possibly fill reserves
2625             my @itemnumbers = $schema->resultset('Item')->search(
2626                 {
2627                     biblionumber => $resrec->{biblionumber},
2628                     onloan       => undef,
2629                     notforloan   => 0,
2630                     -not         => { itemnumber => $itemnumber }
2631                 },
2632                 { columns => 'itemnumber' }
2633             )->get_column('itemnumber')->all();
2634
2635             # Get all other reserves that could have been filled by this item
2636             my @borrowernumbers;
2637             while (1) {
2638                 my ( $reserve_found, $reserve, undef ) =
2639                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2640
2641                 if ($reserve_found) {
2642                     push( @borrowernumbers, $reserve->{borrowernumber} );
2643                 }
2644                 else {
2645                     last;
2646                 }
2647             }
2648
2649             # If the count of the union of the lists of reservable items for each borrower
2650             # is equal or greater than the number of borrowers, we know that all reserves
2651             # can be filled with available items. We can get the union of the sets simply
2652             # by pushing all the elements onto an array and removing the duplicates.
2653             my @reservable;
2654             my %borrowers;
2655             ITEM: foreach my $i (@itemnumbers) {
2656                 my $item = GetItem($i);
2657                 next if IsItemOnHoldAndFound($i);
2658                 for my $b (@borrowernumbers) {
2659                     my $borr = $borrowers{$b} //= Koha::Patrons->find( $b )->unblessed;
2660                     next unless IsAvailableForItemLevelRequest($item, $borr);
2661                     next unless CanItemBeReserved($b,$i);
2662
2663                     push @reservable, $i;
2664                     if (@reservable >= @borrowernumbers) {
2665                         $resfound = 0;
2666                         last ITEM;
2667                     }
2668                     last;
2669                 }
2670             }
2671         }
2672     }
2673     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2674
2675     return ( 1, undef ) if $override_limit;
2676
2677     my $branchcode = _GetCircControlBranch( $item, $patron->unblessed );
2678     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2679         {   categorycode => $patron->categorycode,
2680             itemtype     => $item->{itype},
2681             branchcode   => $branchcode
2682         }
2683     );
2684
2685     return ( 0, "too_many" )
2686       if not $issuing_rule or $issuing_rule->renewalsallowed <= $issue->renewals;
2687
2688     my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2689     my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2690     $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2691     my $restricted  = $patron->is_debarred;
2692     my $hasoverdues = $patron->has_overdues;
2693
2694     if ( $restricted and $restrictionblockrenewing ) {
2695         return ( 0, 'restriction');
2696     } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2697         return ( 0, 'overdue');
2698     }
2699
2700     if ( $issue->auto_renew ) {
2701         if ( defined $issuing_rule->no_auto_renewal_after
2702                 and $issuing_rule->no_auto_renewal_after ne "" ) {
2703             # Get issue_date and add no_auto_renewal_after
2704             # If this is greater than today, it's too late for renewal.
2705             my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2706             $maximum_renewal_date->add(
2707                 $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
2708             );
2709             my $now = dt_from_string;
2710             if ( $now >= $maximum_renewal_date ) {
2711                 return ( 0, "auto_too_late" );
2712             }
2713         }
2714         if ( defined $issuing_rule->no_auto_renewal_after_hard_limit
2715                       and $issuing_rule->no_auto_renewal_after_hard_limit ne "" ) {
2716             # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2717             if ( dt_from_string >= dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit ) ) {
2718                 return ( 0, "auto_too_late" );
2719             }
2720         }
2721
2722         if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2723             my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2724             my ( $amountoutstanding ) = C4::Members::GetMemberAccountRecords($patron->borrowernumber);
2725             if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2726                 return ( 0, "auto_too_much_oweing" );
2727             }
2728         }
2729     }
2730
2731     if ( defined $issuing_rule->norenewalbefore
2732         and $issuing_rule->norenewalbefore ne "" )
2733     {
2734
2735         # Calculate soonest renewal by subtracting 'No renewal before' from due date
2736         my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2737             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
2738
2739         # Depending on syspref reset the exact time, only check the date
2740         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2741             and $issuing_rule->lengthunit eq 'days' )
2742         {
2743             $soonestrenewal->truncate( to => 'day' );
2744         }
2745
2746         if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2747         {
2748             return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2749             return ( 0, "too_soon" );
2750         }
2751         elsif ( $issue->auto_renew ) {
2752             return ( 0, "auto_renew" );
2753         }
2754     }
2755
2756     # Fallback for automatic renewals:
2757     # If norenewalbefore is undef, don't renew before due date.
2758     if ( $issue->auto_renew ) {
2759         my $now = dt_from_string;
2760         return ( 0, "auto_renew" )
2761           if $now >= dt_from_string( $issue->date_due, 'sql' );
2762         return ( 0, "auto_too_soon" );
2763     }
2764
2765     return ( 1, undef );
2766 }
2767
2768 =head2 AddRenewal
2769
2770   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2771
2772 Renews a loan.
2773
2774 C<$borrowernumber> is the borrower number of the patron who currently
2775 has the item.
2776
2777 C<$itemnumber> is the number of the item to renew.
2778
2779 C<$branch> is the library where the renewal took place (if any).
2780            The library that controls the circ policies for the renewal is retrieved from the issues record.
2781
2782 C<$datedue> can be a DateTime object used to set the due date.
2783
2784 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2785 this parameter is not supplied, lastreneweddate is set to the current date.
2786
2787 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2788 from the book's item type.
2789
2790 =cut
2791
2792 sub AddRenewal {
2793     my $borrowernumber  = shift;
2794     my $itemnumber      = shift or return;
2795     my $branch          = shift;
2796     my $datedue         = shift;
2797     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz)->ymd();
2798
2799     my $item   = GetItem($itemnumber) or return;
2800     my $item_object = Koha::Items->find( $itemnumber ); # Should replace $item
2801     my $biblio = $item_object->biblio;
2802
2803     my $dbh = C4::Context->dbh;
2804
2805     # Find the issues record for this book
2806     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } );
2807
2808     return unless $issue;
2809
2810     $borrowernumber ||= $issue->borrowernumber;
2811
2812     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2813         carp 'Invalid date passed to AddRenewal.';
2814         return;
2815     }
2816
2817     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2818     my $patron_unblessed = $patron->unblessed;
2819
2820     if ( C4::Context->preference('CalculateFinesOnReturn') && $issue->is_overdue ) {
2821         _CalculateAndUpdateFine( { issue => $issue, item => $item, borrower => $patron_unblessed } );
2822     }
2823     _FixOverduesOnReturn( $borrowernumber, $itemnumber );
2824
2825     # If the due date wasn't specified, calculate it by adding the
2826     # book's loan length to today's date or the current due date
2827     # based on the value of the RenewalPeriodBase syspref.
2828     unless ($datedue) {
2829
2830         my $itemtype = $item_object->effective_itemtype;
2831         $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2832                                         dt_from_string( $issue->date_due, 'sql' ) :
2833                                         DateTime->now( time_zone => C4::Context->tz());
2834         $datedue =  CalcDateDue($datedue, $itemtype, _GetCircControlBranch($item, $patron_unblessed), $patron_unblessed, 'is a renewal');
2835     }
2836
2837     # Update the issues record to have the new due date, and a new count
2838     # of how many times it has been renewed.
2839     my $renews = $issue->renewals + 1;
2840     my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2841                             WHERE borrowernumber=?
2842                             AND itemnumber=?"
2843     );
2844
2845     $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2846
2847     # Update the renewal count on the item, and tell zebra to reindex
2848     $renews = $item->{renewals} + 1;
2849     ModItem({ renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $item->{biblionumber}, $itemnumber);
2850
2851     # Charge a new rental fee, if applicable?
2852     my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2853     if ( $charge > 0 ) {
2854         my $accountno = getnextacctno( $borrowernumber );
2855         my $manager_id = 0;
2856         $manager_id = C4::Context->userenv->{'number'} if C4::Context->userenv;
2857         $sth = $dbh->prepare(
2858                 "INSERT INTO accountlines
2859                     (date, borrowernumber, accountno, amount, manager_id,
2860                     description,accounttype, amountoutstanding, itemnumber)
2861                     VALUES (now(),?,?,?,?,?,?,?,?)"
2862         );
2863         $sth->execute( $borrowernumber, $accountno, $charge, $manager_id,
2864             "Renewal of Rental Item " . $biblio->title . " $item->{'barcode'}",
2865             'Rent', $charge, $itemnumber );
2866     }
2867
2868     # Send a renewal slip according to checkout alert preferencei
2869     if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2870         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2871         my %conditions        = (
2872             branchcode   => $branch,
2873             categorycode => $patron->categorycode,
2874             item_type    => $item->{itype},
2875             notification => 'CHECKOUT',
2876         );
2877         if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2878             SendCirculationAlert(
2879                 {
2880                     type     => 'RENEWAL',
2881                     item     => $item,
2882                     borrower => $patron->unblessed,
2883                     branch   => $branch,
2884                 }
2885             );
2886         }
2887     }
2888
2889     # Remove any OVERDUES related debarment if the borrower has no overdues
2890     if ( $patron
2891       && $patron->is_debarred
2892       && ! $patron->has_overdues
2893       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2894     ) {
2895         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2896     }
2897
2898     unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
2899         $branch = C4::Context->userenv ? C4::Context->userenv->{branch} : $branch;
2900     }
2901
2902     # Add the renewal to stats
2903     UpdateStats(
2904         {
2905             branch         => $branch,
2906             type           => 'renew',
2907             amount         => $charge,
2908             itemnumber     => $itemnumber,
2909             itemtype       => $item->{itype},
2910             borrowernumber => $borrowernumber,
2911             ccode          => $item->{'ccode'}
2912         }
2913     );
2914
2915     #Log the renewal
2916     logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
2917     return $datedue;
2918 }
2919
2920 sub GetRenewCount {
2921     # check renewal status
2922     my ( $bornum, $itemno ) = @_;
2923     my $dbh           = C4::Context->dbh;
2924     my $renewcount    = 0;
2925     my $renewsallowed = 0;
2926     my $renewsleft    = 0;
2927
2928     my $patron = Koha::Patrons->find( $bornum );
2929     my $item     = GetItem($itemno);
2930
2931     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
2932
2933     # Look in the issues table for this item, lent to this borrower,
2934     # and not yet returned.
2935
2936     # FIXME - I think this function could be redone to use only one SQL call.
2937     my $sth = $dbh->prepare(
2938         "select * from issues
2939                                 where (borrowernumber = ?)
2940                                 and (itemnumber = ?)"
2941     );
2942     $sth->execute( $bornum, $itemno );
2943     my $data = $sth->fetchrow_hashref;
2944     $renewcount = $data->{'renewals'} if $data->{'renewals'};
2945     # $item and $borrower should be calculated
2946     my $branchcode = _GetCircControlBranch($item, $patron->unblessed);
2947
2948     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2949         {   categorycode => $patron->categorycode,
2950             itemtype     => $item->{itype},
2951             branchcode   => $branchcode
2952         }
2953     );
2954
2955     $renewsallowed = $issuing_rule ? $issuing_rule->renewalsallowed : 0;
2956     $renewsleft    = $renewsallowed - $renewcount;
2957     if($renewsleft < 0){ $renewsleft = 0; }
2958     return ( $renewcount, $renewsallowed, $renewsleft );
2959 }
2960
2961 =head2 GetSoonestRenewDate
2962
2963   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
2964
2965 Find out the soonest possible renew date of a borrowed item.
2966
2967 C<$borrowernumber> is the borrower number of the patron who currently
2968 has the item on loan.
2969
2970 C<$itemnumber> is the number of the item to renew.
2971
2972 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
2973 renew date, based on the value "No renewal before" of the applicable
2974 issuing rule. Returns the current date if the item can already be
2975 renewed, and returns undefined if the borrower, loan, or item
2976 cannot be found.
2977
2978 =cut
2979
2980 sub GetSoonestRenewDate {
2981     my ( $borrowernumber, $itemnumber ) = @_;
2982
2983     my $dbh = C4::Context->dbh;
2984
2985     my $item      = GetItem($itemnumber)      or return;
2986     my $itemissue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2987
2988     $borrowernumber ||= $itemissue->borrowernumber;
2989     my $patron = Koha::Patrons->find( $borrowernumber )
2990       or return;
2991
2992     my $branchcode = _GetCircControlBranch( $item, $patron->unblessed );
2993     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2994         {   categorycode => $patron->categorycode,
2995             itemtype     => $item->{itype},
2996             branchcode   => $branchcode
2997         }
2998     );
2999
3000     my $now = dt_from_string;
3001     return $now unless $issuing_rule;
3002
3003     if ( defined $issuing_rule->norenewalbefore
3004         and $issuing_rule->norenewalbefore ne "" )
3005     {
3006         my $soonestrenewal =
3007           dt_from_string( $itemissue->date_due )->subtract(
3008             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
3009
3010         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3011             and $issuing_rule->lengthunit eq 'days' )
3012         {
3013             $soonestrenewal->truncate( to => 'day' );
3014         }
3015         return $soonestrenewal if $now < $soonestrenewal;
3016     }
3017     return $now;
3018 }
3019
3020 =head2 GetLatestAutoRenewDate
3021
3022   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3023
3024 Find out the latest possible auto renew date of a borrowed item.
3025
3026 C<$borrowernumber> is the borrower number of the patron who currently
3027 has the item on loan.
3028
3029 C<$itemnumber> is the number of the item to renew.
3030
3031 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3032 auto renew date, based on the value "No auto renewal after" and the "No auto
3033 renewal after (hard limit) of the applicable issuing rule.
3034 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3035 or item cannot be found.
3036
3037 =cut
3038
3039 sub GetLatestAutoRenewDate {
3040     my ( $borrowernumber, $itemnumber ) = @_;
3041
3042     my $dbh = C4::Context->dbh;
3043
3044     my $item      = GetItem($itemnumber)      or return;
3045     my $itemissue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
3046
3047     $borrowernumber ||= $itemissue->borrowernumber;
3048     my $patron = Koha::Patrons->find( $borrowernumber )
3049       or return;
3050
3051     my $branchcode = _GetCircControlBranch( $item, $patron->unblessed );
3052     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3053         {   categorycode => $patron->categorycode,
3054             itemtype     => $item->{itype},
3055             branchcode   => $branchcode
3056         }
3057     );
3058
3059     return unless $issuing_rule;
3060     return
3061       if ( not $issuing_rule->no_auto_renewal_after
3062             or $issuing_rule->no_auto_renewal_after eq '' )
3063       and ( not $issuing_rule->no_auto_renewal_after_hard_limit
3064              or $issuing_rule->no_auto_renewal_after_hard_limit eq '' );
3065
3066     my $maximum_renewal_date;
3067     if ( $issuing_rule->no_auto_renewal_after ) {
3068         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3069         $maximum_renewal_date->add(
3070             $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
3071         );
3072     }
3073
3074     if ( $issuing_rule->no_auto_renewal_after_hard_limit ) {
3075         my $dt = dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit );
3076         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3077     }
3078     return $maximum_renewal_date;
3079 }
3080
3081
3082 =head2 GetIssuingCharges
3083
3084   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3085
3086 Calculate how much it would cost for a given patron to borrow a given
3087 item, including any applicable discounts.
3088
3089 C<$itemnumber> is the item number of item the patron wishes to borrow.
3090
3091 C<$borrowernumber> is the patron's borrower number.
3092
3093 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3094 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3095 if it's a video).
3096
3097 =cut
3098
3099 sub GetIssuingCharges {
3100
3101     # calculate charges due
3102     my ( $itemnumber, $borrowernumber ) = @_;
3103     my $charge = 0;
3104     my $dbh    = C4::Context->dbh;
3105     my $item_type;
3106
3107     # Get the book's item type and rental charge (via its biblioitem).
3108     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3109         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3110     $charge_query .= (C4::Context->preference('item-level_itypes'))
3111         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3112         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3113
3114     $charge_query .= ' WHERE items.itemnumber =?';
3115
3116     my $sth = $dbh->prepare($charge_query);
3117     $sth->execute($itemnumber);
3118     if ( my $item_data = $sth->fetchrow_hashref ) {
3119         $item_type = $item_data->{itemtype};
3120         $charge    = $item_data->{rentalcharge};
3121         my $branch = C4::Context::mybranch();
3122         my $discount_query = q|SELECT rentaldiscount,
3123             issuingrules.itemtype, issuingrules.branchcode
3124             FROM borrowers
3125             LEFT JOIN issuingrules ON borrowers.categorycode = issuingrules.categorycode
3126             WHERE borrowers.borrowernumber = ?
3127             AND (issuingrules.itemtype = ? OR issuingrules.itemtype = '*')
3128             AND (issuingrules.branchcode = ? OR issuingrules.branchcode = '*')|;
3129         my $discount_sth = $dbh->prepare($discount_query);
3130         $discount_sth->execute( $borrowernumber, $item_type, $branch );
3131         my $discount_rules = $discount_sth->fetchall_arrayref({});
3132         if (@{$discount_rules}) {
3133             # We may have multiple rules so get the most specific
3134             my $discount = _get_discount_from_rule($discount_rules, $branch, $item_type);
3135             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3136         }
3137         if ($charge) {
3138             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3139         }
3140     }
3141
3142     return ( $charge, $item_type );
3143 }
3144
3145 # Select most appropriate discount rule from those returned
3146 sub _get_discount_from_rule {
3147     my ($rules_ref, $branch, $itemtype) = @_;
3148     my $discount;
3149
3150     if (@{$rules_ref} == 1) { # only 1 applicable rule use it
3151         $discount = $rules_ref->[0]->{rentaldiscount};
3152         return (defined $discount) ? $discount : 0;
3153     }
3154     # could have up to 4 does one match $branch and $itemtype
3155     my @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq $itemtype } @{$rules_ref};
3156     if (@d) {
3157         $discount = $d[0]->{rentaldiscount};
3158         return (defined $discount) ? $discount : 0;
3159     }
3160     # do we have item type + all branches
3161     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq $itemtype } @{$rules_ref};
3162     if (@d) {
3163         $discount = $d[0]->{rentaldiscount};
3164         return (defined $discount) ? $discount : 0;
3165     }
3166     # do we all item types + this branch
3167     @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq q{*} } @{$rules_ref};
3168     if (@d) {
3169         $discount = $d[0]->{rentaldiscount};
3170         return (defined $discount) ? $discount : 0;
3171     }
3172     # so all and all (surely we wont get here)
3173     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq q{*} } @{$rules_ref};
3174     if (@d) {
3175         $discount = $d[0]->{rentaldiscount};
3176         return (defined $discount) ? $discount : 0;
3177     }
3178     # none of the above
3179     return 0;
3180 }
3181
3182 =head2 AddIssuingCharge
3183
3184   &AddIssuingCharge( $itemno, $borrowernumber, $charge )
3185
3186 =cut
3187
3188 sub AddIssuingCharge {
3189     my ( $itemnumber, $borrowernumber, $charge ) = @_;
3190
3191     my $nextaccntno = getnextacctno($borrowernumber);
3192
3193     my $manager_id  = 0;
3194     $manager_id = C4::Context->userenv->{'number'} if C4::Context->userenv;
3195
3196     my $accountline = Koha::Account::Line->new(
3197         {
3198             borrowernumber    => $borrowernumber,
3199             itemnumber        => $itemnumber,
3200             accountno         => $nextaccntno,
3201             amount            => $charge,
3202             amountoutstanding => $charge,
3203             manager_id        => $manager_id,
3204             description       => 'Rental',
3205             accounttype       => 'Rent',
3206             date              => \'NOW()',
3207         }
3208     )->store();
3209
3210     Koha::Account::Offset->new(
3211         {
3212             debit_id => $accountline->id,
3213             type     => 'Rental Fee',
3214             amount   => $charge,
3215         }
3216     )->store();
3217 }
3218
3219 =head2 GetTransfers
3220
3221   GetTransfers($itemnumber);
3222
3223 =cut
3224
3225 sub GetTransfers {
3226     my ($itemnumber) = @_;
3227
3228     my $dbh = C4::Context->dbh;
3229
3230     my $query = '
3231         SELECT datesent,
3232                frombranch,
3233                tobranch,
3234                branchtransfer_id
3235         FROM branchtransfers
3236         WHERE itemnumber = ?
3237           AND datearrived IS NULL
3238         ';
3239     my $sth = $dbh->prepare($query);
3240     $sth->execute($itemnumber);
3241     my @row = $sth->fetchrow_array();
3242     return @row;
3243 }
3244
3245 =head2 GetTransfersFromTo
3246
3247   @results = GetTransfersFromTo($frombranch,$tobranch);
3248
3249 Returns the list of pending transfers between $from and $to branch
3250
3251 =cut
3252
3253 sub GetTransfersFromTo {
3254     my ( $frombranch, $tobranch ) = @_;
3255     return unless ( $frombranch && $tobranch );
3256     my $dbh   = C4::Context->dbh;
3257     my $query = "
3258         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3259         FROM   branchtransfers
3260         WHERE  frombranch=?
3261           AND  tobranch=?
3262           AND datearrived IS NULL
3263     ";
3264     my $sth = $dbh->prepare($query);
3265     $sth->execute( $frombranch, $tobranch );
3266     my @gettransfers;
3267
3268     while ( my $data = $sth->fetchrow_hashref ) {
3269         push @gettransfers, $data;
3270     }
3271     return (@gettransfers);
3272 }
3273
3274 =head2 DeleteTransfer
3275
3276   &DeleteTransfer($itemnumber);
3277
3278 =cut
3279
3280 sub DeleteTransfer {
3281     my ($itemnumber) = @_;
3282     return unless $itemnumber;
3283     my $dbh          = C4::Context->dbh;
3284     my $sth          = $dbh->prepare(
3285         "DELETE FROM branchtransfers
3286          WHERE itemnumber=?
3287          AND datearrived IS NULL "
3288     );
3289     return $sth->execute($itemnumber);
3290 }
3291
3292 =head2 SendCirculationAlert
3293
3294 Send out a C<check-in> or C<checkout> alert using the messaging system.
3295
3296 B<Parameters>:
3297
3298 =over 4
3299
3300 =item type
3301
3302 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3303
3304 =item item
3305
3306 Hashref of information about the item being checked in or out.
3307
3308 =item borrower
3309
3310 Hashref of information about the borrower of the item.
3311
3312 =item branch
3313
3314 The branchcode from where the checkout or check-in took place.
3315
3316 =back
3317
3318 B<Example>:
3319
3320     SendCirculationAlert({
3321         type     => 'CHECKOUT',
3322         item     => $item,
3323         borrower => $borrower,
3324         branch   => $branch,
3325     });
3326
3327 =cut
3328
3329 sub SendCirculationAlert {
3330     my ($opts) = @_;
3331     my ($type, $item, $borrower, $branch) =
3332         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3333     my %message_name = (
3334         CHECKIN  => 'Item_Check_in',
3335         CHECKOUT => 'Item_Checkout',
3336         RENEWAL  => 'Item_Checkout',
3337     );
3338     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3339         borrowernumber => $borrower->{borrowernumber},
3340         message_name   => $message_name{$type},
3341     });
3342     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3343
3344     my $schema = Koha::Database->new->schema;
3345     my @transports = keys %{ $borrower_preferences->{transports} };
3346
3347     # From the MySQL doc:
3348     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3349     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3350     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3351     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3352
3353     for my $mtt (@transports) {
3354         my $letter =  C4::Letters::GetPreparedLetter (
3355             module => 'circulation',
3356             letter_code => $type,
3357             branchcode => $branch,
3358             message_transport_type => $mtt,
3359             lang => $borrower->{lang},
3360             tables => {
3361                 $issues_table => $item->{itemnumber},
3362                 'items'       => $item->{itemnumber},
3363                 'biblio'      => $item->{biblionumber},
3364                 'biblioitems' => $item->{biblionumber},
3365                 'borrowers'   => $borrower,
3366                 'branches'    => $branch,
3367             }
3368         ) or next;
3369
3370         $schema->storage->txn_begin;
3371         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3372         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3373         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3374         unless ( $message ) {
3375             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3376             C4::Message->enqueue($letter, $borrower, $mtt);
3377         } else {
3378             $message->append($letter);
3379             $message->update;
3380         }
3381         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3382         $schema->storage->txn_commit;
3383     }
3384
3385     return;
3386 }
3387
3388 =head2 updateWrongTransfer
3389
3390   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3391
3392 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3393
3394 =cut
3395
3396 sub updateWrongTransfer {
3397         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3398         my $dbh = C4::Context->dbh;
3399 # first step validate the actual line of transfert .
3400         my $sth =
3401                 $dbh->prepare(
3402                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3403                 );
3404                 $sth->execute($FromLibrary,$itemNumber);
3405
3406 # second step create a new line of branchtransfer to the right location .
3407         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3408
3409 #third step changing holdingbranch of item
3410         UpdateHoldingbranch($FromLibrary,$itemNumber);
3411 }
3412
3413 =head2 UpdateHoldingbranch
3414
3415   $items = UpdateHoldingbranch($branch,$itmenumber);
3416
3417 Simple methode for updating hodlingbranch in items BDD line
3418
3419 =cut
3420
3421 sub UpdateHoldingbranch {
3422         my ( $branch,$itemnumber ) = @_;
3423     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3424 }
3425
3426 =head2 CalcDateDue
3427
3428 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3429
3430 this function calculates the due date given the start date and configured circulation rules,
3431 checking against the holidays calendar as per the 'useDaysMode' syspref.
3432 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3433 C<$itemtype>  = itemtype code of item in question
3434 C<$branch>  = location whose calendar to use
3435 C<$borrower> = Borrower object
3436 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3437
3438 =cut
3439
3440 sub CalcDateDue {
3441     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3442
3443     $isrenewal ||= 0;
3444
3445     # loanlength now a href
3446     my $loanlength =
3447             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3448
3449     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3450             ? qq{renewalperiod}
3451             : qq{issuelength};
3452
3453     my $datedue;
3454     if ( $startdate ) {
3455         if (ref $startdate ne 'DateTime' ) {
3456             $datedue = dt_from_string($datedue);
3457         } else {
3458             $datedue = $startdate->clone;
3459         }
3460     } else {
3461         $datedue =
3462           DateTime->now( time_zone => C4::Context->tz() )
3463           ->truncate( to => 'minute' );
3464     }
3465
3466
3467     # calculate the datedue as normal
3468     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3469     {    # ignoring calendar
3470         if ( $loanlength->{lengthunit} eq 'hours' ) {
3471             $datedue->add( hours => $loanlength->{$length_key} );
3472         } else {    # days
3473             $datedue->add( days => $loanlength->{$length_key} );
3474             $datedue->set_hour(23);
3475             $datedue->set_minute(59);
3476         }
3477     } else {
3478         my $dur;
3479         if ($loanlength->{lengthunit} eq 'hours') {
3480             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3481         }
3482         else { # days
3483             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3484         }
3485         my $calendar = Koha::Calendar->new( branchcode => $branch );
3486         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3487         if ($loanlength->{lengthunit} eq 'days') {
3488             $datedue->set_hour(23);
3489             $datedue->set_minute(59);
3490         }
3491     }
3492
3493     # if Hard Due Dates are used, retrieve them and apply as necessary
3494     my ( $hardduedate, $hardduedatecompare ) =
3495       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3496     if ($hardduedate) {    # hardduedates are currently dates
3497         $hardduedate->truncate( to => 'minute' );
3498         $hardduedate->set_hour(23);
3499         $hardduedate->set_minute(59);
3500         my $cmp = DateTime->compare( $hardduedate, $datedue );
3501
3502 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3503 # if the calculated date is before the 'after' Hard Due Date (floor), override
3504 # if the hard due date is set to 'exactly', overrride
3505         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3506             $datedue = $hardduedate->clone;
3507         }
3508
3509         # in all other cases, keep the date due as it is
3510
3511     }
3512
3513     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3514     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3515         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3516         if( $expiry_dt ) { #skip empty expiry date..
3517             $expiry_dt->set( hour => 23, minute => 59);
3518             my $d1= $datedue->clone->set_time_zone('floating');
3519             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3520                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3521             }
3522         }
3523         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3524           my $calendar = Koha::Calendar->new( branchcode => $branch );
3525           if ( $calendar->is_holiday($datedue) ) {
3526               # Don't return on a closed day
3527               $datedue = $calendar->prev_open_day( $datedue );
3528           }
3529         }
3530     }
3531
3532     return $datedue;
3533 }
3534
3535
3536 sub CheckValidBarcode{
3537 my ($barcode) = @_;
3538 my $dbh = C4::Context->dbh;
3539 my $query=qq|SELECT count(*)
3540              FROM items
3541              WHERE barcode=?
3542             |;
3543 my $sth = $dbh->prepare($query);
3544 $sth->execute($barcode);
3545 my $exist=$sth->fetchrow ;
3546 return $exist;
3547 }
3548
3549 =head2 IsBranchTransferAllowed
3550
3551   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3552
3553 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3554
3555 =cut
3556
3557 sub IsBranchTransferAllowed {
3558         my ( $toBranch, $fromBranch, $code ) = @_;
3559
3560         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3561
3562         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3563         my $dbh = C4::Context->dbh;
3564
3565         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3566         $sth->execute( $toBranch, $fromBranch, $code );
3567         my $limit = $sth->fetchrow_hashref();
3568
3569         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3570         if ( $limit->{'limitId'} ) {
3571                 return 0;
3572         } else {
3573                 return 1;
3574         }
3575 }
3576
3577 =head2 CreateBranchTransferLimit
3578
3579   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3580
3581 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3582
3583 =cut
3584
3585 sub CreateBranchTransferLimit {
3586    my ( $toBranch, $fromBranch, $code ) = @_;
3587    return unless defined($toBranch) && defined($fromBranch);
3588    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3589
3590    my $dbh = C4::Context->dbh;
3591
3592    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3593    return $sth->execute( $code, $toBranch, $fromBranch );
3594 }
3595
3596 =head2 DeleteBranchTransferLimits
3597
3598     my $result = DeleteBranchTransferLimits($frombranch);
3599
3600 Deletes all the library transfer limits for one library.  Returns the
3601 number of limits deleted, 0e0 if no limits were deleted, or undef if
3602 no arguments are supplied.
3603
3604 =cut
3605
3606 sub DeleteBranchTransferLimits {
3607     my $branch = shift;
3608     return unless defined $branch;
3609     my $dbh    = C4::Context->dbh;
3610     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3611     return $sth->execute($branch);
3612 }
3613
3614 sub ReturnLostItem{
3615     my ( $borrowernumber, $itemnum ) = @_;
3616
3617     MarkIssueReturned( $borrowernumber, $itemnum );
3618     my $patron = Koha::Patrons->find( $borrowernumber );
3619     my $item = C4::Items::GetItem( $itemnum );
3620     my $old_note = ($item->{'paidfor'} && ($item->{'paidfor'} ne q{})) ? $item->{'paidfor'}.' / ' : q{};
3621     my @datearr = localtime(time);
3622     my $date = ( 1900 + $datearr[5] ) . "-" . ( $datearr[4] + 1 ) . "-" . $datearr[3];
3623     my $bor = $patron->firstname . ' ' . $patron->surname . ' ' . $patron->cardnumber;
3624     ModItem({ paidfor =>  $old_note."Paid for by $bor $date" }, undef, $itemnum);
3625 }
3626
3627
3628 sub LostItem{
3629     my ($itemnumber, $mark_returned) = @_;
3630
3631     $mark_returned //= C4::Context->preference('MarkLostItemsAsReturned');
3632
3633     my $dbh = C4::Context->dbh();
3634     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3635                            FROM issues
3636                            JOIN items USING (itemnumber)
3637                            JOIN biblio USING (biblionumber)
3638                            WHERE issues.itemnumber=?");
3639     $sth->execute($itemnumber);
3640     my $issues=$sth->fetchrow_hashref();
3641
3642     # If a borrower lost the item, add a replacement cost to the their record
3643     if ( my $borrowernumber = $issues->{borrowernumber} ){
3644         my $patron = Koha::Patrons->find( $borrowernumber );
3645
3646         if (C4::Context->preference('WhenLostForgiveFine')){
3647             my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, 1, 0); # 1, 0 = exemptfine, no-dropbox
3648             defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3649         }
3650         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3651             C4::Accounts::chargelostitem($borrowernumber, $itemnumber, $issues->{'replacementprice'}, "Lost Item $issues->{'title'} $issues->{'barcode'}");
3652             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3653             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3654         }
3655
3656         MarkIssueReturned($borrowernumber,$itemnumber,undef,undef,$patron->privacy) if $mark_returned;
3657     }
3658 }
3659
3660 sub GetOfflineOperations {
3661     my $dbh = C4::Context->dbh;
3662     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3663     $sth->execute(C4::Context->userenv->{'branch'});
3664     my $results = $sth->fetchall_arrayref({});
3665     return $results;
3666 }
3667
3668 sub GetOfflineOperation {
3669     my $operationid = shift;
3670     return unless $operationid;
3671     my $dbh = C4::Context->dbh;
3672     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3673     $sth->execute( $operationid );
3674     return $sth->fetchrow_hashref;
3675 }
3676
3677 sub AddOfflineOperation {
3678     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3679     my $dbh = C4::Context->dbh;
3680     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3681     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3682     return "Added.";
3683 }
3684
3685 sub DeleteOfflineOperation {
3686     my $dbh = C4::Context->dbh;
3687     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3688     $sth->execute( shift );
3689     return "Deleted.";
3690 }
3691
3692 sub ProcessOfflineOperation {
3693     my $operation = shift;
3694
3695     my $report;
3696     if ( $operation->{action} eq 'return' ) {
3697         $report = ProcessOfflineReturn( $operation );
3698     } elsif ( $operation->{action} eq 'issue' ) {
3699         $report = ProcessOfflineIssue( $operation );
3700     } elsif ( $operation->{action} eq 'payment' ) {
3701         $report = ProcessOfflinePayment( $operation );
3702     }
3703
3704     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3705
3706     return $report;
3707 }
3708
3709 sub ProcessOfflineReturn {
3710     my $operation = shift;
3711
3712     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3713
3714     if ( $item ) {
3715         my $itemnumber = $item->itemnumber;
3716         my $issue = GetOpenIssue( $itemnumber );
3717         if ( $issue ) {
3718             MarkIssueReturned(
3719                 $issue->{borrowernumber},
3720                 $itemnumber,
3721                 undef,
3722                 $operation->{timestamp},
3723             );
3724             ModItem(
3725                 { renewals => 0, onloan => undef },
3726                 $issue->{'biblionumber'},
3727                 $itemnumber
3728             );
3729             return "Success.";
3730         } else {
3731             return "Item not issued.";
3732         }
3733     } else {
3734         return "Item not found.";
3735     }
3736 }
3737
3738 sub ProcessOfflineIssue {
3739     my $operation = shift;
3740
3741     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3742
3743     if ( $patron ) {
3744         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3745         unless ($item) {
3746             return "Barcode not found.";
3747         }
3748         my $itemnumber = $item->itemnumber;
3749         my $issue = GetOpenIssue( $itemnumber );
3750
3751         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3752             MarkIssueReturned(
3753                 $issue->{borrowernumber},
3754                 $itemnumber,
3755                 undef,
3756                 $operation->{timestamp},
3757             );
3758         }
3759         AddIssue(
3760             $patron->unblessed,
3761             $operation->{'barcode'},
3762             undef,
3763             1,
3764             $operation->{timestamp},
3765             undef,
3766         );
3767         return "Success.";
3768     } else {
3769         return "Borrower not found.";
3770     }
3771 }
3772
3773 sub ProcessOfflinePayment {
3774     my $operation = shift;
3775
3776     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} });
3777     my $amount = $operation->{amount};
3778
3779     Koha::Account->new( { patron_id => $patron->id } )->pay( { amount => $amount } );
3780
3781     return "Success."
3782 }
3783
3784
3785 =head2 TransferSlip
3786
3787   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3788
3789   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3790
3791 =cut
3792
3793 sub TransferSlip {
3794     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3795
3796     my $item =  GetItem( $itemnumber, $barcode )
3797       or return;
3798
3799     return C4::Letters::GetPreparedLetter (
3800         module => 'circulation',
3801         letter_code => 'TRANSFERSLIP',
3802         branchcode => $branch,
3803         tables => {
3804             'branches'    => $to_branch,
3805             'biblio'      => $item->{biblionumber},
3806             'items'       => $item,
3807         },
3808     );
3809 }
3810
3811 =head2 CheckIfIssuedToPatron
3812
3813   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3814
3815   Return 1 if any record item is issued to patron, otherwise return 0
3816
3817 =cut
3818
3819 sub CheckIfIssuedToPatron {
3820     my ($borrowernumber, $biblionumber) = @_;
3821
3822     my $dbh = C4::Context->dbh;
3823     my $query = q|
3824         SELECT COUNT(*) FROM issues
3825         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3826         WHERE items.biblionumber = ?
3827         AND issues.borrowernumber = ?
3828     |;
3829     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3830     return 1 if $is_issued;
3831     return;
3832 }
3833
3834 =head2 IsItemIssued
3835
3836   IsItemIssued( $itemnumber )
3837
3838   Return 1 if the item is on loan, otherwise return 0
3839
3840 =cut
3841
3842 sub IsItemIssued {
3843     my $itemnumber = shift;
3844     my $dbh = C4::Context->dbh;
3845     my $sth = $dbh->prepare(q{
3846         SELECT COUNT(*)
3847         FROM issues
3848         WHERE itemnumber = ?
3849     });
3850     $sth->execute($itemnumber);
3851     return $sth->fetchrow;
3852 }
3853
3854 =head2 GetAgeRestriction
3855
3856   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
3857   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
3858
3859   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
3860   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
3861
3862 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
3863 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
3864 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
3865          Negative days mean the borrower has gone past the age restriction age.
3866
3867 =cut
3868
3869 sub GetAgeRestriction {
3870     my ($record_restrictions, $borrower) = @_;
3871     my $markers = C4::Context->preference('AgeRestrictionMarker');
3872
3873     # Split $record_restrictions to something like FSK 16 or PEGI 6
3874     my @values = split ' ', uc($record_restrictions);
3875     return unless @values;
3876
3877     # Search first occurrence of one of the markers
3878     my @markers = split /\|/, uc($markers);
3879     return unless @markers;
3880
3881     my $index            = 0;
3882     my $restriction_year = 0;
3883     for my $value (@values) {
3884         $index++;
3885         for my $marker (@markers) {
3886             $marker =~ s/^\s+//;    #remove leading spaces
3887             $marker =~ s/\s+$//;    #remove trailing spaces
3888             if ( $marker eq $value ) {
3889                 if ( $index <= $#values ) {
3890                     $restriction_year += $values[$index];
3891                 }
3892                 last;
3893             }
3894             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
3895
3896                 # Perhaps it is something like "K16" (as in Finland)
3897                 $restriction_year += $1;
3898                 last;
3899             }
3900         }
3901         last if ( $restriction_year > 0 );
3902     }
3903
3904     #Check if the borrower is age restricted for this material and for how long.
3905     if ($restriction_year && $borrower) {
3906         if ( $borrower->{'dateofbirth'} ) {
3907             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
3908             $alloweddate[0] += $restriction_year;
3909
3910             #Prevent runime eror on leap year (invalid date)
3911             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
3912                 $alloweddate[2] = 28;
3913             }
3914
3915             #Get how many days the borrower has to reach the age restriction
3916             my @Today = split /-/, DateTime->today->ymd();
3917             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
3918             #Negative days means the borrower went past the age restriction age
3919             return ($restriction_year, $daysToAgeRestriction);
3920         }
3921     }
3922
3923     return ($restriction_year);
3924 }
3925
3926
3927 =head2 GetPendingOnSiteCheckouts
3928
3929 =cut
3930
3931 sub GetPendingOnSiteCheckouts {
3932     my $dbh = C4::Context->dbh;
3933     return $dbh->selectall_arrayref(q|
3934         SELECT
3935           items.barcode,
3936           items.biblionumber,
3937           items.itemnumber,
3938           items.itemnotes,
3939           items.itemcallnumber,
3940           items.location,
3941           issues.date_due,
3942           issues.branchcode,
3943           issues.date_due < NOW() AS is_overdue,
3944           biblio.author,
3945           biblio.title,
3946           borrowers.firstname,
3947           borrowers.surname,
3948           borrowers.cardnumber,
3949           borrowers.borrowernumber
3950         FROM items
3951         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
3952         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
3953         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
3954         WHERE issues.onsite_checkout = 1
3955     |, { Slice => {} } );
3956 }
3957
3958 sub GetTopIssues {
3959     my ($params) = @_;
3960
3961     my ($count, $branch, $itemtype, $ccode, $newness)
3962         = @$params{qw(count branch itemtype ccode newness)};
3963
3964     my $dbh = C4::Context->dbh;
3965     my $query = q{
3966         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
3967           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
3968           i.ccode, SUM(i.issues) AS count
3969         FROM biblio b
3970         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
3971         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
3972     };
3973
3974     my (@where_strs, @where_args);
3975
3976     if ($branch) {
3977         push @where_strs, 'i.homebranch = ?';
3978         push @where_args, $branch;
3979     }
3980     if ($itemtype) {
3981         if (C4::Context->preference('item-level_itypes')){
3982             push @where_strs, 'i.itype = ?';
3983             push @where_args, $itemtype;
3984         } else {
3985             push @where_strs, 'bi.itemtype = ?';
3986             push @where_args, $itemtype;
3987         }
3988     }
3989     if ($ccode) {
3990         push @where_strs, 'i.ccode = ?';
3991         push @where_args, $ccode;
3992     }
3993     if ($newness) {
3994         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
3995         push @where_args, $newness;
3996     }
3997
3998     if (@where_strs) {
3999         $query .= 'WHERE ' . join(' AND ', @where_strs);
4000     }
4001
4002     $query .= q{
4003         GROUP BY b.biblionumber
4004         HAVING count > 0
4005         ORDER BY count DESC
4006     };
4007
4008     $count = int($count);
4009     if ($count > 0) {
4010         $query .= "LIMIT $count";
4011     }
4012
4013     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4014
4015     return @$rows;
4016 }
4017
4018 sub _CalculateAndUpdateFine {
4019     my ($params) = @_;
4020
4021     my $borrower    = $params->{borrower};
4022     my $item        = $params->{item};
4023     my $issue       = $params->{issue};
4024     my $return_date = $params->{return_date};
4025
4026     unless ($borrower) { carp "No borrower passed in!" && return; }
4027     unless ($item)     { carp "No item passed in!"     && return; }
4028     unless ($issue)    { carp "No issue passed in!"    && return; }
4029
4030     my $datedue = dt_from_string( $issue->date_due );
4031
4032     # we only need to calculate and change the fines if we want to do that on return
4033     # Should be on for hourly loans
4034     my $control = C4::Context->preference('CircControl');
4035     my $control_branchcode =
4036         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4037       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4038       :                                     $issue->branchcode;
4039
4040     my $date_returned = $return_date ? dt_from_string($return_date) : dt_from_string();
4041
4042     my ( $amount, $type, $unitcounttotal ) =
4043       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4044
4045     $type ||= q{};
4046
4047     if ( C4::Context->preference('finesMode') eq 'production' ) {
4048         if ( $amount > 0 ) {
4049             C4::Overdues::UpdateFine({
4050                 issue_id       => $issue->issue_id,
4051                 itemnumber     => $issue->itemnumber,
4052                 borrowernumber => $issue->borrowernumber,
4053                 amount         => $amount,
4054                 type           => $type,
4055                 due            => output_pref($datedue),
4056             });
4057         }
4058         elsif ($return_date) {
4059
4060             # Backdated returns may have fines that shouldn't exist,
4061             # so in this case, we need to drop those fines to 0
4062
4063             C4::Overdues::UpdateFine({
4064                 issue_id       => $issue->issue_id,
4065                 itemnumber     => $issue->itemnumber,
4066                 borrowernumber => $issue->borrowernumber,
4067                 amount         => 0,
4068                 type           => $type,
4069                 due            => output_pref($datedue),
4070             });
4071         }
4072     }
4073 }
4074
4075 1;
4076
4077 __END__
4078
4079 =head1 AUTHOR
4080
4081 Koha Development Team <http://koha-community.org/>
4082
4083 =cut