C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members::Attributes;
  27 use C4::Members::AttributeTypes;
  28 use C4::Members::Messaging;
  29 use C4::Auth qw(checkpw_internal);
  30 use Koha::Patrons;
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40         @ISA    = qw(Exporter);
  41         @EXPORT = qw( checkpw_ldap );
  42 }
  43
  44 # Redefine checkpw_ldap:
  45 # connect to LDAP (named or anonymous)
  46 # ~ retrieves $userid from KOHA_CONF mapping
  47 # ~ then compares $password with userPassword
  48 # ~ then gets the LDAP entry
  49 # ~ and calls the memberadd if necessary
  50
  51 sub ldapserver_error {
  52         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  53 }
  54
  55 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  56 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  57 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  58 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  59 my $base      = $ldap->{base}           or die ldapserver_error('base');
  60 $ldapname     = $ldap->{user}           ;
  61 $ldappassword = $ldap->{pass}           ;
  62 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  63 my @mapkeys = keys %mapping;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  65 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  66 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  67
  68 my %categorycode_conversions;
  69 my $default_categorycode;
  70 if(defined $ldap->{categorycode_mapping}) {
  71     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  72     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  73         $categorycode_conversions{$cat->{value}} = $cat->{content};
  74     }
  75 }
  76
  77 my %config = (
  78     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  79     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  80        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  81 );
  82
  83 sub description {
  84         my $result = shift or return;
  85         return "LDAP error #" . $result->code
  86                         . ": " . $result->error_name . "\n"
  87                         . "# " . $result->error_text . "\n";
  88 }
  89
  90 sub search_method {
  91     my $db     = shift or return;
  92     my $userid = shift or return;
  93         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  94         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  95         my $search = $db->search(
  96                   base => $base,
  97                 filter => $filter,
  98                 # attrs => ['*'],
  99     );
 100     die "LDAP search failed to return object : " . $search->error if $search->code;
 101
 102         my $count = $search->count;
 103         if ($search->code > 0) {
 104                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 105                 return 0;
 106         }
 107     if ($count == 0) {
 108         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 109         return 0;
 110     }
 111     return $search;
 112 }
 113
 114 sub checkpw_ldap {
 115     my ($dbh, $userid, $password) = @_;
 116     my @hosts = split(',', $prefhost);
 117     my $db = Net::LDAP->new(\@hosts);
 118     unless ( $db ) {
 119         warn "LDAP connexion failed";
 120         return 0;
 121     }
 122
 123         #$debug and $db->debug(5);
 124     my $userldapentry;
 125
 126     # first, LDAP authentication
 127     if ( $ldap->{auth_by_bind} ) {
 128         my $principal_name;
 129         if ( $config{anonymous} ) {
 130
 131             # Perform an anonymous bind
 132             my $res = $db->bind;
 133             if ( $res->code ) {
 134                 warn "Anonymous LDAP bind failed: " . description($res);
 135                 return 0;
 136             }
 137
 138             # Perform a LDAP search for the given username
 139             my $search = search_method( $db, $userid )
 140               or return 0;    # warnings are in the sub
 141             $userldapentry = $search->shift_entry;
 142             $principal_name = $userldapentry->dn;
 143         }
 144         else {
 145             $principal_name = $ldap->{principal_name};
 146             if ( $principal_name and $principal_name =~ /\%/ ) {
 147                 $principal_name = sprintf( $principal_name, $userid );
 148             }
 149             else {
 150                 $principal_name = $userid;
 151             }
 152         }
 153
 154         # Perform a LDAP bind for the given username using the matched DN
 155         my $res = $db->bind( $principal_name, password => $password );
 156         if ( $res->code ) {
 157             if ( $config{anonymous} ) {
 158                 # With anonymous_bind approach we can be sure we have found the correct user
 159                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 160                 # or password changed). We should not fall back to local accounts in this case.
 161                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 162                 return -1;
 163             } else {
 164                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 165                 # at all, and thus we should fall back to local logins to restore previous behaviour
 166                 # see bug 12831
 167                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 168                 return 0;
 169             }
 170         }
 171         if ( !defined($userldapentry)
 172             && ( $config{update} or $config{replicate} ) )
 173         {
 174             my $search = search_method( $db, $userid ) or return 0;
 175             $userldapentry = $search->shift_entry;
 176         }
 177     } else {
 178         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 179                 if ($res->code) {               # connection refused
 180                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 181                         return 0;
 182                 }
 183         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 184         # Handle multiple branches. Same login exists several times in different branches.
 185         my $bind_ok = 0;
 186         while (my $entry = $search->shift_entry) {
 187             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 188             unless ($user_ldap_bind_ret->code) {
 189                 $userldapentry = $entry;
 190                 $bind_ok = 1;
 191                 last;
 192             }
 193         }
 194
 195         unless ($bind_ok) {
 196             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 197             return -1;
 198         }
 199
 200
 201     }
 202
 203     # To get here, LDAP has accepted our user's login attempt.
 204     # But we still have work to do.  See perldoc below for detailed breakdown.
 205
 206     my (%borrower);
 207         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 208
 209     if (( $borrowernumber and $config{update}   ) or
 210         (!$borrowernumber and $config{replicate})   ) {
 211         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 212         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 213     }
 214
 215     if ($borrowernumber) {
 216         if ($config{update}) { # A1, B1
 217             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 218             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 219         } else { # C1, D1
 220             # maybe update just the password?
 221                 return(1, $cardnumber, $local_userid);
 222         }
 223     } elsif ($config{replicate}) { # A2, C2
 224         my @columns = Koha::Patrons->columns;
 225         my $patron = Koha::Patron->new(
 226             map {
 227                 grep join( ' ', @columns ) =~ /$_/
 228                   ? ( $_ => $data{$_} )
 229                   : ()
 230             } keys %borrower
 231         )->store;
 232         die "Insert of new patron failed" unless $patron;
 233         $borrowernumber = $patron->borrowernumber;
 234         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 235    } else {
 236         return 0;   # B2, D2
 237     }
 238     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 239         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 240             my $code = $attribute_type->{code};
 241             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 242                 next;
 243             }
 244             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 245                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, attribute => $borrower{$code}});
 246             } else {
 247                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 248             }
 249         }
 250     }
 251     return(1, $cardnumber, $userid);
 252 }
 253
 254 # Pass LDAP entry object and local cardnumber (userid).
 255 # Returns borrower hash.
 256 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 257 # Ensure that mandatory fields are correctly filled!
 258 #
 259 sub ldap_entry_2_hash {
 260         my $userldapentry = shift;
 261         my %borrower = ( cardnumber => shift );
 262         my %memberhash;
 263         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 264         if ($debug) {
 265                 foreach (keys %$userldapentry) {
 266                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 267                 }
 268         }
 269         my $x = $userldapentry->{attrs} or return;
 270         foreach (keys %$x) {
 271                 $memberhash{$_} = join ' ', @{$x->{$_}};
 272                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 273         }
 274         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 275                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 276         foreach my $key (keys %mapping) {
 277                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 278                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 279                 unless (defined $data) {
 280                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 281                 }
 282                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 283         }
 284         $borrower{initials} = $memberhash{initials} ||
 285                 ( substr($borrower{'firstname'},0,1)
 286                 . substr($borrower{ 'surname' },0,1)
 287                 . " ");
 288
 289     # categorycode conversions
 290     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 291         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 292     }
 293     elsif($default_categorycode) {
 294         $borrower{categorycode} = $default_categorycode;
 295     }
 296
 297         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 298         my $dbh = C4::Context->dbh;
 299         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 300         $sth->execute( uc($borrower{'categorycode'}) );
 301         unless ( my $row = $sth->fetchrow_hashref ) {
 302                 my $default = $mapping{'categorycode'}->{content};
 303                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 304                 $borrower{'categorycode'} = $default
 305         }
 306
 307         return %borrower;
 308 }
 309
 310 sub exists_local {
 311         my $arg = shift;
 312         my $dbh = C4::Context->dbh;
 313         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 314
 315         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 316         $sth->execute($arg);
 317         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 318         ($sth->rows == 1) and return $sth->fetchrow;
 319
 320         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 321         $sth->execute($arg);
 322         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 323         ($sth->rows == 1) and return $sth->fetchrow;
 324         return 0;
 325 }
 326
 327 # This function performs a password update, given the userid, borrowerid,
 328 # and digested password. It will verify that things are correct and return the
 329 # borrowers cardnumber. The idea is that it is used to keep the local
 330 # passwords in sync with the LDAP passwords.
 331 #
 332 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 333 #
 334 # Note: if the LDAP config has the update_password tag set to a false value,
 335 # then this will not update the password, it will simply return the cardnumber.
 336 sub _do_changepassword {
 337     my ($userid, $borrowerid, $password) = @_;
 338
 339     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 340
 341         # We don't store the password in the database
 342         my $sth = C4::Context->dbh->prepare(
 343             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 344         $sth->execute($borrowerid);
 345         die "Unable to access borrowernumber "
 346             . "with userid=$userid, "
 347             . "borrowernumber=$borrowerid"
 348           if !$sth->rows;
 349         my ($cardnum) = $sth->fetchrow;
 350         $sth = C4::Context->dbh->prepare(
 351             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 352         $sth->execute($borrowerid);
 353         return $cardnum;
 354     }
 355
 356     my $digest = hash_password($password);
 357     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 358     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 359
 360     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 361     return $cardnum if $ok;
 362
 363     warn "Password mismatch after update to borrowernumber=$borrowerid";
 364     return;
 365 }
 366
 367 sub update_local {
 368     my $userid     = shift or croak "No userid";
 369     my $password   = shift or croak "No password";
 370     my $borrowerid = shift or croak "No borrowerid";
 371     my $borrower   = shift or croak "No borrower record";
 372
 373     # skip extended patron attributes in 'borrowers' attribute update
 374     my @keys = keys %$borrower;
 375     if (C4::Context->preference('ExtendedPatronAttributes')) {
 376         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 377            my $code = $attribute_type->{code};
 378            @keys = grep { $_ ne $code } @keys;
 379            $debug and printf STDERR "ignoring extended patron attribute '%s' in update_local()\n", $code;
 380         }
 381     }
 382
 383     my $dbh = C4::Context->dbh;
 384     my $query = "UPDATE  borrowers\nSET     " .
 385         join(',', map {"$_=?"} @keys) .
 386         "\nWHERE   borrowernumber=? ";
 387     my $sth = $dbh->prepare($query);
 388     if ($debug) {
 389         print STDERR $query, "\n",
 390             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 391         print STDERR "\nuserid = $userid\n";
 392     }
 393     $sth->execute(
 394         ((map {$borrower->{$_}} @keys), $borrowerid)
 395     );
 396
 397     # MODIFY PASSWORD/LOGIN if password was mapped
 398     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 399 }
 400
 401 1;
 402 __END__
 403
 404 =head1 NAME
 405
 406 C4::Auth - Authenticates Koha users
 407
 408 =head1 SYNOPSIS
 409
 410   use C4::Auth_with_ldap;
 411
 412 =head1 LDAP Configuration
 413
 414     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 415         working LDAP servers.
 416         To use it :
 417            * Modify ldapserver element in KOHA_CONF
 418            * Establish field mapping in <mapping> element.
 419
 420         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 421         the username would match the "uid" field, and the password should match the "userpassword" field.
 422
 423         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 424         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 425
 426         mysql> show COLUMNS from borrowers;
 427                 +---------------------+--------------+------+-----+---------+----------------+
 428                 | Field               | Type         | Null | Key | Default | Extra          |
 429                 +---------------------+--------------+------+-----+---------+----------------+
 430                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 431                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 432                 | surname             | mediumtext   | NO   |     | NULL    |                |
 433                 | firstname           | text         | YES  |     | NULL    |                |
 434                 | title               | mediumtext   | YES  |     | NULL    |                |
 435                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 436                 | initials            | text         | YES  |     | NULL    |                |
 437                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 438                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 439                 | address             | mediumtext   | NO   |     | NULL    |                |
 440                 | address2            | text         | YES  |     | NULL    |                |
 441                 | city                | mediumtext   | NO   |     | NULL    |                |
 442                 | state               | mediumtext   | YES  |     | NULL    |                |
 443                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 444                 | country             | text         | YES  |     | NULL    |                |
 445                 | email               | mediumtext   | YES  |     | NULL    |                |
 446                 | phone               | text         | YES  |     | NULL    |                |
 447                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 448                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 449                 | emailpro            | text         | YES  |     | NULL    |                |
 450                 | phonepro            | text         | YES  |     | NULL    |                |
 451                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 452                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 453                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 454                 | B_address2          | text         | YES  |     | NULL    |                |
 455                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 456                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 457                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 458                 | B_country           | text         | YES  |     | NULL    |                |
 459                 | B_email             | text         | YES  |     | NULL    |                |
 460                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 461                 | dateofbirth         | date         | YES  |     | NULL    |                |
 462                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 463                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 464                 | dateenrolled        | date         | YES  |     | NULL    |                |
 465                 | dateexpiry          | date         | YES  |     | NULL    |                |
 466                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 467                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 468                 | debarred            | date         | YES  |     | NULL    |                |
 469                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 470                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 471                 | contactfirstname    | text         | YES  |     | NULL    |                |
 472                 | contacttitle        | text         | YES  |     | NULL    |                |
 473                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 474                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 475                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 476                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 477                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 478                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 479                 | password            | varchar(30)  | YES  |     | NULL    |                |
 480                 | flags               | int(11)      | YES  |     | NULL    |                |
 481                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 482                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 483                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 484                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 485                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 486                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 487                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 488                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 489                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 490                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 491                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 492                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 493                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 494                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 495                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 496                 | privacy             | int(11)      | NO   |     | 1       |                |
 497                 +---------------------+--------------+------+-----+---------+----------------+
 498                 66 rows in set (0.00 sec)
 499                 Where Null="NO", the field is required.
 500
 501 =head1 KOHA_CONF and field mapping
 502
 503 Example XML stanza for LDAP configuration in KOHA_CONF.
 504
 505  <config>
 506   ...
 507   <useldapserver>1</useldapserver>
 508   <!-- LDAP SERVER (optional) -->
 509   <ldapserver id="ldapserver">
 510     <hostname>localhost</hostname>
 511     <base>dc=metavore,dc=com</base>
 512     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 513     <pass>metavore</pass>          <!-- password, if not anonymous -->
 514     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 515     <update>1</update>             <!-- update existing users in Koha database -->
 516     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 517                                         password comparison, e.g., to use Active Directory -->
 518     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 519                                             an anonymous bind, even when auth_by_bind is on -->
 520     <principal_name>%s@my_domain.com</principal_name>
 521                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 522                                         Not used with anonymous_bind. -->
 523     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 524                                               synced to the local database -->
 525     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 526       <firstname    is="givenname"      ></firstname>
 527       <surname      is="sn"             ></surname>
 528       <address      is="postaladdress"  ></address>
 529       <city         is="l"              >Athens, OH</city>
 530       <zipcode      is="postalcode"     ></zipcode>
 531       <branchcode   is="branch"         >MAIN</branchcode>
 532       <userid       is="uid"            ></userid>
 533       <password     is="userpassword"   ></password>
 534       <email        is="mail"           ></email>
 535       <categorycode is="employeetype"   >PT</categorycode>
 536       <phone        is="telephonenumber"></phone>
 537     </mapping>
 538   </ldapserver>
 539  </config>
 540
 541 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 542 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 543 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 544 patron).
 545
 546 =head1 CONFIGURATION
 547
 548 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 549 your configuration and the presence of a matching Koha user in your local DB:
 550
 551                          LOCAL_USER
 552  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 553    A1      1       1        1      OK : We're updating them anyway.
 554    A2      1       1        0      OK : We're adding them anyway.
 555    B1      1       0        1      OK : We update them.
 556    B2      1       0        0     FAIL: We cannot add new user.
 557    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 558    C2      0       1        0      OK : We add the new user.
 559    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 560    D2      0       0        0     FAIL: We cannot add new user.
 561
 562 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 563 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 564 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 565
 566 If you choose NOT to update local users, the borrowers table will not be affected at all.
 567 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 568 the local table never contained the LDAP values.
 569
 570 =head2 auth_by_bind
 571
 572 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 573
 574 =head2 principal_name
 575
 576 Provides an optional sprintf-style format for manipulating the userid before the bind.
 577 Even though the userPrincipalName is one intended target, any uniquely identifying
 578 attribute that the server allows to be used for binding could be used.
 579
 580 Currently, principal_name only operates when auth_by_bind is enabled.
 581
 582 =head2 update_password
 583
 584 If this tag is left out or set to a true value, then the user's LDAP password
 585 will be stored (hashed) in the local Koha database. If you don't want this
 586 to happen, then set the value of this to '0'. Note that if passwords are not
 587 stored locally, and the connection to the LDAP system fails, then the users
 588 will not be able to log in at all.
 589
 590 =head2 Active Directory
 591
 592 The auth_by_bind and principal_name settings are recommended for Active Directory.
 593
 594 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 595 we would typically under openldap.  Instead of:
 596
 597     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 598
 599 We might get:
 600
 601     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 602
 603 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 604 in Koha userids.  But the userPrincipalName should be consistent, something like:
 605
 606     userPrincipalName: barnes.7@my_company.com
 607
 608 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 609 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 610 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 611 like this:
 612     <principal_name>%s@core.my_company.com</principal_name>
 613
 614 The user of the previous example, barnes.7, would then attempt to bind as:
 615     barnes.7@core.my_company.com
 616
 617 =head1 SEE ALSO
 618
 619 CGI(3)
 620
 621 Net::LDAP()
 622
 623 XML::Simple()
 624
 625 Digest::MD5(3)
 626
 627 sprintf()
 628
 629 =cut
 630
 631 # For reference, here's an important difference in the data structure we rely on.
 632 # ========================================
 633 # Using attrs instead of {asn}->attributes
 634 # ========================================
 635 #
 636 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 637 #       LDAP key: ->{             cn}->{           sss} = sss
 638 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 639 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 640 #
 641 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 642 #       LDAP key: ->{      givenname}->{Steve} = Steve
 643 #