C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Digest::MD5 qw(md5_base64);
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Utils qw( :all );
  30 use List::MoreUtils qw( any );
  31 use Net::LDAP;
  32 use Net::LDAP::Filter;
  33
  34 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  35
  36 BEGIN {
  37         require Exporter;
  38         $VERSION = 3.10;        # set the version for version checking
  39         @ISA    = qw(Exporter);
  40         @EXPORT = qw( checkpw_ldap );
  41 }
  42
  43 # Redefine checkpw_ldap:
  44 # connect to LDAP (named or anonymous)
  45 # ~ retrieves $userid from KOHA_CONF mapping
  46 # ~ then compares $password with userPassword
  47 # ~ then gets the LDAP entry
  48 # ~ and calls the memberadd if necessary
  49
  50 sub ldapserver_error ($) {
  51         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  52 }
  53
  54 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  55 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  56 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  57 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  58 my $base      = $ldap->{base}           or die ldapserver_error('base');
  59 $ldapname     = $ldap->{user}           ;
  60 $ldappassword = $ldap->{pass}           ;
  61 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  62 my @mapkeys = keys %mapping;
  63 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  64 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  66
  67 my %config = (
  68         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  69     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  70        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  71 );
  72
  73 sub description ($) {
  74         my $result = shift or return undef;
  75         return "LDAP error #" . $result->code
  76                         . ": " . $result->error_name . "\n"
  77                         . "# " . $result->error_text . "\n";
  78 }
  79
  80 sub search_method {
  81     my $db     = shift or return;
  82     my $userid = shift or return;
  83         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  84         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  85         my $search = $db->search(
  86                   base => $base,
  87                 filter => $filter,
  88                 # attrs => ['*'],
  89         ) or die "LDAP search failed to return object.";
  90         my $count = $search->count;
  91         if ($search->code > 0) {
  92                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  93                 return 0;
  94         }
  95         if ($count != 1) {
  96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
  97                 return 0;
  98         }
  99     return $search;
 100 }
 101
 102 sub checkpw_ldap {
 103     my ($dbh, $userid, $password) = @_;
 104     my @hosts = split(',', $prefhost);
 105     my $db = Net::LDAP->new(\@hosts);
 106         #$debug and $db->debug(5);
 107     my $userldapentry;
 108         if ( $ldap->{auth_by_bind} ) {
 109         my $principal_name = $ldap->{principal_name};
 110         if ($principal_name and $principal_name =~ /\%/) {
 111             $principal_name = sprintf($principal_name,$userid);
 112         } else {
 113             $principal_name = $userid;
 114         }
 115                 my $res = $db->bind( $principal_name, password => $password );
 116         if ( $res->code ) {
 117             $debug and warn "LDAP bind failed as kohauser $principal_name: ". description($res);
 118             return 0;
 119         }
 120
 121         # FIXME dpavlin -- we really need $userldapentry leater on even if using auth_by_bind!
 122
 123         # BUG #5094
 124         # 2010-08-04 JeremyC
 125         # a $userldapentry is only needed if either updating or replicating are enabled
 126         if($config{update} or $config{replicate}) {
 127             my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 128             $userldapentry = $search->shift_entry;
 129         }
 130
 131         } else {
 132                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 133                 if ($res->code) {               # connection refused
 134                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 135                         return 0;
 136                 }
 137         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 138         $userldapentry = $search->shift_entry;
 139                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 140                 if ($cmpmesg->code != 6) {
 141                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 142                         return 0;
 143                 }
 144         }
 145
 146     # To get here, LDAP has accepted our user's login attempt.
 147     # But we still have work to do.  See perldoc below for detailed breakdown.
 148
 149     my (%borrower);
 150         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 151
 152     if (( $borrowernumber and $config{update}   ) or
 153         (!$borrowernumber and $config{replicate})   ) {
 154         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 155         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 156     }
 157
 158     if ($borrowernumber) {
 159         if ($config{update}) { # A1, B1
 160             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 161             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 162         } else { # C1, D1
 163             # maybe update just the password?
 164                 return(1, $cardnumber); # FIXME dpavlin -- don't destroy ExtendedPatronAttributes
 165         }
 166     } elsif ($config{replicate}) { # A2, C2
 167         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 168    } else {
 169         return 0;   # B2, D2
 170     }
 171         if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 172                 my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 173                 my @attributes = grep{my $key=$_; any{$_ eq $key}@types;} keys %borrower;
 174                 my $extended_patron_attributes = map{{code=>$_,value=>$borrower{$_}}}@attributes;
 175                 my $extended_patron_attributes = [] unless $extended_patron_attributes;
 176                 my @errors;
 177                 #Check before add
 178                 for (my $i; $i< scalar(@$extended_patron_attributes)-1;$i++) {
 179                         my $attr=$extended_patron_attributes->[$i];
 180                         unless (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 181                                 unshift @errors, $i;
 182                                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 183                         }
 184                 }
 185                 #Removing erroneous attributes
 186                 foreach my $index (@errors){
 187                         @$extended_patron_attributes=splice(@$extended_patron_attributes,$index,1);
 188                 }
 189            C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, $extended_patron_attributes);
 190         }
 191 return(1, $cardnumber);
 192 }
 193
 194 # Pass LDAP entry object and local cardnumber (userid).
 195 # Returns borrower hash.
 196 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 197 # Ensure that mandatory fields are correctly filled!
 198 #
 199 sub ldap_entry_2_hash ($$) {
 200         my $userldapentry = shift;
 201         my %borrower = ( cardnumber => shift );
 202         my %memberhash;
 203         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 204         if ($debug) {
 205                 print STDERR "\nkeys(\%\$userldapentry) = " . join(', ', keys %$userldapentry), "\n", $userldapentry->dump();
 206                 foreach (keys %$userldapentry) {
 207                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 208                         hashdump("LDAP key: ",$userldapentry->{$_});
 209                 }
 210         }
 211         my $x = $userldapentry->{attrs} or return undef;
 212         foreach (keys %$x) {
 213                 $memberhash{$_} = join ' ', @{$x->{$_}};
 214                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 215         }
 216         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 217                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 218         foreach my $key (keys %mapping) {
 219                 my  $data = $memberhash{$mapping{$key}->{is}};
 220                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 221                 unless (defined $data) {
 222                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 223                 }
 224                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 225         }
 226         $borrower{initials} = $memberhash{initials} ||
 227                 ( substr($borrower{'firstname'},0,1)
 228                 . substr($borrower{ 'surname' },0,1)
 229                 . " ");
 230         return %borrower;
 231 }
 232
 233 sub exists_local($) {
 234         my $arg = shift;
 235         my $dbh = C4::Context->dbh;
 236         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 237
 238         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 239         $sth->execute($arg);
 240         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 241         ($sth->rows == 1) and return $sth->fetchrow;
 242
 243         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 244         $sth->execute($arg);
 245         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 246         ($sth->rows == 1) and return $sth->fetchrow;
 247         return 0;
 248 }
 249
 250 sub _do_changepassword {
 251     my ($userid, $borrowerid, $digest) = @_;
 252     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 253     changepassword($userid, $borrowerid, $digest);
 254
 255         # Confirm changes
 256         my $sth = C4::Context->dbh->prepare("SELECT password,cardnumber FROM borrowers WHERE borrowernumber=? ");
 257         $sth->execute($borrowerid);
 258         if ($sth->rows) {
 259                 my ($md5password, $cardnum) = $sth->fetchrow;
 260         ($digest eq $md5password) and return $cardnum;
 261                 warn "Password mismatch after update to cardnumber=$cardnum (borrowernumber=$borrowerid)";
 262                 return undef;
 263         }
 264         die "Unexpected error after password update to userid/borrowernumber: $userid / $borrowerid.";
 265 }
 266
 267 sub update_local($$$$) {
 268         my   $userid   = shift             or return undef;
 269         my   $digest   = md5_base64(shift) or return undef;
 270         my $borrowerid = shift             or return undef;
 271         my $borrower   = shift             or return undef;
 272         my @keys = keys %$borrower;
 273         my $dbh = C4::Context->dbh;
 274         my $query = "UPDATE  borrowers\nSET     " .
 275                 join(',', map {"$_=?"} @keys) .
 276                 "\nWHERE   borrowernumber=? ";
 277         my $sth = $dbh->prepare($query);
 278         if ($debug) {
 279                 print STDERR $query, "\n",
 280                         join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 281                 print STDERR "\nuserid = $userid\n";
 282         }
 283         $sth->execute(
 284                 ((map {$borrower->{$_}} @keys), $borrowerid)
 285         );
 286
 287         # MODIFY PASSWORD/LOGIN
 288         _do_changepassword($userid, $borrowerid, $digest);
 289 }
 290
 291 1;
 292 __END__
 293
 294 =head1 NAME
 295
 296 C4::Auth - Authenticates Koha users
 297
 298 =head1 SYNOPSIS
 299
 300   use C4::Auth_with_ldap;
 301
 302 =head1 LDAP Configuration
 303
 304     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 305         working LDAP servers.
 306         To use it :
 307            * Modify ldapserver element in KOHA_CONF
 308            * Establish field mapping in <mapping> element.
 309
 310         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 311         the username would match the "uid" field, and the password should match the "userpassword" field.
 312
 313         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 314         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 315
 316         mysql> show COLUMNS from borrowers;
 317                 +---------------------+--------------+------+-----+---------+----------------+
 318                 | Field               | Type         | Null | Key | Default | Extra          |
 319                 +---------------------+--------------+------+-----+---------+----------------+
 320                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 321                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 322                 | surname             | mediumtext   | NO   |     | NULL    |                |
 323                 | firstname           | text         | YES  |     | NULL    |                |
 324                 | title               | mediumtext   | YES  |     | NULL    |                |
 325                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 326                 | initials            | text         | YES  |     | NULL    |                |
 327                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 328                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 329                 | address             | mediumtext   | NO   |     | NULL    |                |
 330                 | address2            | text         | YES  |     | NULL    |                |
 331                 | city                | mediumtext   | NO   |     | NULL    |                |
 332                 | state               | mediumtext   | YES  |     | NULL    |                |
 333                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 334                 | country             | text         | YES  |     | NULL    |                |
 335                 | email               | mediumtext   | YES  |     | NULL    |                |
 336                 | phone               | text         | YES  |     | NULL    |                |
 337                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 338                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 339                 | emailpro            | text         | YES  |     | NULL    |                |
 340                 | phonepro            | text         | YES  |     | NULL    |                |
 341                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 342                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 343                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 344                 | B_address2          | text         | YES  |     | NULL    |                |
 345                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 346                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 347                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 348                 | B_country           | text         | YES  |     | NULL    |                |
 349                 | B_email             | text         | YES  |     | NULL    |                |
 350                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 351                 | dateofbirth         | date         | YES  |     | NULL    |                |
 352                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 353                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 354                 | dateenrolled        | date         | YES  |     | NULL    |                |
 355                 | dateexpiry          | date         | YES  |     | NULL    |                |
 356                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 357                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 358                 | debarred            | tinyint(1)   | YES  |     | NULL    |                |
 359                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 360                 | contactfirstname    | text         | YES  |     | NULL    |                |
 361                 | contacttitle        | text         | YES  |     | NULL    |                |
 362                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 363                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 364                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 365                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 366                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 367                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 368                 | password            | varchar(30)  | YES  |     | NULL    |                |
 369                 | flags               | int(11)      | YES  |     | NULL    |                |
 370                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 371                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 372                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 373                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 374                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 375                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 376                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 377                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 378                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 379                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 380                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 381                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 382                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 383                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 384                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 385                 | privacy             | int(11)      | NO   |     | 1       |                |
 386                 +---------------------+--------------+------+-----+---------+----------------+
 387                 66 rows in set (0.00 sec)
 388                 Where Null="NO", the field is required.
 389
 390 =head1 KOHA_CONF and field mapping
 391
 392 Example XML stanza for LDAP configuration in KOHA_CONF.
 393
 394  <config>
 395   ...
 396   <useldapserver>1</useldapserver>
 397   <!-- LDAP SERVER (optional) -->
 398   <ldapserver id="ldapserver">
 399     <hostname>localhost</hostname>
 400     <base>dc=metavore,dc=com</base>
 401     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 402     <pass>metavore</pass>          <!-- password, if not anonymous -->
 403     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 404     <update>1</update>             <!-- update existing users in Koha database -->
 405     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 406                                         password comparison, e.g., to use Active Directory -->
 407     <principal_name>%s@my_domain.com</principal_name>
 408                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid -->
 409     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 410       <firstname    is="givenname"      ></firstname>
 411       <surname      is="sn"             ></surname>
 412       <address      is="postaladdress"  ></address>
 413       <city         is="l"              >Athens, OH</city>
 414       <zipcode      is="postalcode"     ></zipcode>
 415       <branchcode   is="branch"         >MAIN</branchcode>
 416       <userid       is="uid"            ></userid>
 417       <password     is="userpassword"   ></password>
 418       <email        is="mail"           ></email>
 419       <categorycode is="employeetype"   >PT</categorycode>
 420       <phone        is="telephonenumber"></phone>
 421     </mapping>
 422   </ldapserver>
 423  </config>
 424
 425 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 426 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 427 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 428 patron).
 429
 430 =head1 CONFIGURATION
 431
 432 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 433 your configuration and the presence of a matching Koha user in your local DB:
 434
 435                          LOCAL_USER
 436  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 437    A1      1       1        1      OK : We're updating them anyway.
 438    A2      1       1        0      OK : We're adding them anyway.
 439    B1      1       0        1      OK : We update them.
 440    B2      1       0        0     FAIL: We cannot add new user.
 441    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 442    C2      0       1        0      OK : We add the new user.
 443    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 444    D2      0       0        0     FAIL: We cannot add new user.
 445
 446 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 447 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 448 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 449
 450 If you choose NOT to update local users, the borrowers table will not be affected at all.
 451 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 452 the local table never contained the LDAP values.
 453
 454 =head2 auth_by_bind
 455
 456 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 457
 458 =head2 principal_name
 459
 460 Provides an optional sprintf-style format for manipulating the userid before the bind.
 461 Even though the userPrincipalName is one intended target, any uniquely identifying
 462 attribute that the server allows to be used for binding could be used.
 463
 464 Currently, principal_name only operates when auth_by_bind is enabled.
 465
 466 =head2 Active Directory
 467
 468 The auth_by_bind and principal_name settings are recommended for Active Directory.
 469
 470 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 471 we would typically under openldap.  Instead of:
 472
 473     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 474
 475 We might get:
 476
 477     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 478
 479 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 480 in Koha userids.  But the userPrincipalName should be consistent, something like:
 481
 482     userPrincipalName: barnes.7@my_company.com
 483
 484 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 485 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 486 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 487 like this:
 488     <principal_name>%s@core.my_company.com</principal_name>
 489
 490 The user of the previous example, barnes.7, would then attempt to bind as:
 491     barnes.7@core.my_company.com
 492
 493 =head1 SEE ALSO
 494
 495 CGI(3)
 496
 497 Net::LDAP()
 498
 499 XML::Simple()
 500
 501 Digest::MD5(3)
 502
 503 sprintf()
 504
 505 =cut
 506
 507 # For reference, here's an important difference in the data structure we rely on.
 508 # ========================================
 509 # Using attrs instead of {asn}->attributes
 510 # ========================================
 511 #
 512 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 513 #       LDAP key: ->{             cn}->{           sss} = sss
 514 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 515 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 516 #
 517 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 518 #       LDAP key: ->{      givenname}->{Steve} = Steve
 519 #