C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use DateTime;
  25 use POSIX qw( floor );
  26 use Koha::DateUtils;
  27 use C4::Context;
  28 use C4::Stats;
  29 use C4::Reserves;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Members;
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Debug;
  37 use C4::Log; # logaction
  38 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  39 use C4::RotatingCollections qw(GetCollectionItemBranches);
  40 use Algorithm::CheckDigits;
  41
  42 use Data::Dumper;
  43 use Koha::Account;
  44 use Koha::AuthorisedValues;
  45 use Koha::Biblioitems;
  46 use Koha::DateUtils;
  47 use Koha::Calendar;
  48 use Koha::Checkouts;
  49 use Koha::IssuingRules;
  50 use Koha::Items;
  51 use Koha::Patrons;
  52 use Koha::Patron::Debarments;
  53 use Koha::Database;
  54 use Koha::Libraries;
  55 use Koha::Account::Lines;
  56 use Koha::Holds;
  57 use Koha::RefundLostItemFeeRule;
  58 use Koha::RefundLostItemFeeRules;
  59 use Koha::Account::Lines;
  60 use Koha::Account::Offsets;
  61 use Koha::Config::SysPrefs;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Date::Calc qw(
  66   Today
  67   Today_and_Now
  68   Add_Delta_YM
  69   Add_Delta_DHMS
  70   Date_to_Days
  71   Day_of_Week
  72   Add_Delta_Days
  73 );
  74 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  75
  76 BEGIN {
  77         require Exporter;
  78         @ISA    = qw(Exporter);
  79
  80         # FIXME subs that should probably be elsewhere
  81         push @EXPORT, qw(
  82                 &barcodedecode
  83         &LostItem
  84         &ReturnLostItem
  85         &GetPendingOnSiteCheckouts
  86         );
  87
  88         # subs to deal with issuing a book
  89         push @EXPORT, qw(
  90                 &CanBookBeIssued
  91                 &CanBookBeRenewed
  92                 &AddIssue
  93                 &AddRenewal
  94                 &GetRenewCount
  95         &GetSoonestRenewDate
  96         &GetLatestAutoRenewDate
  97                 &GetIssuingCharges
  98         &GetBranchBorrowerCircRule
  99         &GetBranchItemRule
 100                 &GetBiblioIssues
 101                 &GetOpenIssue
 102         &CheckIfIssuedToPatron
 103         &IsItemIssued
 104         GetTopIssues
 105         );
 106
 107         # subs to deal with returns
 108         push @EXPORT, qw(
 109                 &AddReturn
 110         &MarkIssueReturned
 111         );
 112
 113         # subs to deal with transfers
 114         push @EXPORT, qw(
 115                 &transferbook
 116                 &GetTransfers
 117                 &GetTransfersFromTo
 118                 &updateWrongTransfer
 119                 &DeleteTransfer
 120                 &IsBranchTransferAllowed
 121                 &CreateBranchTransferLimit
 122                 &DeleteBranchTransferLimits
 123         &TransferSlip
 124         );
 125
 126     # subs to deal with offline circulation
 127     push @EXPORT, qw(
 128       &GetOfflineOperations
 129       &GetOfflineOperation
 130       &AddOfflineOperation
 131       &DeleteOfflineOperation
 132       &ProcessOfflineOperation
 133     );
 134 }
 135
 136 =head1 NAME
 137
 138 C4::Circulation - Koha circulation module
 139
 140 =head1 SYNOPSIS
 141
 142 use C4::Circulation;
 143
 144 =head1 DESCRIPTION
 145
 146 The functions in this module deal with circulation, issues, and
 147 returns, as well as general information about the library.
 148 Also deals with inventory.
 149
 150 =head1 FUNCTIONS
 151
 152 =head2 barcodedecode
 153
 154   $str = &barcodedecode($barcode, [$filter]);
 155
 156 Generic filter function for barcode string.
 157 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 158 Will do some manipulation of the barcode for systems that deliver a barcode
 159 to circulation.pl that differs from the barcode stored for the item.
 160 For proper functioning of this filter, calling the function on the
 161 correct barcode string (items.barcode) should return an unaltered barcode.
 162
 163 The optional $filter argument is to allow for testing or explicit
 164 behavior that ignores the System Pref.  Valid values are the same as the
 165 System Pref options.
 166
 167 =cut
 168
 169 # FIXME -- the &decode fcn below should be wrapped into this one.
 170 # FIXME -- these plugins should be moved out of Circulation.pm
 171 #
 172 sub barcodedecode {
 173     my ($barcode, $filter) = @_;
 174     my $branch = C4::Context::mybranch();
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 decode
 214
 215   $str = &decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 255                                             $barcode, $ignore_reserves);
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$newbranch> is the code for the branch to which the item should be transferred.
 260
 261 C<$barcode> is the barcode of the item to be transferred.
 262
 263 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 264 Otherwise, if an item is reserved, the transfer fails.
 265
 266 Returns three values:
 267
 268 =over
 269
 270 =item $dotransfer
 271
 272 is true if the transfer was successful.
 273
 274 =item $messages
 275
 276 is a reference-to-hash which may have any of the following keys:
 277
 278 =over
 279
 280 =item C<BadBarcode>
 281
 282 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 283
 284 =item C<DestinationEqualsHolding>
 285
 286 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 287
 288 =item C<WasReturned>
 289
 290 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 291
 292 =item C<ResFound>
 293
 294 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 295
 296 =item C<WasTransferred>
 297
 298 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 299
 300 =back
 301
 302 =back
 303
 304 =cut
 305
 306 sub transferbook {
 307     my ( $tbr, $barcode, $ignoreRs ) = @_;
 308     my $messages;
 309     my $dotransfer      = 1;
 310     my $item = Koha::Items->find( { barcode => $barcode } );
 311
 312     # bad barcode..
 313     unless ( $item ) {
 314         $messages->{'BadBarcode'} = $barcode;
 315         $dotransfer = 0;
 316     }
 317
 318     my $itemnumber = $item->itemnumber;
 319     my $issue = GetOpenIssue($itemnumber);
 320     # get branches of book...
 321     my $hbr = $item->homebranch;
 322     my $fbr = $item->holdingbranch;
 323
 324     # if using Branch Transfer Limits
 325     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 326         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 327         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 328             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 329                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 330                 $dotransfer = 0;
 331             }
 332         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 333             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 334             $dotransfer = 0;
 335         }
 336     }
 337
 338     # can't transfer book if is already there....
 339     if ( $fbr eq $tbr ) {
 340         $messages->{'DestinationEqualsHolding'} = 1;
 341         $dotransfer = 0;
 342     }
 343
 344     # check if it is still issued to someone, return it...
 345     if ( $issue ) {
 346         AddReturn( $barcode, $fbr );
 347         $messages->{'WasReturned'} = $issue->borrowernumber;
 348     }
 349
 350     # find reserves.....
 351     # That'll save a database query.
 352     my ( $resfound, $resrec, undef ) =
 353       CheckReserves( $itemnumber );
 354     if ( $resfound and not $ignoreRs ) {
 355         $resrec->{'ResFound'} = $resfound;
 356
 357         #         $messages->{'ResFound'} = $resrec;
 358         $dotransfer = 1;
 359     }
 360
 361     #actually do the transfer....
 362     if ($dotransfer) {
 363         ModItemTransfer( $itemnumber, $fbr, $tbr );
 364
 365         # don't need to update MARC anymore, we do it in batch now
 366         $messages->{'WasTransfered'} = 1;
 367
 368     }
 369     ModDateLastSeen( $itemnumber );
 370     return ( $dotransfer, $messages );
 371 }
 372
 373
 374 sub TooMany {
 375     my $borrower        = shift;
 376     my $biblionumber = shift;
 377         my $item                = shift;
 378     my $params = shift;
 379     my $onsite_checkout = $params->{onsite_checkout} || 0;
 380     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 381     my $cat_borrower    = $borrower->{'categorycode'};
 382     my $dbh             = C4::Context->dbh;
 383         my $branch;
 384         # Get which branchcode we need
 385         $branch = _GetCircControlBranch($item,$borrower);
 386         my $type = (C4::Context->preference('item-level_itypes'))
 387                         ? $item->{'itype'}         # item-level
 388                         : $item->{'itemtype'};     # biblio-level
 389
 390     # given branch, patron category, and item type, determine
 391     # applicable issuing rule
 392     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 393         {
 394             categorycode => $cat_borrower,
 395             itemtype     => $type,
 396             branchcode   => $branch,
 397             rule_name    => 'maxissueqty',
 398         }
 399     );
 400     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 401         {
 402             categorycode => $cat_borrower,
 403             itemtype     => $type,
 404             branchcode   => $branch,
 405             rule_name    => 'maxonsiteissueqty',
 406         }
 407     );
 408
 409
 410     # if a rule is found and has a loan limit set, count
 411     # how many loans the patron already has that meet that
 412     # rule
 413     if (defined($maxissueqty_rule) and defined($maxissueqty_rule->rule_value)) {
 414         my @bind_params;
 415         my $count_query = q|
 416             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 417             FROM issues
 418             JOIN items USING (itemnumber)
 419         |;
 420
 421         my $rule_itemtype = $maxissueqty_rule->itemtype;
 422         unless ($rule_itemtype) {
 423             # matching rule has the default item type, so count only
 424             # those existing loans that don't fall under a more
 425             # specific rule
 426             if (C4::Context->preference('item-level_itypes')) {
 427                 $count_query .= " WHERE items.itype NOT IN (
 428                                     SELECT itemtype FROM issuingrules
 429                                     WHERE branchcode = ?
 430                                     AND   (categorycode = ? OR categorycode = ?)
 431                                     AND   itemtype <> '*'
 432                                   ) ";
 433             } else {
 434                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 435                                   WHERE biblioitems.itemtype NOT IN (
 436                                     SELECT itemtype FROM issuingrules
 437                                     WHERE branchcode = ?
 438                                     AND   (categorycode = ? OR categorycode = ?)
 439                                     AND   itemtype <> '*'
 440                                   ) ";
 441             }
 442             push @bind_params, $maxissueqty_rule->branchcode;
 443             push @bind_params, $maxissueqty_rule->categorycode;
 444             push @bind_params, $cat_borrower;
 445         } else {
 446             # rule has specific item type, so count loans of that
 447             # specific item type
 448             if (C4::Context->preference('item-level_itypes')) {
 449                 $count_query .= " WHERE items.itype = ? ";
 450             } else {
 451                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 452                                   WHERE biblioitems.itemtype= ? ";
 453             }
 454             push @bind_params, $type;
 455         }
 456
 457         $count_query .= " AND borrowernumber = ? ";
 458         push @bind_params, $borrower->{'borrowernumber'};
 459         my $rule_branch = $maxissueqty_rule->branchcode;
 460         unless ($rule_branch) {
 461             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 462                 $count_query .= " AND issues.branchcode = ? ";
 463                 push @bind_params, $branch;
 464             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 465                 ; # if branch is the patron's home branch, then count all loans by patron
 466             } else {
 467                 $count_query .= " AND items.homebranch = ? ";
 468                 push @bind_params, $branch;
 469             }
 470         }
 471
 472         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 473
 474         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 475         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 476
 477         if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 478             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 479                 return {
 480                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 481                     count => $onsite_checkout_count,
 482                     max_allowed => $max_onsite_checkouts_allowed,
 483                 }
 484             }
 485         }
 486         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 487             my $delta = $switch_onsite_checkout ? 1 : 0;
 488             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 489                 return {
 490                     reason => 'TOO_MANY_CHECKOUTS',
 491                     count => $checkout_count,
 492                     max_allowed => $max_checkouts_allowed,
 493                 };
 494             }
 495         } elsif ( not $onsite_checkout ) {
 496             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 497                 return {
 498                     reason => 'TOO_MANY_CHECKOUTS',
 499                     count => $checkout_count - $onsite_checkout_count,
 500                     max_allowed => $max_checkouts_allowed,
 501                 };
 502             }
 503         }
 504     }
 505
 506     # Now count total loans against the limit for the branch
 507     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 508     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 509         my @bind_params = ();
 510         my $branch_count_query = q|
 511             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 512             FROM issues
 513             JOIN items USING (itemnumber)
 514             WHERE borrowernumber = ?
 515         |;
 516         push @bind_params, $borrower->{borrowernumber};
 517
 518         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 519             $branch_count_query .= " AND issues.branchcode = ? ";
 520             push @bind_params, $branch;
 521         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 522             ; # if branch is the patron's home branch, then count all loans by patron
 523         } else {
 524             $branch_count_query .= " AND items.homebranch = ? ";
 525             push @bind_params, $branch;
 526         }
 527         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 528         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 529         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 530
 531         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 532             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 533                 return {
 534                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 535                     count => $onsite_checkout_count,
 536                     max_allowed => $max_onsite_checkouts_allowed,
 537                 }
 538             }
 539         }
 540         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 541             my $delta = $switch_onsite_checkout ? 1 : 0;
 542             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 543                 return {
 544                     reason => 'TOO_MANY_CHECKOUTS',
 545                     count => $checkout_count,
 546                     max_allowed => $max_checkouts_allowed,
 547                 };
 548             }
 549         } elsif ( not $onsite_checkout ) {
 550             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 551                 return {
 552                     reason => 'TOO_MANY_CHECKOUTS',
 553                     count => $checkout_count - $onsite_checkout_count,
 554                     max_allowed => $max_checkouts_allowed,
 555                 };
 556             }
 557         }
 558     }
 559
 560     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 561         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 562     }
 563
 564     # OK, the patron can issue !!!
 565     return;
 566 }
 567
 568 =head2 CanBookBeIssued
 569
 570   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 571                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 572
 573 Check if a book can be issued.
 574
 575 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 576
 577 IMPORTANT: The assumption by users of this routine is that causes blocking
 578 the issue are keyed by uppercase labels and other returned
 579 data is keyed in lower case!
 580
 581 =over 4
 582
 583 =item C<$patron> is a Koha::Patron
 584
 585 =item C<$barcode> is the bar code of the book being issued.
 586
 587 =item C<$duedates> is a DateTime object.
 588
 589 =item C<$inprocess> boolean switch
 590
 591 =item C<$ignore_reserves> boolean switch
 592
 593 =item C<$params> Hashref of additional parameters
 594
 595 Available keys:
 596     override_high_holds - Ignore high holds
 597     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 598
 599 =back
 600
 601 Returns :
 602
 603 =over 4
 604
 605 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 606 Possible values are :
 607
 608 =back
 609
 610 =head3 INVALID_DATE
 611
 612 sticky due date is invalid
 613
 614 =head3 GNA
 615
 616 borrower gone with no address
 617
 618 =head3 CARD_LOST
 619
 620 borrower declared it's card lost
 621
 622 =head3 DEBARRED
 623
 624 borrower debarred
 625
 626 =head3 UNKNOWN_BARCODE
 627
 628 barcode unknown
 629
 630 =head3 NOT_FOR_LOAN
 631
 632 item is not for loan
 633
 634 =head3 WTHDRAWN
 635
 636 item withdrawn.
 637
 638 =head3 RESTRICTED
 639
 640 item is restricted (set by ??)
 641
 642 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 643 could be prevented, but ones that can be overriden by the operator.
 644
 645 Possible values are :
 646
 647 =head3 DEBT
 648
 649 borrower has debts.
 650
 651 =head3 RENEW_ISSUE
 652
 653 renewing, not issuing
 654
 655 =head3 ISSUED_TO_ANOTHER
 656
 657 issued to someone else.
 658
 659 =head3 RESERVED
 660
 661 reserved for someone else.
 662
 663 =head3 INVALID_DATE
 664
 665 sticky due date is invalid or due date in the past
 666
 667 =head3 TOO_MANY
 668
 669 if the borrower borrows to much things
 670
 671 =cut
 672
 673 sub CanBookBeIssued {
 674     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 675     my %needsconfirmation;    # filled with problems that needs confirmations
 676     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 677     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 678     my %messages;             # filled with information messages that should be displayed.
 679
 680     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 681     my $override_high_holds = $params->{override_high_holds} || 0;
 682
 683     my $item = Koha::Items->find({barcode => $barcode });
 684     # MANDATORY CHECKS - unless item exists, nothing else matters
 685     unless ( $item ) {
 686         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 687     }
 688     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 689
 690     my $item_unblessed = $item->unblessed; # Transition...
 691     my $issue = $item->checkout;
 692     my $biblio = $item->biblio;
 693     my $biblioitem = $biblio->biblioitem;
 694     my $effective_itemtype = $item->effective_itemtype;
 695     my $dbh             = C4::Context->dbh;
 696     my $patron_unblessed = $patron->unblessed;
 697
 698     #
 699     # DUE DATE is OK ? -- should already have checked.
 700     #
 701     if ($duedate && ref $duedate ne 'DateTime') {
 702         $duedate = dt_from_string($duedate);
 703     }
 704     my $now = DateTime->now( time_zone => C4::Context->tz() );
 705     unless ( $duedate ) {
 706         my $issuedate = $now->clone();
 707
 708         my $branch = _GetCircControlBranch($item_unblessed, $patron_unblessed);
 709         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $branch, $patron_unblessed );
 710
 711         # Offline circ calls AddIssue directly, doesn't run through here
 712         #  So issuingimpossible should be ok.
 713     }
 714     if ($duedate) {
 715         my $today = $now->clone();
 716         $today->truncate( to => 'minute');
 717         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 718             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 719         }
 720     } else {
 721             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 722     }
 723
 724     #
 725     # BORROWER STATUS
 726     #
 727     if ( $patron->category->category_type eq 'X' && (  $item->barcode  )) {
 728         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 729         &UpdateStats({
 730                      branch => C4::Context->userenv->{'branch'},
 731                      type => 'localuse',
 732                      itemnumber => $item->itemnumber,
 733                      itemtype => $effective_itemtype,
 734                      borrowernumber => $patron->borrowernumber,
 735                      ccode => $item->ccode}
 736                     );
 737         ModDateLastSeen( $item->itemnumber ); # FIXME Move to Koha::Item
 738         return( { STATS => 1 }, {});
 739     }
 740
 741     if ( $patron->gonenoaddress == 1 ) {
 742         $issuingimpossible{GNA} = 1;
 743     }
 744
 745     if ( $patron->lost == 1 ) {
 746         $issuingimpossible{CARD_LOST} = 1;
 747     }
 748     if ( $patron->is_debarred ) {
 749         $issuingimpossible{DEBARRED} = 1;
 750     }
 751
 752     if ( $patron->is_expired ) {
 753         $issuingimpossible{EXPIRED} = 1;
 754     }
 755
 756     #
 757     # BORROWER STATUS
 758     #
 759
 760     # DEBTS
 761     my $account = $patron->account;
 762     my $balance = $account->balance;
 763     my $non_issues_charges = $account->non_issues_charges;
 764     my $other_charges = $balance - $non_issues_charges;
 765
 766     my $amountlimit = C4::Context->preference("noissuescharge");
 767     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 768     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 769
 770     # Check the debt of this patrons guarantees
 771     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 772     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 773     if ( defined $no_issues_charge_guarantees ) {
 774         my @guarantees = $patron->guarantees();
 775         my $guarantees_non_issues_charges;
 776         foreach my $g ( @guarantees ) {
 777             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 778         }
 779
 780         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 781             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 782         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 783             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 784         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 785             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 786         }
 787     }
 788
 789     if ( C4::Context->preference("IssuingInProcess") ) {
 790         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 791             $issuingimpossible{DEBT} = $non_issues_charges;
 792         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 793             $needsconfirmation{DEBT} = $non_issues_charges;
 794         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 795             $needsconfirmation{DEBT} = $non_issues_charges;
 796         }
 797     }
 798     else {
 799         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 800             $needsconfirmation{DEBT} = $non_issues_charges;
 801         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 802             $issuingimpossible{DEBT} = $non_issues_charges;
 803         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 804             $needsconfirmation{DEBT} = $non_issues_charges;
 805         }
 806     }
 807
 808     if ($balance > 0 && $other_charges > 0) {
 809         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 810     }
 811
 812     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 813     $patron_unblessed = $patron->unblessed;
 814
 815     if ( my $debarred_date = $patron->is_debarred ) {
 816          # patron has accrued fine days or has a restriction. $count is a date
 817         if ($debarred_date eq '9999-12-31') {
 818             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 819         }
 820         else {
 821             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 822         }
 823     } elsif ( my $num_overdues = $patron->has_overdues ) {
 824         ## patron has outstanding overdue loans
 825         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 826             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 827         }
 828         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 829             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 830         }
 831     }
 832
 833     #
 834     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 835     #
 836     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 837
 838         # Already issued to current borrower.
 839         # If it is an on-site checkout if it can be switched to a normal checkout
 840         # or ask whether the loan should be renewed
 841
 842         if ( $issue->onsite_checkout
 843                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 844             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 845         } else {
 846             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 847                 $patron->borrowernumber,
 848                 $item->itemnumber,
 849             );
 850             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 851                 if ( $renewerror eq 'onsite_checkout' ) {
 852                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 853                 }
 854                 else {
 855                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 856                 }
 857             }
 858             else {
 859                 $needsconfirmation{RENEW_ISSUE} = 1;
 860             }
 861         }
 862     }
 863     elsif ( $issue ) {
 864
 865         # issued to someone else
 866
 867         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 868
 869         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 870
 871         unless ( $can_be_returned ) {
 872             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 873             $issuingimpossible{branch_to_return} = $message;
 874         } else {
 875             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 876             $needsconfirmation{issued_firstname} = $patron->firstname;
 877             $needsconfirmation{issued_surname} = $patron->surname;
 878             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 879             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 880         }
 881     }
 882
 883     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 884     #
 885     my $switch_onsite_checkout = (
 886           C4::Context->preference('SwitchOnSiteCheckouts')
 887       and $issue
 888       and $issue->onsite_checkout
 889       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 890     my $toomany = TooMany( $patron_unblessed, $item->biblionumber, $item_unblessed, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 891     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 892     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 893         if ( $toomany->{max_allowed} == 0 ) {
 894             $needsconfirmation{PATRON_CANT} = 1;
 895         }
 896         if ( C4::Context->preference("AllowTooManyOverride") ) {
 897             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 898             $needsconfirmation{current_loan_count} = $toomany->{count};
 899             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 900         } else {
 901             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 902             $issuingimpossible{current_loan_count} = $toomany->{count};
 903             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 904         }
 905     }
 906
 907     #
 908     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 909     #
 910     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 911     my $wants_check = $patron->wants_check_for_previous_checkout;
 912     $needsconfirmation{PREVISSUE} = 1
 913         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 914
 915     #
 916     # ITEM CHECKING
 917     #
 918     if ( $item->notforloan )
 919     {
 920         if(!C4::Context->preference("AllowNotForLoanOverride")){
 921             $issuingimpossible{NOT_FOR_LOAN} = 1;
 922             $issuingimpossible{item_notforloan} = $item->notforloan;
 923         }else{
 924             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 925             $needsconfirmation{item_notforloan} = $item->notforloan;
 926         }
 927     }
 928     else {
 929         # we have to check itemtypes.notforloan also
 930         if (C4::Context->preference('item-level_itypes')){
 931             # this should probably be a subroutine
 932             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 933             $sth->execute($effective_itemtype);
 934             my $notforloan=$sth->fetchrow_hashref();
 935             if ($notforloan->{'notforloan'}) {
 936                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 937                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 938                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 939                 } else {
 940                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 941                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 942                 }
 943             }
 944         }
 945         else {
 946             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 947             if ( $itemtype and $itemtype->notforloan == 1){
 948                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 949                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 950                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 951                 } else {
 952                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 953                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 954                 }
 955             }
 956         }
 957     }
 958     if ( $item->withdrawn && $item->withdrawn > 0 )
 959     {
 960         $issuingimpossible{WTHDRAWN} = 1;
 961     }
 962     if (   $item->restricted
 963         && $item->restricted == 1 )
 964     {
 965         $issuingimpossible{RESTRICTED} = 1;
 966     }
 967     if ( $item->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 968         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item->itemlost });
 969         my $code = $av->count ? $av->next->lib : '';
 970         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 971         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 972     }
 973     if ( C4::Context->preference("IndependentBranches") ) {
 974         my $userenv = C4::Context->userenv;
 975         unless ( C4::Context->IsSuperLibrarian() ) {
 976             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 977             if ( $item->$HomeOrHoldingBranch ne $userenv->{branch} ){
 978                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 979                 $issuingimpossible{'itemhomebranch'} = $item->$HomeOrHoldingBranch;
 980             }
 981             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
 982               if ( $patron->branchcode ne $userenv->{branch} );
 983         }
 984     }
 985     #
 986     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
 987     #
 988     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
 989
 990     if ( $rentalConfirmation ){
 991         my ($rentalCharge) = GetIssuingCharges( $item->itemnumber, $patron->borrowernumber );
 992         my $itemtype = Koha::ItemTypes->find( $item->itype ); # GetItem sets effective itemtype
 993         $rentalCharge += $itemtype->calc_rental_charge_daily( { from => dt_from_string(), to => $duedate } );
 994         if ( $rentalCharge > 0 ){
 995             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
 996         }
 997     }
 998
 999     unless ( $ignore_reserves ) {
1000         # See if the item is on reserve.
1001         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item->itemnumber );
1002         if ($restype) {
1003             my $resbor = $res->{'borrowernumber'};
1004             if ( $resbor ne $patron->borrowernumber ) {
1005                 my $patron = Koha::Patrons->find( $resbor );
1006                 if ( $restype eq "Waiting" )
1007                 {
1008                     # The item is on reserve and waiting, but has been
1009                     # reserved by some other patron.
1010                     $needsconfirmation{RESERVE_WAITING} = 1;
1011                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1012                     $needsconfirmation{'ressurname'} = $patron->surname;
1013                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1014                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1015                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1016                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1017                 }
1018                 elsif ( $restype eq "Reserved" ) {
1019                     # The item is on reserve for someone else.
1020                     $needsconfirmation{RESERVED} = 1;
1021                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1022                     $needsconfirmation{'ressurname'} = $patron->surname;
1023                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1024                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1025                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1026                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1027                 }
1028             }
1029         }
1030     }
1031
1032     ## CHECK AGE RESTRICTION
1033     my $agerestriction  = $biblioitem->agerestriction;
1034     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1035     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1036         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1037             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1038         }
1039         else {
1040             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1041         }
1042     }
1043
1044     ## check for high holds decreasing loan period
1045     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1046         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1047
1048         if ( $check->{exceeded} ) {
1049             if ($override_high_holds) {
1050                 $alerts{HIGHHOLDS} = {
1051                     num_holds  => $check->{outstanding},
1052                     duration   => $check->{duration},
1053                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1054                 };
1055             }
1056             else {
1057                 $needsconfirmation{HIGHHOLDS} = {
1058                     num_holds  => $check->{outstanding},
1059                     duration   => $check->{duration},
1060                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1061                 };
1062             }
1063         }
1064     }
1065
1066     if (
1067         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1068         # don't do the multiple loans per bib check if we've
1069         # already determined that we've got a loan on the same item
1070         !$issuingimpossible{NO_MORE_RENEWALS} &&
1071         !$needsconfirmation{RENEW_ISSUE}
1072     ) {
1073         # Check if borrower has already issued an item from the same biblio
1074         # Only if it's not a subscription
1075         my $biblionumber = $item->biblionumber;
1076         require C4::Serials;
1077         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1078         unless ($is_a_subscription) {
1079             # FIXME Should be $patron->checkouts($args);
1080             my $checkouts = Koha::Checkouts->search(
1081                 {
1082                     borrowernumber => $patron->borrowernumber,
1083                     biblionumber   => $biblionumber,
1084                 },
1085                 {
1086                     join => 'item',
1087                 }
1088             );
1089             # if we get here, we don't already have a loan on this item,
1090             # so if there are any loans on this bib, ask for confirmation
1091             if ( $checkouts->count ) {
1092                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1093             }
1094         }
1095     }
1096
1097     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1098 }
1099
1100 =head2 CanBookBeReturned
1101
1102   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1103
1104 Check whether the item can be returned to the provided branch
1105
1106 =over 4
1107
1108 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1109
1110 =item C<$branch> is the branchcode where the return is taking place
1111
1112 =back
1113
1114 Returns:
1115
1116 =over 4
1117
1118 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1119
1120 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1121
1122 =back
1123
1124 =cut
1125
1126 sub CanBookBeReturned {
1127   my ($item, $branch) = @_;
1128   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1129
1130   # assume return is allowed to start
1131   my $allowed = 1;
1132   my $message;
1133
1134   # identify all cases where return is forbidden
1135   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1136      $allowed = 0;
1137      $message = $item->{'homebranch'};
1138   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1139      $allowed = 0;
1140      $message = $item->{'holdingbranch'};
1141   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1142      $allowed = 0;
1143      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1144   }
1145
1146   return ($allowed, $message);
1147 }
1148
1149 =head2 CheckHighHolds
1150
1151     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1152     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1153     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1154
1155 =cut
1156
1157 sub checkHighHolds {
1158     my ( $item, $borrower ) = @_;
1159     my $branch = _GetCircControlBranch( $item, $borrower );
1160     my $item_object = Koha::Items->find( $item->{itemnumber} );
1161
1162     my $return_data = {
1163         exceeded    => 0,
1164         outstanding => 0,
1165         duration    => 0,
1166         due_date    => undef,
1167     };
1168
1169     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1170
1171     if ( $holds->count() ) {
1172         $return_data->{outstanding} = $holds->count();
1173
1174         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1175         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1176         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1177
1178         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1179
1180         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1181
1182             # static means just more than a given number of holds on the record
1183
1184             # If the number of holds is less than the threshold, we can stop here
1185             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1186                 return $return_data;
1187             }
1188         }
1189         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1190
1191             # dynamic means X more than the number of holdable items on the record
1192
1193             # let's get the items
1194             my @items = $holds->next()->biblio()->items();
1195
1196             # Remove any items with status defined to be ignored even if the would not make item unholdable
1197             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1198                 @items = grep { !$_->$status } @items;
1199             }
1200
1201             # Remove any items that are not holdable for this patron
1202             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber )->{status} eq 'OK' } @items;
1203
1204             my $items_count = scalar @items;
1205
1206             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1207
1208             # If the number of holds is less than the count of items we have
1209             # plus the number of holds allowed above that count, we can stop here
1210             if ( $holds->count() <= $threshold ) {
1211                 return $return_data;
1212             }
1213         }
1214
1215         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1216
1217         my $calendar = Koha::Calendar->new( branchcode => $branch );
1218
1219         my $itype = $item_object->effective_itemtype;
1220         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branch, $borrower );
1221
1222         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1223
1224         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1225         $reduced_datedue->set_hour($orig_due->hour);
1226         $reduced_datedue->set_minute($orig_due->minute);
1227         $reduced_datedue->truncate( to => 'minute' );
1228
1229         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1230             $return_data->{exceeded} = 1;
1231             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1232             $return_data->{due_date} = $reduced_datedue;
1233         }
1234     }
1235
1236     return $return_data;
1237 }
1238
1239 =head2 AddIssue
1240
1241   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1242
1243 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1244
1245 =over 4
1246
1247 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1248
1249 =item C<$barcode> is the barcode of the item being issued.
1250
1251 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1252 Calculated if empty.
1253
1254 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1255
1256 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1257 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1258
1259 AddIssue does the following things :
1260
1261   - step 01: check that there is a borrowernumber & a barcode provided
1262   - check for RENEWAL (book issued & being issued to the same patron)
1263       - renewal YES = Calculate Charge & renew
1264       - renewal NO  =
1265           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1266           * RESERVE PLACED ?
1267               - fill reserve if reserve to this patron
1268               - cancel reserve or not, otherwise
1269           * TRANSFERT PENDING ?
1270               - complete the transfert
1271           * ISSUE THE BOOK
1272
1273 =back
1274
1275 =cut
1276
1277 sub AddIssue {
1278     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1279
1280     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1281     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1282     my $auto_renew = $params && $params->{auto_renew};
1283     my $dbh          = C4::Context->dbh;
1284     my $barcodecheck = CheckValidBarcode($barcode);
1285
1286     my $issue;
1287
1288     if ( $datedue && ref $datedue ne 'DateTime' ) {
1289         $datedue = dt_from_string($datedue);
1290     }
1291
1292     # $issuedate defaults to today.
1293     if ( !defined $issuedate ) {
1294         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1295     }
1296     else {
1297         if ( ref $issuedate ne 'DateTime' ) {
1298             $issuedate = dt_from_string($issuedate);
1299
1300         }
1301     }
1302
1303     # Stop here if the patron or barcode doesn't exist
1304     if ( $borrower && $barcode && $barcodecheck ) {
1305         # find which item we issue
1306         my $item = Koha::Items->find({ barcode => $barcode })
1307           or return;    # if we don't get an Item, abort.
1308         my $item_unblessed = $item->unblessed;
1309
1310         my $branch = _GetCircControlBranch( $item_unblessed, $borrower );
1311
1312         # get actual issuing if there is one
1313         my $actualissue = $item->checkout;
1314
1315         # check if we just renew the issue.
1316         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1317                 and not $switch_onsite_checkout ) {
1318             $datedue = AddRenewal(
1319                 $borrower->{'borrowernumber'},
1320                 $item->itemnumber,
1321                 $branch,
1322                 $datedue,
1323                 $issuedate,    # here interpreted as the renewal date
1324             );
1325         }
1326         else {
1327             # it's NOT a renewal
1328             if ( $actualissue and not $switch_onsite_checkout ) {
1329                 # This book is currently on loan, but not to the person
1330                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1331                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1332                 return unless $allowed;
1333                 AddReturn( $item->barcode, C4::Context->userenv->{'branch'} );
1334             }
1335
1336             C4::Reserves::MoveReserve( $item->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1337
1338             # Starting process for transfer job (checking transfert and validate it if we have one)
1339             my ($datesent) = GetTransfers( $item->itemnumber );
1340             if ($datesent) {
1341                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1342                 my $sth = $dbh->prepare(
1343                     "UPDATE branchtransfers
1344                         SET datearrived = now(),
1345                         tobranch = ?,
1346                         comments = 'Forced branchtransfer'
1347                     WHERE itemnumber= ? AND datearrived IS NULL"
1348                 );
1349                 $sth->execute( C4::Context->userenv->{'branch'},
1350                     $item->itemnumber );
1351             }
1352
1353             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1354             unless ($auto_renew) {
1355                 my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1356                     {   categorycode => $borrower->{categorycode},
1357                         itemtype     => $item->effective_itemtype,
1358                         branchcode   => $branch
1359                     }
1360                 );
1361
1362                 $auto_renew = $issuing_rule->auto_renew if $issuing_rule;
1363             }
1364
1365             # Record in the database the fact that the book was issued.
1366             unless ($datedue) {
1367                 my $itype = $item->effective_itemtype;
1368                 $datedue = CalcDateDue( $issuedate, $itype, $branch, $borrower );
1369
1370             }
1371             $datedue->truncate( to => 'minute' );
1372
1373             my $issue_attributes = {
1374                 borrowernumber  => $borrower->{'borrowernumber'},
1375                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1376                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1377                 branchcode      => C4::Context->userenv->{'branch'},
1378                 onsite_checkout => $onsite_checkout,
1379                 auto_renew      => $auto_renew ? 1 : 0,
1380             };
1381
1382             $issue = Koha::Checkouts->find( { itemnumber => $item->itemnumber } );
1383             if ($issue) {
1384                 $issue->set($issue_attributes)->store;
1385             }
1386             else {
1387                 $issue = Koha::Checkout->new(
1388                     {
1389                         itemnumber => $item->itemnumber,
1390                         %$issue_attributes,
1391                     }
1392                 )->store;
1393             }
1394
1395             if ( C4::Context->preference('ReturnToShelvingCart') ) {
1396                 # ReturnToShelvingCart is on, anything issued should be taken off the cart.
1397                 CartToShelf( $item->itemnumber );
1398             }
1399
1400             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1401                 UpdateTotalIssues( $item->biblionumber, 1 );
1402             }
1403
1404             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1405             if ( $item->itemlost ) {
1406                 if (
1407                     Koha::RefundLostItemFeeRules->should_refund(
1408                         {
1409                             current_branch      => C4::Context->userenv->{branch},
1410                             item_home_branch    => $item->homebranch,
1411                             item_holding_branch => $item->holdingbranch,
1412                         }
1413                     )
1414                   )
1415                 {
1416                     _FixAccountForLostAndReturned( $item->itemnumber, undef,
1417                         $item->barcode );
1418                 }
1419             }
1420
1421             ModItem(
1422                 {
1423                     issues        => $item->issues + 1,
1424                     holdingbranch => C4::Context->userenv->{'branch'},
1425                     itemlost      => 0,
1426                     onloan        => $datedue->ymd(),
1427                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1428                 },
1429                 $item->biblionumber,
1430                 $item->itemnumber,
1431                 { log_action => 0 }
1432             );
1433             ModDateLastSeen( $item->itemnumber );
1434
1435            # If it costs to borrow this book, charge it to the patron's account.
1436             my ( $charge, $itemtype ) = GetIssuingCharges( $item->itemnumber, $borrower->{'borrowernumber'} );
1437             if ( $charge > 0 ) {
1438                 my $description = "Rental";
1439                 AddIssuingCharge( $issue, $charge, $description );
1440             }
1441
1442             my $itemtype = Koha::ItemTypes->find( $item_object->effective_itemtype );
1443             if ( $itemtype ) {
1444                 my $daily_charge = $itemtype->calc_rental_charge_daily( { from => $issuedate, to => $datedue } );
1445                 if ( $daily_charge > 0 ) {
1446                     AddIssuingCharge( $issue, $daily_charge, 'Daily rental' ) if $daily_charge > 0;
1447                     $charge += $daily_charge;
1448                     $item->{charge} = $charge;
1449                 }
1450             }
1451
1452             # Record the fact that this book was issued.
1453             &UpdateStats(
1454                 {
1455                     branch => C4::Context->userenv->{'branch'},
1456                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1457                     amount         => $charge,
1458                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1459                     itemnumber     => $item->itemnumber,
1460                     itemtype       => $item->effective_itemtype,
1461                     location       => $item->location,
1462                     borrowernumber => $borrower->{'borrowernumber'},
1463                     ccode          => $item->ccode,
1464                 }
1465             );
1466
1467             # Send a checkout slip.
1468             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1469             my %conditions        = (
1470                 branchcode   => $branch,
1471                 categorycode => $borrower->{categorycode},
1472                 item_type    => $item->effective_itemtype,
1473                 notification => 'CHECKOUT',
1474             );
1475             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1476                 SendCirculationAlert(
1477                     {
1478                         type     => 'CHECKOUT',
1479                         item     => $item->unblessed,
1480                         borrower => $borrower,
1481                         branch   => $branch,
1482                     }
1483                 );
1484             }
1485             logaction(
1486                 "CIRCULATION", "ISSUE",
1487                 $borrower->{'borrowernumber'},
1488                 $item->itemnumber,
1489             ) if C4::Context->preference("IssueLog");
1490         }
1491     }
1492     return $issue;
1493 }
1494
1495 =head2 GetLoanLength
1496
1497   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1498
1499 Get loan length for an itemtype, a borrower type and a branch
1500
1501 =cut
1502
1503 sub GetLoanLength {
1504     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1505     my $dbh = C4::Context->dbh;
1506     my $sth = $dbh->prepare(qq{
1507         SELECT issuelength, lengthunit, renewalperiod
1508         FROM issuingrules
1509         WHERE   categorycode=?
1510             AND itemtype=?
1511             AND branchcode=?
1512             AND issuelength IS NOT NULL
1513     });
1514
1515     # try to find issuelength & return the 1st available.
1516     # check with borrowertype, itemtype and branchcode, then without one of those parameters
1517     $sth->execute( $borrowertype, $itemtype, $branchcode );
1518     my $loanlength = $sth->fetchrow_hashref;
1519
1520     return $loanlength
1521       if defined($loanlength) && defined $loanlength->{issuelength};
1522
1523     $sth->execute( $borrowertype, '*', $branchcode );
1524     $loanlength = $sth->fetchrow_hashref;
1525     return $loanlength
1526       if defined($loanlength) && defined $loanlength->{issuelength};
1527
1528     $sth->execute( '*', $itemtype, $branchcode );
1529     $loanlength = $sth->fetchrow_hashref;
1530     return $loanlength
1531       if defined($loanlength) && defined $loanlength->{issuelength};
1532
1533     $sth->execute( '*', '*', $branchcode );
1534     $loanlength = $sth->fetchrow_hashref;
1535     return $loanlength
1536       if defined($loanlength) && defined $loanlength->{issuelength};
1537
1538     $sth->execute( $borrowertype, $itemtype, '*' );
1539     $loanlength = $sth->fetchrow_hashref;
1540     return $loanlength
1541       if defined($loanlength) && defined $loanlength->{issuelength};
1542
1543     $sth->execute( $borrowertype, '*', '*' );
1544     $loanlength = $sth->fetchrow_hashref;
1545     return $loanlength
1546       if defined($loanlength) && defined $loanlength->{issuelength};
1547
1548     $sth->execute( '*', $itemtype, '*' );
1549     $loanlength = $sth->fetchrow_hashref;
1550     return $loanlength
1551       if defined($loanlength) && defined $loanlength->{issuelength};
1552
1553     $sth->execute( '*', '*', '*' );
1554     $loanlength = $sth->fetchrow_hashref;
1555     return $loanlength
1556       if defined($loanlength) && defined $loanlength->{issuelength};
1557
1558     # if no rule is set => 0 day (hardcoded)
1559     return {
1560         issuelength => 0,
1561         renewalperiod => 0,
1562         lengthunit => 'days',
1563     };
1564
1565 }
1566
1567
1568 =head2 GetHardDueDate
1569
1570   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1571
1572 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1573
1574 =cut
1575
1576 sub GetHardDueDate {
1577     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1578
1579     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1580         {   categorycode => $borrowertype,
1581             itemtype     => $itemtype,
1582             branchcode   => $branchcode
1583         }
1584     );
1585
1586
1587     if ( defined( $issuing_rule ) ) {
1588         if ( $issuing_rule->hardduedate ) {
1589             return (dt_from_string($issuing_rule->hardduedate, 'iso'),$issuing_rule->hardduedatecompare);
1590         } else {
1591             return (undef, undef);
1592         }
1593     }
1594 }
1595
1596 =head2 GetBranchBorrowerCircRule
1597
1598   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1599
1600 Retrieves circulation rule attributes that apply to the given
1601 branch and patron category, regardless of item type.
1602 The return value is a hashref containing the following key:
1603
1604 patron_maxissueqty - maximum number of loans that a
1605 patron of the given category can have at the given
1606 branch.  If the value is undef, no limit.
1607
1608 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1609 patron of the given category can have at the given
1610 branch.  If the value is undef, no limit.
1611
1612 This will check for different branch/category combinations in the following order:
1613 branch and category
1614 branch only
1615 category only
1616 default branch and category
1617
1618 If no rule has been found in the database, it will default to
1619 the buillt in rule:
1620
1621 patron_maxissueqty - undef
1622 patron_maxonsiteissueqty - undef
1623
1624 C<$branchcode> and C<$categorycode> should contain the
1625 literal branch code and patron category code, respectively - no
1626 wildcards.
1627
1628 =cut
1629
1630 sub GetBranchBorrowerCircRule {
1631     my ( $branchcode, $categorycode ) = @_;
1632
1633     # Initialize default values
1634     my $rules = {
1635         patron_maxissueqty       => undef,
1636         patron_maxonsiteissueqty => undef,
1637     };
1638
1639     # Search for rules!
1640     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1641         my $rule = Koha::CirculationRules->get_effective_rule(
1642             {
1643                 categorycode => $categorycode,
1644                 itemtype     => undef,
1645                 branchcode   => $branchcode,
1646                 rule_name    => $rule_name,
1647             }
1648         );
1649
1650         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1651     }
1652
1653     return $rules;
1654 }
1655
1656 =head2 GetBranchItemRule
1657
1658   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1659
1660 Retrieves circulation rule attributes that apply to the given
1661 branch and item type, regardless of patron category.
1662
1663 The return value is a hashref containing the following keys:
1664
1665 holdallowed => Hold policy for this branch and itemtype. Possible values:
1666   0: No holds allowed.
1667   1: Holds allowed only by patrons that have the same homebranch as the item.
1668   2: Holds allowed from any patron.
1669
1670 returnbranch => branch to which to return item.  Possible values:
1671   noreturn: do not return, let item remain where checked in (floating collections)
1672   homebranch: return to item's home branch
1673   holdingbranch: return to issuer branch
1674
1675 This searches branchitemrules in the following order:
1676
1677   * Same branchcode and itemtype
1678   * Same branchcode, itemtype '*'
1679   * branchcode '*', same itemtype
1680   * branchcode and itemtype '*'
1681
1682 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1683
1684 =cut
1685
1686 sub GetBranchItemRule {
1687     my ( $branchcode, $itemtype ) = @_;
1688     my $dbh = C4::Context->dbh();
1689     my $result = {};
1690
1691     my @attempts = (
1692         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1693             FROM branch_item_rules
1694             WHERE branchcode = ?
1695               AND itemtype = ?', $branchcode, $itemtype],
1696         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1697             FROM default_branch_circ_rules
1698             WHERE branchcode = ?', $branchcode],
1699         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1700             FROM default_branch_item_rules
1701             WHERE itemtype = ?', $itemtype],
1702         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1703             FROM default_circ_rules'],
1704     );
1705
1706     foreach my $attempt (@attempts) {
1707         my ($query, @bind_params) = @{$attempt};
1708         my $search_result = $dbh->selectrow_hashref ( $query , {}, @bind_params )
1709           or next;
1710
1711         # Since branch/category and branch/itemtype use the same per-branch
1712         # defaults tables, we have to check that the key we want is set, not
1713         # just that a row was returned
1714         $result->{'holdallowed'}  = $search_result->{'holdallowed'}  unless ( defined $result->{'holdallowed'} );
1715         $result->{'hold_fulfillment_policy'} = $search_result->{'hold_fulfillment_policy'} unless ( defined $result->{'hold_fulfillment_policy'} );
1716         $result->{'returnbranch'} = $search_result->{'returnbranch'} unless ( defined $result->{'returnbranch'} );
1717     }
1718
1719     # built-in default circulation rule
1720     $result->{'holdallowed'} = 2 unless ( defined $result->{'holdallowed'} );
1721     $result->{'hold_fulfillment_policy'} = 'any' unless ( defined $result->{'hold_fulfillment_policy'} );
1722     $result->{'returnbranch'} = 'homebranch' unless ( defined $result->{'returnbranch'} );
1723
1724     return $result;
1725 }
1726
1727 =head2 AddReturn
1728
1729   ($doreturn, $messages, $iteminformation, $borrower) =
1730       &AddReturn( $barcode, $branch [,$exemptfine] [,$dropbox] [,$returndate] );
1731
1732 Returns a book.
1733
1734 =over 4
1735
1736 =item C<$barcode> is the bar code of the book being returned.
1737
1738 =item C<$branch> is the code of the branch where the book is being returned.
1739
1740 =item C<$exemptfine> indicates that overdue charges for the item will be
1741 removed. Optional.
1742
1743 =item C<$dropbox> indicates that the check-in date is assumed to be
1744 yesterday, or the last non-holiday as defined in C4::Calendar .  If
1745 overdue charges are applied and C<$dropbox> is true, the last charge
1746 will be removed.  This assumes that the fines accrual script has run
1747 for _today_. Optional.
1748
1749 =item C<$return_date> allows the default return date to be overridden
1750 by the given return date. Optional.
1751
1752 =back
1753
1754 C<&AddReturn> returns a list of four items:
1755
1756 C<$doreturn> is true iff the return succeeded.
1757
1758 C<$messages> is a reference-to-hash giving feedback on the operation.
1759 The keys of the hash are:
1760
1761 =over 4
1762
1763 =item C<BadBarcode>
1764
1765 No item with this barcode exists. The value is C<$barcode>.
1766
1767 =item C<NotIssued>
1768
1769 The book is not currently on loan. The value is C<$barcode>.
1770
1771 =item C<withdrawn>
1772
1773 This book has been withdrawn/cancelled. The value should be ignored.
1774
1775 =item C<Wrongbranch>
1776
1777 This book has was returned to the wrong branch.  The value is a hashref
1778 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1779 contain the branchcode of the incorrect and correct return library, respectively.
1780
1781 =item C<ResFound>
1782
1783 The item was reserved. The value is a reference-to-hash whose keys are
1784 fields from the reserves table of the Koha database, and
1785 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1786 either C<Waiting>, C<Reserved>, or 0.
1787
1788 =item C<WasReturned>
1789
1790 Value 1 if return is successful.
1791
1792 =item C<NeedsTransfer>
1793
1794 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1795
1796 =back
1797
1798 C<$iteminformation> is a reference-to-hash, giving information about the
1799 returned item from the issues table.
1800
1801 C<$borrower> is a reference-to-hash, giving information about the
1802 patron who last borrowed the book.
1803
1804 =cut
1805
1806 sub AddReturn {
1807     my ( $barcode, $branch, $exemptfine, $dropbox, $return_date, $dropboxdate ) = @_;
1808
1809     if ($branch and not Koha::Libraries->find($branch)) {
1810         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1811         undef $branch;
1812     }
1813     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1814     my $messages;
1815     my $patron;
1816     my $doreturn       = 1;
1817     my $validTransfert = 0;
1818     my $stat_type = 'return';
1819
1820     # get information on item
1821     my $item = Koha::Items->find({ barcode => $barcode });
1822     unless ($item) {
1823         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1824     }
1825
1826     my $itemnumber = $item->itemnumber;
1827     my $itemtype = $item->effective_itemtype;
1828
1829     my $issue  = $item->checkout;
1830     if ( $issue ) {
1831         $patron = $issue->patron
1832             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1833                 . Dumper($issue->unblessed) . "\n";
1834     } else {
1835         $messages->{'NotIssued'} = $barcode;
1836         ModItem({ onloan => undef }, $item->biblionumber, $item->itemnumber) if defined $item->onloan;
1837         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1838         $doreturn = 0;
1839         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1840         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1841         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1842            $messages->{'LocalUse'} = 1;
1843            $stat_type = 'localuse';
1844         }
1845     }
1846
1847     my $item_unblessed = $item->unblessed;
1848     if ( $item->location eq 'PROC' ) {
1849         if ( C4::Context->preference("InProcessingToShelvingCart") ) {
1850             $item_unblessed->{location} = 'CART';
1851         }
1852         else {
1853             $item_unblessed->{location} = $item->permanent_location;
1854         }
1855
1856         ModItem( $item_unblessed, $item->biblionumber, $item->itemnumber, { log_action => 0 } );
1857     }
1858
1859         # full item data, but no borrowernumber or checkout info (no issue)
1860     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1861         # get the proper branch to which to return the item
1862     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1863         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1864
1865     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1866     my $patron_unblessed = $patron ? $patron->unblessed : {};
1867
1868     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1869     if ($yaml) {
1870         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1871         my $rules;
1872         eval { $rules = YAML::Load($yaml); };
1873         if ($@) {
1874             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1875         }
1876         else {
1877             foreach my $key ( keys %$rules ) {
1878                 if ( $item->notforloan eq $key ) {
1879                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1880                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber, { log_action => 0 } );
1881                     last;
1882                 }
1883             }
1884         }
1885     }
1886
1887     # check if the return is allowed at this branch
1888     my ($returnallowed, $message) = CanBookBeReturned($item_unblessed, $branch);
1889     unless ($returnallowed){
1890         $messages->{'Wrongbranch'} = {
1891             Wrongbranch => $branch,
1892             Rightbranch => $message
1893         };
1894         $doreturn = 0;
1895         return ( $doreturn, $messages, $issue, $patron_unblessed);
1896     }
1897
1898     if ( $item->withdrawn ) { # book has been cancelled
1899         $messages->{'withdrawn'} = 1;
1900         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1901     }
1902
1903     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1904         $doreturn = 0;
1905     }
1906
1907     # case of a return of document (deal with issues and holdingbranch)
1908     my $today = DateTime->now( time_zone => C4::Context->tz() );
1909
1910     if ($doreturn) {
1911         my $is_overdue;
1912         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1913         $patron or warn "AddReturn without current borrower";
1914         if ($dropbox) {
1915             $is_overdue = $issue->is_overdue( $dropboxdate );
1916         } else {
1917             $is_overdue = $issue->is_overdue;
1918         }
1919
1920         if ($patron) {
1921             eval {
1922                 if ( $dropbox ) {
1923                     MarkIssueReturned( $borrowernumber, $item->itemnumber,
1924                         $dropboxdate, $patron->privacy );
1925                 }
1926                 else {
1927                     MarkIssueReturned( $borrowernumber, $item->itemnumber,
1928                         $return_date, $patron->privacy );
1929                 }
1930             };
1931             unless ( $@ ) {
1932                 if ( ( C4::Context->preference('CalculateFinesOnReturn') && $is_overdue ) || $return_date ) {
1933                     _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed, return_date => $return_date } );
1934                 }
1935             } else {
1936                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1937
1938                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1939             }
1940
1941             # FIXME is the "= 1" right?  This could be the borrower hash.
1942             $messages->{'WasReturned'} = 1;
1943
1944         }
1945
1946         ModItem( { onloan => undef }, $item->biblionumber, $item->itemnumber, { log_action => 0 } );
1947     }
1948
1949     # the holdingbranch is updated if the document is returned to another location.
1950     # this is always done regardless of whether the item was on loan or not
1951     my $item_holding_branch = $item->holdingbranch;
1952     if ($item->holdingbranch ne $branch) {
1953         UpdateHoldingbranch($branch, $item->itemnumber);
1954         $item_unblessed->{'holdingbranch'} = $branch; # update item data holdingbranch too # FIXME I guess this is for the _debar_user_on_return call later
1955     }
1956
1957     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
1958     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
1959
1960     # check if we have a transfer for this document
1961     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
1962
1963     # if we have a transfer to do, we update the line of transfers with the datearrived
1964     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
1965     if ($datesent) {
1966         if ( $tobranch eq $branch ) {
1967             my $sth = C4::Context->dbh->prepare(
1968                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
1969             );
1970             $sth->execute( $item->itemnumber );
1971             # if we have a reservation with valid transfer, we can set it's status to 'W'
1972             ShelfToCart( $item->itemnumber ) if ( C4::Context->preference("ReturnToShelvingCart") );
1973             C4::Reserves::ModReserveStatus($item->itemnumber, 'W');
1974         } else {
1975             $messages->{'WrongTransfer'}     = $tobranch;
1976             $messages->{'WrongTransferItem'} = $item->itemnumber;
1977         }
1978         $validTransfert = 1;
1979     } else {
1980         ShelfToCart( $item->itemnumber ) if ( C4::Context->preference("ReturnToShelvingCart") );
1981     }
1982
1983     # fix up the accounts.....
1984     if ( $item->itemlost ) {
1985         $messages->{'WasLost'} = 1;
1986         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
1987             if (
1988                 Koha::RefundLostItemFeeRules->should_refund(
1989                     {
1990                         current_branch      => C4::Context->userenv->{branch},
1991                         item_home_branch    => $item->homebranch,
1992                         item_holding_branch => $item_holding_branch
1993                     }
1994                 )
1995               )
1996             {
1997                 _FixAccountForLostAndReturned( $item->itemnumber,
1998                     $borrowernumber, $barcode );
1999                 $messages->{'LostItemFeeRefunded'} = 1;
2000             }
2001         }
2002     }
2003
2004     # fix up the overdues in accounts...
2005     if ($borrowernumber) {
2006         my $fix = _FixOverduesOnReturn($borrowernumber, $item->itemnumber, $exemptfine, $dropbox);
2007         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->itemnumber...) failed!";  # zero is OK, check defined
2008
2009         if ( $issue and $issue->is_overdue ) {
2010         # fix fine days
2011             $today = dt_from_string($return_date) if $return_date;
2012             $today = $dropboxdate if $dropbox;
2013             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item_unblessed, dt_from_string($issue->date_due), $today );
2014             if ($reminder){
2015                 $messages->{'PrevDebarred'} = $debardate;
2016             } else {
2017                 $messages->{'Debarred'} = $debardate if $debardate;
2018             }
2019         # there's no overdue on the item but borrower had been previously debarred
2020         } elsif ( $issue->date_due and $patron->debarred ) {
2021              if ( $patron->debarred eq "9999-12-31") {
2022                 $messages->{'ForeverDebarred'} = $patron->debarred;
2023              } else {
2024                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2025                   $borrower_debar_dt->truncate(to => 'day');
2026                   my $today_dt = $today->clone()->truncate(to => 'day');
2027                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2028                       $messages->{'PrevDebarred'} = $patron->debarred;
2029                   }
2030              }
2031         }
2032     }
2033
2034     # find reserves.....
2035     # if we don't have a reserve with the status W, we launch the Checkreserves routine
2036     my ($resfound, $resrec);
2037     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2038     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2039     if ($resfound) {
2040           $resrec->{'ResFound'} = $resfound;
2041         $messages->{'ResFound'} = $resrec;
2042     }
2043
2044     # Record the fact that this book was returned.
2045     UpdateStats({
2046         branch         => $branch,
2047         type           => $stat_type,
2048         itemnumber     => $itemnumber,
2049         itemtype       => $itemtype,
2050         borrowernumber => $borrowernumber,
2051         ccode          => $item->ccode,
2052     });
2053
2054     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2055     if ( $patron ) {
2056         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2057         my %conditions = (
2058             branchcode   => $branch,
2059             categorycode => $patron->categorycode,
2060             item_type    => $itemtype,
2061             notification => 'CHECKIN',
2062         );
2063         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2064             SendCirculationAlert({
2065                 type     => 'CHECKIN',
2066                 item     => $item_unblessed,
2067                 borrower => $patron->unblessed,
2068                 branch   => $branch,
2069             });
2070         }
2071
2072         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2073             if C4::Context->preference("ReturnLog");
2074         }
2075
2076     # Remove any OVERDUES related debarment if the borrower has no overdues
2077     if ( $borrowernumber
2078       && $patron->debarred
2079       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2080       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2081       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2082     ) {
2083         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2084     }
2085
2086     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2087     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2088         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType");
2089         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2090             (C4::Context->preference("UseBranchTransferLimits") and
2091              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2092            )) {
2093             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s)", $item->itemnumber,$branch, $returnbranch;
2094             $debug and warn "item: " . Dumper($item_unblessed);
2095             ModItemTransfer($item->itemnumber, $branch, $returnbranch);
2096             $messages->{'WasTransfered'} = 1;
2097         } else {
2098             $messages->{'NeedsTransfer'} = $returnbranch;
2099         }
2100     }
2101
2102     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2103 }
2104
2105 =head2 MarkIssueReturned
2106
2107   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2108
2109 Unconditionally marks an issue as being returned by
2110 moving the C<issues> row to C<old_issues> and
2111 setting C<returndate> to the current date.
2112
2113 if C<$returndate> is specified (in iso format), it is used as the date
2114 of the return.
2115
2116 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2117 the old_issue is immediately anonymised
2118
2119 Ideally, this function would be internal to C<C4::Circulation>,
2120 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2121 and offline_circ/process_koc.pl.
2122
2123 =cut
2124
2125 sub MarkIssueReturned {
2126     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2127
2128     # Retrieve the issue
2129     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2130     my $issue_id = $issue->issue_id;
2131
2132     my $anonymouspatron;
2133     if ( $privacy == 2 ) {
2134         # The default of 0 will not work due to foreign key constraints
2135         # The anonymisation will fail if AnonymousPatron is not a valid entry
2136         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2137         # Note that a warning should appear on the about page (System information tab).
2138         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2139         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2140             unless Koha::Patrons->find( $anonymouspatron );
2141     }
2142
2143     my $schema = Koha::Database->schema;
2144
2145     # FIXME Improve the return value and handle it from callers
2146     $schema->txn_do(sub {
2147
2148         # Update the returndate value
2149         if ( $returndate ) {
2150             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2151         }
2152         else {
2153             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2154         }
2155
2156         # Create the old_issues entry
2157         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2158
2159         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2160         if ( $privacy == 2) {
2161             $old_checkout->borrowernumber($anonymouspatron)->store;
2162         }
2163
2164         # And finally delete the issue
2165         $issue->delete;
2166
2167         ModItem( { 'onloan' => undef }, undef, $itemnumber, { log_action => 0 } );
2168
2169         if ( C4::Context->preference('StoreLastBorrower') ) {
2170             my $item = Koha::Items->find( $itemnumber );
2171             my $patron = Koha::Patrons->find( $borrowernumber );
2172             $item->last_returned_by( $patron );
2173         }
2174     });
2175
2176     return $issue_id;
2177 }
2178
2179 =head2 _debar_user_on_return
2180
2181     _debar_user_on_return($borrower, $item, $datedue, today);
2182
2183 C<$borrower> borrower hashref
2184
2185 C<$item> item hashref
2186
2187 C<$datedue> date due DateTime object
2188
2189 C<$return_date> DateTime object representing the return time
2190
2191 Internal function, called only by AddReturn that calculates and updates
2192  the user fine days, and debars them if necessary.
2193
2194 Should only be called for overdue returns
2195
2196 =cut
2197
2198 sub _debar_user_on_return {
2199     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2200
2201     my $branchcode = _GetCircControlBranch( $item, $borrower );
2202
2203     my $circcontrol = C4::Context->preference('CircControl');
2204     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2205         {   categorycode => $borrower->{categorycode},
2206             itemtype     => $item->{itype},
2207             branchcode   => $branchcode
2208         }
2209     );
2210     my $finedays = $issuing_rule ? $issuing_rule->finedays : undef;
2211     my $unit     = $issuing_rule ? $issuing_rule->lengthunit : undef;
2212     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2213
2214     if ($finedays) {
2215
2216         # finedays is in days, so hourly loans must multiply by 24
2217         # thus 1 hour late equals 1 day suspension * finedays rate
2218         $finedays = $finedays * 24 if ( $unit eq 'hours' );
2219
2220         # grace period is measured in the same units as the loan
2221         my $grace =
2222           DateTime::Duration->new( $unit => $issuing_rule->firstremind );
2223
2224         my $deltadays = DateTime::Duration->new(
2225             days => $chargeable_units
2226         );
2227         if ( $deltadays->subtract($grace)->is_positive() ) {
2228             my $suspension_days = $deltadays * $finedays;
2229
2230             # If the max suspension days is < than the suspension days
2231             # the suspension days is limited to this maximum period.
2232             my $max_sd = $issuing_rule->maxsuspensiondays;
2233             if ( defined $max_sd ) {
2234                 $max_sd = DateTime::Duration->new( days => $max_sd );
2235                 $suspension_days = $max_sd
2236                   if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2237             }
2238
2239             my ( $has_been_extended, $is_a_reminder );
2240             if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2241                 my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2242                 if ( $debarment ) {
2243                     $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2244                     $has_been_extended = 1;
2245                 }
2246             }
2247
2248             if ( $issuing_rule->suspension_chargeperiod > 1 ) {
2249                 # No need to / 1 and do not consider / 0
2250                 $suspension_days = DateTime::Duration->new(
2251                     days => floor( $suspension_days->in_units('days') / $issuing_rule->suspension_chargeperiod )
2252                 );
2253             }
2254
2255             my $new_debar_dt;
2256             # Use the calendar or not to calculate the debarment date
2257             if ( C4::Context->preference('finesCalendar') eq 'noFinesWhenClosed' ) {
2258                 my $calendar = Koha::Calendar->new(
2259                     branchcode => $branchcode,
2260                     days_mode  => 'Calendar'
2261                 );
2262                 $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2263             }
2264             else {
2265                 $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2266             }
2267
2268             Koha::Patron::Debarments::AddUniqueDebarment({
2269                 borrowernumber => $borrower->{borrowernumber},
2270                 expiration     => $new_debar_dt->ymd(),
2271                 type           => 'SUSPENSION',
2272             });
2273             # if borrower was already debarred but does not get an extra debarment
2274             my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2275             my $new_debarment_str;
2276             if ( $borrower->{debarred} eq $patron->is_debarred ) {
2277                 $is_a_reminder = 1;
2278                 $new_debarment_str = $borrower->{debarred};
2279             } else {
2280                 $new_debarment_str = $new_debar_dt->ymd();
2281             }
2282             # FIXME Should return a DateTime object
2283             return $new_debarment_str, $is_a_reminder;
2284         }
2285     }
2286     return;
2287 }
2288
2289 =head2 _FixOverduesOnReturn
2290
2291    &_FixOverduesOnReturn($brn,$itm, $exemptfine, $dropboxmode);
2292
2293 C<$brn> borrowernumber
2294
2295 C<$itm> itemnumber
2296
2297 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2298 C<$dropboxmode> BOOL -- remove lastincrement on overdue charge associated with this issue.
2299
2300 Internal function
2301
2302 =cut
2303
2304 sub _FixOverduesOnReturn {
2305     my ($borrowernumber, $item, $exemptfine, $dropbox ) = @_;
2306     unless( $borrowernumber ) {
2307         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2308         return;
2309     }
2310     unless( $item ) {
2311         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2312         return;
2313     }
2314
2315     # check for overdue fine
2316     my $accountline = Koha::Account::Lines->search(
2317         {
2318             borrowernumber => $borrowernumber,
2319             itemnumber     => $item,
2320             -or            => [
2321                 accounttype => 'FU',
2322                 accounttype => 'O',
2323             ],
2324         }
2325     )->next();
2326     return 0 unless $accountline;    # no warning, there's just nothing to fix
2327
2328     if ($exemptfine) {
2329         my $amountoutstanding = $accountline->amountoutstanding;
2330
2331         $accountline->accounttype('FFOR');
2332         $accountline->amountoutstanding(0);
2333
2334         Koha::Account::Offset->new(
2335             {
2336                 debit_id => $accountline->id,
2337                 type => 'Forgiven',
2338                 amount => $amountoutstanding * -1,
2339             }
2340         )->store();
2341
2342         if (C4::Context->preference("FinesLog")) {
2343             &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2344         }
2345     } elsif ($dropbox && $accountline->lastincrement) {
2346         my $outstanding = $accountline->amountoutstanding - $accountline->lastincrement;
2347         my $amt = $accountline->amount - $accountline->lastincrement;
2348
2349         Koha::Account::Offset->new(
2350             {
2351                 debit_id => $accountline->id,
2352                 type => 'Dropbox',
2353                 amount => $accountline->lastincrement * -1,
2354             }
2355         )->store();
2356
2357         if ( C4::Context->preference("FinesLog") ) {
2358             &logaction( "FINES", 'MODIFY', $borrowernumber,
2359                 "Dropbox adjustment $amt, item $item" );
2360         }
2361
2362         $accountline->accounttype('F');
2363
2364         if ( $outstanding >= 0 && $amt >= 0 ) {
2365             $accountline->amount($amt);
2366             $accountline->amountoutstanding($outstanding);
2367         }
2368
2369     } else {
2370         $accountline->accounttype('F');
2371     }
2372
2373     return $accountline->store();
2374 }
2375
2376 =head2 _FixAccountForLostAndReturned
2377
2378   &_FixAccountForLostAndReturned($itemnumber, [$borrowernumber, $barcode]);
2379
2380 Calculates the charge for a book lost and returned.
2381
2382 Internal function, not exported, called only by AddReturn.
2383
2384 =cut
2385
2386 sub _FixAccountForLostAndReturned {
2387     my $itemnumber     = shift or return;
2388     my $borrowernumber = @_ ? shift : undef;
2389     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2390
2391     my $credit;
2392
2393     # check for charge made for lost book
2394     my $accountlines = Koha::Account::Lines->search(
2395         {
2396             itemnumber  => $itemnumber,
2397             accounttype => { -in => [ 'L', 'Rep', 'W' ] },
2398         },
2399         {
2400             order_by => { -desc => [ 'date', 'accountno' ] }
2401         }
2402     );
2403
2404     return unless $accountlines->count > 0;
2405     my $accountline     = $accountlines->next;
2406     my $total_to_refund = 0;
2407     my $account = Koha::Patrons->find( $accountline->borrowernumber )->account;
2408
2409     # Use cases
2410     if ( $accountline->amount > $accountline->amountoutstanding ) {
2411         # some amount has been cancelled. collect the offsets that are not writeoffs
2412         # this works because the only way to subtract from this kind of a debt is
2413         # using the UI buttons 'Pay' and 'Write off'
2414         my $credits_offsets = Koha::Account::Offsets->search({
2415             debit_id  => $accountline->id,
2416             credit_id => { '!=' => undef }, # it is not the debit itself
2417             type      => { '!=' => 'Writeoff' },
2418             amount    => { '<'  => 0 } # credits are negative on the DB
2419         });
2420
2421         $total_to_refund = ( $credits_offsets->count > 0 )
2422                             ? $credits_offsets->total * -1 # credits are negative on the DB
2423                             : 0;
2424     }
2425
2426     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2427
2428     if ( $credit_total > 0 ) {
2429         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2430         $credit = $account->add_credit(
2431             {   amount      => $credit_total,
2432                 description => 'Item Returned ' . $item_id,
2433                 type        => 'lost_item_return',
2434                 library_id  => $branchcode
2435             }
2436         );
2437
2438         # TODO: ->apply should just accept the accountline
2439         $credit->apply( { debits => $accountlines->reset } );
2440     }
2441
2442     # Manually set the accounttype
2443     $accountline->discard_changes->accounttype('LR');
2444     $accountline->store;
2445
2446     ModItem( { paidfor => '' }, undef, $itemnumber, { log_action => 0 } );
2447
2448     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2449         $account->reconcile_balance;
2450     }
2451
2452     return ($credit) ? $credit->id : undef;
2453 }
2454
2455 =head2 _GetCircControlBranch
2456
2457    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2458
2459 Internal function :
2460
2461 Return the library code to be used to determine which circulation
2462 policy applies to a transaction.  Looks up the CircControl and
2463 HomeOrHoldingBranch system preferences.
2464
2465 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2466
2467 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2468
2469 =cut
2470
2471 sub _GetCircControlBranch {
2472     my ($item, $borrower) = @_;
2473     my $circcontrol = C4::Context->preference('CircControl');
2474     my $branch;
2475
2476     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2477         $branch= C4::Context->userenv->{'branch'};
2478     } elsif ($circcontrol eq 'PatronLibrary') {
2479         $branch=$borrower->{branchcode};
2480     } else {
2481         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2482         $branch = $item->{$branchfield};
2483         # default to item home branch if holdingbranch is used
2484         # and is not defined
2485         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2486             $branch = $item->{homebranch};
2487         }
2488     }
2489     return $branch;
2490 }
2491
2492 =head2 GetOpenIssue
2493
2494   $issue = GetOpenIssue( $itemnumber );
2495
2496 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2497
2498 C<$itemnumber> is the item's itemnumber
2499
2500 Returns a hashref
2501
2502 =cut
2503
2504 sub GetOpenIssue {
2505   my ( $itemnumber ) = @_;
2506   return unless $itemnumber;
2507   my $dbh = C4::Context->dbh;
2508   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2509   $sth->execute( $itemnumber );
2510   return $sth->fetchrow_hashref();
2511
2512 }
2513
2514 =head2 GetBiblioIssues
2515
2516   $issues = GetBiblioIssues($biblionumber);
2517
2518 this function get all issues from a biblionumber.
2519
2520 Return:
2521 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2522 tables issues and the firstname,surname & cardnumber from borrowers.
2523
2524 =cut
2525
2526 sub GetBiblioIssues {
2527     my $biblionumber = shift;
2528     return unless $biblionumber;
2529     my $dbh   = C4::Context->dbh;
2530     my $query = "
2531         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2532         FROM issues
2533             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2534             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2535             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2536             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2537         WHERE biblio.biblionumber = ?
2538         UNION ALL
2539         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2540         FROM old_issues
2541             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2542             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2543             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2544             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2545         WHERE biblio.biblionumber = ?
2546         ORDER BY timestamp
2547     ";
2548     my $sth = $dbh->prepare($query);
2549     $sth->execute($biblionumber, $biblionumber);
2550
2551     my @issues;
2552     while ( my $data = $sth->fetchrow_hashref ) {
2553         push @issues, $data;
2554     }
2555     return \@issues;
2556 }
2557
2558 =head2 GetUpcomingDueIssues
2559
2560   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2561
2562 =cut
2563
2564 sub GetUpcomingDueIssues {
2565     my $params = shift;
2566
2567     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2568     my $dbh = C4::Context->dbh;
2569
2570     my $statement = <<END_SQL;
2571 SELECT *
2572 FROM (
2573     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2574     FROM issues
2575     LEFT JOIN items USING (itemnumber)
2576     LEFT OUTER JOIN branches USING (branchcode)
2577     WHERE returndate is NULL
2578 ) tmp
2579 WHERE days_until_due >= 0 AND days_until_due <= ?
2580 END_SQL
2581
2582     my @bind_parameters = ( $params->{'days_in_advance'} );
2583
2584     my $sth = $dbh->prepare( $statement );
2585     $sth->execute( @bind_parameters );
2586     my $upcoming_dues = $sth->fetchall_arrayref({});
2587
2588     return $upcoming_dues;
2589 }
2590
2591 =head2 CanBookBeRenewed
2592
2593   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2594
2595 Find out whether a borrowed item may be renewed.
2596
2597 C<$borrowernumber> is the borrower number of the patron who currently
2598 has the item on loan.
2599
2600 C<$itemnumber> is the number of the item to renew.
2601
2602 C<$override_limit>, if supplied with a true value, causes
2603 the limit on the number of times that the loan can be renewed
2604 (as controlled by the item type) to be ignored. Overriding also allows
2605 to renew sooner than "No renewal before" and to manually renew loans
2606 that are automatically renewed.
2607
2608 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2609 item must currently be on loan to the specified borrower; renewals
2610 must be allowed for the item's type; and the borrower must not have
2611 already renewed the loan. $error will contain the reason the renewal can not proceed
2612
2613 =cut
2614
2615 sub CanBookBeRenewed {
2616     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2617
2618     my $dbh    = C4::Context->dbh;
2619     my $renews = 1;
2620
2621     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2622     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2623     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2624     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2625
2626     my $patron = $issue->patron or return;
2627
2628     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2629
2630     # This item can fill one or more unfilled reserve, can those unfilled reserves
2631     # all be filled by other available items?
2632     if ( $resfound
2633         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2634     {
2635         my $schema = Koha::Database->new()->schema();
2636
2637         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2638         if ($item_holds) {
2639             # There is an item level hold on this item, no other item can fill the hold
2640             $resfound = 1;
2641         }
2642         else {
2643
2644             # Get all other items that could possibly fill reserves
2645             my @itemnumbers = $schema->resultset('Item')->search(
2646                 {
2647                     biblionumber => $resrec->{biblionumber},
2648                     onloan       => undef,
2649                     notforloan   => 0,
2650                     -not         => { itemnumber => $itemnumber }
2651                 },
2652                 { columns => 'itemnumber' }
2653             )->get_column('itemnumber')->all();
2654
2655             # Get all other reserves that could have been filled by this item
2656             my @borrowernumbers;
2657             while (1) {
2658                 my ( $reserve_found, $reserve, undef ) =
2659                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2660
2661                 if ($reserve_found) {
2662                     push( @borrowernumbers, $reserve->{borrowernumber} );
2663                 }
2664                 else {
2665                     last;
2666                 }
2667             }
2668
2669             # If the count of the union of the lists of reservable items for each borrower
2670             # is equal or greater than the number of borrowers, we know that all reserves
2671             # can be filled with available items. We can get the union of the sets simply
2672             # by pushing all the elements onto an array and removing the duplicates.
2673             my @reservable;
2674             my %borrowers;
2675             ITEM: foreach my $i (@itemnumbers) {
2676                 my $item = Koha::Items->find($i)->unblessed;
2677                 next if IsItemOnHoldAndFound($i);
2678                 for my $b (@borrowernumbers) {
2679                     my $borr = $borrowers{$b} //= Koha::Patrons->find( $b )->unblessed;
2680                     next unless IsAvailableForItemLevelRequest($item, $borr);
2681                     next unless CanItemBeReserved($b,$i);
2682
2683                     push @reservable, $i;
2684                     if (@reservable >= @borrowernumbers) {
2685                         $resfound = 0;
2686                         last ITEM;
2687                     }
2688                     last;
2689                 }
2690             }
2691         }
2692     }
2693     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2694
2695     return ( 1, undef ) if $override_limit;
2696
2697     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2698     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2699         {   categorycode => $patron->categorycode,
2700             itemtype     => $item->effective_itemtype,
2701             branchcode   => $branchcode
2702         }
2703     );
2704
2705     return ( 0, "too_many" )
2706       if not $issuing_rule or $issuing_rule->renewalsallowed <= $issue->renewals;
2707
2708     my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2709     my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2710     $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2711     my $restricted  = $patron->is_debarred;
2712     my $hasoverdues = $patron->has_overdues;
2713
2714     if ( $restricted and $restrictionblockrenewing ) {
2715         return ( 0, 'restriction');
2716     } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2717         return ( 0, 'overdue');
2718     }
2719
2720     if ( $issue->auto_renew ) {
2721
2722         if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2723             return ( 0, 'auto_account_expired' );
2724         }
2725
2726         if ( defined $issuing_rule->no_auto_renewal_after
2727                 and $issuing_rule->no_auto_renewal_after ne "" ) {
2728             # Get issue_date and add no_auto_renewal_after
2729             # If this is greater than today, it's too late for renewal.
2730             my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2731             $maximum_renewal_date->add(
2732                 $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
2733             );
2734             my $now = dt_from_string;
2735             if ( $now >= $maximum_renewal_date ) {
2736                 return ( 0, "auto_too_late" );
2737             }
2738         }
2739         if ( defined $issuing_rule->no_auto_renewal_after_hard_limit
2740                       and $issuing_rule->no_auto_renewal_after_hard_limit ne "" ) {
2741             # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2742             if ( dt_from_string >= dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit ) ) {
2743                 return ( 0, "auto_too_late" );
2744             }
2745         }
2746
2747         if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2748             my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2749             my $amountoutstanding = $patron->account->balance;
2750             if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2751                 return ( 0, "auto_too_much_oweing" );
2752             }
2753         }
2754     }
2755
2756     if ( defined $issuing_rule->norenewalbefore
2757         and $issuing_rule->norenewalbefore ne "" )
2758     {
2759
2760         # Calculate soonest renewal by subtracting 'No renewal before' from due date
2761         my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2762             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
2763
2764         # Depending on syspref reset the exact time, only check the date
2765         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2766             and $issuing_rule->lengthunit eq 'days' )
2767         {
2768             $soonestrenewal->truncate( to => 'day' );
2769         }
2770
2771         if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2772         {
2773             return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2774             return ( 0, "too_soon" );
2775         }
2776         elsif ( $issue->auto_renew ) {
2777             return ( 0, "auto_renew" );
2778         }
2779     }
2780
2781     # Fallback for automatic renewals:
2782     # If norenewalbefore is undef, don't renew before due date.
2783     if ( $issue->auto_renew ) {
2784         my $now = dt_from_string;
2785         return ( 0, "auto_renew" )
2786           if $now >= dt_from_string( $issue->date_due, 'sql' );
2787         return ( 0, "auto_too_soon" );
2788     }
2789
2790     return ( 1, undef );
2791 }
2792
2793 =head2 AddRenewal
2794
2795   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2796
2797 Renews a loan.
2798
2799 C<$borrowernumber> is the borrower number of the patron who currently
2800 has the item.
2801
2802 C<$itemnumber> is the number of the item to renew.
2803
2804 C<$branch> is the library where the renewal took place (if any).
2805            The library that controls the circ policies for the renewal is retrieved from the issues record.
2806
2807 C<$datedue> can be a DateTime object used to set the due date.
2808
2809 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2810 this parameter is not supplied, lastreneweddate is set to the current date.
2811
2812 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2813 from the book's item type.
2814
2815 =cut
2816
2817 sub AddRenewal {
2818     my $borrowernumber  = shift;
2819     my $itemnumber      = shift or return;
2820     my $branch          = shift;
2821     my $datedue         = shift;
2822     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz);
2823
2824     my $item   = Koha::Items->find($itemnumber) or return;
2825     my $biblio = $item->biblio;
2826     my $issue  = $item->checkout;
2827     my $item_unblessed = $item->unblessed;
2828
2829     my $dbh = C4::Context->dbh;
2830
2831     return unless $issue;
2832
2833     $borrowernumber ||= $issue->borrowernumber;
2834
2835     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2836         carp 'Invalid date passed to AddRenewal.';
2837         return;
2838     }
2839
2840     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2841     my $patron_unblessed = $patron->unblessed;
2842
2843     if ( C4::Context->preference('CalculateFinesOnReturn') && $issue->is_overdue ) {
2844         _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2845     }
2846     _FixOverduesOnReturn( $borrowernumber, $itemnumber );
2847
2848     # If the due date wasn't specified, calculate it by adding the
2849     # book's loan length to today's date or the current due date
2850     # based on the value of the RenewalPeriodBase syspref.
2851     unless ($datedue) {
2852
2853         my $itemtype = $item->effective_itemtype;
2854         $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2855                                         dt_from_string( $issue->date_due, 'sql' ) :
2856                                         DateTime->now( time_zone => C4::Context->tz());
2857         $datedue =  CalcDateDue($datedue, $itemtype, _GetCircControlBranch($item_unblessed, $patron_unblessed), $patron_unblessed, 'is a renewal');
2858     }
2859
2860     # Update the issues record to have the new due date, and a new count
2861     # of how many times it has been renewed.
2862     my $renews = $issue->renewals + 1;
2863     my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2864                             WHERE borrowernumber=?
2865                             AND itemnumber=?"
2866     );
2867
2868     $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2869
2870     # Update the renewal count on the item, and tell zebra to reindex
2871     $renews = $item->renewals + 1;
2872     ModItem( { renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $item->biblionumber, $itemnumber, { log_action => 0 } );
2873
2874     # Charge a new rental fee, if applicable
2875     my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2876     if ( $charge > 0 ) {
2877         my $description = "Renewal of Rental Item " . $biblio->title . " " .$item->barcode;
2878         AddIssuingCharge($issue, $charge, $description);
2879     }
2880
2881     # Charge a new daily rental fee, if applicable
2882     my $itemtype = Koha::ItemTypes->find( $item_object->effective_itemtype );
2883     if ( $itemtype ) {
2884         my $daily_charge = $itemtype->calc_rental_charge_daily( { from => dt_from_string($lastreneweddate), to => $datedue } );
2885         if ( $daily_charge > 0 ) {
2886             my $type_desc = "Renewal of Daily Rental Item " . $biblio->title . " $item->{'barcode'}";
2887             AddIssuingCharge( $issue, $daily_charge, $type_desc )
2888         }
2889         $charge += $daily_charge;
2890     }
2891
2892     # Send a renewal slip according to checkout alert preferencei
2893     if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2894         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2895         my %conditions        = (
2896             branchcode   => $branch,
2897             categorycode => $patron->categorycode,
2898             item_type    => $item->effective_itemtype,
2899             notification => 'CHECKOUT',
2900         );
2901         if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2902             SendCirculationAlert(
2903                 {
2904                     type     => 'RENEWAL',
2905                     item     => $item_unblessed,
2906                     borrower => $patron->unblessed,
2907                     branch   => $branch,
2908                 }
2909             );
2910         }
2911     }
2912
2913     # Remove any OVERDUES related debarment if the borrower has no overdues
2914     if ( $patron
2915       && $patron->is_debarred
2916       && ! $patron->has_overdues
2917       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2918     ) {
2919         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2920     }
2921
2922     unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
2923         $branch = C4::Context->userenv ? C4::Context->userenv->{branch} : $branch;
2924     }
2925
2926     # Add the renewal to stats
2927     UpdateStats(
2928         {
2929             branch         => $branch,
2930             type           => 'renew',
2931             amount         => $charge,
2932             itemnumber     => $itemnumber,
2933             itemtype       => $item->effective_itemtype,
2934             location       => $item->location,
2935             borrowernumber => $borrowernumber,
2936             ccode          => $item->ccode,
2937         }
2938     );
2939
2940     #Log the renewal
2941     logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
2942     return $datedue;
2943 }
2944
2945 sub GetRenewCount {
2946     # check renewal status
2947     my ( $bornum, $itemno ) = @_;
2948     my $dbh           = C4::Context->dbh;
2949     my $renewcount    = 0;
2950     my $renewsallowed = 0;
2951     my $renewsleft    = 0;
2952
2953     my $patron = Koha::Patrons->find( $bornum );
2954     my $item   = Koha::Items->find($itemno);
2955
2956     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
2957
2958     # Look in the issues table for this item, lent to this borrower,
2959     # and not yet returned.
2960
2961     # FIXME - I think this function could be redone to use only one SQL call.
2962     my $sth = $dbh->prepare(
2963         "select * from issues
2964                                 where (borrowernumber = ?)
2965                                 and (itemnumber = ?)"
2966     );
2967     $sth->execute( $bornum, $itemno );
2968     my $data = $sth->fetchrow_hashref;
2969     $renewcount = $data->{'renewals'} if $data->{'renewals'};
2970     # $item and $borrower should be calculated
2971     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
2972
2973     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2974         {   categorycode => $patron->categorycode,
2975             itemtype     => $item->effective_itemtype,
2976             branchcode   => $branchcode
2977         }
2978     );
2979
2980     $renewsallowed = $issuing_rule ? $issuing_rule->renewalsallowed : 0;
2981     $renewsleft    = $renewsallowed - $renewcount;
2982     if($renewsleft < 0){ $renewsleft = 0; }
2983     return ( $renewcount, $renewsallowed, $renewsleft );
2984 }
2985
2986 =head2 GetSoonestRenewDate
2987
2988   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
2989
2990 Find out the soonest possible renew date of a borrowed item.
2991
2992 C<$borrowernumber> is the borrower number of the patron who currently
2993 has the item on loan.
2994
2995 C<$itemnumber> is the number of the item to renew.
2996
2997 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
2998 renew date, based on the value "No renewal before" of the applicable
2999 issuing rule. Returns the current date if the item can already be
3000 renewed, and returns undefined if the borrower, loan, or item
3001 cannot be found.
3002
3003 =cut
3004
3005 sub GetSoonestRenewDate {
3006     my ( $borrowernumber, $itemnumber ) = @_;
3007
3008     my $dbh = C4::Context->dbh;
3009
3010     my $item      = Koha::Items->find($itemnumber)      or return;
3011     my $itemissue = $item->checkout or return;
3012
3013     $borrowernumber ||= $itemissue->borrowernumber;
3014     my $patron = Koha::Patrons->find( $borrowernumber )
3015       or return;
3016
3017     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3018     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3019         {   categorycode => $patron->categorycode,
3020             itemtype     => $item->effective_itemtype,
3021             branchcode   => $branchcode
3022         }
3023     );
3024
3025     my $now = dt_from_string;
3026     return $now unless $issuing_rule;
3027
3028     if ( defined $issuing_rule->norenewalbefore
3029         and $issuing_rule->norenewalbefore ne "" )
3030     {
3031         my $soonestrenewal =
3032           dt_from_string( $itemissue->date_due )->subtract(
3033             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
3034
3035         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3036             and $issuing_rule->lengthunit eq 'days' )
3037         {
3038             $soonestrenewal->truncate( to => 'day' );
3039         }
3040         return $soonestrenewal if $now < $soonestrenewal;
3041     }
3042     return $now;
3043 }
3044
3045 =head2 GetLatestAutoRenewDate
3046
3047   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3048
3049 Find out the latest possible auto renew date of a borrowed item.
3050
3051 C<$borrowernumber> is the borrower number of the patron who currently
3052 has the item on loan.
3053
3054 C<$itemnumber> is the number of the item to renew.
3055
3056 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3057 auto renew date, based on the value "No auto renewal after" and the "No auto
3058 renewal after (hard limit) of the applicable issuing rule.
3059 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3060 or item cannot be found.
3061
3062 =cut
3063
3064 sub GetLatestAutoRenewDate {
3065     my ( $borrowernumber, $itemnumber ) = @_;
3066
3067     my $dbh = C4::Context->dbh;
3068
3069     my $item      = Koha::Items->find($itemnumber)  or return;
3070     my $itemissue = $item->checkout                 or return;
3071
3072     $borrowernumber ||= $itemissue->borrowernumber;
3073     my $patron = Koha::Patrons->find( $borrowernumber )
3074       or return;
3075
3076     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3077     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3078         {   categorycode => $patron->categorycode,
3079             itemtype     => $item->effective_itemtype,
3080             branchcode   => $branchcode
3081         }
3082     );
3083
3084     return unless $issuing_rule;
3085     return
3086       if ( not $issuing_rule->no_auto_renewal_after
3087             or $issuing_rule->no_auto_renewal_after eq '' )
3088       and ( not $issuing_rule->no_auto_renewal_after_hard_limit
3089              or $issuing_rule->no_auto_renewal_after_hard_limit eq '' );
3090
3091     my $maximum_renewal_date;
3092     if ( $issuing_rule->no_auto_renewal_after ) {
3093         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3094         $maximum_renewal_date->add(
3095             $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
3096         );
3097     }
3098
3099     if ( $issuing_rule->no_auto_renewal_after_hard_limit ) {
3100         my $dt = dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit );
3101         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3102     }
3103     return $maximum_renewal_date;
3104 }
3105
3106
3107 =head2 GetIssuingCharges
3108
3109   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3110
3111 Calculate how much it would cost for a given patron to borrow a given
3112 item, including any applicable discounts.
3113
3114 C<$itemnumber> is the item number of item the patron wishes to borrow.
3115
3116 C<$borrowernumber> is the patron's borrower number.
3117
3118 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3119 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3120 if it's a video).
3121
3122 =cut
3123
3124 sub GetIssuingCharges {
3125
3126     # calculate charges due
3127     my ( $itemnumber, $borrowernumber ) = @_;
3128     my $charge = 0;
3129     my $dbh    = C4::Context->dbh;
3130     my $item_type;
3131
3132     # Get the book's item type and rental charge (via its biblioitem).
3133     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3134         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3135     $charge_query .= (C4::Context->preference('item-level_itypes'))
3136         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3137         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3138
3139     $charge_query .= ' WHERE items.itemnumber =?';
3140
3141     my $sth = $dbh->prepare($charge_query);
3142     $sth->execute($itemnumber);
3143     if ( my $item_data = $sth->fetchrow_hashref ) {
3144         $item_type = $item_data->{itemtype};
3145         $charge    = $item_data->{rentalcharge};
3146         my $branch = C4::Context::mybranch();
3147         my $discount_query = q|SELECT rentaldiscount,
3148             issuingrules.itemtype, issuingrules.branchcode
3149             FROM borrowers
3150             LEFT JOIN issuingrules ON borrowers.categorycode = issuingrules.categorycode
3151             WHERE borrowers.borrowernumber = ?
3152             AND (issuingrules.itemtype = ? OR issuingrules.itemtype = '*')
3153             AND (issuingrules.branchcode = ? OR issuingrules.branchcode = '*')|;
3154         my $discount_sth = $dbh->prepare($discount_query);
3155         $discount_sth->execute( $borrowernumber, $item_type, $branch );
3156         my $discount_rules = $discount_sth->fetchall_arrayref({});
3157         if (@{$discount_rules}) {
3158             # We may have multiple rules so get the most specific
3159             my $discount = _get_discount_from_rule($discount_rules, $branch, $item_type);
3160             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3161         }
3162         if ($charge) {
3163             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3164         }
3165     }
3166
3167     return ( $charge, $item_type );
3168 }
3169
3170 # Select most appropriate discount rule from those returned
3171 sub _get_discount_from_rule {
3172     my ($rules_ref, $branch, $itemtype) = @_;
3173     my $discount;
3174
3175     if (@{$rules_ref} == 1) { # only 1 applicable rule use it
3176         $discount = $rules_ref->[0]->{rentaldiscount};
3177         return (defined $discount) ? $discount : 0;
3178     }
3179     # could have up to 4 does one match $branch and $itemtype
3180     my @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq $itemtype } @{$rules_ref};
3181     if (@d) {
3182         $discount = $d[0]->{rentaldiscount};
3183         return (defined $discount) ? $discount : 0;
3184     }
3185     # do we have item type + all branches
3186     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq $itemtype } @{$rules_ref};
3187     if (@d) {
3188         $discount = $d[0]->{rentaldiscount};
3189         return (defined $discount) ? $discount : 0;
3190     }
3191     # do we all item types + this branch
3192     @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq q{*} } @{$rules_ref};
3193     if (@d) {
3194         $discount = $d[0]->{rentaldiscount};
3195         return (defined $discount) ? $discount : 0;
3196     }
3197     # so all and all (surely we wont get here)
3198     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq q{*} } @{$rules_ref};
3199     if (@d) {
3200         $discount = $d[0]->{rentaldiscount};
3201         return (defined $discount) ? $discount : 0;
3202     }
3203     # none of the above
3204     return 0;
3205 }
3206
3207 =head2 AddIssuingCharge
3208
3209   &AddIssuingCharge( $checkout, $charge, [$description] )
3210
3211 =cut
3212
3213 sub AddIssuingCharge {
3214     my ( $checkout, $charge, $description ) = @_;
3215
3216     # FIXME What if checkout does not exist?
3217
3218     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3219     my $accountline = $account->add_debit(
3220         {
3221             amount      => $charge,
3222             description => $description,
3223             note        => undef,
3224             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : 0,
3225             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3226             type        => 'rent',
3227             item_id     => $checkout->itemnumber,
3228             issue_id    => $checkout->issue_id,
3229         }
3230     );
3231 }
3232
3233 =head2 GetTransfers
3234
3235   GetTransfers($itemnumber);
3236
3237 =cut
3238
3239 sub GetTransfers {
3240     my ($itemnumber) = @_;
3241
3242     my $dbh = C4::Context->dbh;
3243
3244     my $query = '
3245         SELECT datesent,
3246                frombranch,
3247                tobranch,
3248                branchtransfer_id
3249         FROM branchtransfers
3250         WHERE itemnumber = ?
3251           AND datearrived IS NULL
3252         ';
3253     my $sth = $dbh->prepare($query);
3254     $sth->execute($itemnumber);
3255     my @row = $sth->fetchrow_array();
3256     return @row;
3257 }
3258
3259 =head2 GetTransfersFromTo
3260
3261   @results = GetTransfersFromTo($frombranch,$tobranch);
3262
3263 Returns the list of pending transfers between $from and $to branch
3264
3265 =cut
3266
3267 sub GetTransfersFromTo {
3268     my ( $frombranch, $tobranch ) = @_;
3269     return unless ( $frombranch && $tobranch );
3270     my $dbh   = C4::Context->dbh;
3271     my $query = "
3272         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3273         FROM   branchtransfers
3274         WHERE  frombranch=?
3275           AND  tobranch=?
3276           AND datearrived IS NULL
3277     ";
3278     my $sth = $dbh->prepare($query);
3279     $sth->execute( $frombranch, $tobranch );
3280     my @gettransfers;
3281
3282     while ( my $data = $sth->fetchrow_hashref ) {
3283         push @gettransfers, $data;
3284     }
3285     return (@gettransfers);
3286 }
3287
3288 =head2 DeleteTransfer
3289
3290   &DeleteTransfer($itemnumber);
3291
3292 =cut
3293
3294 sub DeleteTransfer {
3295     my ($itemnumber) = @_;
3296     return unless $itemnumber;
3297     my $dbh          = C4::Context->dbh;
3298     my $sth          = $dbh->prepare(
3299         "DELETE FROM branchtransfers
3300          WHERE itemnumber=?
3301          AND datearrived IS NULL "
3302     );
3303     return $sth->execute($itemnumber);
3304 }
3305
3306 =head2 SendCirculationAlert
3307
3308 Send out a C<check-in> or C<checkout> alert using the messaging system.
3309
3310 B<Parameters>:
3311
3312 =over 4
3313
3314 =item type
3315
3316 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3317
3318 =item item
3319
3320 Hashref of information about the item being checked in or out.
3321
3322 =item borrower
3323
3324 Hashref of information about the borrower of the item.
3325
3326 =item branch
3327
3328 The branchcode from where the checkout or check-in took place.
3329
3330 =back
3331
3332 B<Example>:
3333
3334     SendCirculationAlert({
3335         type     => 'CHECKOUT',
3336         item     => $item,
3337         borrower => $borrower,
3338         branch   => $branch,
3339     });
3340
3341 =cut
3342
3343 sub SendCirculationAlert {
3344     my ($opts) = @_;
3345     my ($type, $item, $borrower, $branch) =
3346         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3347     my %message_name = (
3348         CHECKIN  => 'Item_Check_in',
3349         CHECKOUT => 'Item_Checkout',
3350         RENEWAL  => 'Item_Checkout',
3351     );
3352     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3353         borrowernumber => $borrower->{borrowernumber},
3354         message_name   => $message_name{$type},
3355     });
3356     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3357
3358     my $schema = Koha::Database->new->schema;
3359     my @transports = keys %{ $borrower_preferences->{transports} };
3360
3361     # From the MySQL doc:
3362     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3363     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3364     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3365     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3366
3367     for my $mtt (@transports) {
3368         my $letter =  C4::Letters::GetPreparedLetter (
3369             module => 'circulation',
3370             letter_code => $type,
3371             branchcode => $branch,
3372             message_transport_type => $mtt,
3373             lang => $borrower->{lang},
3374             tables => {
3375                 $issues_table => $item->{itemnumber},
3376                 'items'       => $item->{itemnumber},
3377                 'biblio'      => $item->{biblionumber},
3378                 'biblioitems' => $item->{biblionumber},
3379                 'borrowers'   => $borrower,
3380                 'branches'    => $branch,
3381             }
3382         ) or next;
3383
3384         $schema->storage->txn_begin;
3385         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3386         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3387         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3388         unless ( $message ) {
3389             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3390             C4::Message->enqueue($letter, $borrower, $mtt);
3391         } else {
3392             $message->append($letter);
3393             $message->update;
3394         }
3395         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3396         $schema->storage->txn_commit;
3397     }
3398
3399     return;
3400 }
3401
3402 =head2 updateWrongTransfer
3403
3404   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3405
3406 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3407
3408 =cut
3409
3410 sub updateWrongTransfer {
3411         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3412         my $dbh = C4::Context->dbh;
3413 # first step validate the actual line of transfert .
3414         my $sth =
3415                 $dbh->prepare(
3416                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3417                 );
3418                 $sth->execute($FromLibrary,$itemNumber);
3419
3420 # second step create a new line of branchtransfer to the right location .
3421         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3422
3423 #third step changing holdingbranch of item
3424         UpdateHoldingbranch($FromLibrary,$itemNumber);
3425 }
3426
3427 =head2 UpdateHoldingbranch
3428
3429   $items = UpdateHoldingbranch($branch,$itmenumber);
3430
3431 Simple methode for updating hodlingbranch in items BDD line
3432
3433 =cut
3434
3435 sub UpdateHoldingbranch {
3436         my ( $branch,$itemnumber ) = @_;
3437     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3438 }
3439
3440 =head2 CalcDateDue
3441
3442 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3443
3444 this function calculates the due date given the start date and configured circulation rules,
3445 checking against the holidays calendar as per the 'useDaysMode' syspref.
3446 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3447 C<$itemtype>  = itemtype code of item in question
3448 C<$branch>  = location whose calendar to use
3449 C<$borrower> = Borrower object
3450 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3451
3452 =cut
3453
3454 sub CalcDateDue {
3455     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3456
3457     $isrenewal ||= 0;
3458
3459     # loanlength now a href
3460     my $loanlength =
3461             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3462
3463     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3464             ? qq{renewalperiod}
3465             : qq{issuelength};
3466
3467     my $datedue;
3468     if ( $startdate ) {
3469         if (ref $startdate ne 'DateTime' ) {
3470             $datedue = dt_from_string($datedue);
3471         } else {
3472             $datedue = $startdate->clone;
3473         }
3474     } else {
3475         $datedue =
3476           DateTime->now( time_zone => C4::Context->tz() )
3477           ->truncate( to => 'minute' );
3478     }
3479
3480
3481     # calculate the datedue as normal
3482     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3483     {    # ignoring calendar
3484         if ( $loanlength->{lengthunit} eq 'hours' ) {
3485             $datedue->add( hours => $loanlength->{$length_key} );
3486         } else {    # days
3487             $datedue->add( days => $loanlength->{$length_key} );
3488             $datedue->set_hour(23);
3489             $datedue->set_minute(59);
3490         }
3491     } else {
3492         my $dur;
3493         if ($loanlength->{lengthunit} eq 'hours') {
3494             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3495         }
3496         else { # days
3497             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3498         }
3499         my $calendar = Koha::Calendar->new( branchcode => $branch );
3500         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3501         if ($loanlength->{lengthunit} eq 'days') {
3502             $datedue->set_hour(23);
3503             $datedue->set_minute(59);
3504         }
3505     }
3506
3507     # if Hard Due Dates are used, retrieve them and apply as necessary
3508     my ( $hardduedate, $hardduedatecompare ) =
3509       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3510     if ($hardduedate) {    # hardduedates are currently dates
3511         $hardduedate->truncate( to => 'minute' );
3512         $hardduedate->set_hour(23);
3513         $hardduedate->set_minute(59);
3514         my $cmp = DateTime->compare( $hardduedate, $datedue );
3515
3516 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3517 # if the calculated date is before the 'after' Hard Due Date (floor), override
3518 # if the hard due date is set to 'exactly', overrride
3519         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3520             $datedue = $hardduedate->clone;
3521         }
3522
3523         # in all other cases, keep the date due as it is
3524
3525     }
3526
3527     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3528     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3529         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3530         if( $expiry_dt ) { #skip empty expiry date..
3531             $expiry_dt->set( hour => 23, minute => 59);
3532             my $d1= $datedue->clone->set_time_zone('floating');
3533             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3534                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3535             }
3536         }
3537         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3538           my $calendar = Koha::Calendar->new( branchcode => $branch );
3539           if ( $calendar->is_holiday($datedue) ) {
3540               # Don't return on a closed day
3541               $datedue = $calendar->prev_open_day( $datedue );
3542           }
3543         }
3544     }
3545
3546     return $datedue;
3547 }
3548
3549
3550 sub CheckValidBarcode{
3551 my ($barcode) = @_;
3552 my $dbh = C4::Context->dbh;
3553 my $query=qq|SELECT count(*)
3554              FROM items
3555              WHERE barcode=?
3556             |;
3557 my $sth = $dbh->prepare($query);
3558 $sth->execute($barcode);
3559 my $exist=$sth->fetchrow ;
3560 return $exist;
3561 }
3562
3563 =head2 IsBranchTransferAllowed
3564
3565   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3566
3567 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3568
3569 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3570 Koha::Item->can_be_transferred.
3571
3572 =cut
3573
3574 sub IsBranchTransferAllowed {
3575         my ( $toBranch, $fromBranch, $code ) = @_;
3576
3577         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3578
3579         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3580         my $dbh = C4::Context->dbh;
3581
3582         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3583         $sth->execute( $toBranch, $fromBranch, $code );
3584         my $limit = $sth->fetchrow_hashref();
3585
3586         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3587         if ( $limit->{'limitId'} ) {
3588                 return 0;
3589         } else {
3590                 return 1;
3591         }
3592 }
3593
3594 =head2 CreateBranchTransferLimit
3595
3596   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3597
3598 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3599
3600 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3601
3602 =cut
3603
3604 sub CreateBranchTransferLimit {
3605    my ( $toBranch, $fromBranch, $code ) = @_;
3606    return unless defined($toBranch) && defined($fromBranch);
3607    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3608
3609    my $dbh = C4::Context->dbh;
3610
3611    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3612    return $sth->execute( $code, $toBranch, $fromBranch );
3613 }
3614
3615 =head2 DeleteBranchTransferLimits
3616
3617     my $result = DeleteBranchTransferLimits($frombranch);
3618
3619 Deletes all the library transfer limits for one library.  Returns the
3620 number of limits deleted, 0e0 if no limits were deleted, or undef if
3621 no arguments are supplied.
3622
3623 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3624     fromBranch => $fromBranch
3625     })->delete.
3626
3627 =cut
3628
3629 sub DeleteBranchTransferLimits {
3630     my $branch = shift;
3631     return unless defined $branch;
3632     my $dbh    = C4::Context->dbh;
3633     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3634     return $sth->execute($branch);
3635 }
3636
3637 sub ReturnLostItem{
3638     my ( $borrowernumber, $itemnum ) = @_;
3639
3640     MarkIssueReturned( $borrowernumber, $itemnum );
3641     my $patron = Koha::Patrons->find( $borrowernumber );
3642     my $item = Koha::Items->find($itemnum);
3643     my $old_note = ($item->paidfor && ($item->paidfor ne q{})) ? $item->paidfor.' / ' : q{};
3644     my @datearr = localtime(time);
3645     my $date = ( 1900 + $datearr[5] ) . "-" . ( $datearr[4] + 1 ) . "-" . $datearr[3];
3646     my $bor = $patron->firstname . ' ' . $patron->surname . ' ' . $patron->cardnumber;
3647     ModItem({ paidfor =>  $old_note."Paid for by $bor $date" }, undef, $itemnum);
3648 }
3649
3650
3651 sub LostItem{
3652     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3653
3654     unless ( $mark_lost_from ) {
3655         # Temporary check to avoid regressions
3656         die q|LostItem called without $mark_lost_from, check the API.|;
3657     }
3658
3659     my $mark_returned;
3660     if ( $force_mark_returned ) {
3661         $mark_returned = 1;
3662     } else {
3663         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3664         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3665     }
3666
3667     my $dbh = C4::Context->dbh();
3668     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3669                            FROM issues
3670                            JOIN items USING (itemnumber)
3671                            JOIN biblio USING (biblionumber)
3672                            WHERE issues.itemnumber=?");
3673     $sth->execute($itemnumber);
3674     my $issues=$sth->fetchrow_hashref();
3675
3676     # If a borrower lost the item, add a replacement cost to the their record
3677     if ( my $borrowernumber = $issues->{borrowernumber} ){
3678         my $patron = Koha::Patrons->find( $borrowernumber );
3679
3680         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 0); # 1, 0 = exemptfine, no-dropbox
3681         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3682
3683         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3684             C4::Accounts::chargelostitem($borrowernumber, $itemnumber, $issues->{'replacementprice'}, "Lost Item $issues->{'title'} $issues->{'barcode'} $issues->{'itemcallnumber'}");
3685             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3686             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3687         }
3688
3689         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3690     }
3691
3692     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3693     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3694         ModItem({holdingbranch => $frombranch}, undef, $itemnumber);
3695     }
3696     my $transferdeleted = DeleteTransfer($itemnumber);
3697 }
3698
3699 sub GetOfflineOperations {
3700     my $dbh = C4::Context->dbh;
3701     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3702     $sth->execute(C4::Context->userenv->{'branch'});
3703     my $results = $sth->fetchall_arrayref({});
3704     return $results;
3705 }
3706
3707 sub GetOfflineOperation {
3708     my $operationid = shift;
3709     return unless $operationid;
3710     my $dbh = C4::Context->dbh;
3711     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3712     $sth->execute( $operationid );
3713     return $sth->fetchrow_hashref;
3714 }
3715
3716 sub AddOfflineOperation {
3717     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3718     my $dbh = C4::Context->dbh;
3719     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3720     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3721     return "Added.";
3722 }
3723
3724 sub DeleteOfflineOperation {
3725     my $dbh = C4::Context->dbh;
3726     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3727     $sth->execute( shift );
3728     return "Deleted.";
3729 }
3730
3731 sub ProcessOfflineOperation {
3732     my $operation = shift;
3733
3734     my $report;
3735     if ( $operation->{action} eq 'return' ) {
3736         $report = ProcessOfflineReturn( $operation );
3737     } elsif ( $operation->{action} eq 'issue' ) {
3738         $report = ProcessOfflineIssue( $operation );
3739     } elsif ( $operation->{action} eq 'payment' ) {
3740         $report = ProcessOfflinePayment( $operation );
3741     }
3742
3743     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3744
3745     return $report;
3746 }
3747
3748 sub ProcessOfflineReturn {
3749     my $operation = shift;
3750
3751     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3752
3753     if ( $item ) {
3754         my $itemnumber = $item->itemnumber;
3755         my $issue = GetOpenIssue( $itemnumber );
3756         if ( $issue ) {
3757             MarkIssueReturned(
3758                 $issue->{borrowernumber},
3759                 $itemnumber,
3760                 $operation->{timestamp},
3761             );
3762             ModItem(
3763                 { renewals => 0, onloan => undef },
3764                 $issue->{'biblionumber'},
3765                 $itemnumber,
3766                 { log_action => 0 }
3767             );
3768             return "Success.";
3769         } else {
3770             return "Item not issued.";
3771         }
3772     } else {
3773         return "Item not found.";
3774     }
3775 }
3776
3777 sub ProcessOfflineIssue {
3778     my $operation = shift;
3779
3780     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3781
3782     if ( $patron ) {
3783         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3784         unless ($item) {
3785             return "Barcode not found.";
3786         }
3787         my $itemnumber = $item->itemnumber;
3788         my $issue = GetOpenIssue( $itemnumber );
3789
3790         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3791             MarkIssueReturned(
3792                 $issue->{borrowernumber},
3793                 $itemnumber,
3794                 $operation->{timestamp},
3795             );
3796         }
3797         AddIssue(
3798             $patron->unblessed,
3799             $operation->{'barcode'},
3800             undef,
3801             1,
3802             $operation->{timestamp},
3803             undef,
3804         );
3805         return "Success.";
3806     } else {
3807         return "Borrower not found.";
3808     }
3809 }
3810
3811 sub ProcessOfflinePayment {
3812     my $operation = shift;
3813
3814     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3815
3816     $patron->account->pay({ amount => $operation->{amount}, library_id => $operation->{branchcode} });
3817
3818     return "Success.";
3819 }
3820
3821 =head2 TransferSlip
3822
3823   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3824
3825   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3826
3827 =cut
3828
3829 sub TransferSlip {
3830     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3831
3832     my $item =
3833       $itemnumber
3834       ? Koha::Items->find($itemnumber)
3835       : Koha::Items->find( { barcode => $barcode } );
3836
3837     $item or return;
3838
3839     return C4::Letters::GetPreparedLetter (
3840         module => 'circulation',
3841         letter_code => 'TRANSFERSLIP',
3842         branchcode => $branch,
3843         tables => {
3844             'branches'    => $to_branch,
3845             'biblio'      => $item->biblionumber,
3846             'items'       => $item->unblessed,
3847         },
3848     );
3849 }
3850
3851 =head2 CheckIfIssuedToPatron
3852
3853   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3854
3855   Return 1 if any record item is issued to patron, otherwise return 0
3856
3857 =cut
3858
3859 sub CheckIfIssuedToPatron {
3860     my ($borrowernumber, $biblionumber) = @_;
3861
3862     my $dbh = C4::Context->dbh;
3863     my $query = q|
3864         SELECT COUNT(*) FROM issues
3865         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3866         WHERE items.biblionumber = ?
3867         AND issues.borrowernumber = ?
3868     |;
3869     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3870     return 1 if $is_issued;
3871     return;
3872 }
3873
3874 =head2 IsItemIssued
3875
3876   IsItemIssued( $itemnumber )
3877
3878   Return 1 if the item is on loan, otherwise return 0
3879
3880 =cut
3881
3882 sub IsItemIssued {
3883     my $itemnumber = shift;
3884     my $dbh = C4::Context->dbh;
3885     my $sth = $dbh->prepare(q{
3886         SELECT COUNT(*)
3887         FROM issues
3888         WHERE itemnumber = ?
3889     });
3890     $sth->execute($itemnumber);
3891     return $sth->fetchrow;
3892 }
3893
3894 =head2 GetAgeRestriction
3895
3896   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
3897   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
3898
3899   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
3900   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
3901
3902 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
3903 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
3904 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
3905          Negative days mean the borrower has gone past the age restriction age.
3906
3907 =cut
3908
3909 sub GetAgeRestriction {
3910     my ($record_restrictions, $borrower) = @_;
3911     my $markers = C4::Context->preference('AgeRestrictionMarker');
3912
3913     # Split $record_restrictions to something like FSK 16 or PEGI 6
3914     my @values = split ' ', uc($record_restrictions);
3915     return unless @values;
3916
3917     # Search first occurrence of one of the markers
3918     my @markers = split /\|/, uc($markers);
3919     return unless @markers;
3920
3921     my $index            = 0;
3922     my $restriction_year = 0;
3923     for my $value (@values) {
3924         $index++;
3925         for my $marker (@markers) {
3926             $marker =~ s/^\s+//;    #remove leading spaces
3927             $marker =~ s/\s+$//;    #remove trailing spaces
3928             if ( $marker eq $value ) {
3929                 if ( $index <= $#values ) {
3930                     $restriction_year += $values[$index];
3931                 }
3932                 last;
3933             }
3934             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
3935
3936                 # Perhaps it is something like "K16" (as in Finland)
3937                 $restriction_year += $1;
3938                 last;
3939             }
3940         }
3941         last if ( $restriction_year > 0 );
3942     }
3943
3944     #Check if the borrower is age restricted for this material and for how long.
3945     if ($restriction_year && $borrower) {
3946         if ( $borrower->{'dateofbirth'} ) {
3947             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
3948             $alloweddate[0] += $restriction_year;
3949
3950             #Prevent runime eror on leap year (invalid date)
3951             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
3952                 $alloweddate[2] = 28;
3953             }
3954
3955             #Get how many days the borrower has to reach the age restriction
3956             my @Today = split /-/, DateTime->today->ymd();
3957             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
3958             #Negative days means the borrower went past the age restriction age
3959             return ($restriction_year, $daysToAgeRestriction);
3960         }
3961     }
3962
3963     return ($restriction_year);
3964 }
3965
3966
3967 =head2 GetPendingOnSiteCheckouts
3968
3969 =cut
3970
3971 sub GetPendingOnSiteCheckouts {
3972     my $dbh = C4::Context->dbh;
3973     return $dbh->selectall_arrayref(q|
3974         SELECT
3975           items.barcode,
3976           items.biblionumber,
3977           items.itemnumber,
3978           items.itemnotes,
3979           items.itemcallnumber,
3980           items.location,
3981           issues.date_due,
3982           issues.branchcode,
3983           issues.date_due < NOW() AS is_overdue,
3984           biblio.author,
3985           biblio.title,
3986           borrowers.firstname,
3987           borrowers.surname,
3988           borrowers.cardnumber,
3989           borrowers.borrowernumber
3990         FROM items
3991         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
3992         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
3993         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
3994         WHERE issues.onsite_checkout = 1
3995     |, { Slice => {} } );
3996 }
3997
3998 sub GetTopIssues {
3999     my ($params) = @_;
4000
4001     my ($count, $branch, $itemtype, $ccode, $newness)
4002         = @$params{qw(count branch itemtype ccode newness)};
4003
4004     my $dbh = C4::Context->dbh;
4005     my $query = q{
4006         SELECT * FROM (
4007         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4008           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4009           i.ccode, SUM(i.issues) AS count
4010         FROM biblio b
4011         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4012         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4013     };
4014
4015     my (@where_strs, @where_args);
4016
4017     if ($branch) {
4018         push @where_strs, 'i.homebranch = ?';
4019         push @where_args, $branch;
4020     }
4021     if ($itemtype) {
4022         if (C4::Context->preference('item-level_itypes')){
4023             push @where_strs, 'i.itype = ?';
4024             push @where_args, $itemtype;
4025         } else {
4026             push @where_strs, 'bi.itemtype = ?';
4027             push @where_args, $itemtype;
4028         }
4029     }
4030     if ($ccode) {
4031         push @where_strs, 'i.ccode = ?';
4032         push @where_args, $ccode;
4033     }
4034     if ($newness) {
4035         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4036         push @where_args, $newness;
4037     }
4038
4039     if (@where_strs) {
4040         $query .= 'WHERE ' . join(' AND ', @where_strs);
4041     }
4042
4043     $query .= q{
4044         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4045           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4046           i.ccode
4047         ORDER BY count DESC
4048     };
4049
4050     $query .= q{ ) xxx WHERE count > 0 };
4051     $count = int($count);
4052     if ($count > 0) {
4053         $query .= "LIMIT $count";
4054     }
4055
4056     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4057
4058     return @$rows;
4059 }
4060
4061 sub _CalculateAndUpdateFine {
4062     my ($params) = @_;
4063
4064     my $borrower    = $params->{borrower};
4065     my $item        = $params->{item};
4066     my $issue       = $params->{issue};
4067     my $return_date = $params->{return_date};
4068
4069     unless ($borrower) { carp "No borrower passed in!" && return; }
4070     unless ($item)     { carp "No item passed in!"     && return; }
4071     unless ($issue)    { carp "No issue passed in!"    && return; }
4072
4073     my $datedue = dt_from_string( $issue->date_due );
4074
4075     # we only need to calculate and change the fines if we want to do that on return
4076     # Should be on for hourly loans
4077     my $control = C4::Context->preference('CircControl');
4078     my $control_branchcode =
4079         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4080       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4081       :                                     $issue->branchcode;
4082
4083     my $date_returned = $return_date ? dt_from_string($return_date) : dt_from_string();
4084
4085     my ( $amount, $unitcounttotal, $unitcount  ) =
4086       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4087
4088     if ( C4::Context->preference('finesMode') eq 'production' ) {
4089         if ( $amount > 0 ) {
4090             C4::Overdues::UpdateFine({
4091                 issue_id       => $issue->issue_id,
4092                 itemnumber     => $issue->itemnumber,
4093                 borrowernumber => $issue->borrowernumber,
4094                 amount         => $amount,
4095                 due            => output_pref($datedue),
4096             });
4097         }
4098         elsif ($return_date) {
4099
4100             # Backdated returns may have fines that shouldn't exist,
4101             # so in this case, we need to drop those fines to 0
4102
4103             C4::Overdues::UpdateFine({
4104                 issue_id       => $issue->issue_id,
4105                 itemnumber     => $issue->itemnumber,
4106                 borrowernumber => $issue->borrowernumber,
4107                 amount         => 0,
4108                 due            => output_pref($datedue),
4109             });
4110         }
4111     }
4112 }
4113
4114 sub _item_denied_renewal {
4115     my ($params) = @_;
4116
4117     my $item = $params->{item};
4118     return unless $item;
4119
4120     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4121     return unless $denyingrules;
4122     foreach my $field (keys %$denyingrules) {
4123         my $val = $item->$field;
4124         if( !defined $val) {
4125             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4126                 return 1;
4127             }
4128         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4129            # If the results matches the values in the syspref
4130            # We return true if match found
4131             return 1;
4132         }
4133     }
4134     return 0;
4135 }
4136
4137
4138 1;
4139
4140 __END__
4141
4142 =head1 AUTHOR
4143
4144 Koha Development Team <http://koha-community.org/>
4145
4146 =cut