C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::RefundLostItemFeeRules;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Util::SystemPreferences;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Date::Calc qw(
  66   Today
  67   Today_and_Now
  68   Add_Delta_YM
  69   Add_Delta_DHMS
  70   Date_to_Days
  71   Day_of_Week
  72   Add_Delta_Days
  73 );
  74 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  75
  76 BEGIN {
  77         require Exporter;
  78         @ISA    = qw(Exporter);
  79
  80         # FIXME subs that should probably be elsewhere
  81         push @EXPORT, qw(
  82                 &barcodedecode
  83         &LostItem
  84         &ReturnLostItem
  85         &GetPendingOnSiteCheckouts
  86         );
  87
  88         # subs to deal with issuing a book
  89         push @EXPORT, qw(
  90                 &CanBookBeIssued
  91                 &CanBookBeRenewed
  92                 &AddIssue
  93                 &AddRenewal
  94                 &GetRenewCount
  95         &GetSoonestRenewDate
  96         &GetLatestAutoRenewDate
  97                 &GetIssuingCharges
  98         &GetBranchBorrowerCircRule
  99         &GetBranchItemRule
 100                 &GetBiblioIssues
 101                 &GetOpenIssue
 102         &CheckIfIssuedToPatron
 103         &IsItemIssued
 104         GetTopIssues
 105         );
 106
 107         # subs to deal with returns
 108         push @EXPORT, qw(
 109                 &AddReturn
 110         &MarkIssueReturned
 111         );
 112
 113         # subs to deal with transfers
 114         push @EXPORT, qw(
 115                 &transferbook
 116                 &GetTransfers
 117                 &GetTransfersFromTo
 118                 &updateWrongTransfer
 119                 &DeleteTransfer
 120                 &IsBranchTransferAllowed
 121                 &CreateBranchTransferLimit
 122                 &DeleteBranchTransferLimits
 123         &TransferSlip
 124         );
 125
 126     # subs to deal with offline circulation
 127     push @EXPORT, qw(
 128       &GetOfflineOperations
 129       &GetOfflineOperation
 130       &AddOfflineOperation
 131       &DeleteOfflineOperation
 132       &ProcessOfflineOperation
 133     );
 134 }
 135
 136 =head1 NAME
 137
 138 C4::Circulation - Koha circulation module
 139
 140 =head1 SYNOPSIS
 141
 142 use C4::Circulation;
 143
 144 =head1 DESCRIPTION
 145
 146 The functions in this module deal with circulation, issues, and
 147 returns, as well as general information about the library.
 148 Also deals with inventory.
 149
 150 =head1 FUNCTIONS
 151
 152 =head2 barcodedecode
 153
 154   $str = &barcodedecode($barcode, [$filter]);
 155
 156 Generic filter function for barcode string.
 157 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 158 Will do some manipulation of the barcode for systems that deliver a barcode
 159 to circulation.pl that differs from the barcode stored for the item.
 160 For proper functioning of this filter, calling the function on the
 161 correct barcode string (items.barcode) should return an unaltered barcode.
 162
 163 The optional $filter argument is to allow for testing or explicit
 164 behavior that ignores the System Pref.  Valid values are the same as the
 165 System Pref options.
 166
 167 =cut
 168
 169 # FIXME -- the &decode fcn below should be wrapped into this one.
 170 # FIXME -- these plugins should be moved out of Circulation.pm
 171 #
 172 sub barcodedecode {
 173     my ($barcode, $filter) = @_;
 174     my $branch = C4::Context::mybranch();
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 decode
 214
 215   $str = &decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 255                                             $barcode, $ignore_reserves, $trigger);
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$newbranch> is the code for the branch to which the item should be transferred.
 260
 261 C<$barcode> is the barcode of the item to be transferred.
 262
 263 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 264 Otherwise, if an item is reserved, the transfer fails.
 265
 266 C<$trigger> is the enum value for what triggered the transfer.
 267
 268 Returns three values:
 269
 270 =over
 271
 272 =item $dotransfer
 273
 274 is true if the transfer was successful.
 275
 276 =item $messages
 277
 278 is a reference-to-hash which may have any of the following keys:
 279
 280 =over
 281
 282 =item C<BadBarcode>
 283
 284 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 285
 286 =item C<DestinationEqualsHolding>
 287
 288 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 289
 290 =item C<WasReturned>
 291
 292 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 293
 294 =item C<ResFound>
 295
 296 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 297
 298 =item C<WasTransferred>
 299
 300 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 301
 302 =back
 303
 304 =back
 305
 306 =cut
 307
 308 sub transferbook {
 309     my ( $tbr, $barcode, $ignoreRs, $trigger ) = @_;
 310     my $messages;
 311     my $dotransfer      = 1;
 312     my $item = Koha::Items->find( { barcode => $barcode } );
 313
 314     # bad barcode..
 315     unless ( $item ) {
 316         $messages->{'BadBarcode'} = $barcode;
 317         $dotransfer = 0;
 318         return ( $dotransfer, $messages );
 319     }
 320
 321     my $itemnumber = $item->itemnumber;
 322     # get branches of book...
 323     my $hbr = $item->homebranch;
 324     my $fbr = $item->holdingbranch;
 325
 326     # if using Branch Transfer Limits
 327     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 328         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 329         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 330             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 331                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 332                 $dotransfer = 0;
 333             }
 334         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 335             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 336             $dotransfer = 0;
 337         }
 338     }
 339
 340     # can't transfer book if is already there....
 341     if ( $fbr eq $tbr ) {
 342         $messages->{'DestinationEqualsHolding'} = 1;
 343         $dotransfer = 0;
 344     }
 345
 346     # check if it is still issued to someone, return it...
 347     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 348     if ( $issue ) {
 349         AddReturn( $barcode, $fbr );
 350         $messages->{'WasReturned'} = $issue->borrowernumber;
 351     }
 352
 353     # find reserves.....
 354     # That'll save a database query.
 355     my ( $resfound, $resrec, undef ) =
 356       CheckReserves( $itemnumber );
 357     if ( $resfound and not $ignoreRs ) {
 358         $resrec->{'ResFound'} = $resfound;
 359         $messages->{'ResFound'} = $resrec;
 360         $dotransfer = 1;
 361     }
 362
 363     #actually do the transfer....
 364     if ($dotransfer) {
 365         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 366
 367         # don't need to update MARC anymore, we do it in batch now
 368         $messages->{'WasTransfered'} = 1;
 369
 370     }
 371     ModDateLastSeen( $itemnumber );
 372     return ( $dotransfer, $messages );
 373 }
 374
 375
 376 sub TooMany {
 377     my $borrower        = shift;
 378     my $item_object = shift;
 379     my $params = shift;
 380     my $onsite_checkout = $params->{onsite_checkout} || 0;
 381     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 382     my $cat_borrower    = $borrower->{'categorycode'};
 383     my $dbh             = C4::Context->dbh;
 384         my $branch;
 385         # Get which branchcode we need
 386     $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 387     my $type = $item_object->effective_itemtype;
 388
 389     # given branch, patron category, and item type, determine
 390     # applicable issuing rule
 391     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 392         {
 393             categorycode => $cat_borrower,
 394             itemtype     => $type,
 395             branchcode   => $branch,
 396             rule_name    => 'maxissueqty',
 397         }
 398     );
 399     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 400         {
 401             categorycode => $cat_borrower,
 402             itemtype     => $type,
 403             branchcode   => $branch,
 404             rule_name    => 'maxonsiteissueqty',
 405         }
 406     );
 407
 408
 409     # if a rule is found and has a loan limit set, count
 410     # how many loans the patron already has that meet that
 411     # rule
 412     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne '') {
 413         my @bind_params;
 414         my $count_query = q|
 415             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 416             FROM issues
 417             JOIN items USING (itemnumber)
 418         |;
 419
 420         my $rule_itemtype = $maxissueqty_rule->itemtype;
 421         unless ($rule_itemtype) {
 422             # matching rule has the default item type, so count only
 423             # those existing loans that don't fall under a more
 424             # specific rule
 425             if (C4::Context->preference('item-level_itypes')) {
 426                 $count_query .= " WHERE items.itype NOT IN (
 427                                     SELECT itemtype FROM circulation_rules
 428                                     WHERE branchcode = ?
 429                                     AND   (categorycode = ? OR categorycode = ?)
 430                                     AND   itemtype IS NOT NULL
 431                                     AND   rule_name = 'maxissueqty'
 432                                   ) ";
 433             } else {
 434                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 435                                   WHERE biblioitems.itemtype NOT IN (
 436                                     SELECT itemtype FROM circulation_rules
 437                                     WHERE branchcode = ?
 438                                     AND   (categorycode = ? OR categorycode = ?)
 439                                     AND   itemtype IS NOT NULL
 440                                     AND   rule_name = 'maxissueqty'
 441                                   ) ";
 442             }
 443             push @bind_params, $maxissueqty_rule->branchcode;
 444             push @bind_params, $maxissueqty_rule->categorycode;
 445             push @bind_params, $cat_borrower;
 446         } else {
 447             # rule has specific item type, so count loans of that
 448             # specific item type
 449             if (C4::Context->preference('item-level_itypes')) {
 450                 $count_query .= " WHERE items.itype = ? ";
 451             } else {
 452                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 453                                   WHERE biblioitems.itemtype= ? ";
 454             }
 455             push @bind_params, $type;
 456         }
 457
 458         $count_query .= " AND borrowernumber = ? ";
 459         push @bind_params, $borrower->{'borrowernumber'};
 460         my $rule_branch = $maxissueqty_rule->branchcode;
 461         if ($rule_branch) {
 462             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 463                 $count_query .= " AND issues.branchcode = ? ";
 464                 push @bind_params, $rule_branch;
 465             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 466                 ; # if branch is the patron's home branch, then count all loans by patron
 467             } else {
 468                 $count_query .= " AND items.homebranch = ? ";
 469                 push @bind_params, $rule_branch;
 470             }
 471         }
 472
 473         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 474
 475         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 476         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 477
 478         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 479             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 480                 return {
 481                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 482                     count => $onsite_checkout_count,
 483                     max_allowed => $max_onsite_checkouts_allowed,
 484                 }
 485             }
 486         }
 487         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 488             my $delta = $switch_onsite_checkout ? 1 : 0;
 489             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 490                 return {
 491                     reason => 'TOO_MANY_CHECKOUTS',
 492                     count => $checkout_count,
 493                     max_allowed => $max_checkouts_allowed,
 494                 };
 495             }
 496         } elsif ( not $onsite_checkout ) {
 497             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 498                 return {
 499                     reason => 'TOO_MANY_CHECKOUTS',
 500                     count => $checkout_count - $onsite_checkout_count,
 501                     max_allowed => $max_checkouts_allowed,
 502                 };
 503             }
 504         }
 505     }
 506
 507     # Now count total loans against the limit for the branch
 508     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 509     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 510         my @bind_params = ();
 511         my $branch_count_query = q|
 512             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 513             FROM issues
 514             JOIN items USING (itemnumber)
 515             WHERE borrowernumber = ?
 516         |;
 517         push @bind_params, $borrower->{borrowernumber};
 518
 519         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 520             $branch_count_query .= " AND issues.branchcode = ? ";
 521             push @bind_params, $branch;
 522         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 523             ; # if branch is the patron's home branch, then count all loans by patron
 524         } else {
 525             $branch_count_query .= " AND items.homebranch = ? ";
 526             push @bind_params, $branch;
 527         }
 528         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 529         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 530         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 531
 532         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 533             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 534                 return {
 535                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 536                     count => $onsite_checkout_count,
 537                     max_allowed => $max_onsite_checkouts_allowed,
 538                 }
 539             }
 540         }
 541         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 542             my $delta = $switch_onsite_checkout ? 1 : 0;
 543             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 544                 return {
 545                     reason => 'TOO_MANY_CHECKOUTS',
 546                     count => $checkout_count,
 547                     max_allowed => $max_checkouts_allowed,
 548                 };
 549             }
 550         } elsif ( not $onsite_checkout ) {
 551             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 552                 return {
 553                     reason => 'TOO_MANY_CHECKOUTS',
 554                     count => $checkout_count - $onsite_checkout_count,
 555                     max_allowed => $max_checkouts_allowed,
 556                 };
 557             }
 558         }
 559     }
 560
 561     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 562         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 563     }
 564
 565     # OK, the patron can issue !!!
 566     return;
 567 }
 568
 569 =head2 CanBookBeIssued
 570
 571   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 572                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 573
 574 Check if a book can be issued.
 575
 576 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 577
 578 IMPORTANT: The assumption by users of this routine is that causes blocking
 579 the issue are keyed by uppercase labels and other returned
 580 data is keyed in lower case!
 581
 582 =over 4
 583
 584 =item C<$patron> is a Koha::Patron
 585
 586 =item C<$barcode> is the bar code of the book being issued.
 587
 588 =item C<$duedates> is a DateTime object.
 589
 590 =item C<$inprocess> boolean switch
 591
 592 =item C<$ignore_reserves> boolean switch
 593
 594 =item C<$params> Hashref of additional parameters
 595
 596 Available keys:
 597     override_high_holds - Ignore high holds
 598     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 599
 600 =back
 601
 602 Returns :
 603
 604 =over 4
 605
 606 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 607 Possible values are :
 608
 609 =back
 610
 611 =head3 INVALID_DATE
 612
 613 sticky due date is invalid
 614
 615 =head3 GNA
 616
 617 borrower gone with no address
 618
 619 =head3 CARD_LOST
 620
 621 borrower declared it's card lost
 622
 623 =head3 DEBARRED
 624
 625 borrower debarred
 626
 627 =head3 UNKNOWN_BARCODE
 628
 629 barcode unknown
 630
 631 =head3 NOT_FOR_LOAN
 632
 633 item is not for loan
 634
 635 =head3 WTHDRAWN
 636
 637 item withdrawn.
 638
 639 =head3 RESTRICTED
 640
 641 item is restricted (set by ??)
 642
 643 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 644 could be prevented, but ones that can be overriden by the operator.
 645
 646 Possible values are :
 647
 648 =head3 DEBT
 649
 650 borrower has debts.
 651
 652 =head3 RENEW_ISSUE
 653
 654 renewing, not issuing
 655
 656 =head3 ISSUED_TO_ANOTHER
 657
 658 issued to someone else.
 659
 660 =head3 RESERVED
 661
 662 reserved for someone else.
 663
 664 =head3 INVALID_DATE
 665
 666 sticky due date is invalid or due date in the past
 667
 668 =head3 TOO_MANY
 669
 670 if the borrower borrows to much things
 671
 672 =cut
 673
 674 sub CanBookBeIssued {
 675     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 676     my %needsconfirmation;    # filled with problems that needs confirmations
 677     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 678     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 679     my %messages;             # filled with information messages that should be displayed.
 680
 681     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 682     my $override_high_holds = $params->{override_high_holds} || 0;
 683
 684     my $item_object = Koha::Items->find({barcode => $barcode });
 685
 686     # MANDATORY CHECKS - unless item exists, nothing else matters
 687     unless ( $item_object ) {
 688         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 689     }
 690     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 691
 692     my $item_unblessed = $item_object->unblessed; # Transition...
 693     my $issue = $item_object->checkout;
 694     my $biblio = $item_object->biblio;
 695
 696     my $biblioitem = $biblio->biblioitem;
 697     my $effective_itemtype = $item_object->effective_itemtype;
 698     my $dbh             = C4::Context->dbh;
 699     my $patron_unblessed = $patron->unblessed;
 700
 701     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 702     #
 703     # DUE DATE is OK ? -- should already have checked.
 704     #
 705     if ($duedate && ref $duedate ne 'DateTime') {
 706         $duedate = dt_from_string($duedate);
 707     }
 708     my $now = DateTime->now( time_zone => C4::Context->tz() );
 709     unless ( $duedate ) {
 710         my $issuedate = $now->clone();
 711
 712         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 713
 714         # Offline circ calls AddIssue directly, doesn't run through here
 715         #  So issuingimpossible should be ok.
 716     }
 717
 718     my $fees = Koha::Charges::Fees->new(
 719         {
 720             patron    => $patron,
 721             library   => $circ_library,
 722             item      => $item_object,
 723             to_date   => $duedate,
 724         }
 725     );
 726
 727     if ($duedate) {
 728         my $today = $now->clone();
 729         $today->truncate( to => 'minute');
 730         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 731             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 732         }
 733     } else {
 734             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 735     }
 736
 737     #
 738     # BORROWER STATUS
 739     #
 740     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 741         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 742         &UpdateStats({
 743                      branch => C4::Context->userenv->{'branch'},
 744                      type => 'localuse',
 745                      itemnumber => $item_object->itemnumber,
 746                      itemtype => $effective_itemtype,
 747                      borrowernumber => $patron->borrowernumber,
 748                      ccode => $item_object->ccode}
 749                     );
 750         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 751         return( { STATS => 1 }, {});
 752     }
 753
 754     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 755         $issuingimpossible{GNA} = 1;
 756     }
 757
 758     if ( $patron->lost && $patron->lost == 1 ) {
 759         $issuingimpossible{CARD_LOST} = 1;
 760     }
 761     if ( $patron->is_debarred ) {
 762         $issuingimpossible{DEBARRED} = 1;
 763     }
 764
 765     if ( $patron->is_expired ) {
 766         $issuingimpossible{EXPIRED} = 1;
 767     }
 768
 769     #
 770     # BORROWER STATUS
 771     #
 772
 773     # DEBTS
 774     my $account = $patron->account;
 775     my $balance = $account->balance;
 776     my $non_issues_charges = $account->non_issues_charges;
 777     my $other_charges = $balance - $non_issues_charges;
 778
 779     my $amountlimit = C4::Context->preference("noissuescharge");
 780     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 781     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 782
 783     # Check the debt of this patrons guarantees
 784     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 785     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 786     if ( defined $no_issues_charge_guarantees ) {
 787         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 788         my $guarantees_non_issues_charges;
 789         foreach my $g ( @guarantees ) {
 790             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 791         }
 792
 793         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 794             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 795         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 796             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 797         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 798             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 799         }
 800     }
 801
 802     if ( C4::Context->preference("IssuingInProcess") ) {
 803         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 804             $issuingimpossible{DEBT} = $non_issues_charges;
 805         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 806             $needsconfirmation{DEBT} = $non_issues_charges;
 807         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 808             $needsconfirmation{DEBT} = $non_issues_charges;
 809         }
 810     }
 811     else {
 812         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 813             $needsconfirmation{DEBT} = $non_issues_charges;
 814         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 815             $issuingimpossible{DEBT} = $non_issues_charges;
 816         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 817             $needsconfirmation{DEBT} = $non_issues_charges;
 818         }
 819     }
 820
 821     if ($balance > 0 && $other_charges > 0) {
 822         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 823     }
 824
 825     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 826     $patron_unblessed = $patron->unblessed;
 827
 828     if ( my $debarred_date = $patron->is_debarred ) {
 829          # patron has accrued fine days or has a restriction. $count is a date
 830         if ($debarred_date eq '9999-12-31') {
 831             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 832         }
 833         else {
 834             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 835         }
 836     } elsif ( my $num_overdues = $patron->has_overdues ) {
 837         ## patron has outstanding overdue loans
 838         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 839             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 840         }
 841         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 842             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 843         }
 844     }
 845
 846     #
 847     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 848     #
 849     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 850
 851         # Already issued to current borrower.
 852         # If it is an on-site checkout if it can be switched to a normal checkout
 853         # or ask whether the loan should be renewed
 854
 855         if ( $issue->onsite_checkout
 856                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 857             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 858         } else {
 859             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 860                 $patron->borrowernumber,
 861                 $item_object->itemnumber,
 862             );
 863             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 864                 if ( $renewerror eq 'onsite_checkout' ) {
 865                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 866                 }
 867                 else {
 868                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 869                 }
 870             }
 871             else {
 872                 $needsconfirmation{RENEW_ISSUE} = 1;
 873             }
 874         }
 875     }
 876     elsif ( $issue ) {
 877
 878         # issued to someone else
 879
 880         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 881
 882         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 883
 884         unless ( $can_be_returned ) {
 885             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 886             $issuingimpossible{branch_to_return} = $message;
 887         } else {
 888             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 889                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 890             } else {
 891             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 892             $needsconfirmation{issued_firstname} = $patron->firstname;
 893             $needsconfirmation{issued_surname} = $patron->surname;
 894             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 895             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 896             }
 897         }
 898     }
 899
 900     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 901     #
 902     my $switch_onsite_checkout = (
 903           C4::Context->preference('SwitchOnSiteCheckouts')
 904       and $issue
 905       and $issue->onsite_checkout
 906       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 907     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 908     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 909     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 910         if ( $toomany->{max_allowed} == 0 ) {
 911             $needsconfirmation{PATRON_CANT} = 1;
 912         }
 913         if ( C4::Context->preference("AllowTooManyOverride") ) {
 914             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 915             $needsconfirmation{current_loan_count} = $toomany->{count};
 916             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 917         } else {
 918             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 919             $issuingimpossible{current_loan_count} = $toomany->{count};
 920             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 921         }
 922     }
 923
 924     #
 925     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 926     #
 927     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 928     my $wants_check = $patron->wants_check_for_previous_checkout;
 929     $needsconfirmation{PREVISSUE} = 1
 930         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 931
 932     #
 933     # ITEM CHECKING
 934     #
 935     if ( $item_object->notforloan )
 936     {
 937         if(!C4::Context->preference("AllowNotForLoanOverride")){
 938             $issuingimpossible{NOT_FOR_LOAN} = 1;
 939             $issuingimpossible{item_notforloan} = $item_object->notforloan;
 940         }else{
 941             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 942             $needsconfirmation{item_notforloan} = $item_object->notforloan;
 943         }
 944     }
 945     else {
 946         # we have to check itemtypes.notforloan also
 947         if (C4::Context->preference('item-level_itypes')){
 948             # this should probably be a subroutine
 949             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 950             $sth->execute($effective_itemtype);
 951             my $notforloan=$sth->fetchrow_hashref();
 952             if ($notforloan->{'notforloan'}) {
 953                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 954                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 955                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 956                 } else {
 957                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 958                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 959                 }
 960             }
 961         }
 962         else {
 963             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 964             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
 965                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 966                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 967                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 968                 } else {
 969                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 970                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 971                 }
 972             }
 973         }
 974     }
 975     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
 976     {
 977         $issuingimpossible{WTHDRAWN} = 1;
 978     }
 979     if (   $item_object->restricted
 980         && $item_object->restricted == 1 )
 981     {
 982         $issuingimpossible{RESTRICTED} = 1;
 983     }
 984     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 985         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
 986         my $code = $av->count ? $av->next->lib : '';
 987         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 988         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 989     }
 990     if ( C4::Context->preference("IndependentBranches") ) {
 991         my $userenv = C4::Context->userenv;
 992         unless ( C4::Context->IsSuperLibrarian() ) {
 993             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 994             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
 995                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 996                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
 997             }
 998             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
 999               if ( $patron->branchcode ne $userenv->{branch} );
1000         }
1001     }
1002
1003     #
1004     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1005     #
1006     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1007     if ($rentalConfirmation) {
1008         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1009
1010         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1011         if ($itemtype_object) {
1012             my $accumulate_charge = $fees->accumulate_rentalcharge();
1013             if ( $accumulate_charge > 0 ) {
1014                 $rentalCharge += $accumulate_charge;
1015             }
1016         }
1017
1018         if ( $rentalCharge > 0 ) {
1019             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1020         }
1021     }
1022
1023     unless ( $ignore_reserves ) {
1024         # See if the item is on reserve.
1025         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1026         if ($restype) {
1027             my $resbor = $res->{'borrowernumber'};
1028             if ( $resbor ne $patron->borrowernumber ) {
1029                 my $patron = Koha::Patrons->find( $resbor );
1030                 if ( $restype eq "Waiting" )
1031                 {
1032                     # The item is on reserve and waiting, but has been
1033                     # reserved by some other patron.
1034                     $needsconfirmation{RESERVE_WAITING} = 1;
1035                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1036                     $needsconfirmation{'ressurname'} = $patron->surname;
1037                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1038                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1039                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1040                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1041                 }
1042                 elsif ( $restype eq "Reserved" ) {
1043                     # The item is on reserve for someone else.
1044                     $needsconfirmation{RESERVED} = 1;
1045                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1046                     $needsconfirmation{'ressurname'} = $patron->surname;
1047                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1048                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1049                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1050                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1051                 }
1052             }
1053         }
1054     }
1055
1056     ## CHECK AGE RESTRICTION
1057     my $agerestriction  = $biblioitem->agerestriction;
1058     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1059     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1060         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1061             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1062         }
1063         else {
1064             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1065         }
1066     }
1067
1068     ## check for high holds decreasing loan period
1069     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1070         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1071
1072         if ( $check->{exceeded} ) {
1073             if ($override_high_holds) {
1074                 $alerts{HIGHHOLDS} = {
1075                     num_holds  => $check->{outstanding},
1076                     duration   => $check->{duration},
1077                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1078                 };
1079             }
1080             else {
1081                 $needsconfirmation{HIGHHOLDS} = {
1082                     num_holds  => $check->{outstanding},
1083                     duration   => $check->{duration},
1084                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1085                 };
1086             }
1087         }
1088     }
1089
1090     if (
1091         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1092         # don't do the multiple loans per bib check if we've
1093         # already determined that we've got a loan on the same item
1094         !$issuingimpossible{NO_MORE_RENEWALS} &&
1095         !$needsconfirmation{RENEW_ISSUE}
1096     ) {
1097         # Check if borrower has already issued an item from the same biblio
1098         # Only if it's not a subscription
1099         my $biblionumber = $item_object->biblionumber;
1100         require C4::Serials;
1101         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1102         unless ($is_a_subscription) {
1103             # FIXME Should be $patron->checkouts($args);
1104             my $checkouts = Koha::Checkouts->search(
1105                 {
1106                     borrowernumber => $patron->borrowernumber,
1107                     biblionumber   => $biblionumber,
1108                 },
1109                 {
1110                     join => 'item',
1111                 }
1112             );
1113             # if we get here, we don't already have a loan on this item,
1114             # so if there are any loans on this bib, ask for confirmation
1115             if ( $checkouts->count ) {
1116                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1117             }
1118         }
1119     }
1120
1121     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1122 }
1123
1124 =head2 CanBookBeReturned
1125
1126   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1127
1128 Check whether the item can be returned to the provided branch
1129
1130 =over 4
1131
1132 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1133
1134 =item C<$branch> is the branchcode where the return is taking place
1135
1136 =back
1137
1138 Returns:
1139
1140 =over 4
1141
1142 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1143
1144 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1145
1146 =back
1147
1148 =cut
1149
1150 sub CanBookBeReturned {
1151   my ($item, $branch) = @_;
1152   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1153
1154   # assume return is allowed to start
1155   my $allowed = 1;
1156   my $message;
1157
1158   # identify all cases where return is forbidden
1159   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1160      $allowed = 0;
1161      $message = $item->{'homebranch'};
1162   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1163      $allowed = 0;
1164      $message = $item->{'holdingbranch'};
1165   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1166      $allowed = 0;
1167      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1168   }
1169
1170   return ($allowed, $message);
1171 }
1172
1173 =head2 CheckHighHolds
1174
1175     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1176     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1177     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1178
1179 =cut
1180
1181 sub checkHighHolds {
1182     my ( $item, $borrower ) = @_;
1183     my $branchcode = _GetCircControlBranch( $item, $borrower );
1184     my $item_object = Koha::Items->find( $item->{itemnumber} );
1185
1186     my $return_data = {
1187         exceeded    => 0,
1188         outstanding => 0,
1189         duration    => 0,
1190         due_date    => undef,
1191     };
1192
1193     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1194
1195     if ( $holds->count() ) {
1196         $return_data->{outstanding} = $holds->count();
1197
1198         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1199         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1200         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1201
1202         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1203
1204         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1205
1206             # static means just more than a given number of holds on the record
1207
1208             # If the number of holds is less than the threshold, we can stop here
1209             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1210                 return $return_data;
1211             }
1212         }
1213         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1214
1215             # dynamic means X more than the number of holdable items on the record
1216
1217             # let's get the items
1218             my @items = $holds->next()->biblio()->items()->as_list;
1219
1220             # Remove any items with status defined to be ignored even if the would not make item unholdable
1221             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1222                 @items = grep { !$_->$status } @items;
1223             }
1224
1225             # Remove any items that are not holdable for this patron
1226             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber )->{status} eq 'OK' } @items;
1227
1228             my $items_count = scalar @items;
1229
1230             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1231
1232             # If the number of holds is less than the count of items we have
1233             # plus the number of holds allowed above that count, we can stop here
1234             if ( $holds->count() <= $threshold ) {
1235                 return $return_data;
1236             }
1237         }
1238
1239         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1240
1241         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
1242
1243         my $itype = $item_object->effective_itemtype;
1244         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1245
1246         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1247
1248         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1249         $reduced_datedue->set_hour($orig_due->hour);
1250         $reduced_datedue->set_minute($orig_due->minute);
1251         $reduced_datedue->truncate( to => 'minute' );
1252
1253         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1254             $return_data->{exceeded} = 1;
1255             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1256             $return_data->{due_date} = $reduced_datedue;
1257         }
1258     }
1259
1260     return $return_data;
1261 }
1262
1263 =head2 AddIssue
1264
1265   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1266
1267 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1268
1269 =over 4
1270
1271 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1272
1273 =item C<$barcode> is the barcode of the item being issued.
1274
1275 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1276 Calculated if empty.
1277
1278 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1279
1280 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1281 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1282
1283 AddIssue does the following things :
1284
1285   - step 01: check that there is a borrowernumber & a barcode provided
1286   - check for RENEWAL (book issued & being issued to the same patron)
1287       - renewal YES = Calculate Charge & renew
1288       - renewal NO  =
1289           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1290           * RESERVE PLACED ?
1291               - fill reserve if reserve to this patron
1292               - cancel reserve or not, otherwise
1293           * TRANSFERT PENDING ?
1294               - complete the transfert
1295           * ISSUE THE BOOK
1296
1297 =back
1298
1299 =cut
1300
1301 sub AddIssue {
1302     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1303
1304     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1305     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1306     my $auto_renew = $params && $params->{auto_renew};
1307     my $dbh          = C4::Context->dbh;
1308     my $barcodecheck = CheckValidBarcode($barcode);
1309
1310     my $issue;
1311
1312     if ( $datedue && ref $datedue ne 'DateTime' ) {
1313         $datedue = dt_from_string($datedue);
1314     }
1315
1316     # $issuedate defaults to today.
1317     if ( !defined $issuedate ) {
1318         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1319     }
1320     else {
1321         if ( ref $issuedate ne 'DateTime' ) {
1322             $issuedate = dt_from_string($issuedate);
1323
1324         }
1325     }
1326
1327     # Stop here if the patron or barcode doesn't exist
1328     if ( $borrower && $barcode && $barcodecheck ) {
1329         # find which item we issue
1330         my $item_object = Koha::Items->find({ barcode => $barcode })
1331           or return;    # if we don't get an Item, abort.
1332         my $item_unblessed = $item_object->unblessed;
1333
1334         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1335
1336         # get actual issuing if there is one
1337         my $actualissue = $item_object->checkout;
1338
1339         # check if we just renew the issue.
1340         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1341                 and not $switch_onsite_checkout ) {
1342             $datedue = AddRenewal(
1343                 $borrower->{'borrowernumber'},
1344                 $item_object->itemnumber,
1345                 $branchcode,
1346                 $datedue,
1347                 $issuedate,    # here interpreted as the renewal date
1348             );
1349         }
1350         else {
1351             unless ($datedue) {
1352                 my $itype = $item_object->effective_itemtype;
1353                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1354
1355             }
1356             $datedue->truncate( to => 'minute' );
1357
1358             my $patron = Koha::Patrons->find( $borrower );
1359             my $library = Koha::Libraries->find( $branchcode );
1360             my $fees = Koha::Charges::Fees->new(
1361                 {
1362                     patron    => $patron,
1363                     library   => $library,
1364                     item      => $item_object,
1365                     to_date   => $datedue,
1366                 }
1367             );
1368
1369             # it's NOT a renewal
1370             if ( $actualissue and not $switch_onsite_checkout ) {
1371                 # This book is currently on loan, but not to the person
1372                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1373                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1374                 return unless $allowed;
1375                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1376             }
1377
1378             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1379
1380             # Starting process for transfer job (checking transfert and validate it if we have one)
1381             my ($datesent) = GetTransfers( $item_object->itemnumber );
1382             if ($datesent) {
1383                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1384                 my $sth = $dbh->prepare(
1385                     "UPDATE branchtransfers
1386                         SET datearrived = now(),
1387                         tobranch = ?,
1388                         comments = 'Forced branchtransfer'
1389                     WHERE itemnumber= ? AND datearrived IS NULL"
1390                 );
1391                 $sth->execute( C4::Context->userenv->{'branch'},
1392                     $item_object->itemnumber );
1393             }
1394
1395             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1396             unless ($auto_renew) {
1397                 my $rule = Koha::CirculationRules->get_effective_rule(
1398                     {
1399                         categorycode => $borrower->{categorycode},
1400                         itemtype     => $item_object->effective_itemtype,
1401                         branchcode   => $branchcode,
1402                         rule_name    => 'auto_renew'
1403                     }
1404                 );
1405
1406                 $auto_renew = $rule->rule_value if $rule;
1407             }
1408
1409             # Record in the database the fact that the book was issued.
1410             unless ($datedue) {
1411                 my $itype = $item_object->effective_itemtype;
1412                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1413
1414             }
1415             $datedue->truncate( to => 'minute' );
1416
1417             my $issue_attributes = {
1418                 borrowernumber  => $borrower->{'borrowernumber'},
1419                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1420                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1421                 branchcode      => C4::Context->userenv->{'branch'},
1422                 onsite_checkout => $onsite_checkout,
1423                 auto_renew      => $auto_renew ? 1 : 0,
1424             };
1425
1426             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1427             if ($issue) {
1428                 $issue->set($issue_attributes)->store;
1429             }
1430             else {
1431                 $issue = Koha::Checkout->new(
1432                     {
1433                         itemnumber => $item_object->itemnumber,
1434                         %$issue_attributes,
1435                     }
1436                 )->store;
1437             }
1438             if ( $item_object->location && $item_object->location eq 'CART'
1439                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1440             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1441                 CartToShelf( $item_object->itemnumber );
1442             }
1443
1444             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1445                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1446             }
1447
1448             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1449             if ( $item_object->itemlost ) {
1450                 if (
1451                     Koha::RefundLostItemFeeRules->should_refund(
1452                         {
1453                             current_branch      => C4::Context->userenv->{branch},
1454                             item_home_branch    => $item_object->homebranch,
1455                             item_holding_branch => $item_object->holdingbranch,
1456                         }
1457                     )
1458                   )
1459                 {
1460                     _FixAccountForLostAndFound( $item_object->itemnumber, undef,
1461                         $item_object->barcode );
1462                 }
1463             }
1464
1465             ModItem(
1466                 {
1467                     issues        => ( $item_object->issues || 0 ) + 1,
1468                     holdingbranch => C4::Context->userenv->{'branch'},
1469                     itemlost      => 0,
1470                     onloan        => $datedue->ymd(),
1471                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1472                 },
1473                 $item_object->biblionumber,
1474                 $item_object->itemnumber,
1475                 { log_action => 0 }
1476             );
1477             ModDateLastSeen( $item_object->itemnumber );
1478
1479             # If it costs to borrow this book, charge it to the patron's account.
1480             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1481             if ( $charge && $charge > 0 ) {
1482                 AddIssuingCharge( $issue, $charge, 'RENT' );
1483             }
1484
1485             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1486             if ( $itemtype_object ) {
1487                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1488                 if ( $accumulate_charge > 0 ) {
1489                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1490                     $charge += $accumulate_charge;
1491                     $item_unblessed->{charge} = $charge;
1492                 }
1493             }
1494
1495             # Record the fact that this book was issued.
1496             &UpdateStats(
1497                 {
1498                     branch => C4::Context->userenv->{'branch'},
1499                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1500                     amount         => $charge,
1501                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1502                     itemnumber     => $item_object->itemnumber,
1503                     itemtype       => $item_object->effective_itemtype,
1504                     location       => $item_object->location,
1505                     borrowernumber => $borrower->{'borrowernumber'},
1506                     ccode          => $item_object->ccode,
1507                 }
1508             );
1509
1510             # Send a checkout slip.
1511             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1512             my %conditions        = (
1513                 branchcode   => $branchcode,
1514                 categorycode => $borrower->{categorycode},
1515                 item_type    => $item_object->effective_itemtype,
1516                 notification => 'CHECKOUT',
1517             );
1518             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1519                 SendCirculationAlert(
1520                     {
1521                         type     => 'CHECKOUT',
1522                         item     => $item_object->unblessed,
1523                         borrower => $borrower,
1524                         branch   => $branchcode,
1525                     }
1526                 );
1527             }
1528             logaction(
1529                 "CIRCULATION", "ISSUE",
1530                 $borrower->{'borrowernumber'},
1531                 $item_object->itemnumber,
1532             ) if C4::Context->preference("IssueLog");
1533         }
1534     }
1535     return $issue;
1536 }
1537
1538 =head2 GetLoanLength
1539
1540   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1541
1542 Get loan length for an itemtype, a borrower type and a branch
1543
1544 =cut
1545
1546 sub GetLoanLength {
1547     my ( $categorycode, $itemtype, $branchcode ) = @_;
1548
1549     # Set search precedences
1550     my @params = (
1551         {
1552             categorycode => $categorycode,
1553             itemtype     => $itemtype,
1554             branchcode   => $branchcode,
1555         },
1556         {
1557             categorycode => $categorycode,
1558             itemtype     => undef,
1559             branchcode   => $branchcode,
1560         },
1561         {
1562             categorycode => undef,
1563             itemtype     => $itemtype,
1564             branchcode   => $branchcode,
1565         },
1566         {
1567             categorycode => undef,
1568             itemtype     => undef,
1569             branchcode   => $branchcode,
1570         },
1571         {
1572             categorycode => $categorycode,
1573             itemtype     => $itemtype,
1574             branchcode   => undef,
1575         },
1576         {
1577             categorycode => $categorycode,
1578             itemtype     => undef,
1579             branchcode   => undef,
1580         },
1581         {
1582             categorycode => undef,
1583             itemtype     => $itemtype,
1584             branchcode   => undef,
1585         },
1586         {
1587             categorycode => undef,
1588             itemtype     => undef,
1589             branchcode   => undef,
1590         },
1591     );
1592
1593     # Initialize default values
1594     my $rules = {
1595         issuelength   => 0,
1596         renewalperiod => 0,
1597         lengthunit    => 'days',
1598     };
1599
1600     # Search for rules!
1601     foreach my $rule_name (qw( issuelength renewalperiod lengthunit )) {
1602         foreach my $params (@params) {
1603             my $rule = Koha::CirculationRules->search(
1604                 {
1605                     rule_name => $rule_name,
1606                     %$params,
1607                 }
1608             )->next();
1609
1610             if ($rule) {
1611                 $rules->{$rule_name} = $rule->rule_value;
1612                 last;
1613             }
1614         }
1615     }
1616
1617     return $rules;
1618 }
1619
1620
1621 =head2 GetHardDueDate
1622
1623   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1624
1625 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1626
1627 =cut
1628
1629 sub GetHardDueDate {
1630     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1631
1632     my $rules = Koha::CirculationRules->get_effective_rules(
1633         {
1634             categorycode => $borrowertype,
1635             itemtype     => $itemtype,
1636             branchcode   => $branchcode,
1637             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1638         }
1639     );
1640
1641     if ( defined( $rules->{hardduedate} ) ) {
1642         if ( $rules->{hardduedate} ) {
1643             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1644         }
1645         else {
1646             return ( undef, undef );
1647         }
1648     }
1649 }
1650
1651 =head2 GetBranchBorrowerCircRule
1652
1653   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1654
1655 Retrieves circulation rule attributes that apply to the given
1656 branch and patron category, regardless of item type.
1657 The return value is a hashref containing the following key:
1658
1659 patron_maxissueqty - maximum number of loans that a
1660 patron of the given category can have at the given
1661 branch.  If the value is undef, no limit.
1662
1663 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1664 patron of the given category can have at the given
1665 branch.  If the value is undef, no limit.
1666
1667 This will check for different branch/category combinations in the following order:
1668 branch and category
1669 branch only
1670 category only
1671 default branch and category
1672
1673 If no rule has been found in the database, it will default to
1674 the buillt in rule:
1675
1676 patron_maxissueqty - undef
1677 patron_maxonsiteissueqty - undef
1678
1679 C<$branchcode> and C<$categorycode> should contain the
1680 literal branch code and patron category code, respectively - no
1681 wildcards.
1682
1683 =cut
1684
1685 sub GetBranchBorrowerCircRule {
1686     my ( $branchcode, $categorycode ) = @_;
1687
1688     # Initialize default values
1689     my $rules = {
1690         patron_maxissueqty       => undef,
1691         patron_maxonsiteissueqty => undef,
1692     };
1693
1694     # Search for rules!
1695     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1696         my $rule = Koha::CirculationRules->get_effective_rule(
1697             {
1698                 categorycode => $categorycode,
1699                 itemtype     => undef,
1700                 branchcode   => $branchcode,
1701                 rule_name    => $rule_name,
1702             }
1703         );
1704
1705         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1706     }
1707
1708     return $rules;
1709 }
1710
1711 =head2 GetBranchItemRule
1712
1713   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1714
1715 Retrieves circulation rule attributes that apply to the given
1716 branch and item type, regardless of patron category.
1717
1718 The return value is a hashref containing the following keys:
1719
1720 holdallowed => Hold policy for this branch and itemtype. Possible values:
1721   0: No holds allowed.
1722   1: Holds allowed only by patrons that have the same homebranch as the item.
1723   2: Holds allowed from any patron.
1724
1725 returnbranch => branch to which to return item.  Possible values:
1726   noreturn: do not return, let item remain where checked in (floating collections)
1727   homebranch: return to item's home branch
1728   holdingbranch: return to issuer branch
1729
1730 This searches branchitemrules in the following order:
1731
1732   * Same branchcode and itemtype
1733   * Same branchcode, itemtype '*'
1734   * branchcode '*', same itemtype
1735   * branchcode and itemtype '*'
1736
1737 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1738
1739 =cut
1740
1741 sub GetBranchItemRule {
1742     my ( $branchcode, $itemtype ) = @_;
1743
1744     # Search for rules!
1745     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1746         {
1747             branchcode => $branchcode,
1748             itemtype => $itemtype,
1749             rule_name => 'holdallowed',
1750         }
1751     );
1752     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1753         {
1754             branchcode => $branchcode,
1755             itemtype => $itemtype,
1756             rule_name => 'hold_fulfillment_policy',
1757         }
1758     );
1759     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1760         {
1761             branchcode => $branchcode,
1762             itemtype => $itemtype,
1763             rule_name => 'returnbranch',
1764         }
1765     );
1766
1767     # built-in default circulation rule
1768     my $rules;
1769     $rules->{holdallowed} = defined $holdallowed_rule
1770         ? $holdallowed_rule->rule_value
1771         : 2;
1772     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1773         ? $hold_fulfillment_policy_rule->rule_value
1774         : 'any';
1775     $rules->{returnbranch} = defined $returnbranch_rule
1776         ? $returnbranch_rule->rule_value
1777         : 'homebranch';
1778
1779     return $rules;
1780 }
1781
1782 =head2 AddReturn
1783
1784   ($doreturn, $messages, $iteminformation, $borrower) =
1785       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1786
1787 Returns a book.
1788
1789 =over 4
1790
1791 =item C<$barcode> is the bar code of the book being returned.
1792
1793 =item C<$branch> is the code of the branch where the book is being returned.
1794
1795 =item C<$exemptfine> indicates that overdue charges for the item will be
1796 removed. Optional.
1797
1798 =item C<$return_date> allows the default return date to be overridden
1799 by the given return date. Optional.
1800
1801 =back
1802
1803 C<&AddReturn> returns a list of four items:
1804
1805 C<$doreturn> is true iff the return succeeded.
1806
1807 C<$messages> is a reference-to-hash giving feedback on the operation.
1808 The keys of the hash are:
1809
1810 =over 4
1811
1812 =item C<BadBarcode>
1813
1814 No item with this barcode exists. The value is C<$barcode>.
1815
1816 =item C<NotIssued>
1817
1818 The book is not currently on loan. The value is C<$barcode>.
1819
1820 =item C<withdrawn>
1821
1822 This book has been withdrawn/cancelled. The value should be ignored.
1823
1824 =item C<Wrongbranch>
1825
1826 This book has was returned to the wrong branch.  The value is a hashref
1827 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1828 contain the branchcode of the incorrect and correct return library, respectively.
1829
1830 =item C<ResFound>
1831
1832 The item was reserved. The value is a reference-to-hash whose keys are
1833 fields from the reserves table of the Koha database, and
1834 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1835 either C<Waiting>, C<Reserved>, or 0.
1836
1837 =item C<WasReturned>
1838
1839 Value 1 if return is successful.
1840
1841 =item C<NeedsTransfer>
1842
1843 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1844
1845 =back
1846
1847 C<$iteminformation> is a reference-to-hash, giving information about the
1848 returned item from the issues table.
1849
1850 C<$borrower> is a reference-to-hash, giving information about the
1851 patron who last borrowed the book.
1852
1853 =cut
1854
1855 sub AddReturn {
1856     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1857
1858     if ($branch and not Koha::Libraries->find($branch)) {
1859         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1860         undef $branch;
1861     }
1862     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1863     $return_date //= dt_from_string();
1864     my $messages;
1865     my $patron;
1866     my $doreturn       = 1;
1867     my $validTransfert = 0;
1868     my $stat_type = 'return';
1869
1870     # get information on item
1871     my $item = Koha::Items->find({ barcode => $barcode });
1872     unless ($item) {
1873         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1874     }
1875
1876     my $itemnumber = $item->itemnumber;
1877     my $itemtype = $item->effective_itemtype;
1878
1879     my $issue  = $item->checkout;
1880     if ( $issue ) {
1881         $patron = $issue->patron
1882             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1883                 . Dumper($issue->unblessed) . "\n";
1884     } else {
1885         $messages->{'NotIssued'} = $barcode;
1886         ModItem({ onloan => undef }, $item->biblionumber, $item->itemnumber) if defined $item->onloan;
1887         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1888         $doreturn = 0;
1889         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1890         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1891         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1892            $messages->{'LocalUse'} = 1;
1893            $stat_type = 'localuse';
1894         }
1895     }
1896
1897     my $item_unblessed = $item->unblessed;
1898         # full item data, but no borrowernumber or checkout info (no issue)
1899     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1900         # get the proper branch to which to return the item
1901     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1902         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1903     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1904
1905     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1906     my $patron_unblessed = $patron ? $patron->unblessed : {};
1907
1908     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1909     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1910     if ($update_loc_rules) {
1911         if (defined $update_loc_rules->{_ALL_}) {
1912             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1913             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1914             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1915                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1916                 ModItem( { location => $update_loc_rules->{_ALL_} }, undef, $itemnumber );
1917             }
1918         }
1919         else {
1920             foreach my $key ( keys %$update_loc_rules ) {
1921                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1922                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1923                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1924                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1925                     ModItem( { location => $update_loc_rules->{$key} }, undef, $itemnumber );
1926                     last;
1927                 }
1928             }
1929         }
1930     }
1931
1932     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1933     if ($yaml) {
1934         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1935         my $rules;
1936         eval { $rules = YAML::Load($yaml); };
1937         if ($@) {
1938             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1939         }
1940         else {
1941             foreach my $key ( keys %$rules ) {
1942                 if ( $item->notforloan eq $key ) {
1943                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1944                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber, { log_action => 0 } );
1945                     last;
1946                 }
1947             }
1948         }
1949     }
1950
1951     # check if the return is allowed at this branch
1952     my ($returnallowed, $message) = CanBookBeReturned($item_unblessed, $branch);
1953     unless ($returnallowed){
1954         $messages->{'Wrongbranch'} = {
1955             Wrongbranch => $branch,
1956             Rightbranch => $message
1957         };
1958         $doreturn = 0;
1959         return ( $doreturn, $messages, $issue, $patron_unblessed);
1960     }
1961
1962     if ( $item->withdrawn ) { # book has been cancelled
1963         $messages->{'withdrawn'} = 1;
1964         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1965     }
1966
1967     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1968         $doreturn = 0;
1969     }
1970
1971     # case of a return of document (deal with issues and holdingbranch)
1972     if ($doreturn) {
1973         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1974         $patron or warn "AddReturn without current borrower";
1975
1976         if ($patron) {
1977             eval {
1978                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1979             };
1980             unless ( $@ ) {
1981                 if ( C4::Context->preference('CalculateFinesOnReturn') && !$item->itemlost ) {
1982                     _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed, return_date => $return_date } );
1983                 }
1984             } else {
1985                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1986
1987                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1988             }
1989
1990             # FIXME is the "= 1" right?  This could be the borrower hash.
1991             $messages->{'WasReturned'} = 1;
1992
1993         }
1994
1995         ModItem( { onloan => undef }, $item->biblionumber, $item->itemnumber, { log_action => 0 } );
1996     }
1997
1998     # the holdingbranch is updated if the document is returned to another location.
1999     # this is always done regardless of whether the item was on loan or not
2000     my $item_holding_branch = $item->holdingbranch;
2001     if ($item->holdingbranch ne $branch) {
2002         UpdateHoldingbranch($branch, $item->itemnumber);
2003         $item_unblessed->{'holdingbranch'} = $branch; # update item data holdingbranch too # FIXME I guess this is for the _debar_user_on_return call later
2004     }
2005
2006     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2007     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
2008
2009     # check if we have a transfer for this document
2010     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2011
2012     # if we have a transfer to do, we update the line of transfers with the datearrived
2013     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2014     if ($datesent) {
2015         if ( $tobranch eq $branch ) {
2016             my $sth = C4::Context->dbh->prepare(
2017                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2018             );
2019             $sth->execute( $item->itemnumber );
2020             # if we have a reservation with valid transfer, we can set it's status to 'W'
2021             C4::Reserves::ModReserveStatus($item->itemnumber, 'W');
2022         } else {
2023             $messages->{'WrongTransfer'}     = $tobranch;
2024             $messages->{'WrongTransferItem'} = $item->itemnumber;
2025         }
2026         $validTransfert = 1;
2027     }
2028
2029     # fix up the accounts.....
2030     if ( $item->itemlost ) {
2031         $messages->{'WasLost'} = 1;
2032         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2033             if (
2034                 Koha::RefundLostItemFeeRules->should_refund(
2035                     {
2036                         current_branch      => C4::Context->userenv->{branch},
2037                         item_home_branch    => $item->homebranch,
2038                         item_holding_branch => $item_holding_branch
2039                     }
2040                 )
2041               )
2042             {
2043                 _FixAccountForLostAndFound( $item->itemnumber,
2044                     $borrowernumber, $barcode );
2045                 $messages->{'LostItemFeeRefunded'} = 1;
2046             }
2047         }
2048     }
2049
2050     # fix up the overdues in accounts...
2051     if ($borrowernumber) {
2052         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2053         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->itemnumber...) failed!";  # zero is OK, check defined
2054
2055         if ( $issue and $issue->is_overdue ) {
2056         # fix fine days
2057             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item_unblessed, dt_from_string($issue->date_due), $return_date );
2058             if ($reminder){
2059                 $messages->{'PrevDebarred'} = $debardate;
2060             } else {
2061                 $messages->{'Debarred'} = $debardate if $debardate;
2062             }
2063         # there's no overdue on the item but borrower had been previously debarred
2064         } elsif ( $issue->date_due and $patron->debarred ) {
2065              if ( $patron->debarred eq "9999-12-31") {
2066                 $messages->{'ForeverDebarred'} = $patron->debarred;
2067              } else {
2068                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2069                   $borrower_debar_dt->truncate(to => 'day');
2070                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2071                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2072                       $messages->{'PrevDebarred'} = $patron->debarred;
2073                   }
2074              }
2075         }
2076     }
2077
2078     # find reserves.....
2079     # launch the Checkreserves routine to find any holds
2080     my ($resfound, $resrec);
2081     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2082     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2083     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2084     if ( $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2085         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2086         $resfound = 'Reserved';
2087         $resrec = $hold->unblessed;
2088     }
2089     if ($resfound) {
2090           $resrec->{'ResFound'} = $resfound;
2091         $messages->{'ResFound'} = $resrec;
2092     }
2093
2094     # Record the fact that this book was returned.
2095     UpdateStats({
2096         branch         => $branch,
2097         type           => $stat_type,
2098         itemnumber     => $itemnumber,
2099         itemtype       => $itemtype,
2100         borrowernumber => $borrowernumber,
2101         ccode          => $item->ccode,
2102     });
2103
2104     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2105     if ( $patron ) {
2106         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2107         my %conditions = (
2108             branchcode   => $branch,
2109             categorycode => $patron->categorycode,
2110             item_type    => $itemtype,
2111             notification => 'CHECKIN',
2112         );
2113         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2114             SendCirculationAlert({
2115                 type     => 'CHECKIN',
2116                 item     => $item_unblessed,
2117                 borrower => $patron->unblessed,
2118                 branch   => $branch,
2119             });
2120         }
2121
2122         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2123             if C4::Context->preference("ReturnLog");
2124         }
2125
2126     # Remove any OVERDUES related debarment if the borrower has no overdues
2127     if ( $borrowernumber
2128       && $patron->debarred
2129       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2130       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2131       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2132     ) {
2133         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2134     }
2135
2136     # Check if this item belongs to a biblio record that is attached to an
2137     # ILL request, if it is we need to update the ILL request's status
2138     if (C4::Context->preference('CirculateILL')) {
2139         my $request = Koha::Illrequests->find(
2140             { biblio_id => $item->biblio->biblionumber }
2141         );
2142         $request->status('RET') if $request;
2143     }
2144
2145     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2146     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2147         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2148         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2149             (C4::Context->preference("UseBranchTransferLimits") and
2150              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2151            )) {
2152             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2153             $debug and warn "item: " . Dumper($item_unblessed);
2154             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger);
2155             $messages->{'WasTransfered'} = 1;
2156         } else {
2157             $messages->{'NeedsTransfer'} = $returnbranch;
2158             $messages->{'TransferTrigger'} = $transfer_trigger;
2159         }
2160     }
2161
2162     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2163         my $claims = Koha::Checkouts::ReturnClaims->search(
2164            {
2165                itemnumber => $item->id,
2166                resolution => undef,
2167            }
2168         );
2169
2170         if ( $claims->count ) {
2171             $messages->{ReturnClaims} = $claims;
2172         }
2173     }
2174
2175     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2176 }
2177
2178 =head2 MarkIssueReturned
2179
2180   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2181
2182 Unconditionally marks an issue as being returned by
2183 moving the C<issues> row to C<old_issues> and
2184 setting C<returndate> to the current date.
2185
2186 if C<$returndate> is specified (in iso format), it is used as the date
2187 of the return.
2188
2189 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2190 the old_issue is immediately anonymised
2191
2192 Ideally, this function would be internal to C<C4::Circulation>,
2193 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2194 and offline_circ/process_koc.pl.
2195
2196 =cut
2197
2198 sub MarkIssueReturned {
2199     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2200
2201     # Retrieve the issue
2202     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2203
2204     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2205
2206     my $issue_id = $issue->issue_id;
2207
2208     my $anonymouspatron;
2209     if ( $privacy && $privacy == 2 ) {
2210         # The default of 0 will not work due to foreign key constraints
2211         # The anonymisation will fail if AnonymousPatron is not a valid entry
2212         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2213         # Note that a warning should appear on the about page (System information tab).
2214         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2215         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2216             unless Koha::Patrons->find( $anonymouspatron );
2217     }
2218
2219     my $schema = Koha::Database->schema;
2220
2221     # FIXME Improve the return value and handle it from callers
2222     $schema->txn_do(sub {
2223
2224         # Update the returndate value
2225         if ( $returndate ) {
2226             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2227         }
2228         else {
2229             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2230         }
2231
2232         # Create the old_issues entry
2233         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2234
2235         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2236         if ( $privacy && $privacy == 2) {
2237             $old_checkout->borrowernumber($anonymouspatron)->store;
2238         }
2239
2240         # And finally delete the issue
2241         $issue->delete;
2242
2243         ModItem( { 'onloan' => undef }, undef, $itemnumber, { log_action => 0 } );
2244
2245         if ( C4::Context->preference('StoreLastBorrower') ) {
2246             my $item = Koha::Items->find( $itemnumber );
2247             my $patron = Koha::Patrons->find( $borrowernumber );
2248             $item->last_returned_by( $patron );
2249         }
2250     });
2251
2252     return $issue_id;
2253 }
2254
2255 =head2 _debar_user_on_return
2256
2257     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2258
2259 C<$borrower> borrower hashref
2260
2261 C<$item> item hashref
2262
2263 C<$datedue> date due DateTime object
2264
2265 C<$returndate> DateTime object representing the return time
2266
2267 Internal function, called only by AddReturn that calculates and updates
2268  the user fine days, and debars them if necessary.
2269
2270 Should only be called for overdue returns
2271
2272 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2273 to ease testing.
2274
2275 =cut
2276
2277 sub _calculate_new_debar_dt {
2278     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2279
2280     my $branchcode = _GetCircControlBranch( $item, $borrower );
2281     my $circcontrol = C4::Context->preference('CircControl');
2282     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2283         {   categorycode => $borrower->{categorycode},
2284             itemtype     => $item->{itype},
2285             branchcode   => $branchcode,
2286             rules => [
2287                 'finedays',
2288                 'lengthunit',
2289                 'firstremind',
2290                 'maxsuspensiondays',
2291                 'suspension_chargeperiod',
2292             ]
2293         }
2294     );
2295     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2296     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2297     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2298
2299     return unless $finedays;
2300
2301     # finedays is in days, so hourly loans must multiply by 24
2302     # thus 1 hour late equals 1 day suspension * finedays rate
2303     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2304
2305     # grace period is measured in the same units as the loan
2306     my $grace =
2307       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2308
2309     my $deltadays = DateTime::Duration->new(
2310         days => $chargeable_units
2311     );
2312
2313     if ( $deltadays->subtract($grace)->is_positive() ) {
2314         my $suspension_days = $deltadays * $finedays;
2315
2316         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2317             # No need to / 1 and do not consider / 0
2318             $suspension_days = DateTime::Duration->new(
2319                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2320             );
2321         }
2322
2323         # If the max suspension days is < than the suspension days
2324         # the suspension days is limited to this maximum period.
2325         my $max_sd = $issuing_rule->{maxsuspensiondays};
2326         if ( defined $max_sd && $max_sd ne '' ) {
2327             $max_sd = DateTime::Duration->new( days => $max_sd );
2328             $suspension_days = $max_sd
2329               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2330         }
2331
2332         my ( $has_been_extended );
2333         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2334             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2335             if ( $debarment ) {
2336                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2337                 $has_been_extended = 1;
2338             }
2339         }
2340
2341         my $new_debar_dt;
2342         # Use the calendar or not to calculate the debarment date
2343         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2344             my $calendar = Koha::Calendar->new(
2345                 branchcode => $branchcode,
2346                 days_mode  => 'Calendar'
2347             );
2348             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2349         }
2350         else {
2351             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2352         }
2353         return $new_debar_dt;
2354     }
2355     return;
2356 }
2357
2358 sub _debar_user_on_return {
2359     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2360
2361     $return_date //= dt_from_string();
2362
2363     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2364
2365     return unless $new_debar_dt;
2366
2367     Koha::Patron::Debarments::AddUniqueDebarment({
2368         borrowernumber => $borrower->{borrowernumber},
2369         expiration     => $new_debar_dt->ymd(),
2370         type           => 'SUSPENSION',
2371     });
2372     # if borrower was already debarred but does not get an extra debarment
2373     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2374     my ($new_debarment_str, $is_a_reminder);
2375     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2376         $is_a_reminder = 1;
2377         $new_debarment_str = $borrower->{debarred};
2378     } else {
2379         $new_debarment_str = $new_debar_dt->ymd();
2380     }
2381     # FIXME Should return a DateTime object
2382     return $new_debarment_str, $is_a_reminder;
2383 }
2384
2385 =head2 _FixOverduesOnReturn
2386
2387    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2388
2389 C<$borrowernumber> borrowernumber
2390
2391 C<$itemnumber> itemnumber
2392
2393 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2394
2395 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2396
2397 Internal function
2398
2399 =cut
2400
2401 sub _FixOverduesOnReturn {
2402     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2403     unless( $borrowernumber ) {
2404         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2405         return;
2406     }
2407     unless( $item ) {
2408         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2409         return;
2410     }
2411     unless( $status ) {
2412         warn "_FixOverduesOnReturn() not supplied valid status";
2413         return;
2414     }
2415
2416     my $schema = Koha::Database->schema;
2417
2418     my $result = $schema->txn_do(
2419         sub {
2420             # check for overdue fine
2421             my $accountlines = Koha::Account::Lines->search(
2422                 {
2423                     borrowernumber  => $borrowernumber,
2424                     itemnumber      => $item,
2425                     debit_type_code => 'OVERDUE',
2426                     status          => 'UNRETURNED'
2427                 }
2428             );
2429             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2430
2431             my $accountline = $accountlines->next;
2432             if ($exemptfine) {
2433                 my $amountoutstanding = $accountline->amountoutstanding;
2434
2435                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2436                 my $credit = $account->add_credit(
2437                     {
2438                         amount     => $amountoutstanding,
2439                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2440                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2441                         interface  => C4::Context->interface,
2442                         type       => 'FORGIVEN',
2443                         item_id    => $item
2444                     }
2445                 );
2446
2447                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2448
2449                 $accountline->status('FORGIVEN');
2450
2451                 if (C4::Context->preference("FinesLog")) {
2452                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2453                 }
2454             } else {
2455                 $accountline->status($status);
2456             }
2457
2458             return $accountline->store();
2459         }
2460     );
2461
2462     return $result;
2463 }
2464
2465 =head2 _FixAccountForLostAndFound
2466
2467   &_FixAccountForLostAndFound($itemnumber, [$borrowernumber, $barcode]);
2468
2469 Finds the most recent lost item charge for this item and refunds the borrower
2470 appropriatly, taking into account any payments or writeoffs already applied
2471 against the charge.
2472
2473 Internal function, not exported, called only by AddReturn.
2474
2475 =cut
2476
2477 sub _FixAccountForLostAndFound {
2478     my $itemnumber     = shift or return;
2479     my $borrowernumber = @_ ? shift : undef;
2480     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2481
2482     my $credit;
2483
2484     # check for charge made for lost book
2485     my $accountlines = Koha::Account::Lines->search(
2486         {
2487             itemnumber      => $itemnumber,
2488             debit_type_code => 'LOST',
2489             status          => [ undef, { '<>' => 'FOUND' } ]
2490         },
2491         {
2492             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2493         }
2494     );
2495
2496     return unless $accountlines->count > 0;
2497     my $accountline     = $accountlines->next;
2498     my $total_to_refund = 0;
2499
2500     return unless $accountline->borrowernumber;
2501     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2502     return unless $patron; # Patron has been deleted, nobody to credit the return to
2503
2504     my $account = $patron->account;
2505
2506     # Use cases
2507     if ( $accountline->amount > $accountline->amountoutstanding ) {
2508         # some amount has been cancelled. collect the offsets that are not writeoffs
2509         # this works because the only way to subtract from this kind of a debt is
2510         # using the UI buttons 'Pay' and 'Write off'
2511         my $credits_offsets = Koha::Account::Offsets->search({
2512             debit_id  => $accountline->id,
2513             credit_id => { '!=' => undef }, # it is not the debit itself
2514             type      => { '!=' => 'Writeoff' },
2515             amount    => { '<'  => 0 } # credits are negative on the DB
2516         });
2517
2518         $total_to_refund = ( $credits_offsets->count > 0 )
2519                             ? $credits_offsets->total * -1 # credits are negative on the DB
2520                             : 0;
2521     }
2522
2523     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2524
2525     if ( $credit_total > 0 ) {
2526         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2527         $credit = $account->add_credit(
2528             {
2529                 amount      => $credit_total,
2530                 description => 'Item found ' . $item_id,
2531                 type        => 'LOST_FOUND',
2532                 interface   => C4::Context->interface,
2533                 library_id  => $branchcode,
2534                 item_id     => $itemnumber
2535             }
2536         );
2537
2538         $credit->apply( { debits => [ $accountline ] } );
2539     }
2540
2541     # Update the account status
2542     $accountline->discard_changes->status('FOUND');
2543     $accountline->store;
2544
2545     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2546         $account->reconcile_balance;
2547     }
2548
2549     return ($credit) ? $credit->id : undef;
2550 }
2551
2552 =head2 _GetCircControlBranch
2553
2554    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2555
2556 Internal function :
2557
2558 Return the library code to be used to determine which circulation
2559 policy applies to a transaction.  Looks up the CircControl and
2560 HomeOrHoldingBranch system preferences.
2561
2562 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2563
2564 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2565
2566 =cut
2567
2568 sub _GetCircControlBranch {
2569     my ($item, $borrower) = @_;
2570     my $circcontrol = C4::Context->preference('CircControl');
2571     my $branch;
2572
2573     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2574         $branch= C4::Context->userenv->{'branch'};
2575     } elsif ($circcontrol eq 'PatronLibrary') {
2576         $branch=$borrower->{branchcode};
2577     } else {
2578         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2579         $branch = $item->{$branchfield};
2580         # default to item home branch if holdingbranch is used
2581         # and is not defined
2582         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2583             $branch = $item->{homebranch};
2584         }
2585     }
2586     return $branch;
2587 }
2588
2589 =head2 GetOpenIssue
2590
2591   $issue = GetOpenIssue( $itemnumber );
2592
2593 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2594
2595 C<$itemnumber> is the item's itemnumber
2596
2597 Returns a hashref
2598
2599 =cut
2600
2601 sub GetOpenIssue {
2602   my ( $itemnumber ) = @_;
2603   return unless $itemnumber;
2604   my $dbh = C4::Context->dbh;
2605   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2606   $sth->execute( $itemnumber );
2607   return $sth->fetchrow_hashref();
2608
2609 }
2610
2611 =head2 GetBiblioIssues
2612
2613   $issues = GetBiblioIssues($biblionumber);
2614
2615 this function get all issues from a biblionumber.
2616
2617 Return:
2618 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2619 tables issues and the firstname,surname & cardnumber from borrowers.
2620
2621 =cut
2622
2623 sub GetBiblioIssues {
2624     my $biblionumber = shift;
2625     return unless $biblionumber;
2626     my $dbh   = C4::Context->dbh;
2627     my $query = "
2628         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2629         FROM issues
2630             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2631             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2632             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2633             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2634         WHERE biblio.biblionumber = ?
2635         UNION ALL
2636         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2637         FROM old_issues
2638             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2639             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2640             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2641             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2642         WHERE biblio.biblionumber = ?
2643         ORDER BY timestamp
2644     ";
2645     my $sth = $dbh->prepare($query);
2646     $sth->execute($biblionumber, $biblionumber);
2647
2648     my @issues;
2649     while ( my $data = $sth->fetchrow_hashref ) {
2650         push @issues, $data;
2651     }
2652     return \@issues;
2653 }
2654
2655 =head2 GetUpcomingDueIssues
2656
2657   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2658
2659 =cut
2660
2661 sub GetUpcomingDueIssues {
2662     my $params = shift;
2663
2664     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2665     my $dbh = C4::Context->dbh;
2666
2667     my $statement = <<END_SQL;
2668 SELECT *
2669 FROM (
2670     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2671     FROM issues
2672     LEFT JOIN items USING (itemnumber)
2673     LEFT OUTER JOIN branches USING (branchcode)
2674     WHERE returndate is NULL
2675 ) tmp
2676 WHERE days_until_due >= 0 AND days_until_due <= ?
2677 END_SQL
2678
2679     my @bind_parameters = ( $params->{'days_in_advance'} );
2680
2681     my $sth = $dbh->prepare( $statement );
2682     $sth->execute( @bind_parameters );
2683     my $upcoming_dues = $sth->fetchall_arrayref({});
2684
2685     return $upcoming_dues;
2686 }
2687
2688 =head2 CanBookBeRenewed
2689
2690   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2691
2692 Find out whether a borrowed item may be renewed.
2693
2694 C<$borrowernumber> is the borrower number of the patron who currently
2695 has the item on loan.
2696
2697 C<$itemnumber> is the number of the item to renew.
2698
2699 C<$override_limit>, if supplied with a true value, causes
2700 the limit on the number of times that the loan can be renewed
2701 (as controlled by the item type) to be ignored. Overriding also allows
2702 to renew sooner than "No renewal before" and to manually renew loans
2703 that are automatically renewed.
2704
2705 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2706 item must currently be on loan to the specified borrower; renewals
2707 must be allowed for the item's type; and the borrower must not have
2708 already renewed the loan. $error will contain the reason the renewal can not proceed
2709
2710 =cut
2711
2712 sub CanBookBeRenewed {
2713     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2714
2715     my $dbh    = C4::Context->dbh;
2716     my $renews = 1;
2717     my $auto_renew = 0;
2718
2719     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2720     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2721     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2722     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2723
2724     my $patron = $issue->patron or return;
2725
2726     # override_limit will override anything else except on_reserve
2727     unless ( $override_limit ){
2728         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2729         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2730             {
2731                 categorycode => $patron->categorycode,
2732                 itemtype     => $item->effective_itemtype,
2733                 branchcode   => $branchcode,
2734                 rules => [
2735                     'renewalsallowed',
2736                     'no_auto_renewal_after',
2737                     'no_auto_renewal_after_hard_limit',
2738                     'lengthunit',
2739                     'norenewalbefore',
2740                 ]
2741             }
2742         );
2743
2744         return ( 0, "too_many" )
2745           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2746
2747         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2748         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2749         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2750         my $restricted  = $patron->is_debarred;
2751         my $hasoverdues = $patron->has_overdues;
2752
2753         if ( $restricted and $restrictionblockrenewing ) {
2754             return ( 0, 'restriction');
2755         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2756             return ( 0, 'overdue');
2757         }
2758
2759         if ( $issue->auto_renew ) {
2760
2761             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2762                 return ( 0, 'auto_account_expired' );
2763             }
2764
2765             if ( defined $issuing_rule->{no_auto_renewal_after}
2766                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2767                 # Get issue_date and add no_auto_renewal_after
2768                 # If this is greater than today, it's too late for renewal.
2769                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2770                 $maximum_renewal_date->add(
2771                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2772                 );
2773                 my $now = dt_from_string;
2774                 if ( $now >= $maximum_renewal_date ) {
2775                     return ( 0, "auto_too_late" );
2776                 }
2777             }
2778             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2779                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2780                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2781                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2782                     return ( 0, "auto_too_late" );
2783                 }
2784             }
2785
2786             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2787                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2788                 my $amountoutstanding =
2789                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2790                   ? $patron->account->balance
2791                   : $patron->account->outstanding_debits->total_outstanding;
2792                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2793                     return ( 0, "auto_too_much_oweing" );
2794                 }
2795             }
2796         }
2797
2798         if ( defined $issuing_rule->{norenewalbefore}
2799             and $issuing_rule->{norenewalbefore} ne "" )
2800         {
2801
2802             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2803             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2804                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2805
2806             # Depending on syspref reset the exact time, only check the date
2807             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2808                 and $issuing_rule->{lengthunit} eq 'days' )
2809             {
2810                 $soonestrenewal->truncate( to => 'day' );
2811             }
2812
2813             if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2814             {
2815                 return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2816                 return ( 0, "too_soon" );
2817             }
2818             elsif ( $issue->auto_renew ) {
2819                 $auto_renew = 1;
2820             }
2821         }
2822
2823         # Fallback for automatic renewals:
2824         # If norenewalbefore is undef, don't renew before due date.
2825         if ( $issue->auto_renew && !$auto_renew ) {
2826             my $now = dt_from_string;
2827             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2828                 $auto_renew = 1;
2829             } else {
2830                 return ( 0, "auto_too_soon" );
2831             }
2832         }
2833     }
2834
2835     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2836
2837     # This item can fill one or more unfilled reserve, can those unfilled reserves
2838     # all be filled by other available items?
2839     if ( $resfound
2840         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2841     {
2842         my $schema = Koha::Database->new()->schema();
2843
2844         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2845         if ($item_holds) {
2846             # There is an item level hold on this item, no other item can fill the hold
2847             $resfound = 1;
2848         }
2849         else {
2850
2851             # Get all other items that could possibly fill reserves
2852             my @itemnumbers = $schema->resultset('Item')->search(
2853                 {
2854                     biblionumber => $resrec->{biblionumber},
2855                     onloan       => undef,
2856                     notforloan   => 0,
2857                     -not         => { itemnumber => $itemnumber }
2858                 },
2859                 { columns => 'itemnumber' }
2860             )->get_column('itemnumber')->all();
2861
2862             # Get all other reserves that could have been filled by this item
2863             my @borrowernumbers;
2864             while (1) {
2865                 my ( $reserve_found, $reserve, undef ) =
2866                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2867
2868                 if ($reserve_found) {
2869                     push( @borrowernumbers, $reserve->{borrowernumber} );
2870                 }
2871                 else {
2872                     last;
2873                 }
2874             }
2875
2876             # If the count of the union of the lists of reservable items for each borrower
2877             # is equal or greater than the number of borrowers, we know that all reserves
2878             # can be filled with available items. We can get the union of the sets simply
2879             # by pushing all the elements onto an array and removing the duplicates.
2880             my @reservable;
2881             my %patrons;
2882             ITEM: foreach my $itemnumber (@itemnumbers) {
2883                 my $item = Koha::Items->find( $itemnumber );
2884                 next if IsItemOnHoldAndFound( $itemnumber );
2885                 for my $borrowernumber (@borrowernumbers) {
2886                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2887                     next unless IsAvailableForItemLevelRequest($item, $patron);
2888                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2889
2890                     push @reservable, $itemnumber;
2891                     if (@reservable >= @borrowernumbers) {
2892                         $resfound = 0;
2893                         last ITEM;
2894                     }
2895                     last;
2896                 }
2897             }
2898         }
2899     }
2900     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2901     return ( 0, "auto_renew" ) if $auto_renew && !$override_limit; # 0 if auto-renewal should not succeed
2902
2903     return ( 1, undef );
2904 }
2905
2906 =head2 AddRenewal
2907
2908   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2909
2910 Renews a loan.
2911
2912 C<$borrowernumber> is the borrower number of the patron who currently
2913 has the item.
2914
2915 C<$itemnumber> is the number of the item to renew.
2916
2917 C<$branch> is the library where the renewal took place (if any).
2918            The library that controls the circ policies for the renewal is retrieved from the issues record.
2919
2920 C<$datedue> can be a DateTime object used to set the due date.
2921
2922 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2923 this parameter is not supplied, lastreneweddate is set to the current date.
2924
2925 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2926 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2927 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2928 syspref)
2929
2930 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2931 from the book's item type.
2932
2933 =cut
2934
2935 sub AddRenewal {
2936     my $borrowernumber  = shift;
2937     my $itemnumber      = shift or return;
2938     my $branch          = shift;
2939     my $datedue         = shift;
2940     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz);
2941     my $skipfinecalc    = shift;
2942
2943     my $item_object   = Koha::Items->find($itemnumber) or return;
2944     my $biblio = $item_object->biblio;
2945     my $issue  = $item_object->checkout;
2946     my $item_unblessed = $item_object->unblessed;
2947
2948     my $dbh = C4::Context->dbh;
2949
2950     return unless $issue;
2951
2952     $borrowernumber ||= $issue->borrowernumber;
2953
2954     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2955         carp 'Invalid date passed to AddRenewal.';
2956         return;
2957     }
2958
2959     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2960     my $patron_unblessed = $patron->unblessed;
2961
2962     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2963
2964     my $schema = Koha::Database->schema;
2965     $schema->txn_do(sub{
2966
2967         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
2968             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2969         }
2970         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2971
2972         # If the due date wasn't specified, calculate it by adding the
2973         # book's loan length to today's date or the current due date
2974         # based on the value of the RenewalPeriodBase syspref.
2975         my $itemtype = $item_object->effective_itemtype;
2976         unless ($datedue) {
2977
2978             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2979                                             dt_from_string( $issue->date_due, 'sql' ) :
2980                                             DateTime->now( time_zone => C4::Context->tz());
2981             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2982         }
2983
2984         my $fees = Koha::Charges::Fees->new(
2985             {
2986                 patron    => $patron,
2987                 library   => $circ_library,
2988                 item      => $item_object,
2989                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2990                 to_date   => dt_from_string($datedue),
2991             }
2992         );
2993
2994         # Update the issues record to have the new due date, and a new count
2995         # of how many times it has been renewed.
2996         my $renews = ( $issue->renewals || 0 ) + 1;
2997         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2998                                 WHERE borrowernumber=?
2999                                 AND itemnumber=?"
3000         );
3001
3002         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
3003
3004         # Update the renewal count on the item, and tell zebra to reindex
3005         $renews = ( $item_object->renewals || 0 ) + 1;
3006         ModItem( { renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $item_object->biblionumber, $itemnumber, { log_action => 0 } );
3007
3008         # Charge a new rental fee, if applicable
3009         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3010         if ( $charge > 0 ) {
3011             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3012         }
3013
3014         # Charge a new accumulate rental fee, if applicable
3015         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3016         if ( $itemtype_object ) {
3017             my $accumulate_charge = $fees->accumulate_rentalcharge();
3018             if ( $accumulate_charge > 0 ) {
3019                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3020             }
3021             $charge += $accumulate_charge;
3022         }
3023
3024         # Send a renewal slip according to checkout alert preferencei
3025         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3026             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3027             my %conditions        = (
3028                 branchcode   => $branch,
3029                 categorycode => $patron->categorycode,
3030                 item_type    => $itemtype,
3031                 notification => 'CHECKOUT',
3032             );
3033             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3034                 SendCirculationAlert(
3035                     {
3036                         type     => 'RENEWAL',
3037                         item     => $item_unblessed,
3038                         borrower => $patron->unblessed,
3039                         branch   => $branch,
3040                     }
3041                 );
3042             }
3043         }
3044
3045         # Remove any OVERDUES related debarment if the borrower has no overdues
3046         if ( $patron
3047           && $patron->is_debarred
3048           && ! $patron->has_overdues
3049           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3050         ) {
3051             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3052         }
3053
3054         unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
3055             $branch = ( C4::Context->userenv && defined C4::Context->userenv->{branch} ) ? C4::Context->userenv->{branch} : $branch;
3056         }
3057
3058         # Add the renewal to stats
3059         UpdateStats(
3060             {
3061                 branch         => $branch,
3062                 type           => 'renew',
3063                 amount         => $charge,
3064                 itemnumber     => $itemnumber,
3065                 itemtype       => $itemtype,
3066                 location       => $item_object->location,
3067                 borrowernumber => $borrowernumber,
3068                 ccode          => $item_object->ccode,
3069             }
3070         );
3071
3072         #Log the renewal
3073         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3074     });
3075
3076     return $datedue;
3077 }
3078
3079 sub GetRenewCount {
3080     # check renewal status
3081     my ( $bornum, $itemno ) = @_;
3082     my $dbh           = C4::Context->dbh;
3083     my $renewcount    = 0;
3084     my $renewsallowed = 0;
3085     my $renewsleft    = 0;
3086
3087     my $patron = Koha::Patrons->find( $bornum );
3088     my $item   = Koha::Items->find($itemno);
3089
3090     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3091
3092     # Look in the issues table for this item, lent to this borrower,
3093     # and not yet returned.
3094
3095     # FIXME - I think this function could be redone to use only one SQL call.
3096     my $sth = $dbh->prepare(
3097         "select * from issues
3098                                 where (borrowernumber = ?)
3099                                 and (itemnumber = ?)"
3100     );
3101     $sth->execute( $bornum, $itemno );
3102     my $data = $sth->fetchrow_hashref;
3103     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3104     # $item and $borrower should be calculated
3105     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3106
3107     my $rule = Koha::CirculationRules->get_effective_rule(
3108         {
3109             categorycode => $patron->categorycode,
3110             itemtype     => $item->effective_itemtype,
3111             branchcode   => $branchcode,
3112             rule_name    => 'renewalsallowed',
3113         }
3114     );
3115
3116     $renewsallowed = $rule ? $rule->rule_value : 0;
3117     $renewsleft    = $renewsallowed - $renewcount;
3118     if($renewsleft < 0){ $renewsleft = 0; }
3119     return ( $renewcount, $renewsallowed, $renewsleft );
3120 }
3121
3122 =head2 GetSoonestRenewDate
3123
3124   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3125
3126 Find out the soonest possible renew date of a borrowed item.
3127
3128 C<$borrowernumber> is the borrower number of the patron who currently
3129 has the item on loan.
3130
3131 C<$itemnumber> is the number of the item to renew.
3132
3133 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3134 renew date, based on the value "No renewal before" of the applicable
3135 issuing rule. Returns the current date if the item can already be
3136 renewed, and returns undefined if the borrower, loan, or item
3137 cannot be found.
3138
3139 =cut
3140
3141 sub GetSoonestRenewDate {
3142     my ( $borrowernumber, $itemnumber ) = @_;
3143
3144     my $dbh = C4::Context->dbh;
3145
3146     my $item      = Koha::Items->find($itemnumber)      or return;
3147     my $itemissue = $item->checkout or return;
3148
3149     $borrowernumber ||= $itemissue->borrowernumber;
3150     my $patron = Koha::Patrons->find( $borrowernumber )
3151       or return;
3152
3153     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3154     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3155         {   categorycode => $patron->categorycode,
3156             itemtype     => $item->effective_itemtype,
3157             branchcode   => $branchcode,
3158             rules => [
3159                 'norenewalbefore',
3160                 'lengthunit',
3161             ]
3162         }
3163     );
3164
3165     my $now = dt_from_string;
3166     return $now unless $issuing_rule;
3167
3168     if ( defined $issuing_rule->{norenewalbefore}
3169         and $issuing_rule->{norenewalbefore} ne "" )
3170     {
3171         my $soonestrenewal =
3172           dt_from_string( $itemissue->date_due )->subtract(
3173             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3174
3175         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3176             and $issuing_rule->{lengthunit} eq 'days' )
3177         {
3178             $soonestrenewal->truncate( to => 'day' );
3179         }
3180         return $soonestrenewal if $now < $soonestrenewal;
3181     }
3182     return $now;
3183 }
3184
3185 =head2 GetLatestAutoRenewDate
3186
3187   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3188
3189 Find out the latest possible auto renew date of a borrowed item.
3190
3191 C<$borrowernumber> is the borrower number of the patron who currently
3192 has the item on loan.
3193
3194 C<$itemnumber> is the number of the item to renew.
3195
3196 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3197 auto renew date, based on the value "No auto renewal after" and the "No auto
3198 renewal after (hard limit) of the applicable issuing rule.
3199 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3200 or item cannot be found.
3201
3202 =cut
3203
3204 sub GetLatestAutoRenewDate {
3205     my ( $borrowernumber, $itemnumber ) = @_;
3206
3207     my $dbh = C4::Context->dbh;
3208
3209     my $item      = Koha::Items->find($itemnumber)  or return;
3210     my $itemissue = $item->checkout                 or return;
3211
3212     $borrowernumber ||= $itemissue->borrowernumber;
3213     my $patron = Koha::Patrons->find( $borrowernumber )
3214       or return;
3215
3216     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3217     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3218         {
3219             categorycode => $patron->categorycode,
3220             itemtype     => $item->effective_itemtype,
3221             branchcode   => $branchcode,
3222             rules => [
3223                 'no_auto_renewal_after',
3224                 'no_auto_renewal_after_hard_limit',
3225                 'lengthunit',
3226             ]
3227         }
3228     );
3229
3230     return unless $circulation_rules;
3231     return
3232       if ( not $circulation_rules->{no_auto_renewal_after}
3233             or $circulation_rules->{no_auto_renewal_after} eq '' )
3234       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3235              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3236
3237     my $maximum_renewal_date;
3238     if ( $circulation_rules->{no_auto_renewal_after} ) {
3239         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3240         $maximum_renewal_date->add(
3241             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3242         );
3243     }
3244
3245     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3246         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3247         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3248     }
3249     return $maximum_renewal_date;
3250 }
3251
3252
3253 =head2 GetIssuingCharges
3254
3255   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3256
3257 Calculate how much it would cost for a given patron to borrow a given
3258 item, including any applicable discounts.
3259
3260 C<$itemnumber> is the item number of item the patron wishes to borrow.
3261
3262 C<$borrowernumber> is the patron's borrower number.
3263
3264 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3265 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3266 if it's a video).
3267
3268 =cut
3269
3270 sub GetIssuingCharges {
3271
3272     # calculate charges due
3273     my ( $itemnumber, $borrowernumber ) = @_;
3274     my $charge = 0;
3275     my $dbh    = C4::Context->dbh;
3276     my $item_type;
3277
3278     # Get the book's item type and rental charge (via its biblioitem).
3279     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3280         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3281     $charge_query .= (C4::Context->preference('item-level_itypes'))
3282         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3283         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3284
3285     $charge_query .= ' WHERE items.itemnumber =?';
3286
3287     my $sth = $dbh->prepare($charge_query);
3288     $sth->execute($itemnumber);
3289     if ( my $item_data = $sth->fetchrow_hashref ) {
3290         $item_type = $item_data->{itemtype};
3291         $charge    = $item_data->{rentalcharge};
3292         my $branch = C4::Context::mybranch();
3293         my $patron = Koha::Patrons->find( $borrowernumber );
3294         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3295         if ($discount) {
3296             # We may have multiple rules so get the most specific
3297             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3298         }
3299         if ($charge) {
3300             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3301         }
3302     }
3303
3304     return ( $charge, $item_type );
3305 }
3306
3307 # Select most appropriate discount rule from those returned
3308 sub _get_discount_from_rule {
3309     my ($categorycode, $branchcode, $itemtype) = @_;
3310
3311     # Set search precedences
3312     my @params = (
3313         {
3314             branchcode   => $branchcode,
3315             itemtype     => $itemtype,
3316             categorycode => $categorycode,
3317         },
3318         {
3319             branchcode   => undef,
3320             categorycode => $categorycode,
3321             itemtype     => $itemtype,
3322         },
3323         {
3324             branchcode   => $branchcode,
3325             categorycode => $categorycode,
3326             itemtype     => undef,
3327         },
3328         {
3329             branchcode   => undef,
3330             categorycode => $categorycode,
3331             itemtype     => undef,
3332         },
3333     );
3334
3335     foreach my $params (@params) {
3336         my $rule = Koha::CirculationRules->search(
3337             {
3338                 rule_name => 'rentaldiscount',
3339                 %$params,
3340             }
3341         )->next();
3342
3343         return $rule->rule_value if $rule;
3344     }
3345
3346     # none of the above
3347     return 0;
3348 }
3349
3350 =head2 AddIssuingCharge
3351
3352   &AddIssuingCharge( $checkout, $charge, $type )
3353
3354 =cut
3355
3356 sub AddIssuingCharge {
3357     my ( $checkout, $charge, $type ) = @_;
3358
3359     # FIXME What if checkout does not exist?
3360
3361     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3362     my $accountline = $account->add_debit(
3363         {
3364             amount      => $charge,
3365             note        => undef,
3366             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3367             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3368             interface   => C4::Context->interface,
3369             type        => $type,
3370             item_id     => $checkout->itemnumber,
3371             issue_id    => $checkout->issue_id,
3372         }
3373     );
3374 }
3375
3376 =head2 GetTransfers
3377
3378   GetTransfers($itemnumber);
3379
3380 =cut
3381
3382 sub GetTransfers {
3383     my ($itemnumber) = @_;
3384
3385     my $dbh = C4::Context->dbh;
3386
3387     my $query = '
3388         SELECT datesent,
3389                frombranch,
3390                tobranch,
3391                branchtransfer_id
3392         FROM branchtransfers
3393         WHERE itemnumber = ?
3394           AND datearrived IS NULL
3395         ';
3396     my $sth = $dbh->prepare($query);
3397     $sth->execute($itemnumber);
3398     my @row = $sth->fetchrow_array();
3399     return @row;
3400 }
3401
3402 =head2 GetTransfersFromTo
3403
3404   @results = GetTransfersFromTo($frombranch,$tobranch);
3405
3406 Returns the list of pending transfers between $from and $to branch
3407
3408 =cut
3409
3410 sub GetTransfersFromTo {
3411     my ( $frombranch, $tobranch ) = @_;
3412     return unless ( $frombranch && $tobranch );
3413     my $dbh   = C4::Context->dbh;
3414     my $query = "
3415         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3416         FROM   branchtransfers
3417         WHERE  frombranch=?
3418           AND  tobranch=?
3419           AND datearrived IS NULL
3420     ";
3421     my $sth = $dbh->prepare($query);
3422     $sth->execute( $frombranch, $tobranch );
3423     my @gettransfers;
3424
3425     while ( my $data = $sth->fetchrow_hashref ) {
3426         push @gettransfers, $data;
3427     }
3428     return (@gettransfers);
3429 }
3430
3431 =head2 DeleteTransfer
3432
3433   &DeleteTransfer($itemnumber);
3434
3435 =cut
3436
3437 sub DeleteTransfer {
3438     my ($itemnumber) = @_;
3439     return unless $itemnumber;
3440     my $dbh          = C4::Context->dbh;
3441     my $sth          = $dbh->prepare(
3442         "DELETE FROM branchtransfers
3443          WHERE itemnumber=?
3444          AND datearrived IS NULL "
3445     );
3446     return $sth->execute($itemnumber);
3447 }
3448
3449 =head2 SendCirculationAlert
3450
3451 Send out a C<check-in> or C<checkout> alert using the messaging system.
3452
3453 B<Parameters>:
3454
3455 =over 4
3456
3457 =item type
3458
3459 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3460
3461 =item item
3462
3463 Hashref of information about the item being checked in or out.
3464
3465 =item borrower
3466
3467 Hashref of information about the borrower of the item.
3468
3469 =item branch
3470
3471 The branchcode from where the checkout or check-in took place.
3472
3473 =back
3474
3475 B<Example>:
3476
3477     SendCirculationAlert({
3478         type     => 'CHECKOUT',
3479         item     => $item,
3480         borrower => $borrower,
3481         branch   => $branch,
3482     });
3483
3484 =cut
3485
3486 sub SendCirculationAlert {
3487     my ($opts) = @_;
3488     my ($type, $item, $borrower, $branch) =
3489         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3490     my %message_name = (
3491         CHECKIN  => 'Item_Check_in',
3492         CHECKOUT => 'Item_Checkout',
3493         RENEWAL  => 'Item_Checkout',
3494     );
3495     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3496         borrowernumber => $borrower->{borrowernumber},
3497         message_name   => $message_name{$type},
3498     });
3499     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3500
3501     my $schema = Koha::Database->new->schema;
3502     my @transports = keys %{ $borrower_preferences->{transports} };
3503
3504     # From the MySQL doc:
3505     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3506     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3507     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3508     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3509
3510     for my $mtt (@transports) {
3511         my $letter =  C4::Letters::GetPreparedLetter (
3512             module => 'circulation',
3513             letter_code => $type,
3514             branchcode => $branch,
3515             message_transport_type => $mtt,
3516             lang => $borrower->{lang},
3517             tables => {
3518                 $issues_table => $item->{itemnumber},
3519                 'items'       => $item->{itemnumber},
3520                 'biblio'      => $item->{biblionumber},
3521                 'biblioitems' => $item->{biblionumber},
3522                 'borrowers'   => $borrower,
3523                 'branches'    => $branch,
3524             }
3525         ) or next;
3526
3527         $schema->storage->txn_begin;
3528         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3529         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3530         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3531         unless ( $message ) {
3532             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3533             C4::Message->enqueue($letter, $borrower, $mtt);
3534         } else {
3535             $message->append($letter);
3536             $message->update;
3537         }
3538         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3539         $schema->storage->txn_commit;
3540     }
3541
3542     return;
3543 }
3544
3545 =head2 updateWrongTransfer
3546
3547   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3548
3549 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3550
3551 =cut
3552
3553 sub updateWrongTransfer {
3554         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3555         my $dbh = C4::Context->dbh;
3556 # first step validate the actual line of transfert .
3557         my $sth =
3558                 $dbh->prepare(
3559                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3560                 );
3561                 $sth->execute($FromLibrary,$itemNumber);
3562
3563 # second step create a new line of branchtransfer to the right location .
3564         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3565
3566 #third step changing holdingbranch of item
3567         UpdateHoldingbranch($FromLibrary,$itemNumber);
3568 }
3569
3570 =head2 UpdateHoldingbranch
3571
3572   $items = UpdateHoldingbranch($branch,$itmenumber);
3573
3574 Simple methode for updating hodlingbranch in items BDD line
3575
3576 =cut
3577
3578 sub UpdateHoldingbranch {
3579         my ( $branch,$itemnumber ) = @_;
3580     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3581 }
3582
3583 =head2 CalcDateDue
3584
3585 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3586
3587 this function calculates the due date given the start date and configured circulation rules,
3588 checking against the holidays calendar as per the 'useDaysMode' syspref.
3589 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3590 C<$itemtype>  = itemtype code of item in question
3591 C<$branch>  = location whose calendar to use
3592 C<$borrower> = Borrower object
3593 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3594
3595 =cut
3596
3597 sub CalcDateDue {
3598     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3599
3600     $isrenewal ||= 0;
3601
3602     # loanlength now a href
3603     my $loanlength =
3604             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3605
3606     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3607             ? qq{renewalperiod}
3608             : qq{issuelength};
3609
3610     my $datedue;
3611     if ( $startdate ) {
3612         if (ref $startdate ne 'DateTime' ) {
3613             $datedue = dt_from_string($datedue);
3614         } else {
3615             $datedue = $startdate->clone;
3616         }
3617     } else {
3618         $datedue =
3619           DateTime->now( time_zone => C4::Context->tz() )
3620           ->truncate( to => 'minute' );
3621     }
3622
3623
3624     # calculate the datedue as normal
3625     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3626     {    # ignoring calendar
3627         if ( $loanlength->{lengthunit} eq 'hours' ) {
3628             $datedue->add( hours => $loanlength->{$length_key} );
3629         } else {    # days
3630             $datedue->add( days => $loanlength->{$length_key} );
3631             $datedue->set_hour(23);
3632             $datedue->set_minute(59);
3633         }
3634     } else {
3635         my $dur;
3636         if ($loanlength->{lengthunit} eq 'hours') {
3637             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3638         }
3639         else { # days
3640             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3641         }
3642         my $calendar = Koha::Calendar->new( branchcode => $branch );
3643         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3644         if ($loanlength->{lengthunit} eq 'days') {
3645             $datedue->set_hour(23);
3646             $datedue->set_minute(59);
3647         }
3648     }
3649
3650     # if Hard Due Dates are used, retrieve them and apply as necessary
3651     my ( $hardduedate, $hardduedatecompare ) =
3652       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3653     if ($hardduedate) {    # hardduedates are currently dates
3654         $hardduedate->truncate( to => 'minute' );
3655         $hardduedate->set_hour(23);
3656         $hardduedate->set_minute(59);
3657         my $cmp = DateTime->compare( $hardduedate, $datedue );
3658
3659 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3660 # if the calculated date is before the 'after' Hard Due Date (floor), override
3661 # if the hard due date is set to 'exactly', overrride
3662         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3663             $datedue = $hardduedate->clone;
3664         }
3665
3666         # in all other cases, keep the date due as it is
3667
3668     }
3669
3670     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3671     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3672         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3673         if( $expiry_dt ) { #skip empty expiry date..
3674             $expiry_dt->set( hour => 23, minute => 59);
3675             my $d1= $datedue->clone->set_time_zone('floating');
3676             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3677                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3678             }
3679         }
3680         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3681           my $calendar = Koha::Calendar->new( branchcode => $branch );
3682           if ( $calendar->is_holiday($datedue) ) {
3683               # Don't return on a closed day
3684               $datedue = $calendar->prev_open_days( $datedue, 1 );
3685           }
3686         }
3687     }
3688
3689     return $datedue;
3690 }
3691
3692
3693 sub CheckValidBarcode{
3694 my ($barcode) = @_;
3695 my $dbh = C4::Context->dbh;
3696 my $query=qq|SELECT count(*)
3697              FROM items
3698              WHERE barcode=?
3699             |;
3700 my $sth = $dbh->prepare($query);
3701 $sth->execute($barcode);
3702 my $exist=$sth->fetchrow ;
3703 return $exist;
3704 }
3705
3706 =head2 IsBranchTransferAllowed
3707
3708   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3709
3710 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3711
3712 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3713 Koha::Item->can_be_transferred.
3714
3715 =cut
3716
3717 sub IsBranchTransferAllowed {
3718         my ( $toBranch, $fromBranch, $code ) = @_;
3719
3720         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3721
3722         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3723         my $dbh = C4::Context->dbh;
3724
3725         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3726         $sth->execute( $toBranch, $fromBranch, $code );
3727         my $limit = $sth->fetchrow_hashref();
3728
3729         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3730         if ( $limit->{'limitId'} ) {
3731                 return 0;
3732         } else {
3733                 return 1;
3734         }
3735 }
3736
3737 =head2 CreateBranchTransferLimit
3738
3739   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3740
3741 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3742
3743 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3744
3745 =cut
3746
3747 sub CreateBranchTransferLimit {
3748    my ( $toBranch, $fromBranch, $code ) = @_;
3749    return unless defined($toBranch) && defined($fromBranch);
3750    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3751
3752    my $dbh = C4::Context->dbh;
3753
3754    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3755    return $sth->execute( $code, $toBranch, $fromBranch );
3756 }
3757
3758 =head2 DeleteBranchTransferLimits
3759
3760     my $result = DeleteBranchTransferLimits($frombranch);
3761
3762 Deletes all the library transfer limits for one library.  Returns the
3763 number of limits deleted, 0e0 if no limits were deleted, or undef if
3764 no arguments are supplied.
3765
3766 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3767     fromBranch => $fromBranch
3768     })->delete.
3769
3770 =cut
3771
3772 sub DeleteBranchTransferLimits {
3773     my $branch = shift;
3774     return unless defined $branch;
3775     my $dbh    = C4::Context->dbh;
3776     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3777     return $sth->execute($branch);
3778 }
3779
3780 sub ReturnLostItem{
3781     my ( $borrowernumber, $itemnum ) = @_;
3782     MarkIssueReturned( $borrowernumber, $itemnum );
3783 }
3784
3785
3786 sub LostItem{
3787     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3788
3789     unless ( $mark_lost_from ) {
3790         # Temporary check to avoid regressions
3791         die q|LostItem called without $mark_lost_from, check the API.|;
3792     }
3793
3794     my $mark_returned;
3795     if ( $force_mark_returned ) {
3796         $mark_returned = 1;
3797     } else {
3798         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3799         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3800     }
3801
3802     my $dbh = C4::Context->dbh();
3803     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3804                            FROM issues
3805                            JOIN items USING (itemnumber)
3806                            JOIN biblio USING (biblionumber)
3807                            WHERE issues.itemnumber=?");
3808     $sth->execute($itemnumber);
3809     my $issues=$sth->fetchrow_hashref();
3810
3811     # If a borrower lost the item, add a replacement cost to the their record
3812     if ( my $borrowernumber = $issues->{borrowernumber} ){
3813         my $patron = Koha::Patrons->find( $borrowernumber );
3814
3815         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3816         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3817
3818         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3819             C4::Accounts::chargelostitem(
3820                 $borrowernumber,
3821                 $itemnumber,
3822                 $issues->{'replacementprice'},
3823                 sprintf( "%s %s %s",
3824                     $issues->{'title'}          || q{},
3825                     $issues->{'barcode'}        || q{},
3826                     $issues->{'itemcallnumber'} || q{},
3827                 ),
3828             );
3829             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3830             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3831         }
3832
3833         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3834     }
3835
3836     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3837     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3838         ModItem({holdingbranch => $frombranch}, undef, $itemnumber);
3839     }
3840     my $transferdeleted = DeleteTransfer($itemnumber);
3841 }
3842
3843 sub GetOfflineOperations {
3844     my $dbh = C4::Context->dbh;
3845     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3846     $sth->execute(C4::Context->userenv->{'branch'});
3847     my $results = $sth->fetchall_arrayref({});
3848     return $results;
3849 }
3850
3851 sub GetOfflineOperation {
3852     my $operationid = shift;
3853     return unless $operationid;
3854     my $dbh = C4::Context->dbh;
3855     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3856     $sth->execute( $operationid );
3857     return $sth->fetchrow_hashref;
3858 }
3859
3860 sub AddOfflineOperation {
3861     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3862     my $dbh = C4::Context->dbh;
3863     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3864     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3865     return "Added.";
3866 }
3867
3868 sub DeleteOfflineOperation {
3869     my $dbh = C4::Context->dbh;
3870     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3871     $sth->execute( shift );
3872     return "Deleted.";
3873 }
3874
3875 sub ProcessOfflineOperation {
3876     my $operation = shift;
3877
3878     my $report;
3879     if ( $operation->{action} eq 'return' ) {
3880         $report = ProcessOfflineReturn( $operation );
3881     } elsif ( $operation->{action} eq 'issue' ) {
3882         $report = ProcessOfflineIssue( $operation );
3883     } elsif ( $operation->{action} eq 'payment' ) {
3884         $report = ProcessOfflinePayment( $operation );
3885     }
3886
3887     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3888
3889     return $report;
3890 }
3891
3892 sub ProcessOfflineReturn {
3893     my $operation = shift;
3894
3895     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3896
3897     if ( $item ) {
3898         my $itemnumber = $item->itemnumber;
3899         my $issue = GetOpenIssue( $itemnumber );
3900         if ( $issue ) {
3901             MarkIssueReturned(
3902                 $issue->{borrowernumber},
3903                 $itemnumber,
3904                 $operation->{timestamp},
3905             );
3906             ModItem(
3907                 { renewals => 0, onloan => undef },
3908                 $issue->{'biblionumber'},
3909                 $itemnumber,
3910                 { log_action => 0 }
3911             );
3912             return "Success.";
3913         } else {
3914             return "Item not issued.";
3915         }
3916     } else {
3917         return "Item not found.";
3918     }
3919 }
3920
3921 sub ProcessOfflineIssue {
3922     my $operation = shift;
3923
3924     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3925
3926     if ( $patron ) {
3927         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3928         unless ($item) {
3929             return "Barcode not found.";
3930         }
3931         my $itemnumber = $item->itemnumber;
3932         my $issue = GetOpenIssue( $itemnumber );
3933
3934         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3935             MarkIssueReturned(
3936                 $issue->{borrowernumber},
3937                 $itemnumber,
3938                 $operation->{timestamp},
3939             );
3940         }
3941         AddIssue(
3942             $patron->unblessed,
3943             $operation->{'barcode'},
3944             undef,
3945             1,
3946             $operation->{timestamp},
3947             undef,
3948         );
3949         return "Success.";
3950     } else {
3951         return "Borrower not found.";
3952     }
3953 }
3954
3955 sub ProcessOfflinePayment {
3956     my $operation = shift;
3957
3958     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3959
3960     $patron->account->pay(
3961         {
3962             amount     => $operation->{amount},
3963             library_id => $operation->{branchcode},
3964             interface  => 'koc'
3965         }
3966     );
3967
3968     return "Success.";
3969 }
3970
3971 =head2 TransferSlip
3972
3973   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3974
3975   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3976
3977 =cut
3978
3979 sub TransferSlip {
3980     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3981
3982     my $item =
3983       $itemnumber
3984       ? Koha::Items->find($itemnumber)
3985       : Koha::Items->find( { barcode => $barcode } );
3986
3987     $item or return;
3988
3989     return C4::Letters::GetPreparedLetter (
3990         module => 'circulation',
3991         letter_code => 'TRANSFERSLIP',
3992         branchcode => $branch,
3993         tables => {
3994             'branches'    => $to_branch,
3995             'biblio'      => $item->biblionumber,
3996             'items'       => $item->unblessed,
3997         },
3998     );
3999 }
4000
4001 =head2 CheckIfIssuedToPatron
4002
4003   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4004
4005   Return 1 if any record item is issued to patron, otherwise return 0
4006
4007 =cut
4008
4009 sub CheckIfIssuedToPatron {
4010     my ($borrowernumber, $biblionumber) = @_;
4011
4012     my $dbh = C4::Context->dbh;
4013     my $query = q|
4014         SELECT COUNT(*) FROM issues
4015         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4016         WHERE items.biblionumber = ?
4017         AND issues.borrowernumber = ?
4018     |;
4019     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4020     return 1 if $is_issued;
4021     return;
4022 }
4023
4024 =head2 IsItemIssued
4025
4026   IsItemIssued( $itemnumber )
4027
4028   Return 1 if the item is on loan, otherwise return 0
4029
4030 =cut
4031
4032 sub IsItemIssued {
4033     my $itemnumber = shift;
4034     my $dbh = C4::Context->dbh;
4035     my $sth = $dbh->prepare(q{
4036         SELECT COUNT(*)
4037         FROM issues
4038         WHERE itemnumber = ?
4039     });
4040     $sth->execute($itemnumber);
4041     return $sth->fetchrow;
4042 }
4043
4044 =head2 GetAgeRestriction
4045
4046   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4047   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4048
4049   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4050   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4051
4052 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4053 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4054 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4055          Negative days mean the borrower has gone past the age restriction age.
4056
4057 =cut
4058
4059 sub GetAgeRestriction {
4060     my ($record_restrictions, $borrower) = @_;
4061     my $markers = C4::Context->preference('AgeRestrictionMarker');
4062
4063     return unless $record_restrictions;
4064     # Split $record_restrictions to something like FSK 16 or PEGI 6
4065     my @values = split ' ', uc($record_restrictions);
4066     return unless @values;
4067
4068     # Search first occurrence of one of the markers
4069     my @markers = split /\|/, uc($markers);
4070     return unless @markers;
4071
4072     my $index            = 0;
4073     my $restriction_year = 0;
4074     for my $value (@values) {
4075         $index++;
4076         for my $marker (@markers) {
4077             $marker =~ s/^\s+//;    #remove leading spaces
4078             $marker =~ s/\s+$//;    #remove trailing spaces
4079             if ( $marker eq $value ) {
4080                 if ( $index <= $#values ) {
4081                     $restriction_year += $values[$index];
4082                 }
4083                 last;
4084             }
4085             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4086
4087                 # Perhaps it is something like "K16" (as in Finland)
4088                 $restriction_year += $1;
4089                 last;
4090             }
4091         }
4092         last if ( $restriction_year > 0 );
4093     }
4094
4095     #Check if the borrower is age restricted for this material and for how long.
4096     if ($restriction_year && $borrower) {
4097         if ( $borrower->{'dateofbirth'} ) {
4098             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4099             $alloweddate[0] += $restriction_year;
4100
4101             #Prevent runime eror on leap year (invalid date)
4102             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4103                 $alloweddate[2] = 28;
4104             }
4105
4106             #Get how many days the borrower has to reach the age restriction
4107             my @Today = split /-/, DateTime->today->ymd();
4108             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4109             #Negative days means the borrower went past the age restriction age
4110             return ($restriction_year, $daysToAgeRestriction);
4111         }
4112     }
4113
4114     return ($restriction_year);
4115 }
4116
4117
4118 =head2 GetPendingOnSiteCheckouts
4119
4120 =cut
4121
4122 sub GetPendingOnSiteCheckouts {
4123     my $dbh = C4::Context->dbh;
4124     return $dbh->selectall_arrayref(q|
4125         SELECT
4126           items.barcode,
4127           items.biblionumber,
4128           items.itemnumber,
4129           items.itemnotes,
4130           items.itemcallnumber,
4131           items.location,
4132           issues.date_due,
4133           issues.branchcode,
4134           issues.date_due < NOW() AS is_overdue,
4135           biblio.author,
4136           biblio.title,
4137           borrowers.firstname,
4138           borrowers.surname,
4139           borrowers.cardnumber,
4140           borrowers.borrowernumber
4141         FROM items
4142         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4143         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4144         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4145         WHERE issues.onsite_checkout = 1
4146     |, { Slice => {} } );
4147 }
4148
4149 sub GetTopIssues {
4150     my ($params) = @_;
4151
4152     my ($count, $branch, $itemtype, $ccode, $newness)
4153         = @$params{qw(count branch itemtype ccode newness)};
4154
4155     my $dbh = C4::Context->dbh;
4156     my $query = q{
4157         SELECT * FROM (
4158         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4159           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4160           i.ccode, SUM(i.issues) AS count
4161         FROM biblio b
4162         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4163         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4164     };
4165
4166     my (@where_strs, @where_args);
4167
4168     if ($branch) {
4169         push @where_strs, 'i.homebranch = ?';
4170         push @where_args, $branch;
4171     }
4172     if ($itemtype) {
4173         if (C4::Context->preference('item-level_itypes')){
4174             push @where_strs, 'i.itype = ?';
4175             push @where_args, $itemtype;
4176         } else {
4177             push @where_strs, 'bi.itemtype = ?';
4178             push @where_args, $itemtype;
4179         }
4180     }
4181     if ($ccode) {
4182         push @where_strs, 'i.ccode = ?';
4183         push @where_args, $ccode;
4184     }
4185     if ($newness) {
4186         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4187         push @where_args, $newness;
4188     }
4189
4190     if (@where_strs) {
4191         $query .= 'WHERE ' . join(' AND ', @where_strs);
4192     }
4193
4194     $query .= q{
4195         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4196           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4197           i.ccode
4198         ORDER BY count DESC
4199     };
4200
4201     $query .= q{ ) xxx WHERE count > 0 };
4202     $count = int($count);
4203     if ($count > 0) {
4204         $query .= "LIMIT $count";
4205     }
4206
4207     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4208
4209     return @$rows;
4210 }
4211
4212 sub _CalculateAndUpdateFine {
4213     my ($params) = @_;
4214
4215     my $borrower    = $params->{borrower};
4216     my $item        = $params->{item};
4217     my $issue       = $params->{issue};
4218     my $return_date = $params->{return_date};
4219
4220     unless ($borrower) { carp "No borrower passed in!" && return; }
4221     unless ($item)     { carp "No item passed in!"     && return; }
4222     unless ($issue)    { carp "No issue passed in!"    && return; }
4223
4224     my $datedue = dt_from_string( $issue->date_due );
4225
4226     # we only need to calculate and change the fines if we want to do that on return
4227     # Should be on for hourly loans
4228     my $control = C4::Context->preference('CircControl');
4229     my $control_branchcode =
4230         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4231       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4232       :                                     $issue->branchcode;
4233
4234     my $date_returned = $return_date ? $return_date : dt_from_string();
4235
4236     my ( $amount, $unitcounttotal, $unitcount  ) =
4237       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4238
4239     if ( C4::Context->preference('finesMode') eq 'production' ) {
4240         if ( $amount > 0 ) {
4241             C4::Overdues::UpdateFine({
4242                 issue_id       => $issue->issue_id,
4243                 itemnumber     => $issue->itemnumber,
4244                 borrowernumber => $issue->borrowernumber,
4245                 amount         => $amount,
4246                 due            => output_pref($datedue),
4247             });
4248         }
4249         elsif ($return_date) {
4250
4251             # Backdated returns may have fines that shouldn't exist,
4252             # so in this case, we need to drop those fines to 0
4253
4254             C4::Overdues::UpdateFine({
4255                 issue_id       => $issue->issue_id,
4256                 itemnumber     => $issue->itemnumber,
4257                 borrowernumber => $issue->borrowernumber,
4258                 amount         => 0,
4259                 due            => output_pref($datedue),
4260             });
4261         }
4262     }
4263 }
4264
4265 sub _item_denied_renewal {
4266     my ($params) = @_;
4267
4268     my $item = $params->{item};
4269     return unless $item;
4270
4271     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4272     return unless $denyingrules;
4273     foreach my $field (keys %$denyingrules) {
4274         my $val = $item->$field;
4275         if( !defined $val) {
4276             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4277                 return 1;
4278             }
4279         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4280            # If the results matches the values in the syspref
4281            # We return true if match found
4282             return 1;
4283         }
4284     }
4285     return 0;
4286 }
4287
4288
4289 1;
4290
4291 __END__
4292
4293 =head1 AUTHOR
4294
4295 Koha Development Team <http://koha-community.org/>
4296
4297 =cut