C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::Patrons;
  32 use Koha::AuthUtils qw(hash_password);
  33 use List::MoreUtils qw( any );
  34 use Net::LDAP;
  35 use Net::LDAP::Filter;
  36
  37 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  38
  39 BEGIN {
  40         require Exporter;
  41         @ISA    = qw(Exporter);
  42         @EXPORT = qw( checkpw_ldap );
  43 }
  44
  45 # Redefine checkpw_ldap:
  46 # connect to LDAP (named or anonymous)
  47 # ~ retrieves $userid from KOHA_CONF mapping
  48 # ~ then compares $password with userPassword
  49 # ~ then gets the LDAP entry
  50 # ~ and calls the memberadd if necessary
  51
  52 sub ldapserver_error {
  53         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  54 }
  55
  56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  57 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  59 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  60 my $base      = $ldap->{base}           or die ldapserver_error('base');
  61 $ldapname     = $ldap->{user}           ;
  62 $ldappassword = $ldap->{pass}           ;
  63 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  64 my @mapkeys = keys %mapping;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  66 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  67 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  68
  69 my %categorycode_conversions;
  70 my $default_categorycode;
  71 if(defined $ldap->{categorycode_mapping}) {
  72     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  73     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  74         $categorycode_conversions{$cat->{value}} = $cat->{content};
  75     }
  76 }
  77
  78 my %config = (
  79         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  80     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  81        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  82 );
  83
  84 sub description {
  85         my $result = shift or return;
  86         return "LDAP error #" . $result->code
  87                         . ": " . $result->error_name . "\n"
  88                         . "# " . $result->error_text . "\n";
  89 }
  90
  91 sub search_method {
  92     my $db     = shift or return;
  93     my $userid = shift or return;
  94         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  95         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  96         my $search = $db->search(
  97                   base => $base,
  98                 filter => $filter,
  99                 # attrs => ['*'],
 100     );
 101     die "LDAP search failed to return object : " . $search->error if $search->code;
 102
 103         my $count = $search->count;
 104         if ($search->code > 0) {
 105                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 106                 return 0;
 107         }
 108         if ($count != 1) {
 109                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 110                 return 0;
 111         }
 112     return $search;
 113 }
 114
 115 sub checkpw_ldap {
 116     my ($dbh, $userid, $password) = @_;
 117     my @hosts = split(',', $prefhost);
 118     my $db = Net::LDAP->new(\@hosts);
 119     unless ( $db ) {
 120         warn "LDAP connexion failed";
 121         return 0;
 122     }
 123
 124         #$debug and $db->debug(5);
 125     my $userldapentry;
 126
 127     # first, LDAP authentication
 128     if ( $ldap->{auth_by_bind} ) {
 129         my $principal_name;
 130         if ( $ldap->{anonymous_bind} ) {
 131
 132             # Perform an anonymous bind
 133             my $res = $db->bind;
 134             if ( $res->code ) {
 135                 warn "Anonymous LDAP bind failed: " . description($res);
 136                 return 0;
 137             }
 138
 139             # Perform a LDAP search for the given username
 140             my $search = search_method( $db, $userid )
 141               or return 0;    # warnings are in the sub
 142             $userldapentry = $search->shift_entry;
 143             $principal_name = $userldapentry->dn;
 144         }
 145         else {
 146             $principal_name = $ldap->{principal_name};
 147             if ( $principal_name and $principal_name =~ /\%/ ) {
 148                 $principal_name = sprintf( $principal_name, $userid );
 149             }
 150             else {
 151                 $principal_name = $userid;
 152             }
 153         }
 154
 155         # Perform a LDAP bind for the given username using the matched DN
 156         my $res = $db->bind( $principal_name, password => $password );
 157         if ( $res->code ) {
 158             if ( $ldap->{anonymous_bind} ) {
 159                 # With anonymous_bind approach we can be sure we have found the correct user
 160                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 161                 # or password changed). We should not fall back to local accounts in this case.
 162                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 163                 return -1;
 164             } else {
 165                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 166                 # at all, and thus we should fall back to local logins to restore previous behaviour
 167                 # see bug 12831
 168                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 169                 return 0;
 170             }
 171         }
 172         if ( !defined($userldapentry)
 173             && ( $config{update} or $config{replicate} ) )
 174         {
 175             my $search = search_method( $db, $userid ) or return 0;
 176             $userldapentry = $search->shift_entry;
 177         }
 178     } else {
 179                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 180                 if ($res->code) {               # connection refused
 181                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 182                         return 0;
 183                 }
 184         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 185         $userldapentry = $search->shift_entry;
 186         my $dn = $userldapentry->dn;
 187         my $user_ldap_bind_ret = $db->bind($dn, password => $password);
 188         if ($user_ldap_bind_ret->code) {
 189             warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($user_ldap_bind_ret);
 190             return -1;
 191         }
 192         }
 193
 194     # To get here, LDAP has accepted our user's login attempt.
 195     # But we still have work to do.  See perldoc below for detailed breakdown.
 196
 197     my (%borrower);
 198         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 199
 200     if (( $borrowernumber and $config{update}   ) or
 201         (!$borrowernumber and $config{replicate})   ) {
 202         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 203         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 204     }
 205
 206     if ($borrowernumber) {
 207         if ($config{update}) { # A1, B1
 208             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 209             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 210         } else { # C1, D1
 211             # maybe update just the password?
 212                 return(1, $cardnumber, $local_userid);
 213         }
 214     } elsif ($config{replicate}) { # A2, C2
 215         $borrowernumber = C4::Members::AddMember(%borrower) or die "AddMember failed";
 216         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 217    } else {
 218         return 0;   # B2, D2
 219     }
 220     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 221         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 222             my $code = $attribute_type->{code};
 223             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 224                 next;
 225             }
 226             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 227                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, attribute => $borrower{$code}});
 228             } else {
 229                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 230             }
 231         }
 232     }
 233     return(1, $cardnumber, $userid);
 234 }
 235
 236 # Pass LDAP entry object and local cardnumber (userid).
 237 # Returns borrower hash.
 238 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 239 # Ensure that mandatory fields are correctly filled!
 240 #
 241 sub ldap_entry_2_hash {
 242         my $userldapentry = shift;
 243         my %borrower = ( cardnumber => shift );
 244         my %memberhash;
 245         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 246         if ($debug) {
 247                 foreach (keys %$userldapentry) {
 248                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 249                 }
 250         }
 251         my $x = $userldapentry->{attrs} or return;
 252         foreach (keys %$x) {
 253                 $memberhash{$_} = join ' ', @{$x->{$_}};
 254                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 255         }
 256         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 257                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 258         foreach my $key (keys %mapping) {
 259                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 260                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 261                 unless (defined $data) {
 262                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 263                 }
 264                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 265         }
 266         $borrower{initials} = $memberhash{initials} ||
 267                 ( substr($borrower{'firstname'},0,1)
 268                 . substr($borrower{ 'surname' },0,1)
 269                 . " ");
 270
 271     # categorycode conversions
 272     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 273         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 274     }
 275     elsif($default_categorycode) {
 276         $borrower{categorycode} = $default_categorycode;
 277     }
 278
 279         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 280         my $dbh = C4::Context->dbh;
 281         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 282         $sth->execute( uc($borrower{'categorycode'}) );
 283         unless ( my $row = $sth->fetchrow_hashref ) {
 284                 my $default = $mapping{'categorycode'}->{content};
 285                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 286                 $borrower{'categorycode'} = $default
 287         }
 288
 289         return %borrower;
 290 }
 291
 292 sub exists_local {
 293         my $arg = shift;
 294         my $dbh = C4::Context->dbh;
 295         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 296
 297         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 298         $sth->execute($arg);
 299         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 300         ($sth->rows == 1) and return $sth->fetchrow;
 301
 302         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 303         $sth->execute($arg);
 304         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 305         ($sth->rows == 1) and return $sth->fetchrow;
 306         return 0;
 307 }
 308
 309 # This function performs a password update, given the userid, borrowerid,
 310 # and digested password. It will verify that things are correct and return the
 311 # borrowers cardnumber. The idea is that it is used to keep the local
 312 # passwords in sync with the LDAP passwords.
 313 #
 314 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 315 #
 316 # Note: if the LDAP config has the update_password tag set to a false value,
 317 # then this will not update the password, it will simply return the cardnumber.
 318 sub _do_changepassword {
 319     my ($userid, $borrowerid, $password) = @_;
 320
 321     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 322
 323         # We don't store the password in the database
 324         my $sth = C4::Context->dbh->prepare(
 325             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 326         $sth->execute($borrowerid);
 327         die "Unable to access borrowernumber "
 328             . "with userid=$userid, "
 329             . "borrowernumber=$borrowerid"
 330           if !$sth->rows;
 331         my ($cardnum) = $sth->fetchrow;
 332         $sth = C4::Context->dbh->prepare(
 333             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 334         $sth->execute($borrowerid);
 335         return $cardnum;
 336     }
 337     my $digest = hash_password($password);
 338
 339     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 340     Koha::Patrons->find($borrowerid)->update_password( $userid, $digest );
 341
 342     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 343     return $cardnum if $ok;
 344
 345     warn "Password mismatch after update to borrowernumber=$borrowerid";
 346     return;
 347 }
 348
 349 sub update_local {
 350     my $userid     = shift or croak "No userid";
 351     my $password   = shift or croak "No password";
 352     my $borrowerid = shift or croak "No borrowerid";
 353     my $borrower   = shift or croak "No borrower record";
 354
 355     my @keys = keys %$borrower;
 356     my $dbh = C4::Context->dbh;
 357     my $query = "UPDATE  borrowers\nSET     " .
 358         join(',', map {"$_=?"} @keys) .
 359         "\nWHERE   borrowernumber=? ";
 360     my $sth = $dbh->prepare($query);
 361     if ($debug) {
 362         print STDERR $query, "\n",
 363             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 364         print STDERR "\nuserid = $userid\n";
 365     }
 366     $sth->execute(
 367         ((map {$borrower->{$_}} @keys), $borrowerid)
 368     );
 369
 370     # MODIFY PASSWORD/LOGIN if password was mapped
 371     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 372 }
 373
 374 1;
 375 __END__
 376
 377 =head1 NAME
 378
 379 C4::Auth - Authenticates Koha users
 380
 381 =head1 SYNOPSIS
 382
 383   use C4::Auth_with_ldap;
 384
 385 =head1 LDAP Configuration
 386
 387     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 388         working LDAP servers.
 389         To use it :
 390            * Modify ldapserver element in KOHA_CONF
 391            * Establish field mapping in <mapping> element.
 392
 393         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 394         the username would match the "uid" field, and the password should match the "userpassword" field.
 395
 396         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 397         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 398
 399         mysql> show COLUMNS from borrowers;
 400                 +---------------------+--------------+------+-----+---------+----------------+
 401                 | Field               | Type         | Null | Key | Default | Extra          |
 402                 +---------------------+--------------+------+-----+---------+----------------+
 403                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 404                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 405                 | surname             | mediumtext   | NO   |     | NULL    |                |
 406                 | firstname           | text         | YES  |     | NULL    |                |
 407                 | title               | mediumtext   | YES  |     | NULL    |                |
 408                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 409                 | initials            | text         | YES  |     | NULL    |                |
 410                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 411                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 412                 | address             | mediumtext   | NO   |     | NULL    |                |
 413                 | address2            | text         | YES  |     | NULL    |                |
 414                 | city                | mediumtext   | NO   |     | NULL    |                |
 415                 | state               | mediumtext   | YES  |     | NULL    |                |
 416                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 417                 | country             | text         | YES  |     | NULL    |                |
 418                 | email               | mediumtext   | YES  |     | NULL    |                |
 419                 | phone               | text         | YES  |     | NULL    |                |
 420                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 421                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 422                 | emailpro            | text         | YES  |     | NULL    |                |
 423                 | phonepro            | text         | YES  |     | NULL    |                |
 424                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 425                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 426                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 427                 | B_address2          | text         | YES  |     | NULL    |                |
 428                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 429                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 430                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 431                 | B_country           | text         | YES  |     | NULL    |                |
 432                 | B_email             | text         | YES  |     | NULL    |                |
 433                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 434                 | dateofbirth         | date         | YES  |     | NULL    |                |
 435                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 436                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 437                 | dateenrolled        | date         | YES  |     | NULL    |                |
 438                 | dateexpiry          | date         | YES  |     | NULL    |                |
 439                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 440                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 441                 | debarred            | date         | YES  |     | NULL    |                |
 442                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 443                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 444                 | contactfirstname    | text         | YES  |     | NULL    |                |
 445                 | contacttitle        | text         | YES  |     | NULL    |                |
 446                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 447                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 448                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 449                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 450                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 451                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 452                 | password            | varchar(30)  | YES  |     | NULL    |                |
 453                 | flags               | int(11)      | YES  |     | NULL    |                |
 454                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 455                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 456                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 457                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 458                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 459                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 460                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 461                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 462                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 463                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 464                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 465                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 466                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 467                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 468                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 469                 | privacy             | int(11)      | NO   |     | 1       |                |
 470                 +---------------------+--------------+------+-----+---------+----------------+
 471                 66 rows in set (0.00 sec)
 472                 Where Null="NO", the field is required.
 473
 474 =head1 KOHA_CONF and field mapping
 475
 476 Example XML stanza for LDAP configuration in KOHA_CONF.
 477
 478  <config>
 479   ...
 480   <useldapserver>1</useldapserver>
 481   <!-- LDAP SERVER (optional) -->
 482   <ldapserver id="ldapserver">
 483     <hostname>localhost</hostname>
 484     <base>dc=metavore,dc=com</base>
 485     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 486     <pass>metavore</pass>          <!-- password, if not anonymous -->
 487     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 488     <update>1</update>             <!-- update existing users in Koha database -->
 489     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 490                                         password comparison, e.g., to use Active Directory -->
 491     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 492                                             an anonymous bind, even when auth_by_bind is on -->
 493     <principal_name>%s@my_domain.com</principal_name>
 494                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 495                                         Not used with anonymous_bind. -->
 496     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 497                                               synced to the local database -->
 498     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 499       <firstname    is="givenname"      ></firstname>
 500       <surname      is="sn"             ></surname>
 501       <address      is="postaladdress"  ></address>
 502       <city         is="l"              >Athens, OH</city>
 503       <zipcode      is="postalcode"     ></zipcode>
 504       <branchcode   is="branch"         >MAIN</branchcode>
 505       <userid       is="uid"            ></userid>
 506       <password     is="userpassword"   ></password>
 507       <email        is="mail"           ></email>
 508       <categorycode is="employeetype"   >PT</categorycode>
 509       <phone        is="telephonenumber"></phone>
 510     </mapping>
 511   </ldapserver>
 512  </config>
 513
 514 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 515 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 516 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 517 patron).
 518
 519 =head1 CONFIGURATION
 520
 521 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 522 your configuration and the presence of a matching Koha user in your local DB:
 523
 524                          LOCAL_USER
 525  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 526    A1      1       1        1      OK : We're updating them anyway.
 527    A2      1       1        0      OK : We're adding them anyway.
 528    B1      1       0        1      OK : We update them.
 529    B2      1       0        0     FAIL: We cannot add new user.
 530    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 531    C2      0       1        0      OK : We add the new user.
 532    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 533    D2      0       0        0     FAIL: We cannot add new user.
 534
 535 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 536 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 537 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 538
 539 If you choose NOT to update local users, the borrowers table will not be affected at all.
 540 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 541 the local table never contained the LDAP values.
 542
 543 =head2 auth_by_bind
 544
 545 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 546
 547 =head2 principal_name
 548
 549 Provides an optional sprintf-style format for manipulating the userid before the bind.
 550 Even though the userPrincipalName is one intended target, any uniquely identifying
 551 attribute that the server allows to be used for binding could be used.
 552
 553 Currently, principal_name only operates when auth_by_bind is enabled.
 554
 555 =head2 update_password
 556
 557 If this tag is left out or set to a true value, then the user's LDAP password
 558 will be stored (hashed) in the local Koha database. If you don't want this
 559 to happen, then set the value of this to '0'. Note that if passwords are not
 560 stored locally, and the connection to the LDAP system fails, then the users
 561 will not be able to log in at all.
 562
 563 =head2 Active Directory
 564
 565 The auth_by_bind and principal_name settings are recommended for Active Directory.
 566
 567 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 568 we would typically under openldap.  Instead of:
 569
 570     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 571
 572 We might get:
 573
 574     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 575
 576 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 577 in Koha userids.  But the userPrincipalName should be consistent, something like:
 578
 579     userPrincipalName: barnes.7@my_company.com
 580
 581 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 582 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 583 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 584 like this:
 585     <principal_name>%s@core.my_company.com</principal_name>
 586
 587 The user of the previous example, barnes.7, would then attempt to bind as:
 588     barnes.7@core.my_company.com
 589
 590 =head1 SEE ALSO
 591
 592 CGI(3)
 593
 594 Net::LDAP()
 595
 596 XML::Simple()
 597
 598 Digest::MD5(3)
 599
 600 sprintf()
 601
 602 =cut
 603
 604 # For reference, here's an important difference in the data structure we rely on.
 605 # ========================================
 606 # Using attrs instead of {asn}->attributes
 607 # ========================================
 608 #
 609 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 610 #       LDAP key: ->{             cn}->{           sss} = sss
 611 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 612 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 613 #
 614 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 615 #       LDAP key: ->{      givenname}->{Steve} = Steve
 616 #