C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40     $VERSION = 3.07.00.049;     # set the version for version checking
  41         @ISA    = qw(Exporter);
  42         @EXPORT = qw( checkpw_ldap );
  43 }
  44
  45 # Redefine checkpw_ldap:
  46 # connect to LDAP (named or anonymous)
  47 # ~ retrieves $userid from KOHA_CONF mapping
  48 # ~ then compares $password with userPassword
  49 # ~ then gets the LDAP entry
  50 # ~ and calls the memberadd if necessary
  51
  52 sub ldapserver_error {
  53         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  54 }
  55
  56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  57 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  59 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  60 my $base      = $ldap->{base}           or die ldapserver_error('base');
  61 $ldapname     = $ldap->{user}           ;
  62 $ldappassword = $ldap->{pass}           ;
  63 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  64 my @mapkeys = keys %mapping;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  66 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  67 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  68
  69 my %config = (
  70         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  71     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  72        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  73 );
  74
  75 sub description {
  76         my $result = shift or return;
  77         return "LDAP error #" . $result->code
  78                         . ": " . $result->error_name . "\n"
  79                         . "# " . $result->error_text . "\n";
  80 }
  81
  82 sub search_method {
  83     my $db     = shift or return;
  84     my $userid = shift or return;
  85         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  86         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  87         my $search = $db->search(
  88                   base => $base,
  89                 filter => $filter,
  90                 # attrs => ['*'],
  91     );
  92     die "LDAP search failed to return object : " . $search->error if $search->code;
  93
  94         my $count = $search->count;
  95         if ($search->code > 0) {
  96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  97                 return 0;
  98         }
  99         if ($count != 1) {
 100                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 101                 return 0;
 102         }
 103     return $search;
 104 }
 105
 106 sub checkpw_ldap {
 107     my ($dbh, $userid, $password) = @_;
 108     my @hosts = split(',', $prefhost);
 109     my $db = Net::LDAP->new(\@hosts);
 110     unless ( $db ) {
 111         warn "LDAP connexion failed";
 112         return 0;
 113     }
 114
 115         #$debug and $db->debug(5);
 116     my $userldapentry;
 117
 118     if ( $ldap->{auth_by_bind} ) {
 119         my $principal_name;
 120         if ( $ldap->{anonymous_bind} ) {
 121
 122             # Perform an anonymous bind
 123             my $res = $db->bind;
 124             if ( $res->code ) {
 125                 warn "Anonymous LDAP bind failed: " . description($res);
 126                 return 0;
 127             }
 128
 129             # Perform a LDAP search for the given username
 130             my $search = search_method( $db, $userid )
 131               or return 0;    # warnings are in the sub
 132             $userldapentry = $search->shift_entry;
 133             $principal_name = $userldapentry->dn;
 134         }
 135         else {
 136             $principal_name = $ldap->{principal_name};
 137             if ( $principal_name and $principal_name =~ /\%/ ) {
 138                 $principal_name = sprintf( $principal_name, $userid );
 139             }
 140             else {
 141                 $principal_name = $userid;
 142             }
 143         }
 144
 145         # Perform a LDAP bind for the given username using the matched DN
 146         my $res = $db->bind( $principal_name, password => $password );
 147         if ( $res->code ) {
 148             if ( $ldap->{anonymous_bind} ) {
 149                 # With anonymous_bind approach we can be sure we have found the correct user
 150                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 151                 # or password changed). We should not fall back to local accounts in this case.
 152                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 153                 return -1;
 154             } else {
 155                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 156                 # at all, and thus we should fall back to local logins to restore previous behaviour
 157                 # see bug 12831
 158                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 159                 return 0;
 160             }
 161         }
 162         if ( !defined($userldapentry)
 163             && ( $config{update} or $config{replicate} ) )
 164         {
 165             my $search = search_method( $db, $userid ) or return 0;
 166             $userldapentry = $search->shift_entry;
 167         }
 168     } else {
 169                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 170                 if ($res->code) {               # connection refused
 171                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 172                         return 0;
 173                 }
 174         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 175         $userldapentry = $search->shift_entry;
 176                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 177                 if ($cmpmesg->code != 6) {
 178                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 179                         return -1;
 180                 }
 181         }
 182
 183     # To get here, LDAP has accepted our user's login attempt.
 184     # But we still have work to do.  See perldoc below for detailed breakdown.
 185
 186     my (%borrower);
 187         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 188
 189     if (( $borrowernumber and $config{update}   ) or
 190         (!$borrowernumber and $config{replicate})   ) {
 191         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 192         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 193     }
 194
 195     if ($borrowernumber) {
 196         if ($config{update}) { # A1, B1
 197             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 198             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 199         } else { # C1, D1
 200             # maybe update just the password?
 201                 return(1, $cardnumber, $local_userid);
 202         }
 203     } elsif ($config{replicate}) { # A2, C2
 204         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 205         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 206    } else {
 207         return 0;   # B2, D2
 208     }
 209     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 210         my @extended_patron_attributes;
 211         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 212             my $code = $attribute_type->{code};
 213             if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
 214                 push @extended_patron_attributes, { code => $code, value => $borrower{$code} };
 215             }
 216         }
 217         #Check before add
 218         my @unique_attr;
 219         foreach my $attr ( @extended_patron_attributes ) {
 220             if (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 221                 push @unique_attr, $attr;
 222             } else {
 223                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 224             }
 225         }
 226         C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, \@unique_attr);
 227     }
 228 return(1, $cardnumber, $userid);
 229 }
 230
 231 # Pass LDAP entry object and local cardnumber (userid).
 232 # Returns borrower hash.
 233 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 234 # Ensure that mandatory fields are correctly filled!
 235 #
 236 sub ldap_entry_2_hash {
 237         my $userldapentry = shift;
 238         my %borrower = ( cardnumber => shift );
 239         my %memberhash;
 240         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 241         if ($debug) {
 242                 foreach (keys %$userldapentry) {
 243                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 244                 }
 245         }
 246         my $x = $userldapentry->{attrs} or return;
 247         foreach (keys %$x) {
 248                 $memberhash{$_} = join ' ', @{$x->{$_}};
 249                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 250         }
 251         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 252                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 253         foreach my $key (keys %mapping) {
 254                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 255                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 256                 unless (defined $data) {
 257                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 258                 }
 259                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 260         }
 261         $borrower{initials} = $memberhash{initials} ||
 262                 ( substr($borrower{'firstname'},0,1)
 263                 . substr($borrower{ 'surname' },0,1)
 264                 . " ");
 265
 266         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 267         my $dbh = C4::Context->dbh;
 268         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 269         $sth->execute( uc($borrower{'categorycode'}) );
 270         unless ( my $row = $sth->fetchrow_hashref ) {
 271                 my $default = $mapping{'categorycode'}->{content};
 272                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 273                 $borrower{'categorycode'} = $default
 274         }
 275
 276         return %borrower;
 277 }
 278
 279 sub exists_local {
 280         my $arg = shift;
 281         my $dbh = C4::Context->dbh;
 282         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 283
 284         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 285         $sth->execute($arg);
 286         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 287         ($sth->rows == 1) and return $sth->fetchrow;
 288
 289         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 290         $sth->execute($arg);
 291         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 292         ($sth->rows == 1) and return $sth->fetchrow;
 293         return 0;
 294 }
 295
 296 # This function performs a password update, given the userid, borrowerid,
 297 # and digested password. It will verify that things are correct and return the
 298 # borrowers cardnumber. The idea is that it is used to keep the local
 299 # passwords in sync with the LDAP passwords.
 300 #
 301 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 302 #
 303 # Note: if the LDAP config has the update_password tag set to a false value,
 304 # then this will not update the password, it will simply return the cardnumber.
 305 sub _do_changepassword {
 306     my ($userid, $borrowerid, $password) = @_;
 307
 308     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 309
 310         # We don't store the password in the database
 311         my $sth = C4::Context->dbh->prepare(
 312             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 313         $sth->execute($borrowerid);
 314         die
 315 "Unable to access borrowernumber with userid=$userid, borrowernumber=$borrowerid"
 316           if !$sth->rows;
 317         my ($cardnum) = $sth->fetchrow;
 318         return $cardnum;
 319     }
 320     my $digest = hash_password($password);
 321
 322     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 323     changepassword($userid, $borrowerid, $digest);
 324
 325     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 326     return $cardnum if $ok;
 327
 328     warn "Password mismatch after update to borrowernumber=$borrowerid";
 329     return;
 330 }
 331
 332 sub update_local {
 333     my $userid     = shift or croak "No userid";
 334     my $password   = shift or croak "No password";
 335     my $borrowerid = shift or croak "No borrowerid";
 336     my $borrower   = shift or croak "No borrower record";
 337
 338     my @keys = keys %$borrower;
 339     my $dbh = C4::Context->dbh;
 340     my $query = "UPDATE  borrowers\nSET     " .
 341         join(',', map {"$_=?"} @keys) .
 342         "\nWHERE   borrowernumber=? ";
 343     my $sth = $dbh->prepare($query);
 344     if ($debug) {
 345         print STDERR $query, "\n",
 346             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 347         print STDERR "\nuserid = $userid\n";
 348     }
 349     $sth->execute(
 350         ((map {$borrower->{$_}} @keys), $borrowerid)
 351     );
 352
 353     # MODIFY PASSWORD/LOGIN if password was mapped
 354     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 355 }
 356
 357 1;
 358 __END__
 359
 360 =head1 NAME
 361
 362 C4::Auth - Authenticates Koha users
 363
 364 =head1 SYNOPSIS
 365
 366   use C4::Auth_with_ldap;
 367
 368 =head1 LDAP Configuration
 369
 370     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 371         working LDAP servers.
 372         To use it :
 373            * Modify ldapserver element in KOHA_CONF
 374            * Establish field mapping in <mapping> element.
 375
 376         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 377         the username would match the "uid" field, and the password should match the "userpassword" field.
 378
 379         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 380         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 381
 382         mysql> show COLUMNS from borrowers;
 383                 +---------------------+--------------+------+-----+---------+----------------+
 384                 | Field               | Type         | Null | Key | Default | Extra          |
 385                 +---------------------+--------------+------+-----+---------+----------------+
 386                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 387                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 388                 | surname             | mediumtext   | NO   |     | NULL    |                |
 389                 | firstname           | text         | YES  |     | NULL    |                |
 390                 | title               | mediumtext   | YES  |     | NULL    |                |
 391                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 392                 | initials            | text         | YES  |     | NULL    |                |
 393                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 394                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 395                 | address             | mediumtext   | NO   |     | NULL    |                |
 396                 | address2            | text         | YES  |     | NULL    |                |
 397                 | city                | mediumtext   | NO   |     | NULL    |                |
 398                 | state               | mediumtext   | YES  |     | NULL    |                |
 399                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 400                 | country             | text         | YES  |     | NULL    |                |
 401                 | email               | mediumtext   | YES  |     | NULL    |                |
 402                 | phone               | text         | YES  |     | NULL    |                |
 403                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 404                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 405                 | emailpro            | text         | YES  |     | NULL    |                |
 406                 | phonepro            | text         | YES  |     | NULL    |                |
 407                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 408                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 409                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 410                 | B_address2          | text         | YES  |     | NULL    |                |
 411                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 412                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 413                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 414                 | B_country           | text         | YES  |     | NULL    |                |
 415                 | B_email             | text         | YES  |     | NULL    |                |
 416                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 417                 | dateofbirth         | date         | YES  |     | NULL    |                |
 418                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 419                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 420                 | dateenrolled        | date         | YES  |     | NULL    |                |
 421                 | dateexpiry          | date         | YES  |     | NULL    |                |
 422                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 423                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 424                 | debarred            | date         | YES  |     | NULL    |                |
 425                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 426                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 427                 | contactfirstname    | text         | YES  |     | NULL    |                |
 428                 | contacttitle        | text         | YES  |     | NULL    |                |
 429                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 430                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 431                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 432                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 433                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 434                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 435                 | password            | varchar(30)  | YES  |     | NULL    |                |
 436                 | flags               | int(11)      | YES  |     | NULL    |                |
 437                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 438                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 439                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 440                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 441                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 442                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 443                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 444                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 445                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 446                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 447                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 448                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 449                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 450                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 451                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 452                 | privacy             | int(11)      | NO   |     | 1       |                |
 453                 +---------------------+--------------+------+-----+---------+----------------+
 454                 66 rows in set (0.00 sec)
 455                 Where Null="NO", the field is required.
 456
 457 =head1 KOHA_CONF and field mapping
 458
 459 Example XML stanza for LDAP configuration in KOHA_CONF.
 460
 461  <config>
 462   ...
 463   <useldapserver>1</useldapserver>
 464   <!-- LDAP SERVER (optional) -->
 465   <ldapserver id="ldapserver">
 466     <hostname>localhost</hostname>
 467     <base>dc=metavore,dc=com</base>
 468     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 469     <pass>metavore</pass>          <!-- password, if not anonymous -->
 470     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 471     <update>1</update>             <!-- update existing users in Koha database -->
 472     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 473                                         password comparison, e.g., to use Active Directory -->
 474     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 475                                             an anonymous bind, even when auth_by_bind is on -->
 476     <principal_name>%s@my_domain.com</principal_name>
 477                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 478                                         Not used with anonymous_bind. -->
 479     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 480                                               synced to the local database -->
 481     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 482       <firstname    is="givenname"      ></firstname>
 483       <surname      is="sn"             ></surname>
 484       <address      is="postaladdress"  ></address>
 485       <city         is="l"              >Athens, OH</city>
 486       <zipcode      is="postalcode"     ></zipcode>
 487       <branchcode   is="branch"         >MAIN</branchcode>
 488       <userid       is="uid"            ></userid>
 489       <password     is="userpassword"   ></password>
 490       <email        is="mail"           ></email>
 491       <categorycode is="employeetype"   >PT</categorycode>
 492       <phone        is="telephonenumber"></phone>
 493     </mapping>
 494   </ldapserver>
 495  </config>
 496
 497 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 498 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 499 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 500 patron).
 501
 502 =head1 CONFIGURATION
 503
 504 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 505 your configuration and the presence of a matching Koha user in your local DB:
 506
 507                          LOCAL_USER
 508  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 509    A1      1       1        1      OK : We're updating them anyway.
 510    A2      1       1        0      OK : We're adding them anyway.
 511    B1      1       0        1      OK : We update them.
 512    B2      1       0        0     FAIL: We cannot add new user.
 513    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 514    C2      0       1        0      OK : We add the new user.
 515    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 516    D2      0       0        0     FAIL: We cannot add new user.
 517
 518 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 519 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 520 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 521
 522 If you choose NOT to update local users, the borrowers table will not be affected at all.
 523 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 524 the local table never contained the LDAP values.
 525
 526 =head2 auth_by_bind
 527
 528 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 529
 530 =head2 principal_name
 531
 532 Provides an optional sprintf-style format for manipulating the userid before the bind.
 533 Even though the userPrincipalName is one intended target, any uniquely identifying
 534 attribute that the server allows to be used for binding could be used.
 535
 536 Currently, principal_name only operates when auth_by_bind is enabled.
 537
 538 =head2 update_password
 539
 540 If this tag is left out or set to a true value, then the user's LDAP password
 541 will be stored (hashed) in the local Koha database. If you don't want this
 542 to happen, then set the value of this to '0'. Note that if passwords are not
 543 stored locally, and the connection to the LDAP system fails, then the users
 544 will not be able to log in at all.
 545
 546 =head2 Active Directory
 547
 548 The auth_by_bind and principal_name settings are recommended for Active Directory.
 549
 550 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 551 we would typically under openldap.  Instead of:
 552
 553     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 554
 555 We might get:
 556
 557     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 558
 559 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 560 in Koha userids.  But the userPrincipalName should be consistent, something like:
 561
 562     userPrincipalName: barnes.7@my_company.com
 563
 564 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 565 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 566 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 567 like this:
 568     <principal_name>%s@core.my_company.com</principal_name>
 569
 570 The user of the previous example, barnes.7, would then attempt to bind as:
 571     barnes.7@core.my_company.com
 572
 573 =head1 SEE ALSO
 574
 575 CGI(3)
 576
 577 Net::LDAP()
 578
 579 XML::Simple()
 580
 581 Digest::MD5(3)
 582
 583 sprintf()
 584
 585 =cut
 586
 587 # For reference, here's an important difference in the data structure we rely on.
 588 # ========================================
 589 # Using attrs instead of {asn}->attributes
 590 # ========================================
 591 #
 592 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 593 #       LDAP key: ->{             cn}->{           sss} = sss
 594 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 595 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 596 #
 597 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 598 #       LDAP key: ->{      givenname}->{Steve} = Steve
 599 #